meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 meson.add_dist_script('scripts/save-tarball-version.sh', meson.project_version())
   8
   9 pa_version_str = meson.project_version()
  10 # For tarballs, the first split will do nothing, but for builds in git, we
  11 # split out suffixes when there are commits since the last tag
  12 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  13 version_split = pa_version_str.split('-')[0].split('.')
  14 pa_version_major = version_split[0].split('v')[0]
  15 pa_version_minor = version_split[1]
  16 if version_split.length() > 2
  17   pa_version_micro = version_split[2]
  18 else
  19   pa_version_micro = '0'
  20 endif
  21 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  22
  23 pa_api_version = 12
  24 pa_protocol_version = 35
  25
  26 # The stable ABI for client applications, for the version info x:y:z
  27 # always will hold x=z
  28 libpulse_version_info = [24, 0, 24]
  29
  30 # A simplified, synchronous, ABI-stable interface for client
  31 # applications, for the version info x:y:z always will hold x=z
  32 libpulse_simple_version_info = [1, 1, 1]
  33
  34 # The ABI-stable GLib adapter for client applications, for the version
  35 # info x:y:z always will hold x=z
  36 libpulse_mainloop_glib_version_info = [0, 6, 0]
  37
  38 libpulse_version = '@0@.@1@.@2@'.format(
  39   libpulse_version_info[0] - libpulse_version_info[2],
  40   libpulse_version_info[0],
  41   libpulse_version_info[1],
  42 )
  43
  44 libpulse_simple_version = '@0@.@1@.@2@'.format(
  45   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  46   libpulse_simple_version_info[0],
  47   libpulse_simple_version_info[1],
  48 )
  49
  50 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  51   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  52   libpulse_mainloop_glib_version_info[0],
  53   libpulse_mainloop_glib_version_info[1],
  54 )
  55
  56 # Paths
  57
  58 prefix = get_option('prefix')
  59 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  60
  61 bindir = join_paths(prefix, get_option('bindir'))
  62 includedir = join_paths(prefix, get_option('includedir'))
  63 libdir = join_paths(prefix, get_option('libdir'))
  64 libexecdir = join_paths(prefix, get_option('libexecdir'))
  65 mandir = join_paths(prefix, get_option('mandir'))
  66 #datadir = join_paths(prefix, get_option('datadir'))
  67 #FIXME: meson.build:1:0: ERROR: The value of the 'datadir' option is '/hal/share' which must be a subdir of the prefix '/usr'.
  68 datadir = get_option('hal-datadir')
  69 localedir = join_paths(prefix, get_option('localedir'))
  70 localstatedir = join_paths(prefix, get_option('localstatedir'))
  71 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  72 privlibdir = join_paths(libdir, 'pulseaudio')
  73
  74 if host_machine.system() == 'windows'
  75   # Windows only supports loading libraries from the same dir as the executable
  76   privlibdir = bindir
  77 endif
  78
  79 alsadatadir = get_option('alsadatadir')
  80 if alsadatadir == ''
  81   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  82 endif
  83
  84 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  85 pulselibexecdir = join_paths(libexecdir, 'pulse')
  86 #pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  87 pulsesysconfdir = join_paths(get_option('hal-sysconfdir'), 'pulse')
  88
  89 modlibexecdir = get_option('modlibexecdir')
  90 if modlibexecdir == ''
  91   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  92 endif
  93
  94 padsplibdir = get_option('padsplibdir')
  95 if padsplibdir == ''
  96   padsplibdir = privlibdir
  97 endif
  98
  99 pulsedsp_location = get_option('pulsedsp-location')
 100 if pulsedsp_location == ''
 101   pulsedsp_location = join_paths(prefix, padsplibdir)
 102 endif
 103
 104 systemduserunitdir = get_option('systemduserunitdir')
 105 systemdsystemunitdir = get_option('systemdsystemunitdir')
 106 # the default value is set below
 107
 108 udevrulesdir = get_option('udevrulesdir')
 109 if udevrulesdir == ''
 110   # absolute path, otherwise meson prepends the prefix
 111   udevrulesdir = '/lib/udev/rules.d'
 112 endif
 113
 114 vapidir = join_paths(datadir, 'vala', 'vapi')
 115
 116 bashcompletiondir = get_option('bashcompletiondir')
 117 if bashcompletiondir == ''
 118   bash_completion_dep = dependency('bash-completion', required : false)
 119   if bash_completion_dep.found()
 120     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 121   else
 122     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 123   endif
 124 endif
 125
 126 zshcompletiondir = get_option('zshcompletiondir')
 127 if zshcompletiondir == ''
 128   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 129 endif
 130
 131 # Configuration data
 132
 133 cc = meson.get_compiler('c')
 134
 135 cdata = configuration_data()
 136 cdata.set_quoted('PACKAGE', 'pulseaudio')
 137 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 138 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 139 cdata.set('PA_MAJOR', pa_version_major)
 140 cdata.set('PA_MINOR', pa_version_minor)
 141 cdata.set('PA_API_VERSION', pa_api_version)
 142 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 143 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 144 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 145 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 146 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 147 cdata.set_quoted('PA_SOEXT', '.so')
 148 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 149 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 150 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 151 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 152 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 153 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 154 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 155 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 156 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 157 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 158 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 159 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 160 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 161 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 162 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 163 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 164 cdata.set('ENABLE_NLS', 1)
 165 cdata.set('top_srcdir', meson.source_root())
 166
 167 # Platform specifics
 168 # First some defaults to keep config file generation happy
 169 cdata.set('HAVE_COREAUDIO', 0)
 170 cdata.set('HAVE_WAVEOUT', 0)
 171 cdata.set('OS_IS_FREEBSD', 0)
 172
 173 platform_socket_dep = []
 174 platform_dep = []
 175
 176 if host_machine.endian() == 'big'
 177   cdata.set('WORDS_BIGENDIAN', 1)
 178 endif
 179
 180 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 181 # rather than ending up in the config.h file?
 182 if host_machine.system() == 'darwin'
 183   cdata.set('OS_IS_DARWIN', 1)
 184   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 185 elif host_machine.system() == 'windows'
 186   cdata.set('OS_IS_WIN32', 1)
 187   cdata.set('HAVE_WINDOWS_H', 1)
 188   cdata.set('HAVE_WAVEOUT', 1)
 189   cdata.set('HAVE_WINSOCK2_H', 1)
 190   cdata.set('HAVE_WS2TCPIP_H', 1)
 191   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 192   cdata.set('gid_t', 'int')
 193   cdata.set('uid_t', 'int')
 194   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 195   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 196   ole32_dep = meson.get_compiler('c').find_library('ole32')
 197   ssp_dep = meson.get_compiler('c').find_library('ssp')
 198   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 199   platform_socket_dep = [ws2_32_dep, winsock_dep]
 200   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 201 elif host_machine.system() == 'freebsd'
 202   cdata.set('OS_IS_FREEBSD', 1)
 203 #elif host_machine.system() == 'solaris'
 204 #  # Apparently meson has no solaris support?
 205 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 206 #  cdata.set('_XOPEN_SOURCE', 600)
 207 #  cdata.set('__EXTENSIONS__', 1)
 208 endif
 209
 210 if cc.has_type('_Bool')
 211   cdata.set('HAVE_STD_BOOL', 1)
 212 endif
 213
 214 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 215   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 216 endif
 217
 218 # Headers
 219
 220 check_headers = [
 221   'arpa/inet.h',
 222   'byteswap.h',
 223   'cpuid.h',
 224   'dlfcn.h',
 225   'execinfo.h',
 226   'grp.h',
 227   'langinfo.h',
 228   'linux/sockios.h',
 229   'locale.h',
 230   'netdb.h',
 231   'netinet/in.h',
 232   'netinet/in_systm.h',
 233   'netinet/ip.h',
 234   'netinet/tcp.h',
 235   'pcreposix.h',
 236   'poll.h',
 237   'pwd.h',
 238   'regex.h',
 239   'sched.h',
 240   'stdint.h',
 241   'sys/atomic.h',
 242   'sys/capability.h',
 243   'sys/conf.h',
 244   'sys/dl.h',
 245   'sys/eventfd.h',
 246   'sys/filio.h',
 247   'sys/ioctl.h',
 248   'sys/mman.h',
 249   'sys/prctl.h',
 250   'sys/resource.h',
 251   'sys/select.h',
 252   'sys/socket.h',
 253   'sys/syscall.h',
 254   'sys/uio.h',
 255   'sys/un.h',
 256   'sys/wait.h',
 257   'syslog.h',
 258   'xlocale.h',
 259 ]
 260
 261 foreach h : check_headers
 262   if cc.has_header(h)
 263     define = 'HAVE_' + h.underscorify().to_upper()
 264     cdata.set(define, 1)
 265   endif
 266 endforeach
 267
 268 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 269   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 270 endif
 271
 272 # FIXME: move this to the above set
 273 if host_machine.system() != 'windows'
 274   if cc.has_header('pthread.h')
 275     cdata.set('HAVE_PTHREAD', 1)
 276   endif
 277 endif
 278
 279 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 280   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 281 endif
 282
 283 # Functions
 284
 285 check_functions = [
 286   'accept4',
 287   'clock_gettime',
 288   'ctime_r',
 289   'fchmod',
 290   'fchown',
 291   'fork',
 292   'fstat',
 293   'getaddrinfo',
 294   'getgrgid_r',
 295   'getgrnam_r',
 296   'getpwnam_r',
 297   'getpwuid_r',
 298   'gettimeofday',
 299   'getuid',
 300   'lrintf',
 301   'lstat',
 302   'memfd_create',
 303   'mkfifo',
 304   'mlock',
 305   'nanosleep',
 306   'open64',
 307   'paccept',
 308   'pipe',
 309   'pipe2',
 310   'posix_fadvise',
 311   'posix_madvise',
 312   'posix_memalign',
 313   'ppoll',
 314   'readlink',
 315   'setegid',
 316   'seteuid',
 317   'setpgid',
 318   'setregid',
 319   'setresgid',
 320   'setresuid',
 321   'setreuid',
 322   'setsid',
 323   'sig2str',
 324   'sigaction',
 325   'strerror_r',
 326   'strtod_l',
 327   'strtof',
 328   'symlink',
 329   'sysconf',
 330   'uname',
 331 ]
 332
 333 foreach f : check_functions
 334   if cc.has_function(f)
 335     define = 'HAVE_' + f.underscorify().to_upper()
 336
 337     if f == 'posix_memalign' and host_machine.system() == 'windows'
 338       message('Win32/mingw32 does not properly define posix_memalign.')
 339     elif f == 'fork' and host_machine.system() == 'windows'
 340       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 341       # This causes Meson to think that Windows has a fork() which causes a link error...
 342       message('Win32/mingw32 does not properly define fork.')
 343     else
 344       cdata.set(define, 1)
 345     endif
 346   endif
 347 endforeach
 348
 349 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create') \
 350   or cc.has_function('memfd_create')
 351   cdata.set('HAVE_MEMFD', 1)
 352 endif
 353
 354 if cc.has_function('dgettext')
 355   if host_machine.system() != 'windows'
 356     libintl_dep = []
 357   else
 358     libintl_dep = cc.find_library('intl')
 359   endif
 360 else
 361   libintl_dep = cc.find_library('intl')
 362 endif
 363
 364 # Symbols
 365
 366 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 367   cdata.set('HAVE_SIGXCPU', 1)
 368 endif
 369
 370 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 371   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 372     # Define INADDR_NONE if not found (Solaris)
 373     cdata.set('INADDR_NONE', '0xffffffff')
 374   endif
 375 endif
 376
 377 check_decls = [
 378   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 379   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 380   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 381   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 382 ]
 383
 384 foreach s : check_decls
 385   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 386     define = 'HAVE_DECL_' + s[0].to_upper()
 387     cdata.set(define, 1)
 388   endif
 389 endforeach
 390
 391 # Types
 392
 393 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 394 cdata.set('GETGROUPS_T', 'gid_t')
 395
 396 # Include paths
 397
 398 configinc = include_directories('.')
 399 topinc = include_directories('src')
 400
 401 # CFLAGS/LDFLAGS
 402
 403 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 404 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 405 cdata.set('MESON_BUILD', 1)
 406
 407 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 408 # so we request the nodelete flag to be enabled.
 409 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 410 # Windows doesn't support this flag.
 411 if host_machine.system() != 'windows'
 412   nodelete_link_args = ['-Wl,-z,nodelete']
 413 else
 414   nodelete_link_args = []
 415 endif
 416
 417 # Code coverage
 418
 419 if get_option('gcov')
 420   add_project_arguments('--coverage', language: ['c', 'cpp'])
 421   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 422 endif
 423
 424 # Core Dependencies
 425
 426 libm_dep = cc.find_library('m', required : true)
 427
 428 thread_dep = dependency('threads')
 429 foreach f : [
 430   'pthread_getname_np',
 431   'pthread_setaffinity_np',
 432   'pthread_setname_np',
 433 ]
 434   if cc.has_function(f, dependencies : thread_dep)
 435     define = 'HAVE_' + f.underscorify().to_upper()
 436     cdata.set(define, 1)
 437   endif
 438 endforeach
 439
 440 cap_dep = cc.find_library('cap', required : false)
 441
 442 shm_dep = cc.find_library('rt', required : false)
 443 if cc.has_function('shm_open', dependencies : shm_dep)
 444   cdata.set('HAVE_SHM_OPEN', 1)
 445 endif
 446
 447 dl_dep = cc.find_library('dl', required : false)
 448 if cc.has_function('dladdr', dependencies : dl_dep)
 449   cdata.set('HAVE_DLADDR', 1)
 450 endif
 451
 452 have_iconv = false
 453 if cc.has_function('iconv_open')
 454   iconv_dep = dependency('', required : false)
 455   have_iconv = true
 456   # tell the libiconv header to pretend to be libc iconv
 457   cdata.set('LIBICONV_PLUG', 1)
 458 else
 459   iconv_dep = cc.find_library('iconv', required : false)
 460   have_iconv = iconv_dep.found()
 461 endif
 462 if have_iconv
 463   cdata.set('HAVE_ICONV', 1)
 464   iconvconsttest = '''#include <iconv.h>
 465 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 466 '''
 467   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 468     cdata.set('ICONV_CONST', '')
 469   else
 470     cdata.set('ICONV_CONST', 'const')
 471   endif
 472 endif
 473
 474 # Used for backtraces on BSD
 475 execinfo_dep = cc.find_library('execinfo', required : false)
 476
 477 # Atomic operations
 478
 479 if get_option('atomic-arm-memory-barrier')
 480     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 481 endif
 482
 483 need_libatomic_ops = false
 484
 485 atomictest = '''void func() {
 486   volatile int atomic = 2;
 487   __sync_bool_compare_and_swap (&atomic, 2, 3);
 488 }
 489 '''
 490
 491 if cc.compiles(atomictest)
 492   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 493
 494   newatomictest = '''void func() {
 495     int c = 0;
 496     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 497   }
 498   '''
 499
 500   if(cc.compiles(newatomictest))
 501     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 502   endif
 503
 504 elif host_machine.cpu_family() == 'arm'
 505   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 506     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 507   else
 508     armatomictest = '''int func() {
 509       volatile int a=0;
 510       int o=0, n=1, r;
 511       asm volatile (
 512               "ldrex    %0, [%1]\n"
 513               "subs  %0, %0, %2\n"
 514               "strexeq %0, %3, [%1]\n"
 515               : "=&r" (r)
 516               : "r" (&a), "Ir" (o), "r" (n)
 517       : "cc");
 518       return (a==1 ? 0 : -1);
 519     }
 520     '''
 521
 522     if cc.compiles(armatomictest)
 523       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 524     else
 525       need_libatomic_ops = true
 526     endif
 527   endif # arm && !linux
 528
 529 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 530   need_libatomic_ops = true
 531 endif # !atomic helpers && !arm
 532
 533 if need_libatomic_ops
 534   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 535
 536   cdata.set('AO_REQUIRE_CAS', 1)
 537
 538   if host_machine.system() != 'windows'
 539     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 540   else
 541     libatomic_ops_dep = dependency('', required: false)
 542   endif
 543 else
 544   libatomic_ops_dep = dependency('', required: false)
 545 endif
 546
 547 # ARM checks
 548 # ARMV6 instructions we need
 549 if host_machine.cpu_family() == 'arm'
 550   armv6test = '''int func() {
 551     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 552     asm volatile ("ldr r0, %2 \n"
 553                   "ldr r2, %3 \n"
 554                   "ldr r3, %4 \n"
 555                   "ssat r1, #8, r0 \n"
 556                   "str r1, %0 \n"
 557                   "pkhbt r1, r3, r2, LSL #8 \n"
 558                   "str r1, %1 \n"
 559                   : "=m" (a), "=m" (b)
 560                   : "m" (a), "m" (b), "m" (c)
 561                   : "r0", "r1", "r2", "r3", "cc");
 562     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 563   }
 564   '''
 565
 566   if cc.compiles(armv6test)
 567     cdata.set('HAVE_ARMV6', 1)
 568   endif
 569 endif
 570 # NEON checks are automatically done by the unstable-simd module
 571
 572 if get_option('daemon')
 573   # FIXME: make sure it's >= 2.2
 574   ltdl_dep = cc.find_library('ltdl', required : true)
 575 endif
 576
 577 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 578 #        and do we still want to support this at all?
 579 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 580
 581 if get_option('database') == 'tdb'
 582   database_dep = dependency('tdb')
 583 elif get_option('database') == 'gdbm'
 584   database_dep = cc.find_library('gdbm', required : true)
 585 else
 586   database_dep = dependency('', required: false)
 587 endif
 588
 589 # TIZEN BUILD OPTION
 590 vconf_dep = dependency('vconf')
 591 if vconf_dep.found()
 592   cdata.set('HAVE_VCONF', 1)
 593 endif
 594
 595 dlog_dep = dependency('dlog', required : get_option('dlog'))
 596 if dlog_dep.found()
 597   cdata.set('TIZEN_DLOG', 1)
 598 endif
 599
 600 if get_option('buffer-attribute')
 601   cdata.set('TIZEN_BUFFER_ATTR', 1)
 602 endif
 603
 604 if get_option('udev-usb-only')
 605   cdata.set('TIZEN_UDEV_USB_ONLY', 1)
 606 endif
 607
 608 if get_option('pcm-dump')
 609   cdata.set('TIZEN_PCM_DUMP', 1)
 610 endif
 611
 612 if get_option('udev-usb-only')
 613   cdata.set('TIZEN_UDEV_USB_ONLY', 1)
 614 endif
 615
 616 if get_option('pa-ready')
 617   cdata.set('TIZEN_PA_READY', 1)
 618 endif
 619
 620 if get_option('pa-simple-extensions')
 621   cdata.set('TIZEN_PA_SIMPLE_EXT', 1)
 622 endif
 623
 624 if get_option('empty-pop')
 625   cdata.set('TIZEN_EMPTY_POP', 1)
 626 endif
 627
 628 if get_option('volume-ramp')
 629   cdata.set('TIZEN_VOLUME_RAMP', 1)
 630 endif
 631
 632 if get_option('individual-volume-ratio')
 633   cdata.set('TIZEN_INDIVIDUAL_VOLUME_RATIO', 1)
 634 endif
 635
 636 if get_option('filter-group')
 637   cdata.set('TIZEN_FILTER_GROUP', 1)
 638 endif
 639
 640 if get_option('prelink')
 641   cdata.set('TIZEN_TV_PROD_PRELINK', 1)
 642 endif
 643
 644 if get_option('cpu-boosting')
 645   cdata.set('TIZEN_TV_PROD_CPU_BOOSTING', 1)
 646 endif
 647
 648 lwipc_dep = dependency('lwipc', required : get_option('lwipc'))
 649 if lwipc_dep.found()
 650   cdata.set('TIZEN_TV_PROD_LWIPC', 1)
 651 endif
 652
 653 boost_tv_dep = dependency('capi-boost-tv', required : get_option('cpu-boosting'))
 654 system_info_dep = dependency('capi-system-info', required : get_option('cpu-boosting'))
 655
 656 if get_option('aec')
 657   cdata.set('TIZEN_AEC', 1)
 658 endif
 659
 660 enable_security = false
 661 cynara_client_dep = dependency('cynara-client', required : get_option('security'))
 662 cynara_creds_socket_dep = dependency('cynara-creds-socket', required : get_option('security'))
 663 cynara_session_dep = dependency('cynara-session', required : get_option('security'))
 664 if cynara_client_dep.found() and cynara_creds_socket_dep.found() and cynara_session_dep.found()
 665   cdata.set('TIZEN_SECURITY', 1)
 666   enable_security = true
 667 endif
 668
 669 # TIZEN BUILD OPTION end
 670
 671 if get_option('ipv6')
 672   cdata.set('HAVE_IPV6', 1)
 673 endif
 674
 675 if get_option('legacy-database-entry-format')
 676   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 677 endif
 678
 679 if get_option('stream-restore-clear-old-devices')
 680   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 681 endif
 682
 683 if get_option('running-from-build-tree')
 684   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 685 endif
 686
 687 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 688 if alsa_dep.found()
 689   cdata.set('HAVE_ALSA', 1)
 690   cdata.set('HAVE_ALSA_UCM', 1)
 691 endif
 692
 693 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 694 if asyncns_dep.found()
 695   cdata.set('HAVE_LIBASYNCNS', 1)
 696 endif
 697
 698 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 699 if dbus_dep.found()
 700   cdata.set('HAVE_DBUS', 1)
 701 endif
 702
 703 gio_dep = dependency('gio-2.0', version : '>= 2.26.0')
 704 if get_option('gsettings').enabled()
 705   assert(gio_dep.found(), 'GSettings support needs glib I/O library (GIO)')
 706   cdata.set('HAVE_GSETTINGS', 1)
 707 else
 708   cdata.set('HAVE_GSETTINGS', 0)
 709 endif
 710
 711 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 712 if glib_dep.found()
 713   cdata.set('HAVE_GLIB', 1)
 714 endif
 715
 716 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 717 if gtk_dep.found()
 718   cdata.set('HAVE_GTK', 1)
 719 endif
 720
 721 have_orcc = false
 722 orcc_args = []
 723 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 724 orcc = find_program('orcc', required : get_option('orc'))
 725 if orc_dep.found() and orcc.found()
 726   have_orcc = true
 727   orcc_args = [orcc]
 728   #orcc_args = [orcc, '--include', 'glib.h']
 729   cdata.set('HAVE_ORC', 1)
 730 else
 731   cdata.set('DISABLE_ORC', 1)
 732 endif
 733
 734 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 735 if samplerate_dep.found()
 736   cdata.set('HAVE_LIBSAMPLERATE', 1)
 737 endif
 738
 739 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 740
 741 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 742 if soxr_dep.found()
 743   cdata.set('HAVE_SOXR', 1)
 744 endif
 745
 746 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 747 if libsystemd_dep.found()
 748   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 749   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 750   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 751 endif
 752 systemd_dep = dependency('systemd', required : get_option('systemd'))
 753 if systemd_dep.found() and systemduserunitdir == ''
 754   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 755 endif
 756 if systemd_dep.found() and systemdsystemunitdir == ''
 757   systemdsystemunitdir = systemd_dep.get_pkgconfig_variable('systemdsystemunitdir')
 758 endif
 759
 760 libelogind_dep = dependency('libelogind', required : get_option('elogind'))
 761 if libelogind_dep.found()
 762   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 763 endif
 764
 765 tcpwrap_dep = cc.find_library('wrap', required: get_option('tcpwrap'))
 766 if cc.has_header('tcpd.h') and cc.has_function('hosts_access', dependencies : tcpwrap_dep)
 767   cdata.set('HAVE_LIBWRAP', 1)
 768 endif
 769
 770 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 771 if x11_dep.found()
 772   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 773   ice_dep  = dependency('ice',  required : true)
 774   sm_dep   = dependency('sm',   required : true)
 775   xtst_dep = dependency('xtst', required : true)
 776   cdata.set('HAVE_X11', 1)
 777   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 778     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 779   endif
 780 endif
 781
 782 # Module dependencies
 783 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 784   cdata.set('HAVE_OSS_OUTPUT', 1)
 785   # OSS wrapper
 786   cdata.set('HAVE_OSS_WRAPPER', 1)
 787   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 788 endif
 789
 790 if get_option('hal-compat')
 791   cdata.set('HAVE_HAL_COMPAT', 1)
 792 endif
 793
 794 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 795 if avahi_dep.found()
 796   cdata.set('HAVE_AVAHI', 1)
 797 else
 798   cdata.set('HAVE_AVAHI', 0)
 799 endif
 800
 801 if get_option('bluez5')
 802   sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 803   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 804   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 805   cdata.set('HAVE_SBC', 1)
 806   cdata.set('HAVE_BLUEZ', 1)
 807   cdata.set('HAVE_BLUEZ_5', 1)
 808   if get_option('bluez5-native-headset')
 809     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 810   endif
 811   if get_option('bluez5-ofono-headset')
 812     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 813   endif
 814 endif
 815
 816 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 817 if fftw_dep.found()
 818   cdata.set('HAVE_FFTW', 1)
 819 endif
 820
 821 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 822 if jack_dep.found()
 823   cdata.set('HAVE_JACK', 1)
 824 endif
 825
 826 lirc_dep = dependency('lirc', required : get_option('lirc'))
 827 if lirc_dep.found()
 828   cdata.set('HAVE_LIRC', 1)
 829 endif
 830
 831 openssl_dep = dependency('openssl3', version : '>= 0.9', required : get_option('openssl'))
 832 if openssl_dep.found()
 833   cdata.set('HAVE_OPENSSL', 1)
 834 endif
 835
 836 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 837 if speex_dep.found()
 838   cdata.set('HAVE_SPEEX', 1)
 839 endif
 840
 841 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 842 if udev_dep.found()
 843   cdata.set('HAVE_UDEV', 1)
 844 endif
 845
 846 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 847 if webrtc_dep.found()
 848   cdata.set('HAVE_WEBRTC', 1)
 849 endif
 850
 851 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 852 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 853 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 854
 855 have_gstreamer = false
 856 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 857   assert(gio_dep.found(), 'GStreamer-based RTP needs glib I/O library (GIO)')
 858   have_gstreamer = true
 859 endif
 860
 861 bluez5_gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('bluez5-gstreamer'))
 862 bluez5_gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('bluez5-gstreamer'))
 863 have_bluez5_gstreamer = false
 864 if bluez5_gst_dep.found() and bluez5_gstapp_dep.found()
 865   have_bluez5_gstreamer = true
 866   cdata.set('HAVE_GSTLDAC', 1)
 867   cdata.set('HAVE_GSTAPTX', 1)
 868 endif
 869
 870 # These are required for the CMake file generation
 871 cdata.set('PA_LIBDIR', libdir)
 872 cdata.set('PA_INCDIR', includedir)
 873 if glib_dep.found()
 874   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 875 endif
 876
 877 # Test dependencies
 878
 879 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 880
 881 # Subdirs
 882
 883 if get_option('doxygen')
 884   subdir('doxygen')
 885 endif
 886 subdir('po')
 887 if get_option('man')
 888   subdir('man')
 889 endif
 890 subdir('shell-completion/bash')
 891 subdir('shell-completion/zsh')
 892 subdir('src')
 893 subdir('vala')
 894
 895 # Now generate config.h from everything above
 896 configure_file(output : 'config.h', configuration : cdata)
 897
 898 # pkg-config files
 899
 900 pc_cdata = configuration_data()
 901
 902 pc_cdata.set('prefix', prefix)
 903 pc_cdata.set('exec_prefix', prefix)
 904 pc_cdata.set('libdir', libdir)
 905 pc_cdata.set('includedir', includedir)
 906 pc_cdata.set('modlibexecdir', modlibexecdir)
 907 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 908 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 909 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 910 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 911 # get_configtool_variable() work with it, so we have no way to get this flag right,
 912 # unless we do all the work ourselves. See current work in glib, also meson #553.
 913 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 914 pc_cdata.set('PA_DEFAULT_CONFIG_DIR', cdata.get_unquoted('PA_DEFAULT_CONFIG_DIR'))
 915
 916 pc_files = [
 917   'libpulse.pc',
 918   'libpulse-simple.pc',
 919   'pulsecore.pc',
 920 ]
 921
 922 if glib_dep.found()
 923   pc_files += 'libpulse-mainloop-glib.pc'
 924 endif
 925
 926 foreach file : pc_files
 927   configure_file(
 928     input : file + '.in',
 929     output : file,
 930     configuration : pc_cdata,
 931     install_dir : pkgconfigdir)
 932 endforeach
 933
 934 # CMake files
 935
 936 m4 = find_program('m4', required: true)
 937
 938 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 939
 940 cmake_template_file = configure_file(
 941   input : 'PulseAudioConfig.cmake.in',
 942   output : 'PulseAudioConfig.cmake.tmp',
 943   configuration: cdata,
 944 )
 945
 946 custom_target('PulseAudioConfig.cmake',
 947   input : cmake_template_file,
 948   output : 'PulseAudioConfig.cmake',
 949   capture : true,
 950   command : [m4, '@INPUT@'],
 951   build_by_default : true,
 952   install : true,
 953   install_dir : cmakedir,
 954 )
 955
 956 configure_file(
 957   input : 'PulseAudioConfigVersion.cmake.in',
 958   output : 'PulseAudioConfigVersion.cmake',
 959   configuration: cdata,
 960   install : true,
 961   install_dir : cmakedir,
 962 )
 963
 964 ############################################################
 965
 966 # Final summary
 967
 968 summary = [
 969   '',
 970   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 971   '',
 972   'prefix:                        @0@'.format(prefix),
 973   'bindir:                        @0@'.format(bindir),
 974   'libdir:                        @0@'.format(libdir),
 975   'libexecdir:                    @0@'.format(libexecdir),
 976   'mandir:                        @0@'.format(mandir),
 977   'datadir:                       @0@'.format(datadir),
 978   'sysconfdir:                    @0@'.format(sysconfdir),
 979   'localstatedir:                 @0@'.format(localstatedir),
 980   'modlibexecdir:                 @0@'.format(modlibexecdir),
 981   'alsadatadir:                   @0@'.format(alsadatadir),
 982   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 983   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 984   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 985   'Bash completions directory:    @0@'.format(bashcompletiondir),
 986   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 987   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 988 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 989 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 990 #  'LIBS:                          @0@'.format(${LIBS}),
 991   '',
 992   'Enable pulseaudio daemon:      @0@'.format(get_option('daemon')),
 993   '',
 994   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 995   'Enable X11:                    @0@'.format(x11_dep.found()),
 996   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 997   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 998   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 999 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
1000   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
1001 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
1002 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
1003 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
1004   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
1005   'Enable GSettings:              @0@'.format(gio_dep.found()),
1006   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
1007   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
1008   'Enable Jack:                   @0@'.format(jack_dep.found()),
1009   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
1010   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
1011   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
1012   '  Enable BlueZ 5:              @0@'.format(cdata.has('HAVE_BLUEZ_5')),
1013   '    Enable native headsets:    @0@'.format(cdata.has('HAVE_BLUEZ_5_NATIVE_HEADSET')),
1014   '    Enable  ofono headsets:    @0@'.format(cdata.has('HAVE_BLUEZ_5_OFONO_HEADSET')),
1015   '    Enable GStreamer based codecs: @0@'.format(have_bluez5_gstreamer),
1016   'Enable udev:                   @0@'.format(udev_dep.found()),
1017   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
1018   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
1019   'Enable elogind:                @0@'.format(libelogind_dep.found()),
1020   'Enable TCP Wrappers:           @0@'.format(tcpwrap_dep.found()),
1021   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
1022   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
1023   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
1024   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
1025   'Enable ORC:                    @0@'.format(have_orcc),
1026   'Enable GStreamer:              @0@'.format(have_gstreamer),
1027   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
1028   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
1029   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
1030   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
1031   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
1032   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
1033   'Enable man pages:              @0@'.format(get_option('man')),
1034   'Enable unit tests:             @0@'.format(get_option('tests')),
1035   '',
1036   'Database:                      @0@'.format(get_option('database')),
1037   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
1038   'module-stream-restore:',
1039   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
1040   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
1041   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
1042   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
1043   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
1044 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
1045 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
1046 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
1047   '',
1048   'Tizen options:',
1049   '  dlog:                        @0@'.format(dlog_dep.found()),
1050   '  buffer-attribute:            @0@'.format(get_option('buffer-attribute')),
1051   '  pcm-dump:                    @0@'.format(get_option('pcm-dump')),
1052   '  security:                    @0@'.format(enable_security),
1053   '  udev-usb-only:               @0@'.format(get_option('udev-usb-only')),
1054   '  pa-ready:                    @0@'.format(get_option('pa-ready')),
1055   '  pa-simple-extensions:        @0@'.format(get_option('pa-simple-extensions')),
1056   '  empty-pop:                   @0@'.format(get_option('empty-pop')),
1057   '  volume-ramp:                 @0@'.format(get_option('volume-ramp')),
1058   '  individual-volume-ratio:     @0@'.format(get_option('individual-volume-ratio')),
1059   '  aec:                         @0@'.format(get_option('aec')),
1060   '  prelink (for TV):            @0@'.format(get_option('prelink')),
1061   '  lwipc (for TV):              @0@'.format(get_option('lwipc')),
1062   '  cpu-boosting (for TV):       @0@'.format(get_option('cpu-boosting')),
1063 ]
1064
1065 message('\n    '.join(summary))
1066
1067 # Sanity checks
1068
1069 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
1070   error('At least one echo canceller implementation must be available!')
1071 endif
1072
1073 if samplerate_dep.found()
1074   warning('Support for libsamplerate is DEPRECATED')
1075 endif
1076
1077 if host_machine.system() != 'windows'
1078   if not dbus_dep.found()
1079     message = [
1080       'You do not have D-Bus support enabled. It is strongly recommended',
1081       'that you enable D-Bus support if your platform supports it.',
1082       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
1083       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
1084       'support and even a native control protocol for communicating and',
1085       'controlling the PulseAudio daemon itself.',
1086     ]
1087     warning('\n' + '\n'.join(message))
1088   endif
1089   if host_machine.system() == 'linux' and not udev_dep.found()
1090     message = [
1091       'You do not have udev support enabled. It is strongly recommended',
1092       'that you enable udev support if your platform supports it as it is',
1093       'the primary method used to detect hardware audio devices (on Linux)',
1094       'and is thus a critical part of PulseAudio on that platform.',
1095     ]
1096     warning('\n' + '\n'.join(message))
1097   endif
1098   if not speex_dep.found()
1099     message = [
1100       'You do not have speex support enabled. It is strongly recommended',
1101       'that you enable speex support if your platform supports it as it is',
1102       'the primary method used for audio resampling and is thus a critical',
1103       'part of PulseAudio on that platform.',
1104     ]
1105     warning('\n' + '\n'.join(message))
1106   endif
1107 endif