CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0067)
  60   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  61 endif()
  62
  63 if(POLICY CMP0068)
  64   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  65 endif()
  66
  67 if(POLICY CMP0075)
  68   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  69 endif()
  70
  71
  72 #
  73 # Configure OpenCV CMake hooks
  74 #
  75 include(cmake/OpenCVUtils.cmake)
  76 ocv_cmake_reset_hooks()
  77 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  78 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  79   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  80     get_filename_component(__dir "${__dir}" ABSOLUTE)
  81     ocv_cmake_hook_register_dir(${__dir})
  82   endforeach()
  83 endif()
  84
  85 ocv_cmake_hook(CMAKE_INIT)
  86
  87 # must go before the project()/enable_language() commands
  88 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  89 if(DEFINED CMAKE_BUILD_TYPE)
  90   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  91 endif()
  92
  93 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  94 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  95
  96 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
  97
  98 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
  99 enable_language(CXX C)
 100
 101 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 102
 103 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 104   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 105   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 106     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 107   endif()
 108 endif()
 109
 110 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 111   if(NOT CMAKE_TOOLCHAIN_FILE)
 112     if(WIN32)
 113       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 114     else()
 115       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 116     endif()
 117   else()
 118     # any cross-compiling
 119     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 120   endif()
 121 endif()
 122
 123 enable_testing()
 124
 125 project(OpenCV CXX C)
 126
 127 if(MSVC)
 128   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 129 endif()
 130
 131 ocv_cmake_eval(DEBUG_PRE ONCE)
 132
 133 ocv_clear_vars(OpenCVModules_TARGETS)
 134
 135 include(cmake/OpenCVDownload.cmake)
 136
 137 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 138
 139 # ----------------------------------------------------------------------------
 140 # Break in case of popular CMake configuration mistakes
 141 # ----------------------------------------------------------------------------
 142 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 143   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 144   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 145 endif()
 146
 147 # ----------------------------------------------------------------------------
 148 # Detect compiler and target platform architecture
 149 # ----------------------------------------------------------------------------
 150 include(cmake/OpenCVDetectCXXCompiler.cmake)
 151 ocv_cmake_hook(POST_DETECT_COMPILER)
 152
 153 # Add these standard paths to the search paths for FIND_LIBRARY
 154 # to find libraries from these locations first
 155 if(UNIX AND NOT ANDROID)
 156   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 157     if(EXISTS /lib64)
 158       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 159     else()
 160       list(APPEND CMAKE_LIBRARY_PATH /lib)
 161     endif()
 162     if(EXISTS /usr/lib64)
 163       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 164     else()
 165       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 166     endif()
 167   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 168     if(EXISTS /lib32)
 169       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 170     else()
 171       list(APPEND CMAKE_LIBRARY_PATH /lib)
 172     endif()
 173     if(EXISTS /usr/lib32)
 174       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 175     else()
 176       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 177     endif()
 178   endif()
 179 endif()
 180
 181 # Add these standard paths to the search paths for FIND_PATH
 182 # to find include files from these locations first
 183 if(MINGW)
 184   if(EXISTS /mingw)
 185       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 186   endif()
 187   if(EXISTS /mingw32)
 188       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 189   endif()
 190   if(EXISTS /mingw64)
 191       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 192   endif()
 193 endif()
 194
 195 # ----------------------------------------------------------------------------
 196 # OpenCV cmake options
 197 # ----------------------------------------------------------------------------
 198
 199 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 200
 201 # 3rd party libs
 202 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 203 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 204 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 205 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 206 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 207 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 208 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 209 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 210 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 211 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 212 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 213     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 214     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 215 )
 216
 217 # Optional 3rd party components
 218 # ===================================================
 219 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 220   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 221   VERIFY HAVE_DC1394_2)
 222 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 223   VISIBLE_IF APPLE
 224   VERIFY HAVE_AVFOUNDATION)
 225 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 226   VISIBLE_IF IOS
 227   VERIFY HAVE_CAP_IOS)
 228 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 229   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 230 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 231   VISIBLE_IF ANDROID
 232   VERIFY HAVE_CPUFEATURES)
 233 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 234   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 235   VERIFY HAVE_VTK)
 236 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 237   VISIBLE_IF NOT IOS AND NOT WINRT
 238   VERIFY HAVE_CUDA)
 239 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 240   VISIBLE_IF WITH_CUDA
 241   VERIFY HAVE_CUFFT)
 242 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 243   VISIBLE_IF WITH_CUDA
 244   VERIFY HAVE_CUBLAS)
 245 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 246   VISIBLE_IF WITH_CUDA
 247   VERIFY HAVE_CUDNN)
 248 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 249   VISIBLE_IF WITH_CUDA
 250   VERIFY HAVE_NVCUVID)
 251 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 252   VISIBLE_IF NOT WINRT
 253   VERIFY HAVE_EIGEN)
 254 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 255   VISIBLE_IF NOT IOS AND NOT WINRT
 256   VERIFY HAVE_FFMPEG)
 257 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 258   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 259   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 260 OCV_OPTION(WITH_GTK "Include GTK support" ON
 261   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 262   VERIFY HAVE_GTK)
 263 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 264   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 265   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 266 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 267   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 268   VERIFY HAVE_IPP)
 269 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 270   VISIBLE_IF TRUE
 271   VERIFY HAVE_HALIDE)
 272 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 273   VISIBLE_IF TRUE
 274   VERIFY HAVE_VULKAN)
 275 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 276   VISIBLE_IF TRUE
 277   VERIFY INF_ENGINE_TARGET)
 278 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 279   VISIBLE_IF TRUE
 280   VERIFY TARGET ngraph::ngraph)
 281 OCV_OPTION(WITH_JASPER "Include JPEG2K support" ON
 282   VISIBLE_IF NOT IOS
 283   VERIFY HAVE_JASPER)
 284 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 285   VISIBLE_IF TRUE
 286   VERIFY HAVE_JPEG)
 287 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 288   VISIBLE_IF NOT WINRT
 289   VERIFY HAVE_WEBP)
 290 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 291   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 292   VERIFY HAVE_OPENEXR)
 293 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 294   VISIBLE_IF NOT ANDROID AND NOT WINRT
 295   VERIFY HAVE_OPENGL)
 296 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 297   VISIBLE_IF TRUE
 298   VERIFY HAVE_OPENVX)
 299 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 300   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 301   VERIFY HAVE_OPENNI)
 302 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 303   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 304   VERIFY HAVE_OPENNI2)
 305 OCV_OPTION(WITH_PNG "Include PNG support" ON
 306   VISIBLE_IF TRUE
 307   VERIFY HAVE_PNG)
 308 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 309   VISIBLE_IF TRUE
 310   VERIFY HAVE_GDCM)
 311 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 312   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 313   VERIFY HAVE_PVAPI)
 314 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 315   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 316   VERIFY HAVE_ARAVIS_API)
 317 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 318   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 319   VERIFY HAVE_QT)
 320 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 321   VISIBLE_IF WIN32 AND NOT WINRT
 322   VERIFY HAVE_WIN32UI)
 323 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 324   VISIBLE_IF NOT IOS AND NOT WINRT
 325   VERIFY HAVE_TBB)
 326 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 327   VISIBLE_IF TRUE
 328   VERIFY HAVE_HPX)
 329 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 330   VISIBLE_IF TRUE
 331   VERIFY HAVE_OPENMP)
 332 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 333   VISIBLE_IF NOT WIN32 OR MINGW
 334   VERIFY HAVE_PTHREADS_PF)
 335 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 336   VISIBLE_IF NOT IOS
 337   VERIFY HAVE_TIFF)
 338 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 339   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 340   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 341 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 342   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 343   VERIFY HAVE_DSHOW)
 344 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 345   VISIBLE_IF WIN32
 346   VERIFY HAVE_MSMF)
 347 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 348   VISIBLE_IF WIN32
 349   VERIFY HAVE_MSMF_DXVA)
 350 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 351   VISIBLE_IF NOT ANDROID AND NOT WINRT
 352   VERIFY HAVE_XIMEA)
 353 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 354   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 355   VERIFY HAVE_XINE)
 356 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 357   VISIBLE_IF TRUE
 358   VERIFY HAVE_CLP)
 359 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 360   VISIBLE_IF NOT IOS AND NOT WINRT
 361   VERIFY HAVE_OPENCL)
 362 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 363   VISIBLE_IF TRUE
 364   VERIFY HAVE_OPENCL_SVM) # experimental
 365 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 366   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 367   VERIFY HAVE_CLAMDFFT)
 368 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 369   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 370   VERIFY HAVE_CLAMDBLAS)
 371 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 372   VISIBLE_IF WIN32 AND NOT WINRT
 373   VERIFY HAVE_DIRECTX)
 374 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 375   VISIBLE_IF WIN32 AND NOT WINRT
 376   VERIFY HAVE_OPENCL_D3D11_NV)
 377 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 378   VISIBLE_IF NOT WITH_INTELPERC
 379   VERIFY HAVE_LIBREALSENSE)
 380 OCV_OPTION(WITH_VA "Include VA support" OFF
 381   VISIBLE_IF UNIX AND NOT ANDROID
 382   VERIFY HAVE_VA)
 383 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 384   VISIBLE_IF UNIX AND NOT ANDROID
 385   VERIFY HAVE_VA_INTEL)
 386 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 387   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 388   VERIFY HAVE_MFX)
 389 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 390   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 391   VERIFY HAVE_GDAL)
 392 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 393   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 394   VERIFY HAVE_GPHOTO2)
 395 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 396   VISIBLE_IF NOT ANDROID AND NOT IOS
 397   VERIFY HAVE_LAPACK)
 398 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 399   VISIBLE_IF NOT APPLE_FRAMEWORK
 400   VERIFY HAVE_ITT)
 401 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 402   VISIBLE_IF TRUE
 403   VERIFY HAVE_PROTOBUF)
 404 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 405   VISIBLE_IF TRUE
 406   VERIFY HAVE_IMGCODEC_HDR)
 407 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 408   VISIBLE_IF TRUE
 409   VERIFY HAVE_IMGCODEC_SUNRASTER)
 410 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 411   VISIBLE_IF TRUE
 412   VERIFY HAVE_IMGCODEC_PXM)
 413 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 414   VISIBLE_IF TRUE
 415   VERIFY HAVE_IMGCODEC_PFM)
 416 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 417   VISIBLE_IF TRUE
 418   VERIFY HAVE_QUIRC)
 419 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 420   VISIBLE_IF ANDROID
 421   VERIFY HAVE_ANDROID_MEDIANDK)
 422
 423 # OpenCV build components
 424 # ===================================================
 425 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 426 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 427 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 428 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 429 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 430 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 431 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 432 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 433 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 434 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 435 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 436 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 437 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 438 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 439 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 440 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 441 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 442
 443 # OpenCV installation options
 444 # ===================================================
 445 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 446 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 447 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 448 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 449 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 450 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 451
 452 # OpenCV build options
 453 # ===================================================
 454 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 455 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 456 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 457 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 458 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 459 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 460 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 461 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 462 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 463 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 464 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 465 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 466 endif()
 467 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 468 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 469 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 470 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 471 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 472 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 473 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 474 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 475 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 476 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 477 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 478 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 479 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 480 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 481 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 482 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 483 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 484
 485 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 486 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 487
 488 if(ENABLE_IMPL_COLLECTION)
 489   add_definitions(-DCV_COLLECT_IMPL_DATA)
 490 endif()
 491
 492 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 493
 494 # ----------------------------------------------------------------------------
 495 #  Get actual OpenCV version number from sources
 496 # ----------------------------------------------------------------------------
 497 include(cmake/OpenCVVersion.cmake)
 498
 499 ocv_cmake_hook(POST_OPTIONS)
 500
 501 # ----------------------------------------------------------------------------
 502 #  Build & install layouts
 503 # ----------------------------------------------------------------------------
 504
 505 if(OPENCV_TEST_DATA_PATH)
 506   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 507 endif()
 508
 509 # Save libs and executables in the same place
 510 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 511
 512 if(ANDROID)
 513   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 514   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 515 else()
 516   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 517   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 518 endif()
 519
 520 if(ANDROID)
 521   if(ANDROID_ABI MATCHES "NEON")
 522     set(ENABLE_NEON ON)
 523   endif()
 524   if(ANDROID_ABI MATCHES "VFPV3")
 525     set(ENABLE_VFPV3 ON)
 526   endif()
 527 endif()
 528
 529 if(WIN32)
 530   # Postfix of DLLs:
 531   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 532   ocv_update(OPENCV_DEBUG_POSTFIX d)
 533 else()
 534   # Postfix of so's:
 535   ocv_update(OPENCV_DLLVERSION "")
 536   ocv_update(OPENCV_DEBUG_POSTFIX "")
 537 endif()
 538
 539 if(DEFINED CMAKE_DEBUG_POSTFIX)
 540   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 541 endif()
 542
 543 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 544   set(BUILD_opencv_world ON CACHE INTERNAL "")
 545 endif()
 546
 547 include(cmake/OpenCVInstallLayout.cmake)
 548
 549 # ----------------------------------------------------------------------------
 550 #  Path for build/platform -specific headers
 551 # ----------------------------------------------------------------------------
 552 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 553 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 554
 555 # ----------------------------------------------------------------------------
 556 #  Path for additional modules
 557 # ----------------------------------------------------------------------------
 558 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 559
 560 # ----------------------------------------------------------------------------
 561 #  Autodetect if we are in a GIT repository
 562 # ----------------------------------------------------------------------------
 563 find_host_package(Git QUIET)
 564
 565 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 566   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 567 elseif(NOT DEFINED OPENCV_VCSVERSION)
 568   # We don't have git:
 569   set(OPENCV_VCSVERSION "unknown")
 570 endif()
 571
 572
 573 # ----------------------------------------------------------------------------
 574 # OpenCV compiler and linker options
 575 # ----------------------------------------------------------------------------
 576 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 577 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 578   set(CMAKE_BUILD_TYPE Release)
 579 endif()
 580
 581 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 582
 583 # --- Python Support ---
 584 if(NOT IOS)
 585   include(cmake/OpenCVDetectPython.cmake)
 586 endif()
 587
 588 include(cmake/OpenCVCompilerOptions.cmake)
 589
 590 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 591
 592 # ----------------------------------------------------------------------------
 593 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 594 # ----------------------------------------------------------------------------
 595 if(UNIX)
 596   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 597     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 598         AND NOT OPENCV_ENABLE_PKG_CONFIG
 599     )
 600       if(NOT PkgConfig_FOUND)
 601         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 602       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 603         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 604       endif()
 605     elseif(OPENCV_DISABLE_PKG_CONFIG)
 606       if(PkgConfig_FOUND)
 607         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 608       endif()
 609     else()
 610       find_package(PkgConfig QUIET)
 611     endif()
 612   endif()
 613   include(CheckFunctionExists)
 614   include(CheckIncludeFile)
 615   include(CheckSymbolExists)
 616
 617   if(NOT APPLE)
 618     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 619     if(ANDROID)
 620       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 621     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 622       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 623     elseif(EMSCRIPTEN)
 624       # no need to link to system libs with emscripten
 625     else()
 626       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 627     endif()
 628   else()
 629     set(HAVE_PTHREAD 1)
 630   endif()
 631
 632   if(OPENCV_ENABLE_MEMALIGN)
 633     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 634     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 635     if(HAVE_MALLOC_H)
 636       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 637     endif()
 638     # TODO:
 639     # - _aligned_malloc() on Win32
 640     # - std::aligned_alloc() C++17 / C11
 641   endif()
 642 endif()
 643
 644 include(cmake/OpenCVPCHSupport.cmake)
 645 include(cmake/OpenCVModule.cmake)
 646
 647 # ----------------------------------------------------------------------------
 648 #  Detect endianness of build platform
 649 # ----------------------------------------------------------------------------
 650
 651 if(IOS)
 652   # test_big_endian needs try_compile, which doesn't work for iOS
 653   # http://public.kitware.com/Bug/view.php?id=12288
 654   set(WORDS_BIGENDIAN 0)
 655 else()
 656   include(TestBigEndian)
 657   test_big_endian(WORDS_BIGENDIAN)
 658 endif()
 659
 660 # ----------------------------------------------------------------------------
 661 #  Detect 3rd-party libraries
 662 # ----------------------------------------------------------------------------
 663
 664 if(ANDROID AND WITH_CPUFEATURES)
 665   add_subdirectory(3rdparty/cpufeatures)
 666   set(HAVE_CPUFEATURES 1)
 667 endif()
 668
 669 include(cmake/OpenCVFindFrameworks.cmake)
 670
 671 include(cmake/OpenCVFindLibsGrfmt.cmake)
 672 include(cmake/OpenCVFindLibsGUI.cmake)
 673 include(cmake/OpenCVFindLibsVideo.cmake)
 674 include(cmake/OpenCVFindLibsPerf.cmake)
 675 include(cmake/OpenCVFindLAPACK.cmake)
 676 include(cmake/OpenCVFindProtobuf.cmake)
 677
 678 # ----------------------------------------------------------------------------
 679 #  Detect other 3rd-party libraries/tools
 680 # ----------------------------------------------------------------------------
 681
 682 # --- Java Support ---
 683 if(BUILD_JAVA)
 684   if(ANDROID)
 685     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 686   else()
 687     include(cmake/OpenCVDetectApacheAnt.cmake)
 688     find_package(JNI)
 689   endif()
 690 endif()
 691
 692 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 693   include(cmake/OpenCVPylint.cmake)
 694 endif()
 695 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 696   find_package(Flake8 QUIET)
 697   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 698     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 699   endif()
 700   if(FLAKE8_FOUND)
 701     add_custom_target(check_flake8
 702         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 703         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 704         COMMENT "Running flake8"
 705     )
 706   endif()
 707 endif()
 708
 709
 710 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 711   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 712 else()
 713   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 714 endif()
 715
 716 # --- OpenCL ---
 717 if(WITH_OPENCL)
 718   include(cmake/OpenCVDetectOpenCL.cmake)
 719 endif()
 720
 721 # --- Halide ---
 722 if(WITH_HALIDE)
 723   include(cmake/OpenCVDetectHalide.cmake)
 724 endif()
 725
 726 # --- VkCom ---
 727 if(WITH_VULKAN)
 728   include(cmake/OpenCVDetectVulkan.cmake)
 729 endif()
 730
 731 # --- Inference Engine ---
 732 if(WITH_INF_ENGINE)
 733   include(cmake/OpenCVDetectInferenceEngine.cmake)
 734 endif()
 735
 736 # --- DirectX ---
 737 if(WITH_DIRECTX)
 738   include(cmake/OpenCVDetectDirectX.cmake)
 739 endif()
 740
 741 if(WITH_VTK)
 742   include(cmake/OpenCVDetectVTK.cmake)
 743 endif()
 744
 745 if(WITH_OPENVX)
 746   include(cmake/FindOpenVX.cmake)
 747 endif()
 748
 749 if(WITH_QUIRC)
 750   add_subdirectory(3rdparty/quirc)
 751   set(HAVE_QUIRC TRUE)
 752 endif()
 753 # ----------------------------------------------------------------------------
 754 # OpenCV HAL
 755 # ----------------------------------------------------------------------------
 756 set(_hal_includes "")
 757 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 758   # 1. libraries
 759   foreach (l ${${HAL_LIBRARIES_VAR}})
 760     if(NOT TARGET ${l})
 761       get_filename_component(l "${l}" ABSOLUTE)
 762     endif()
 763     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 764   endforeach()
 765   # 2. headers
 766   foreach (h ${${HAL_HEADERS_VAR}})
 767     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 768   endforeach()
 769   # 3. include paths
 770   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 771 endmacro()
 772
 773 if(NOT DEFINED OpenCV_HAL)
 774   set(OpenCV_HAL "OpenCV_HAL")
 775 endif()
 776
 777 if(HAVE_OPENVX)
 778   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 779     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 780   endif()
 781 endif()
 782
 783 if(WITH_CAROTENE)
 784   ocv_debug_message(STATUS "Enable carotene acceleration")
 785   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 786     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 787   endif()
 788 endif()
 789
 790 foreach(hal ${OpenCV_HAL})
 791   if(hal STREQUAL "carotene")
 792     add_subdirectory(3rdparty/carotene/hal)
 793     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 794     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 795   elseif(hal STREQUAL "openvx")
 796     add_subdirectory(3rdparty/openvx)
 797     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 798     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 799   else()
 800     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 801     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 802     find_package(${hal} NO_MODULE QUIET)
 803     if(${hal}_FOUND)
 804       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 805       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 806     endif()
 807   endif()
 808 endforeach()
 809 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 810 unset(_hal_includes)
 811
 812
 813 # ----------------------------------------------------------------------------
 814 # Code trace support
 815 # ----------------------------------------------------------------------------
 816 if(CV_TRACE)
 817   include(cmake/OpenCVDetectTrace.cmake)
 818 endif()
 819
 820 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 821 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 822
 823 # ----------------------------------------------------------------------------
 824 # Solution folders:
 825 # ----------------------------------------------------------------------------
 826 if(ENABLE_SOLUTION_FOLDERS)
 827   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 828   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 829 endif()
 830
 831 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 832 include(cmake/OpenCVExtraTargets.cmake)
 833
 834 # ----------------------------------------------------------------------------
 835 # Process subdirectories
 836 # ----------------------------------------------------------------------------
 837
 838 # opencv.hpp and legacy headers
 839 add_subdirectory(include)
 840
 841 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 842 ocv_add_modules_compiler_options()
 843
 844 # OpenCV modules
 845 add_subdirectory(modules)
 846
 847 # Generate targets for documentation
 848 add_subdirectory(doc)
 849
 850 # various data that is used by cv libraries and/or demo applications.
 851 add_subdirectory(data)
 852
 853 # extra applications
 854 if(BUILD_opencv_apps)
 855   add_subdirectory(apps)
 856 endif()
 857
 858 # examples
 859 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 860   add_subdirectory(samples)
 861 endif()
 862
 863 if(ANDROID)
 864   add_subdirectory(platforms/android/service)
 865 endif()
 866
 867 # ----------------------------------------------------------------------------
 868 # Finalization: generate configuration-based files
 869 # ----------------------------------------------------------------------------
 870
 871 ocv_cmake_hook(PRE_FINALIZE)
 872
 873 # Generate platform-dependent and configuration-dependent headers
 874 include(cmake/OpenCVGenHeaders.cmake)
 875
 876 # Generate opencv.pc for pkg-config command
 877 if(OPENCV_GENERATE_PKGCONFIG)
 878   include(cmake/OpenCVGenPkgconfig.cmake)
 879 endif()
 880
 881 # Generate OpenCV.mk for ndk-build (Android build tool)
 882 include(cmake/OpenCVGenAndroidMK.cmake)
 883
 884 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 885 include(cmake/OpenCVGenConfig.cmake)
 886
 887 # Generate Info.plist for the IOS framework
 888 if(APPLE_FRAMEWORK)
 889   include(cmake/OpenCVGenInfoPlist.cmake)
 890 endif()
 891
 892 # Generate ABI descriptor
 893 include(cmake/OpenCVGenABI.cmake)
 894
 895 # Generate environment setup file
 896 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 897   if(ANDROID)
 898     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 899     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 900                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 901     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 902             DESTINATION ./ COMPONENT tests)
 903   elseif(WIN32)
 904     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 905                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 906     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 907             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 908   elseif(UNIX)
 909     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 910                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 911     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 912             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 913   endif()
 914 endif()
 915
 916 if(NOT OPENCV_README_FILE)
 917   if(ANDROID)
 918     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 919   endif()
 920 endif()
 921
 922 if(NOT OPENCV_LICENSE_FILE)
 923   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 924 endif()
 925
 926 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 927 if(ANDROID OR NOT UNIX)
 928   install(FILES ${OPENCV_LICENSE_FILE}
 929         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 930         DESTINATION ./ COMPONENT libs)
 931   if(OPENCV_README_FILE)
 932     install(FILES ${OPENCV_README_FILE}
 933             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 934             DESTINATION ./ COMPONENT libs)
 935   endif()
 936 endif()
 937
 938 if(COMMAND ocv_pylint_finalize)
 939   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 940   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 941   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 942   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 943   ocv_pylint_finalize()
 944 endif()
 945
 946 if(OPENCV_GENERATE_SETUPVARS)
 947   include(cmake/OpenCVGenSetupVars.cmake)
 948 endif()
 949
 950 # ----------------------------------------------------------------------------
 951 # Summary:
 952 # ----------------------------------------------------------------------------
 953 status("")
 954 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 955 if(OPENCV_VCSVERSION)
 956   status("  Version control:" ${OPENCV_VCSVERSION})
 957 endif()
 958 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 959   set(__dump_extra_header OFF)
 960   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 961     if(EXISTS ${p})
 962       if(NOT __dump_extra_header)
 963         set(__dump_extra_header ON)
 964         status("")
 965         status("  Extra modules:")
 966       else()
 967         status("")
 968       endif()
 969       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 970       status("    Location (extra):" ${p})
 971       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 972     endif()
 973   endforeach()
 974   unset(__dump_extra_header)
 975 endif()
 976
 977 # ========================== build platform ==========================
 978 status("")
 979 status("  Platform:")
 980 if(NOT DEFINED OPENCV_TIMESTAMP
 981     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 982     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 983 )
 984   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 985   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 986 endif()
 987 if(OPENCV_TIMESTAMP)
 988   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 989 endif()
 990 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 991 if(CMAKE_CROSSCOMPILING)
 992   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 993 endif()
 994 status("    CMake:"            ${CMAKE_VERSION})
 995 status("    CMake generator:"  ${CMAKE_GENERATOR})
 996 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 997 if(MSVC)
 998   status("    MSVC:"           ${MSVC_VERSION})
 999 endif()
1000 if(CMAKE_GENERATOR MATCHES Xcode)
1001   status("    Xcode:"          ${XCODE_VERSION})
1002 endif()
1003 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1004   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1005 endif()
1006
1007
1008 # ========================= CPU code generation mode =========================
1009 status("")
1010 status("  CPU/HW features:")
1011 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1012 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1013   status("      requested:"  "${CPU_BASELINE}")
1014 endif()
1015 if(CPU_BASELINE_REQUIRE)
1016   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1017 endif()
1018 if(CPU_BASELINE_DISABLE)
1019   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1020 endif()
1021 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1022   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1023   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1024     status("      requested:"  "${CPU_DISPATCH}")
1025   endif()
1026   if(CPU_DISPATCH_REQUIRE)
1027     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1028   endif()
1029   foreach(OPT ${CPU_DISPATCH_FINAL})
1030     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1031   endforeach()
1032 endif()
1033
1034 # ========================== C/C++ options ==========================
1035 if(CMAKE_CXX_COMPILER_VERSION)
1036   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1037 else()
1038   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1039 endif()
1040 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1041
1042 status("")
1043 status("  C/C++:")
1044 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1045 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1046 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1047 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1048 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1049 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1050 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1051 if(WIN32)
1052   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1053   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1054 else()
1055   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1056   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1057 endif()
1058 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1059 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1060
1061 # ========================== Dependencies ============================
1062 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1063 status("    Extra dependencies:" ${deps_extra})
1064 status("    3rdparty dependencies:" ${deps_3rdparty})
1065
1066 # ========================== OpenCV modules ==========================
1067 status("")
1068 status("  OpenCV modules:")
1069 set(OPENCV_MODULES_BUILD_ST "")
1070 foreach(the_module ${OPENCV_MODULES_BUILD})
1071   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1072     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1073   endif()
1074 endforeach()
1075 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1076 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1077 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1078 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1079 list(SORT OPENCV_MODULES_BUILD_ST)
1080 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1081 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1082 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1083 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1084 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1085 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1086 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1087
1088 ocv_build_features_string(apps_status
1089   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1090   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1091   IF BUILD_EXAMPLES THEN "examples"
1092   IF BUILD_opencv_apps THEN "apps"
1093   IF BUILD_ANDROID_SERVICE THEN "android_service"
1094   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1095   ELSE "-")
1096 status("    Applications:" "${apps_status}")
1097 ocv_build_features_string(docs_status
1098     IF TARGET doxygen_cpp THEN "doxygen"
1099     IF TARGET doxygen_python THEN "python"
1100     IF TARGET doxygen_javadoc THEN "javadoc"
1101     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1102     ELSE "NO"
1103 )
1104 status("    Documentation:" "${docs_status}")
1105 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1106
1107 # ========================== Android details ==========================
1108 if(ANDROID)
1109   status("")
1110   if(DEFINED ANDROID_NDK_REVISION)
1111     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1112   else()
1113     set(__msg "location: ${ANDROID_NDK}")
1114   endif()
1115   status("  Android NDK: " ${__msg})
1116   status("    Android ABI:" ${ANDROID_ABI})
1117   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1118     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1119   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1120     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1121   endif()
1122   status("    STL type:" ${ANDROID_STL})
1123   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1124
1125   if(BUILD_ANDROID_PROJECTS)
1126     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1127     if(ANDROID_EXECUTABLE)
1128       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1129     endif()
1130   else()
1131     status("  Android SDK: " "not used, projects are not built")
1132   endif()
1133   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1134     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1135   endif()
1136   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1137     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1138       status("    Projects build scripts:" "Ant/Eclipse compatible")
1139     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1140       status("    Projects build scripts:" "Gradle")
1141     endif()
1142   endif()
1143 endif()
1144
1145 # ================== Windows RT features ==================
1146 if(WIN32)
1147 status("")
1148 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1149   if(WINRT)
1150     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1151     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1152     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1153     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1154       status("    Building for C++ without CX extensions")
1155     endif()
1156   endif()
1157 endif(WIN32)
1158
1159 # ========================== GUI ==========================
1160 status("")
1161 status("  GUI: ")
1162
1163 if(WITH_QT OR HAVE_QT)
1164   if(HAVE_QT5)
1165     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1166     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1167   elseif(HAVE_QT)
1168     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1169     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1170   else()
1171     status("    QT:" "NO")
1172   endif()
1173 endif()
1174
1175 if(WITH_WIN32UI)
1176   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1177 endif()
1178
1179 if(HAVE_COCOA)  # APPLE
1180   status("    Cocoa:"  YES)
1181 endif()
1182
1183 if(WITH_GTK OR HAVE_GTK)
1184   if(HAVE_GTK3)
1185     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1186   elseif(HAVE_GTK)
1187     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1188   else()
1189     status("    GTK+:" "NO")
1190   endif()
1191   if(HAVE_GTK)
1192     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1193     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1194   endif()
1195 endif()
1196
1197 if(WITH_OPENGL OR HAVE_OPENGL)
1198   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1199 endif()
1200
1201 if(WITH_VTK OR HAVE_VTK)
1202   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1203 endif()
1204
1205 # ========================== MEDIA IO ==========================
1206 status("")
1207 status("  Media I/O: ")
1208 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1209
1210 if(WITH_JPEG OR HAVE_JPEG)
1211   if(NOT HAVE_JPEG)
1212     status("    JPEG:" NO)
1213   elseif(BUILD_JPEG)
1214     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1215   else()
1216     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1217   endif()
1218 endif()
1219
1220 if(WITH_WEBP OR HAVE_WEBP)
1221   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1222 endif()
1223
1224 if(WITH_PNG OR HAVE_PNG)
1225   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1226 endif()
1227
1228 if(WITH_TIFF OR HAVE_TIFF)
1229   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1230 endif()
1231
1232 if(WITH_JASPER OR HAVE_JASPER)
1233   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1234 endif()
1235
1236 if(WITH_OPENEXR OR HAVE_OPENEXR)
1237   if(HAVE_OPENEXR)
1238     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1239   else()
1240     status("    OpenEXR:" "NO")
1241   endif()
1242 endif()
1243
1244 if(WITH_GDAL OR HAVE_GDAL)
1245   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1246 endif()
1247
1248 if(WITH_GDCM OR HAVE_GDCM)
1249   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1250 endif()
1251
1252 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1253   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1254 endif()
1255
1256 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1257   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1258 endif()
1259
1260 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1261   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1262 endif()
1263
1264 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1265   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1266 endif()
1267
1268 # ========================== VIDEO IO ==========================
1269 status("")
1270 status("  Video I/O:")
1271
1272 if(WITH_1394 OR HAVE_DC1394_2)
1273   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1274 endif()
1275
1276 if(WITH_FFMPEG OR HAVE_FFMPEG)
1277   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1278     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1279   elseif(WIN32)
1280     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1281   else()
1282     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1283   endif()
1284   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1285   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1286   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1287   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1288   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1289 endif()
1290
1291 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1292   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1293 endif()
1294
1295 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1296   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1297 endif()
1298
1299 if(WITH_PVAPI OR HAVE_PVAPI)
1300   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1301 endif()
1302
1303 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1304   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1305 endif()
1306
1307 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1308   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1309 endif()
1310
1311 if(HAVE_CAP_IOS)
1312   status("    iOS capture:" YES)
1313 endif()
1314
1315 if(WITH_V4L OR HAVE_V4L)
1316   ocv_build_features_string(v4l_status
1317     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1318     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1319     ELSE "NO")
1320   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1321 endif()
1322
1323 if(WITH_DSHOW OR HAVE_DSHOW)
1324   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1325 endif()
1326
1327 if(WITH_MSMF OR HAVE_MSMF)
1328   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1329   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1330 endif()
1331
1332 if(WITH_XIMEA OR HAVE_XIMEA)
1333   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1334 endif()
1335
1336 if(WITH_XINE OR HAVE_XINE)
1337   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1338 endif()
1339
1340 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1341   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1342 endif()
1343
1344 if(WITH_MFX OR HAVE_MFX)
1345   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1346 endif()
1347
1348 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1349   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1350 endif()
1351
1352 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1353 ocv_build_features_string(parallel_status EXCLUSIVE
1354   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1355   IF HAVE_HPX THEN "HPX"
1356   IF HAVE_OPENMP THEN "OpenMP"
1357   IF HAVE_GCD THEN "GCD"
1358   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1359   IF HAVE_PTHREADS_PF THEN "pthreads"
1360   ELSE "none")
1361 status("")
1362 status("  Parallel framework:" "${parallel_status}")
1363
1364 if(CV_TRACE OR OPENCV_TRACE)
1365   ocv_build_features_string(trace_status EXCLUSIVE
1366     IF HAVE_ITT THEN "with Intel ITT"
1367     ELSE "built-in")
1368   status("")
1369   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1370 endif()
1371
1372 # ========================== Other third-party libraries ==========================
1373 status("")
1374 status("  Other third-party libraries:")
1375
1376 if(WITH_IPP AND HAVE_IPP)
1377   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1378   status("           at:" "${IPP_ROOT_DIR}")
1379   if(NOT HAVE_IPP_ICV)
1380     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1381   endif()
1382   if(HAVE_IPP_IW)
1383     if(BUILD_IPP_IW)
1384       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1385     else()
1386       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1387     endif()
1388     status("              at:" "${IPP_IW_PATH}")
1389   else()
1390     status("    Intel IPP IW:"   NO)
1391   endif()
1392 endif()
1393
1394 if(WITH_VA OR HAVE_VA)
1395   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1396 endif()
1397
1398 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1399   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1400 endif()
1401
1402 if(WITH_LAPACK OR HAVE_LAPACK)
1403   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1404 endif()
1405
1406 if(WITH_HALIDE OR HAVE_HALIDE)
1407   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1408 endif()
1409
1410 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1411   if(INF_ENGINE_TARGET)
1412     list(GET INF_ENGINE_TARGET 0 ie_target)
1413     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1414     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1415     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1416     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1417     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1418     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1419     ocv_build_features_string(_lib
1420       IF _lib THEN "${_lib}"
1421       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1422       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1423       IF _lib_rel  THEN "${_lib_rel}"
1424       IF _lib_dbg  THEN "${_lib_dbg}"
1425       ELSE "unknown"
1426     )
1427     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1428     status("    Inference Engine:" "${__msg}")
1429     status("        * libs:" "${_lib}")
1430     status("        * includes:" "${_inc}")
1431   else()
1432     status("    Inference Engine:"     "NO")
1433   endif()
1434 endif()
1435 if(WITH_NGRAPH OR HAVE_NGRAPH)
1436   if(HAVE_NGRAPH)
1437     set(__target ngraph::ngraph)
1438     set(__msg "YES (${ngraph_VERSION})")
1439     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1440     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1441     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1442     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1443     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1444     ocv_build_features_string(_lib
1445       IF _lib THEN "${_lib}"
1446       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1447       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1448       IF _lib_rel  THEN "${_lib_rel}"
1449       IF _lib_dbg  THEN "${_lib_dbg}"
1450       ELSE "unknown"
1451     )
1452     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1453     status("    nGraph:" "${__msg}")
1454     status("        * libs:" "${_lib}")
1455     status("        * includes:" "${_inc}")
1456   else()
1457     status("    nGraph:"     "NO")
1458   endif()
1459 endif()
1460
1461 if(WITH_EIGEN OR HAVE_EIGEN)
1462   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1463 endif()
1464
1465 if(WITH_OPENVX OR HAVE_OPENVX)
1466   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1467 endif()
1468
1469 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1470
1471 foreach(s ${CUSTOM_STATUS})
1472   status(${CUSTOM_STATUS_${s}})
1473 endforeach()
1474
1475 if(WITH_CUDA OR HAVE_CUDA)
1476   ocv_build_features_string(cuda_features
1477     IF HAVE_CUFFT THEN "CUFFT"
1478     IF HAVE_CUBLAS THEN "CUBLAS"
1479     IF HAVE_NVCUVID THEN "NVCUVID"
1480     IF CUDA_FAST_MATH THEN "FAST_MATH"
1481     ELSE "no extra features")
1482   status("")
1483   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1484   if(HAVE_CUDA)
1485     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1486     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1487   endif()
1488  endif()
1489
1490  if(WITH_CUDNN OR HAVE_CUDNN)
1491     status("")
1492     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1493 endif()
1494
1495 if(WITH_VULKAN OR HAVE_VULKAN)
1496   status("")
1497   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1498   if(HAVE_VULKAN)
1499     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1500     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1501   endif()
1502 endif()
1503
1504 if(WITH_OPENCL OR HAVE_OPENCL)
1505   ocv_build_features_string(opencl_features
1506     IF HAVE_OPENCL_SVM THEN "SVM"
1507     IF HAVE_CLAMDFFT THEN "AMDFFT"
1508     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1509     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1510     ELSE "no extra features")
1511   status("")
1512   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1513   if(HAVE_OPENCL)
1514     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1515     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1516   endif()
1517 endif()
1518
1519 # ========================== python ==========================
1520 if(BUILD_opencv_python2)
1521   status("")
1522   status("  Python 2:")
1523   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1524   if(PYTHON2LIBS_VERSION_STRING)
1525     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1526   else()
1527     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1528   endif()
1529   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1530   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1531 endif()
1532
1533 if(BUILD_opencv_python3)
1534   status("")
1535   status("  Python 3:")
1536   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1537   if(PYTHON3LIBS_VERSION_STRING)
1538     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1539   else()
1540     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1541   endif()
1542   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1543   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1544 endif()
1545
1546 status("")
1547 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1548 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1549   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1550 endif()
1551 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1552   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1553 endif()
1554
1555 # ========================== java ==========================
1556 if(BUILD_JAVA)
1557   status("")
1558   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1559   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1560   if(NOT ANDROID)
1561     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1562   endif()
1563   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1564   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1565 endif()
1566
1567 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1568
1569 # ========================== auxiliary ==========================
1570 status("")
1571 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1572 status("-----------------------------------------------------------------")
1573 status("")
1574
1575
1576 ocv_finalize_status()
1577
1578 if(ENABLE_CONFIG_VERIFICATION)
1579   ocv_verify_config()
1580 endif()
1581
1582 ocv_cmake_hook(POST_FINALIZE)
1583
1584 # ----------------------------------------------------------------------------
1585 # CPack stuff
1586 # ----------------------------------------------------------------------------
1587
1588 include(cmake/OpenCVPackaging.cmake)
1589
1590 # This should be the last command
1591 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1592 ocv_cmake_eval(DEBUG_POST ONCE)