CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  21   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  22   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  23   #CMake fails to find _fseeko() which leads to subsequent linker error.
  24   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  25   cmake_policy(VERSION 2.8)
  26 else()
  27   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  28 endif()
  29
  30 #
  31 # Configure CMake policies
  32 #
  33 if(POLICY CMP0026)
  34   cmake_policy(SET CMP0026 NEW)
  35 endif()
  36
  37 if(POLICY CMP0042)
  38   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  39 endif()
  40
  41 if(POLICY CMP0046)
  42   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  43 endif()
  44
  45 if(POLICY CMP0051)
  46   cmake_policy(SET CMP0051 NEW)
  47 endif()
  48
  49 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  50   cmake_policy(SET CMP0054 NEW)
  51 endif()
  52
  53 if(POLICY CMP0056)
  54   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  55 endif()
  56
  57 if(POLICY CMP0066)
  58   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  59 endif()
  60
  61 if(POLICY CMP0067)
  62   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  63 endif()
  64
  65 if(POLICY CMP0068)
  66   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  67 endif()
  68
  69 if(POLICY CMP0075)
  70   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  71 endif()
  72
  73 if(POLICY CMP0077)
  74   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  75 endif()
  76
  77 #
  78 # Configure OpenCV CMake hooks
  79 #
  80 include(cmake/OpenCVUtils.cmake)
  81 ocv_cmake_reset_hooks()
  82 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  83 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  84   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  85     get_filename_component(__dir "${__dir}" ABSOLUTE)
  86     ocv_cmake_hook_register_dir(${__dir})
  87   endforeach()
  88 endif()
  89
  90 ocv_cmake_hook(CMAKE_INIT)
  91
  92 # must go before the project()/enable_language() commands
  93 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  94 if(NOT DEFINED CMAKE_BUILD_TYPE
  95     AND NOT OPENCV_SKIP_DEFAULT_BUILD_TYPE
  96 )
  97   message(STATUS "'Release' build type is used by default. Use CMAKE_BUILD_TYPE to specify build type (Release or Debug)")
  98   set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build")
  99 endif()
 100 if(DEFINED CMAKE_BUILD_TYPE)
 101   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
 102 endif()
 103
 104 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 105 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 106
 107 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 108
 109 # Bootstrap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 110 if(OPENCV_WORKAROUND_CMAKE_20989)
 111   set(CMAKE_SYSTEM_PROCESSOR_BACKUP ${CMAKE_SYSTEM_PROCESSOR})
 112 endif()
 113 enable_language(CXX C)
 114 if(OPENCV_WORKAROUND_CMAKE_20989)
 115   set(CMAKE_SYSTEM_PROCESSOR ${CMAKE_SYSTEM_PROCESSOR_BACKUP})
 116 endif()
 117
 118 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 119
 120 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 121   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 122   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 123     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 124   endif()
 125 endif()
 126
 127 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 128   if(NOT CMAKE_TOOLCHAIN_FILE)
 129     if(WIN32)
 130       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 131     else()
 132       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 133     endif()
 134   else()
 135     # any cross-compiling
 136     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 137   endif()
 138 endif()
 139
 140 enable_testing()
 141
 142 project(OpenCV CXX C)
 143
 144 if(MSVC)
 145   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 146 endif()
 147
 148 ocv_cmake_eval(DEBUG_PRE ONCE)
 149
 150 ocv_clear_vars(OpenCVModules_TARGETS)
 151
 152 include(cmake/OpenCVDownload.cmake)
 153
 154 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 155
 156 # ----------------------------------------------------------------------------
 157 # Break in case of popular CMake configuration mistakes
 158 # ----------------------------------------------------------------------------
 159 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 160   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 161   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 162 endif()
 163
 164 # ----------------------------------------------------------------------------
 165 # Detect compiler and target platform architecture
 166 # ----------------------------------------------------------------------------
 167 include(cmake/OpenCVDetectCXXCompiler.cmake)
 168 ocv_cmake_hook(POST_DETECT_COMPILER)
 169
 170 # Add these standard paths to the search paths for FIND_LIBRARY
 171 # to find libraries from these locations first
 172 if(UNIX AND NOT ANDROID)
 173   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 174     if(EXISTS /lib64)
 175       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 176     else()
 177       list(APPEND CMAKE_LIBRARY_PATH /lib)
 178     endif()
 179     if(EXISTS /usr/lib64)
 180       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 181     else()
 182       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 183     endif()
 184   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 185     if(EXISTS /lib32)
 186       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 187     else()
 188       list(APPEND CMAKE_LIBRARY_PATH /lib)
 189     endif()
 190     if(EXISTS /usr/lib32)
 191       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 192     else()
 193       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 194     endif()
 195   endif()
 196 endif()
 197
 198 # Add these standard paths to the search paths for FIND_PATH
 199 # to find include files from these locations first
 200 if(MINGW)
 201   if(EXISTS /mingw)
 202       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 203   endif()
 204   if(EXISTS /mingw32)
 205       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 206   endif()
 207   if(EXISTS /mingw64)
 208       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 209   endif()
 210 endif()
 211
 212 # ----------------------------------------------------------------------------
 213 # OpenCV cmake options
 214 # ----------------------------------------------------------------------------
 215
 216 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 217
 218 # 3rd party libs
 219 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 220 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 221 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 222 OCV_OPTION(BUILD_OPENJPEG           "Build OpenJPEG from source"         (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 223 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 224 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 225 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 226 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (OPENCV_FORCE_3RDPARTY_BUILD) )
 227 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 228 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 229 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 230 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 231     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 232     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 233 )
 234
 235 # Optional 3rd party components
 236 # ===================================================
 237 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 238   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 239   VERIFY HAVE_DC1394_2)
 240 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 241   VISIBLE_IF APPLE
 242   VERIFY HAVE_AVFOUNDATION)
 243 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 244   VISIBLE_IF IOS
 245   VERIFY HAVE_CAP_IOS)
 246 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" (NOT CV_DISABLE_OPTIMIZATION)
 247   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS)
 248 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 249   VISIBLE_IF ANDROID
 250   VERIFY HAVE_CPUFEATURES)
 251 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 252   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 253   VERIFY HAVE_VTK)
 254 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 255   VISIBLE_IF NOT IOS AND NOT WINRT
 256   VERIFY HAVE_CUDA)
 257 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 258   VISIBLE_IF WITH_CUDA
 259   VERIFY HAVE_CUFFT)
 260 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 261   VISIBLE_IF WITH_CUDA
 262   VERIFY HAVE_CUBLAS)
 263 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 264   VISIBLE_IF WITH_CUDA
 265   VERIFY HAVE_CUDNN)
 266 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" ON
 267   VISIBLE_IF WITH_CUDA
 268   VERIFY HAVE_NVCUVID)
 269 OCV_OPTION(WITH_NVCUVENC "Include NVidia Video Encoding library support" ON
 270   VISIBLE_IF WITH_CUDA
 271   VERIFY HAVE_NVCUVENC)
 272 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 273   VISIBLE_IF NOT WINRT
 274   VERIFY HAVE_EIGEN)
 275 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 276   VISIBLE_IF NOT IOS AND NOT WINRT
 277   VERIFY HAVE_FFMPEG)
 278 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 279   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 280   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 281 OCV_OPTION(WITH_GTK "Include GTK support" ON
 282   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 283   VERIFY HAVE_GTK)
 284 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 285   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 286   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 287 OCV_OPTION(WITH_WAYLAND "Include Wayland support" OFF
 288         VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 289         VERIFY HAVE_WAYLAND)
 290 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 291   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 292   VERIFY HAVE_IPP)
 293 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 294   VISIBLE_IF TRUE
 295   VERIFY HAVE_HALIDE)
 296 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 297   VISIBLE_IF TRUE
 298   VERIFY HAVE_VULKAN)
 299 # replacement for deprecated options: WITH_INF_ENGINE, WITH_NGRAPH
 300 OCV_OPTION(WITH_OPENVINO "Include Intel OpenVINO toolkit support" (WITH_INF_ENGINE)
 301   VISIBLE_IF TRUE
 302   VERIFY TARGET ocv.3rdparty.openvino)
 303 OCV_OPTION(WITH_WEBNN "Include WebNN support" OFF
 304   VISIBLE_IF TRUE
 305   VERIFY HAVE_WEBNN)
 306 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 307   VISIBLE_IF NOT IOS
 308   VERIFY HAVE_JASPER)
 309 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 310   VISIBLE_IF NOT IOS
 311   VERIFY HAVE_OPENJPEG)
 312 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 313   VISIBLE_IF TRUE
 314   VERIFY HAVE_JPEG)
 315 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 316   VISIBLE_IF NOT WINRT
 317   VERIFY HAVE_WEBP)
 318 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" ((WIN32 OR ANDROID OR APPLE) OR BUILD_OPENEXR) OR NOT CMAKE_CROSSCOMPILING
 319   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 320   VERIFY HAVE_OPENEXR)
 321 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 322   VISIBLE_IF NOT ANDROID AND NOT WINRT
 323   VERIFY HAVE_OPENGL)
 324 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 325   VISIBLE_IF TRUE
 326   VERIFY HAVE_OPENVX)
 327 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 328   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 329   VERIFY HAVE_OPENNI)
 330 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 331   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 332   VERIFY HAVE_OPENNI2)
 333 OCV_OPTION(WITH_PNG "Include PNG support" ON
 334   VISIBLE_IF TRUE
 335   VERIFY HAVE_PNG)
 336 OCV_OPTION(WITH_SPNG "Include SPNG support" OFF
 337   VISIBLE_IF TRUE
 338   VERIFY HAVE_SPNG)
 339 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 340   VISIBLE_IF TRUE
 341   VERIFY HAVE_GDCM)
 342 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 343   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 344   VERIFY HAVE_PVAPI)
 345 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 346   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 347   VERIFY HAVE_ARAVIS_API)
 348 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 349   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 350   VERIFY HAVE_QT)
 351 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 352   VISIBLE_IF WIN32 AND NOT WINRT
 353   VERIFY HAVE_WIN32UI)
 354 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 355   VISIBLE_IF NOT IOS AND NOT WINRT
 356   VERIFY HAVE_TBB)
 357 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 358   VISIBLE_IF TRUE
 359   VERIFY HAVE_HPX)
 360 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 361   VISIBLE_IF TRUE
 362   VERIFY HAVE_OPENMP)
 363 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 364   VISIBLE_IF NOT WIN32 OR MINGW
 365   VERIFY HAVE_PTHREADS_PF)
 366 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 367   VISIBLE_IF NOT IOS
 368   VERIFY HAVE_TIFF)
 369 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 370   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 371   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 372 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 373   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 374   VERIFY HAVE_DSHOW)
 375 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 376   VISIBLE_IF WIN32
 377   VERIFY HAVE_MSMF)
 378 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 379   VISIBLE_IF WIN32
 380   VERIFY HAVE_MSMF_DXVA)
 381 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 382   VISIBLE_IF NOT ANDROID AND NOT WINRT
 383   VERIFY HAVE_XIMEA)
 384 OCV_OPTION(WITH_UEYE "Include UEYE camera support" OFF
 385   VISIBLE_IF NOT ANDROID AND NOT APPLE AND NOT WINRT
 386   VERIFY HAVE_UEYE)
 387 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 388   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 389   VERIFY HAVE_XINE)
 390 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 391   VISIBLE_IF TRUE
 392   VERIFY HAVE_CLP)
 393 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 394   VISIBLE_IF NOT IOS AND NOT WINRT
 395   VERIFY HAVE_OPENCL)
 396 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 397   VISIBLE_IF TRUE
 398   VERIFY HAVE_OPENCL_SVM) # experimental
 399 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 400   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 401   VERIFY HAVE_CLAMDFFT)
 402 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 403   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 404   VERIFY HAVE_CLAMDBLAS)
 405 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 406   VISIBLE_IF WIN32 AND NOT WINRT
 407   VERIFY HAVE_DIRECTX)
 408 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 409   VISIBLE_IF WIN32 AND NOT WINRT
 410   VERIFY HAVE_OPENCL_D3D11_NV)
 411 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 412   VISIBLE_IF NOT WITH_INTELPERC
 413   VERIFY HAVE_LIBREALSENSE)
 414 OCV_OPTION(WITH_VA "Include VA support" (X86_64 OR X86)
 415   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 416   VERIFY HAVE_VA)
 417 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" (X86_64 OR X86)
 418   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 419   VERIFY HAVE_VA_INTEL)
 420 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 421   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 422   VERIFY HAVE_MFX)
 423 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 424   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 425   VERIFY HAVE_GDAL)
 426 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 427   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 428   VERIFY HAVE_GPHOTO2)
 429 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 430   VISIBLE_IF NOT ANDROID AND NOT IOS
 431   VERIFY HAVE_LAPACK)
 432 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 433   VISIBLE_IF NOT APPLE_FRAMEWORK
 434   VERIFY HAVE_ITT)
 435 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 436   VISIBLE_IF TRUE
 437   VERIFY HAVE_PROTOBUF)
 438 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 439   VISIBLE_IF TRUE
 440   VERIFY HAVE_IMGCODEC_HDR)
 441 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 442   VISIBLE_IF TRUE
 443   VERIFY HAVE_IMGCODEC_SUNRASTER)
 444 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 445   VISIBLE_IF TRUE
 446   VERIFY HAVE_IMGCODEC_PXM)
 447 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 448   VISIBLE_IF TRUE
 449   VERIFY HAVE_IMGCODEC_PFM)
 450 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 451   VISIBLE_IF TRUE
 452   VERIFY HAVE_QUIRC)
 453 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 454   VISIBLE_IF ANDROID
 455   VERIFY HAVE_ANDROID_MEDIANDK)
 456 OCV_OPTION(WITH_ANDROID_NATIVE_CAMERA "Use Android NDK for Camera I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 23)
 457   VISIBLE_IF ANDROID
 458   VERIFY HAVE_ANDROID_NATIVE_CAMERA)
 459 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 460   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 461   VERIFY HAVE_TENGINE)
 462 OCV_OPTION(WITH_ONNX "Include Microsoft ONNX Runtime support" OFF
 463   VISIBLE_IF TRUE
 464   VERIFY HAVE_ONNX)
 465 OCV_OPTION(WITH_TIMVX "Include Tim-VX support" OFF
 466   VISIBLE_IF TRUE
 467   VERIFY HAVE_TIMVX)
 468 OCV_OPTION(WITH_OBSENSOR "Include obsensor support (Orbbec RGB-D modules: Astra+/Femto)" ON
 469   VISIBLE_IF (WIN32 AND NOT ARM AND NOT WINRT) OR ( UNIX AND NOT APPLE AND NOT ANDROID)
 470   VERIFY HAVE_OBSENSOR)
 471 OCV_OPTION(WITH_CANN "Include CANN support" OFF
 472   VISIBLE_IF TRUE
 473   VERIFY HAVE_CANN)
 474
 475 # OpenCV build components
 476 # ===================================================
 477 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 478 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 479 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 480 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 481 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 482 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 483 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 484 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 485 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 486 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 487 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 488 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 489 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 490 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 491 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 492 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 493 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 494 OCV_OPTION(BUILD_OBJC               "Enable Objective-C support"                  ON  IF APPLE_FRAMEWORK )
 495 OCV_OPTION(BUILD_KOTLIN_EXTENSIONS  "Build Kotlin extensions (Android)"           ON  IF ANDROID )
 496
 497 # OpenCV installation options
 498 # ===================================================
 499 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 500 OCV_OPTION(INSTALL_BIN_EXAMPLES     "Install prebuilt examples" WIN32 IF BUILD_EXAMPLES)
 501 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 502 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 503 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 504 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 505 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 506
 507 # OpenCV build options
 508 # ===================================================
 509 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja" OR CMAKE_GENERATOR MATCHES "Xcode")) )
 510 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 511 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 512 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 513 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 514 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 515 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 516 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 517 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 518 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS) AND CMAKE_CROSSCOMPILING)  # Use CPU_BASELINE instead
 519 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 520 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 521 endif()
 522 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 523 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 524 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 525 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 526 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 527 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF CV_GCC )
 528 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 529 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 530 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 531 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 532 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 533 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 534 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 535 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 536 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 537 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 538 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 539 OCV_OPTION(OPENCV_DISABLE_FILESYSTEM_SUPPORT "Disable filesystem support" OFF)
 540 OCV_OPTION(OPENCV_DISABLE_THREAD_SUPPORT "Build the library without multi-threaded code." OFF)
 541 OCV_OPTION(OPENCV_SEMIHOSTING         "Build the library for semihosting target (Arm). See https://developer.arm.com/documentation/100863/latest." OFF)
 542
 543 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 544 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 545
 546 if(ENABLE_IMPL_COLLECTION)
 547   add_definitions(-DCV_COLLECT_IMPL_DATA)
 548 endif()
 549
 550 if(OPENCV_DISABLE_FILESYSTEM_SUPPORT)
 551   add_definitions(-DOPENCV_HAVE_FILESYSTEM_SUPPORT=0)
 552 endif()
 553
 554 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 555
 556 # ----------------------------------------------------------------------------
 557 #  Get actual OpenCV version number from sources
 558 # ----------------------------------------------------------------------------
 559 include(cmake/OpenCVVersion.cmake)
 560
 561 ocv_cmake_hook(POST_OPTIONS)
 562
 563 # ----------------------------------------------------------------------------
 564 #  Build & install layouts
 565 # ----------------------------------------------------------------------------
 566
 567 if(OPENCV_TEST_DATA_PATH)
 568   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 569 endif()
 570
 571 # Save libs and executables in the same place
 572 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 573
 574 if(ANDROID)
 575   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 576   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 577 else()
 578   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 579   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 580 endif()
 581
 582 if(ANDROID)
 583   if(ANDROID_ABI MATCHES "NEON")
 584     set(ENABLE_NEON ON)
 585   endif()
 586   if(ANDROID_ABI MATCHES "VFPV3")
 587     set(ENABLE_VFPV3 ON)
 588   endif()
 589 endif()
 590
 591 if(WIN32)
 592   # Postfix of DLLs:
 593   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 594   ocv_update(OPENCV_DEBUG_POSTFIX d)
 595 else()
 596   # Postfix of so's:
 597   ocv_update(OPENCV_DLLVERSION "")
 598   ocv_update(OPENCV_DEBUG_POSTFIX "")
 599 endif()
 600
 601 if(DEFINED CMAKE_DEBUG_POSTFIX)
 602   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 603 endif()
 604
 605 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 606   set(BUILD_opencv_world ON CACHE INTERNAL "")
 607 endif()
 608
 609 include(cmake/OpenCVInstallLayout.cmake)
 610
 611 # ----------------------------------------------------------------------------
 612 #  Path for build/platform -specific headers
 613 # ----------------------------------------------------------------------------
 614 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 615 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 616
 617 # ----------------------------------------------------------------------------
 618 #  Path for additional modules
 619 # ----------------------------------------------------------------------------
 620 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 621
 622 # ----------------------------------------------------------------------------
 623 #  Autodetect if we are in a GIT repository
 624 # ----------------------------------------------------------------------------
 625 find_host_package(Git QUIET)
 626
 627 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 628   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 629 elseif(NOT DEFINED OPENCV_VCSVERSION)
 630   # We don't have git:
 631   set(OPENCV_VCSVERSION "unknown")
 632 endif()
 633
 634
 635 # ----------------------------------------------------------------------------
 636 # OpenCV compiler and linker options
 637 # ----------------------------------------------------------------------------
 638
 639 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 640
 641 # --- Python Support ---
 642 if(NOT IOS)
 643   include(cmake/OpenCVDetectPython.cmake)
 644 endif()
 645
 646 include(cmake/OpenCVCompilerOptions.cmake)
 647
 648 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 649
 650 # ----------------------------------------------------------------------------
 651 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 652 # ----------------------------------------------------------------------------
 653 if(UNIX OR MINGW)
 654   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 655     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 656         AND NOT OPENCV_ENABLE_PKG_CONFIG
 657     )
 658       if(NOT PkgConfig_FOUND)
 659         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 660       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 661         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 662       endif()
 663     elseif(OPENCV_DISABLE_PKG_CONFIG)
 664       if(PkgConfig_FOUND)
 665         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 666       endif()
 667     else()
 668       find_package(PkgConfig QUIET)
 669     endif()
 670   endif()
 671   include(CheckFunctionExists)
 672   include(CheckIncludeFile)
 673   include(CheckSymbolExists)
 674
 675   if(NOT APPLE)
 676     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 677     if(ANDROID)
 678       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 679     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 680       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 681     elseif(EMSCRIPTEN)
 682       # no need to link to system libs with emscripten
 683     elseif(QNXNTO)
 684       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m)
 685     elseif(MINGW)
 686       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} pthread)
 687     else()
 688       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 689     endif()
 690   else()
 691     set(HAVE_PTHREAD 1)
 692   endif()
 693
 694   # Ensure that libpthread is not listed as one of the libraries to pass to the linker.
 695   if (OPENCV_DISABLE_THREAD_SUPPORT)
 696     list(REMOVE_ITEM OPENCV_LINKER_LIBS pthread)
 697   endif()
 698
 699   if(OPENCV_ENABLE_MEMALIGN)
 700     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 701     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 702     if(HAVE_MALLOC_H)
 703       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 704     endif()
 705     # TODO:
 706     # - std::aligned_alloc() C++17 / C11
 707   endif()
 708 elseif(WIN32)
 709   include(CheckIncludeFile)
 710   include(CheckSymbolExists)
 711
 712   if(OPENCV_ENABLE_MEMALIGN)
 713     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 714     if(HAVE_MALLOC_H)
 715       CHECK_SYMBOL_EXISTS(_aligned_malloc malloc.h HAVE_WIN32_ALIGNED_MALLOC)
 716     endif()
 717   endif()
 718 endif()
 719
 720 include(cmake/OpenCVPCHSupport.cmake)
 721 include(cmake/OpenCVModule.cmake)
 722
 723 # ----------------------------------------------------------------------------
 724 #  Detect endianness of build platform
 725 # ----------------------------------------------------------------------------
 726
 727 if(IOS)
 728   # test_big_endian needs try_compile, which doesn't work for iOS
 729   # http://public.kitware.com/Bug/view.php?id=12288
 730   set(WORDS_BIGENDIAN 0)
 731 else()
 732   include(TestBigEndian)
 733   test_big_endian(WORDS_BIGENDIAN)
 734 endif()
 735
 736 # ----------------------------------------------------------------------------
 737 #  Detect 3rd-party libraries
 738 # ----------------------------------------------------------------------------
 739
 740 if(ANDROID AND WITH_CPUFEATURES)
 741   add_subdirectory(3rdparty/cpufeatures)
 742   set(HAVE_CPUFEATURES 1)
 743 endif()
 744
 745 include(cmake/OpenCVFindFrameworks.cmake)
 746
 747 include(cmake/OpenCVFindLibsGrfmt.cmake)
 748 include(cmake/OpenCVFindLibsGUI.cmake)
 749 include(cmake/OpenCVFindLibsVideo.cmake)
 750 include(cmake/OpenCVFindLibsPerf.cmake)
 751 include(cmake/OpenCVFindLAPACK.cmake)
 752 include(cmake/OpenCVFindProtobuf.cmake)
 753 if(WITH_TENGINE)
 754   include(cmake/OpenCVFindTengine.cmake)
 755 endif()
 756 if(WITH_TIMVX)
 757   include(cmake/OpenCVFindTIMVX.cmake)
 758 endif()
 759 if(WITH_CANN)
 760   include(cmake/OpenCVFindCANN.cmake)
 761 endif()
 762
 763 # ----------------------------------------------------------------------------
 764 #  Detect other 3rd-party libraries/tools
 765 # ----------------------------------------------------------------------------
 766
 767 # --- Java Support ---
 768 if(BUILD_JAVA)
 769   if(ANDROID)
 770     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 771   else()
 772     include(cmake/OpenCVDetectApacheAnt.cmake)
 773     find_package(JNI)
 774   endif()
 775 endif()
 776
 777 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 778   include(cmake/OpenCVPylint.cmake)
 779 endif()
 780 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 781   find_package(Flake8 QUIET)
 782   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 783     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 784   endif()
 785   if(FLAKE8_FOUND)
 786     list(APPEND OPENCV_FLAKE8_EXCLUDES ".git" "__pycache__" "config.py" "*.config.py" "config-*.py")
 787     list(APPEND OPENCV_FLAKE8_EXCLUDES "svgfig.py")  # 3rdparty
 788     if(NOT PYTHON3_VERSION_STRING VERSION_GREATER 3.6)
 789       # Python 3.6+ (PEP 526): variable annotations (type hints)
 790       list(APPEND OPENCV_FLAKE8_EXCLUDES "samples/dnn/dnn_model_runner/dnn_conversion/common/test/configs")
 791     endif()
 792     string(REPLACE ";" "," OPENCV_FLAKE8_EXCLUDES_STR "${OPENCV_FLAKE8_EXCLUDES}")
 793     add_custom_target(check_flake8
 794         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='${OPENCV_FLAKE8_EXCLUDES_STR}'
 795         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 796         COMMENT "Running flake8"
 797     )
 798   endif()
 799 endif()
 800
 801
 802 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 803   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 804 else()
 805   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 806 endif()
 807
 808 # --- OpenCL ---
 809 if(WITH_OPENCL)
 810   include(cmake/OpenCVDetectOpenCL.cmake)
 811 endif()
 812
 813 # --- Halide ---
 814 if(WITH_HALIDE)
 815   include(cmake/OpenCVDetectHalide.cmake)
 816 endif()
 817
 818 # --- VkCom ---
 819 if(WITH_VULKAN)
 820   include(cmake/OpenCVDetectVulkan.cmake)
 821 endif()
 822
 823 # --- WebNN ---
 824 if(WITH_WEBNN)
 825   include(cmake/OpenCVDetectWebNN.cmake)
 826 endif()
 827
 828 # --- Inference Engine ---
 829 if(WITH_INF_ENGINE OR WITH_OPENVINO)
 830   include(cmake/OpenCVDetectInferenceEngine.cmake)
 831 endif()
 832
 833 # --- DirectX ---
 834 if(WITH_DIRECTX)
 835   include(cmake/OpenCVDetectDirectX.cmake)
 836 endif()
 837
 838 if(WITH_VTK)
 839   include(cmake/OpenCVDetectVTK.cmake)
 840 endif()
 841
 842 if(WITH_OPENVX)
 843   include(cmake/FindOpenVX.cmake)
 844 endif()
 845
 846 if(WITH_QUIRC)
 847   add_subdirectory(3rdparty/quirc)
 848   set(HAVE_QUIRC TRUE)
 849 endif()
 850
 851 if(WITH_ONNX)
 852   include(cmake/FindONNX.cmake)
 853 endif()
 854
 855 # ----------------------------------------------------------------------------
 856 # OpenCV HAL
 857 # ----------------------------------------------------------------------------
 858 set(_hal_includes "")
 859 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 860   # 1. libraries
 861   foreach (l ${${HAL_LIBRARIES_VAR}})
 862     if(NOT TARGET ${l})
 863       get_filename_component(l "${l}" ABSOLUTE)
 864     endif()
 865     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 866   endforeach()
 867   # 2. headers
 868   foreach (h ${${HAL_HEADERS_VAR}})
 869     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 870   endforeach()
 871   # 3. include paths
 872   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 873 endmacro()
 874
 875 if(NOT DEFINED OpenCV_HAL)
 876   set(OpenCV_HAL "OpenCV_HAL")
 877 endif()
 878
 879 if(HAVE_OPENVX)
 880   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 881     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 882   endif()
 883 endif()
 884
 885 if(WITH_CAROTENE)
 886   ocv_debug_message(STATUS "Enable carotene acceleration")
 887   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 888     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 889   endif()
 890 endif()
 891
 892 foreach(hal ${OpenCV_HAL})
 893   if(hal STREQUAL "carotene")
 894     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 895       add_subdirectory(3rdparty/carotene/hal)
 896       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 897       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 898     else()
 899       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 900     endif()
 901   elseif(hal STREQUAL "openvx")
 902     add_subdirectory(3rdparty/openvx)
 903     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 904     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 905   else()
 906     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 907     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 908     find_package(${hal} NO_MODULE QUIET)
 909     if(${hal}_FOUND)
 910       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 911       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 912     endif()
 913   endif()
 914 endforeach()
 915 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 916 unset(_hal_includes)
 917
 918
 919 # ----------------------------------------------------------------------------
 920 # Code trace support
 921 # ----------------------------------------------------------------------------
 922 if(CV_TRACE)
 923   include(cmake/OpenCVDetectTrace.cmake)
 924 endif()
 925
 926 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 927 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 928
 929 # ----------------------------------------------------------------------------
 930 # Solution folders:
 931 # ----------------------------------------------------------------------------
 932 if(ENABLE_SOLUTION_FOLDERS)
 933   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 934   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 935 endif()
 936
 937 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 938 include(cmake/OpenCVExtraTargets.cmake)
 939
 940 # ----------------------------------------------------------------------------
 941 # Process subdirectories
 942 # ----------------------------------------------------------------------------
 943
 944 # opencv.hpp and legacy headers
 945 add_subdirectory(include)
 946
 947 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 948 ocv_add_modules_compiler_options()
 949
 950 # OpenCV modules
 951 ocv_register_modules()
 952
 953 # Generate targets for documentation
 954 add_subdirectory(doc)
 955
 956 # various data that is used by cv libraries and/or demo applications.
 957 add_subdirectory(data)
 958
 959 # extra applications
 960 if(BUILD_opencv_apps)
 961   add_subdirectory(apps)
 962 endif()
 963
 964 # examples
 965 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 966   add_subdirectory(samples)
 967 endif()
 968
 969 if(ANDROID)
 970   add_subdirectory(platforms/android/service)
 971 endif()
 972
 973 # ----------------------------------------------------------------------------
 974 # Finalization: generate configuration-based files
 975 # ----------------------------------------------------------------------------
 976
 977 ocv_cmake_hook(PRE_FINALIZE)
 978
 979 # Generate platform-dependent and configuration-dependent headers
 980 include(cmake/OpenCVGenHeaders.cmake)
 981
 982 # Generate opencv.pc for pkg-config command
 983 if(OPENCV_GENERATE_PKGCONFIG)
 984   include(cmake/OpenCVGenPkgconfig.cmake)
 985 endif()
 986
 987 # Generate OpenCV.mk for ndk-build (Android build tool)
 988 include(cmake/OpenCVGenAndroidMK.cmake)
 989
 990 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 991 include(cmake/OpenCVGenConfig.cmake)
 992
 993 # Generate Info.plist for the IOS framework
 994 if(APPLE_FRAMEWORK)
 995   include(cmake/OpenCVGenInfoPlist.cmake)
 996 endif()
 997
 998 # Generate ABI descriptor
 999 include(cmake/OpenCVGenABI.cmake)
1000
1001 # Generate environment setup file
1002 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
1003   if(ANDROID)
1004     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
1005     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
1006                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
1007     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
1008             DESTINATION ./ COMPONENT tests)
1009   elseif(WIN32)
1010     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
1011                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
1012     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
1013             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
1014   elseif(UNIX)
1015     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
1016                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
1017     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
1018             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
1019   endif()
1020 endif()
1021
1022 if(NOT OPENCV_README_FILE)
1023   if(ANDROID)
1024     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
1025   endif()
1026 endif()
1027
1028 if(NOT OPENCV_LICENSE_FILE)
1029   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
1030 endif()
1031
1032 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
1033 if(ANDROID OR NOT UNIX)
1034   install(FILES ${OPENCV_LICENSE_FILE}
1035         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
1036         DESTINATION ./ COMPONENT libs)
1037   if(OPENCV_README_FILE)
1038     install(FILES ${OPENCV_README_FILE}
1039             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
1040             DESTINATION ./ COMPONENT libs)
1041   endif()
1042 endif()
1043
1044 if(COMMAND ocv_pylint_finalize)
1045   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
1046   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
1047   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
1048   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
1049   ocv_pylint_finalize()
1050 endif()
1051 if(TARGET check_pylint)
1052   message(STATUS "Registered 'check_pylint' target: using ${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}), checks: ${PYLINT_TOTAL_TARGETS}")
1053 endif()
1054 if(TARGET check_flake8)
1055   message(STATUS "Registered 'check_flake8' target: using ${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})")
1056 endif()
1057
1058 if(OPENCV_GENERATE_SETUPVARS)
1059   include(cmake/OpenCVGenSetupVars.cmake)
1060 endif()
1061
1062 # ----------------------------------------------------------------------------
1063 # Summary:
1064 # ----------------------------------------------------------------------------
1065 status("")
1066 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
1067 if(OPENCV_VCSVERSION)
1068   status("  Version control:" ${OPENCV_VCSVERSION})
1069 endif()
1070 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
1071   set(__dump_extra_header OFF)
1072   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
1073     if(EXISTS ${p})
1074       if(NOT __dump_extra_header)
1075         set(__dump_extra_header ON)
1076         status("")
1077         status("  Extra modules:")
1078       else()
1079         status("")
1080       endif()
1081       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
1082       status("    Location (extra):" ${p})
1083       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1084     endif()
1085   endforeach()
1086   unset(__dump_extra_header)
1087 endif()
1088
1089 # ========================== build platform ==========================
1090 status("")
1091 status("  Platform:")
1092 if(NOT DEFINED OPENCV_TIMESTAMP
1093     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1094 )
1095   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1096   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1097 endif()
1098 if(OPENCV_TIMESTAMP)
1099   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1100 endif()
1101 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1102 if(CMAKE_CROSSCOMPILING)
1103   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1104 endif()
1105 status("    CMake:"            ${CMAKE_VERSION})
1106 status("    CMake generator:"  ${CMAKE_GENERATOR})
1107 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1108 if(MSVC)
1109   status("    MSVC:"           ${MSVC_VERSION})
1110 endif()
1111 if(CMAKE_GENERATOR MATCHES Xcode)
1112   status("    Xcode:"          ${XCODE_VERSION})
1113 endif()
1114 if(CMAKE_GENERATOR MATCHES "Xcode|Visual Studio|Multi-Config")
1115   status("    Configuration:"  ${CMAKE_CONFIGURATION_TYPES})
1116 else()
1117   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1118 endif()
1119
1120
1121 # ========================= CPU code generation mode =========================
1122 status("")
1123 status("  CPU/HW features:")
1124 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1125 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1126   status("      requested:"  "${CPU_BASELINE}")
1127 endif()
1128 if(CPU_BASELINE_REQUIRE)
1129   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1130 endif()
1131 if(CPU_BASELINE_DISABLE)
1132   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1133 endif()
1134 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1135   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1136   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1137     status("      requested:"  "${CPU_DISPATCH}")
1138   endif()
1139   if(CPU_DISPATCH_REQUIRE)
1140     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1141   endif()
1142   foreach(OPT ${CPU_DISPATCH_FINAL})
1143     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1144   endforeach()
1145 endif()
1146
1147 # ========================== C/C++ options ==========================
1148 if(CMAKE_CXX_COMPILER_VERSION)
1149   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1150 else()
1151   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1152 endif()
1153 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1154
1155 status("")
1156 status("  C/C++:")
1157 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1158 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1159   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1160 endif()
1161 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1162 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1163 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1164 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1165 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1166 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1167 if(WIN32)
1168   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1169   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1170 else()
1171   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1172   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1173 endif()
1174 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1175 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1176
1177 if(OPENCV_DISABLE_FILESYSTEM_SUPPORT)
1178   status("    Filesystem support is disabled")
1179 endif()
1180
1181 # ========================== Dependencies ============================
1182 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1183 status("    Extra dependencies:" ${deps_extra})
1184 status("    3rdparty dependencies:" ${deps_3rdparty})
1185
1186 # ========================== OpenCV modules ==========================
1187 status("")
1188 status("  OpenCV modules:")
1189 set(OPENCV_MODULES_BUILD_ST "")
1190 foreach(the_module ${OPENCV_MODULES_BUILD})
1191   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1192     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1193   endif()
1194 endforeach()
1195 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1196 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1197 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1198 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1199 list(SORT OPENCV_MODULES_BUILD_ST)
1200 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1201 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1202 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1203 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1204 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1205 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1206 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1207
1208 ocv_build_features_string(apps_status
1209   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1210   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1211   IF BUILD_EXAMPLES THEN "examples"
1212   IF BUILD_opencv_apps THEN "apps"
1213   IF BUILD_ANDROID_SERVICE THEN "android_service"
1214   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1215   ELSE "-")
1216 status("    Applications:" "${apps_status}")
1217 ocv_build_features_string(docs_status
1218     IF TARGET doxygen_cpp THEN "doxygen"
1219     IF TARGET doxygen_python THEN "python"
1220     IF TARGET doxygen_javadoc THEN "javadoc"
1221     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1222     ELSE "NO"
1223 )
1224 status("    Documentation:" "${docs_status}")
1225 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1226
1227 # ========================== Android details ==========================
1228 if(ANDROID)
1229   status("")
1230   if(DEFINED ANDROID_NDK_REVISION)
1231     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1232   else()
1233     set(__msg "location: ${ANDROID_NDK}")
1234   endif()
1235   status("  Android NDK: " ${__msg})
1236   status("    Android ABI:" ${ANDROID_ABI})
1237   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1238     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1239   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1240     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1241   endif()
1242   status("    STL type:" ${ANDROID_STL})
1243   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1244
1245   if(BUILD_ANDROID_PROJECTS)
1246     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1247     if(ANDROID_EXECUTABLE)
1248       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1249     endif()
1250   else()
1251     status("  Android SDK: " "not used, projects are not built")
1252   endif()
1253   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1254     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1255   endif()
1256   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1257     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1258       status("    Projects build scripts:" "Ant/Eclipse compatible")
1259     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1260       status("    Projects build scripts:" "Gradle")
1261     endif()
1262   endif()
1263 endif()
1264
1265 # ================== Windows RT features ==================
1266 if(WIN32)
1267 status("")
1268 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1269   if(WINRT)
1270     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1271     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1272     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1273     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1274       status("    Building for C++ without CX extensions")
1275     endif()
1276   endif()
1277 endif(WIN32)
1278
1279 # ========================== GUI ==========================
1280 status("")
1281 status("  GUI: " "${OPENCV_HIGHGUI_BUILTIN_BACKEND}")
1282
1283 if(WITH_WAYLAND OR HAVE_WAYLAND)
1284   if(HAVE_WAYLAND_CLIENT)
1285     status("    Wayland Client:" "YES (ver ${WAYLAND_CLIENT_VERSION})")
1286   endif()
1287   if(HAVE_WAYLAND_CURSOR)
1288     status("    Wayland Cursor:" "YES (ver ${WAYLAND_CURSOR_VERSION})")
1289   endif()
1290   if(HAVE_WAYLAND_PROTOCOL)
1291     status("    Wayland Protocol:" "YES (ver ${WAYLAND_PROTOCOL_VERSION})")
1292   endif()
1293   if(HAVE_WAYLAND_EGL)
1294     status("    Wayland EGL:" "YES (ver ${WAYLAND_EGL_VERSION})")
1295   endif()
1296   if(HAVE_XKBCOMMON)
1297     status("    Xkbcommon:" "YES (ver ${XKBCOMMON_VERSION})")
1298   endif()
1299 endif()
1300
1301 if(WITH_QT OR HAVE_QT)
1302   if(HAVE_QT)
1303     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1304     if(HAVE_QT_OPENGL)
1305       if(Qt${QT_VERSION_MAJOR}OpenGL_LIBRARIES)
1306         status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt${QT_VERSION_MAJOR}OpenGL_LIBRARIES} ${Qt${QT_VERSION_MAJOR}OpenGL_VERSION_STRING})" ELSE NO)
1307       else()
1308         status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1309       endif()
1310     else()
1311       status("      QT OpenGL support:" "NO")
1312     endif()
1313   else()
1314     status("    QT:" "NO")
1315   endif()
1316 endif()
1317
1318 if(WITH_WIN32UI)
1319   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1320 endif()
1321
1322 if(HAVE_COCOA)  # APPLE
1323   status("    Cocoa:"  YES)
1324 endif()
1325
1326 if(WITH_GTK OR HAVE_GTK)
1327   if(HAVE_GTK3)
1328     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1329   elseif(HAVE_GTK)
1330     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1331   else()
1332     status("    GTK+:" "NO")
1333   endif()
1334   if(HAVE_GTK)
1335     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1336     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1337   endif()
1338 endif()
1339
1340 if(WITH_OPENGL OR HAVE_OPENGL)
1341   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1342 endif()
1343
1344 if(WITH_VTK OR HAVE_VTK)
1345   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1346 endif()
1347
1348 # ========================== MEDIA IO ==========================
1349 status("")
1350 status("  Media I/O: ")
1351 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1352
1353 if(WITH_JPEG OR HAVE_JPEG)
1354   if(NOT HAVE_JPEG)
1355     status("    JPEG:" NO)
1356   elseif(BUILD_JPEG)
1357     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1358     if(ENABLE_LIBJPEG_TURBO_SIMD)
1359       status("      SIMD Support Request:" "YES")
1360       if(HAVE_LIBJPEG_TURBO_SIMD)
1361         status("      SIMD Support:" "YES")
1362       else()
1363         status("      SIMD Support:" "NO")
1364       endif()
1365     else()
1366       status("      SIMD Support Request:" "NO")
1367     endif()
1368   else()
1369     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1370   endif()
1371 endif()
1372
1373 if(WITH_WEBP OR HAVE_WEBP)
1374   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1375 endif()
1376
1377 if(WITH_PNG OR HAVE_PNG OR WITH_SPNG)
1378   if(WITH_SPNG)
1379     status("    PNG:" "build-${SPNG_LIBRARY} (ver ${SPNG_VERSION})")
1380   else()
1381     status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1382   endif()
1383 endif()
1384
1385 if(WITH_TIFF OR HAVE_TIFF)
1386   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1387 endif()
1388
1389 if(HAVE_OPENJPEG)
1390   status("    JPEG 2000:" OpenJPEG_FOUND
1391       THEN "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})"
1392       ELSE "build (ver ${OPENJPEG_VERSION})"
1393   )
1394 elseif(HAVE_JASPER)
1395   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1396 elseif(WITH_OPENJPEG OR WITH_JASPER)
1397   status("    JPEG 2000:" "NO")
1398 endif()
1399
1400 if(WITH_OPENEXR OR HAVE_OPENEXR)
1401   if(HAVE_OPENEXR)
1402     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1403   else()
1404     status("    OpenEXR:" "NO")
1405   endif()
1406 endif()
1407
1408 if(WITH_GDAL OR HAVE_GDAL)
1409   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1410 endif()
1411
1412 if(WITH_GDCM OR HAVE_GDCM)
1413   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1414 endif()
1415
1416 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1417   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1418 endif()
1419
1420 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1421   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1422 endif()
1423
1424 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1425   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1426 endif()
1427
1428 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1429   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1430 endif()
1431
1432 # ========================== VIDEO IO ==========================
1433 status("")
1434 status("  Video I/O:")
1435
1436 if(WITH_1394 OR HAVE_DC1394_2)
1437   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1438 endif()
1439
1440 if(WITH_FFMPEG OR HAVE_FFMPEG)
1441   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1442     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1443   elseif(WIN32)
1444     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1445   else()
1446     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1447   endif()
1448   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1449   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1450   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1451   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1452   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1453   if(OPENCV_FFMPEG_ENABLE_LIBAVDEVICE)
1454     status("      avdevice:"     FFMPEG_libavdevice_VERSION   THEN "YES (${FFMPEG_libavdevice_VERSION})"   ELSE NO)
1455   endif()
1456 endif()
1457
1458 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1459   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1460 endif()
1461
1462 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1463   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1464 endif()
1465
1466 if(WITH_PVAPI OR HAVE_PVAPI)
1467   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1468 endif()
1469
1470 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1471   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1472 endif()
1473
1474 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1475   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1476 endif()
1477
1478 if(HAVE_CAP_IOS)
1479   status("    iOS capture:" YES)
1480 endif()
1481
1482 if(WITH_V4L OR HAVE_V4L)
1483   ocv_build_features_string(v4l_status
1484     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1485     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1486     ELSE "NO")
1487   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1488 endif()
1489
1490 if(WITH_DSHOW OR HAVE_DSHOW)
1491   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1492 endif()
1493
1494 if(WITH_MSMF OR HAVE_MSMF)
1495   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1496   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1497 endif()
1498
1499 if(WITH_XIMEA OR HAVE_XIMEA)
1500   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1501 endif()
1502
1503 if(WITH_UEYE OR HAVE_UEYE)
1504   status("    uEye:" HAVE_UEYE THEN YES ELSE NO)
1505 endif()
1506
1507 if(WITH_XINE OR HAVE_XINE)
1508   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1509 endif()
1510
1511 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1512   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1513 endif()
1514
1515 if(WITH_MFX OR HAVE_MFX)
1516   if(HAVE_MFX)
1517     if(MFX_LIBRARY)
1518       set(__details " (${MFX_LIBRARY})")
1519     elseif(MFX_LIBRARIES)
1520       set(__details " (${MFX_LIBRARIES})")
1521     else()
1522       set(__details " (unknown)")
1523     endif()
1524   endif()
1525   status("    Intel Media SDK:" HAVE_MFX      THEN "YES${__details}" ELSE NO)
1526 endif()
1527
1528 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1529   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1530 endif()
1531
1532 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1533 ocv_build_features_string(parallel_status EXCLUSIVE
1534   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1535   IF HAVE_HPX THEN "HPX"
1536   IF HAVE_OPENMP THEN "OpenMP"
1537   IF HAVE_GCD THEN "GCD"
1538   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1539   IF HAVE_PTHREADS_PF THEN "pthreads"
1540   ELSE "none")
1541 status("")
1542 status("  Parallel framework:" "${parallel_status}")
1543 if (OPENCV_DISABLE_THREAD_SUPPORT)
1544   status("" "Multi thread code explicitly disabled with OPENCV_DISABLE_THREAD_SUPPORT.")
1545   if(HAVE_PTHREADS_PF OR HAVE_HPX OR HAVE_OPENMP OR HAVE_GCD OR HAVE_CONCURRENCY)
1546     message(FATAL_ERROR "Not all parallel frameworks have been disabled (using ${parallel_status}).")
1547   endif()
1548   if(HAVE_PTHREAD)
1549     message(FATAL_ERROR "Thread execution might be in use in some component.")
1550   endif()
1551 endif()
1552
1553 if(CV_TRACE OR OPENCV_TRACE)
1554   ocv_build_features_string(trace_status EXCLUSIVE
1555     IF HAVE_ITT THEN "with Intel ITT"
1556     ELSE "built-in")
1557   status("")
1558   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1559 endif()
1560
1561 # ========================== Other third-party libraries ==========================
1562 status("")
1563 status("  Other third-party libraries:")
1564
1565 if(WITH_IPP AND HAVE_IPP)
1566   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1567   status("           at:" "${IPP_ROOT_DIR}")
1568   if(NOT HAVE_IPP_ICV)
1569     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1570   endif()
1571   if(HAVE_IPP_IW)
1572     if(BUILD_IPP_IW)
1573       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1574     else()
1575       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1576     endif()
1577     status("              at:" "${IPP_IW_PATH}")
1578   else()
1579     status("    Intel IPP IW:"   NO)
1580   endif()
1581 endif()
1582
1583 if(WITH_VA OR HAVE_VA)
1584   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1585 endif()
1586
1587 if(WITH_TENGINE OR HAVE_TENGINE)
1588   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1589 endif()
1590
1591 if(WITH_LAPACK OR HAVE_LAPACK)
1592   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1593 endif()
1594
1595 if(WITH_HALIDE OR HAVE_HALIDE)
1596   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1597 endif()
1598
1599 if(HAVE_OPENVINO
1600     OR (WITH_OPENVINO AND NOT WITH_INF_ENGINE AND NOT INF_ENGINE_TARGET)
1601 )
1602   status("    OpenVINO:" TARGET openvino::runtime THEN "YES (${OpenVINO_VERSION})" ELSE "NO")
1603 else()
1604   if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1605     if(INF_ENGINE_TARGET)
1606       list(GET INF_ENGINE_TARGET 0 ie_target)
1607       set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1608       ocv_get_imported_target(ie_target "${ie_target}")
1609       get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1610       get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1611       get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1612       get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1613       get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1614       ocv_build_features_string(_lib
1615         IF _lib THEN "${_lib}"
1616         IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1617         IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1618         IF _lib_rel  THEN "${_lib_rel}"
1619         IF _lib_dbg  THEN "${_lib_dbg}"
1620         ELSE "unknown"
1621       )
1622       get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1623       status("    Inference Engine:" "${__msg}")
1624       status("        * libs:" "${_lib}")
1625       status("        * includes:" "${_inc}")
1626     else()
1627       status("    Inference Engine:"     "NO")
1628     endif()
1629   endif()
1630   if(WITH_NGRAPH OR HAVE_NGRAPH)
1631     if(HAVE_NGRAPH)
1632       ocv_get_imported_target(__target ngraph::ngraph)
1633       set(__msg "YES (${ngraph_VERSION})")
1634       get_target_property(_lib ${__target} IMPORTED_LOCATION)
1635       get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1636       get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1637       get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1638       get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1639       ocv_build_features_string(_lib
1640         IF _lib THEN "${_lib}"
1641         IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1642         IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1643         IF _lib_rel  THEN "${_lib_rel}"
1644         IF _lib_dbg  THEN "${_lib_dbg}"
1645         ELSE "unknown"
1646       )
1647       get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1648       status("    nGraph:" "${__msg}")
1649       status("        * libs:" "${_lib}")
1650       status("        * includes:" "${_inc}")
1651     else()
1652       status("    nGraph:"     "NO")
1653     endif()
1654   endif()
1655 endif()
1656
1657 if(WITH_EIGEN OR HAVE_EIGEN)
1658   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1659 endif()
1660
1661 if(WITH_OPENVX OR HAVE_OPENVX)
1662   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1663 endif()
1664
1665 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1666
1667 foreach(s ${CUSTOM_STATUS})
1668   status(${CUSTOM_STATUS_${s}})
1669 endforeach()
1670
1671 if(WITH_CUDA OR HAVE_CUDA)
1672   ocv_build_features_string(cuda_features
1673     IF HAVE_CUFFT THEN "CUFFT"
1674     IF HAVE_CUBLAS THEN "CUBLAS"
1675     IF HAVE_NVCUVID THEN "NVCUVID"
1676     IF HAVE_NVCUVENC THEN "NVCUVENC"
1677     IF CUDA_FAST_MATH THEN "FAST_MATH"
1678     ELSE "no extra features")
1679   status("")
1680   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1681   if(HAVE_CUDA)
1682     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1683     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1684   endif()
1685  endif()
1686
1687  if(WITH_CUDNN OR HAVE_CUDNN)
1688     status("")
1689     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1690 endif()
1691
1692 if(WITH_VULKAN OR HAVE_VULKAN)
1693   status("")
1694   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1695   if(HAVE_VULKAN)
1696     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1697     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1698   endif()
1699 endif()
1700
1701 if(WITH_WEBNN OR HAVE_WEBNN)
1702   status("")
1703   status("  WebNN:"     HAVE_WEBNN THEN "YES" ELSE "NO")
1704   if(HAVE_WEBNN AND NOT EMSCRIPTEN)
1705     status("    Include path:"  WEBNN_HEADER_DIRS THEN "${WEBNN_HEADER_DIRS}" ELSE "NO")
1706     status("    Link libraries:" WEBNN_LIBRARIES THEN "${WEBNN_LIBRARIES}" ELSE "NO")
1707   endif()
1708 endif()
1709
1710 if(WITH_TIMVX)
1711   status("")
1712   status("  Tim-VX:"     HAVE_TIMVX THEN "YES" ELSE "NO")
1713   if(HAVE_TIMVX)
1714     status("    Include path"  TIMVX_INCLUDE_DIR THEN "${TIMVX_INCLUDE_DIR}" ELSE "NO")
1715     status("    Link libraries:" TIMVX_LIBRARY THEN "${TIMVX_LIBRARY}" ELSE "NO")
1716     status("    VIVANTE SDK path" VIVANTE_SDK_DIR THEN "${VIVANTE_SDK_DIR}" ELSE "NO")
1717   endif()
1718 endif()
1719
1720 if(WITH_OPENCL OR HAVE_OPENCL)
1721   ocv_build_features_string(opencl_features
1722     IF HAVE_OPENCL_SVM THEN "SVM"
1723     IF HAVE_CLAMDFFT THEN "AMDFFT"
1724     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1725     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1726     IF HAVE_VA_INTEL THEN "INTELVA"
1727     ELSE "no extra features")
1728   status("")
1729   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1730   if(HAVE_OPENCL)
1731     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1732     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1733   endif()
1734 endif()
1735
1736 if(WITH_ONNX OR HAVE_ONNX)
1737   status("")
1738   status("  ONNX:"     HAVE_ONNX THEN "YES" ELSE "NO")
1739   if(HAVE_ONNX)
1740     status("    Include path:"  ONNX_INCLUDE_DIR THEN "${ONNX_INCLUDE_DIR}" ELSE "NO")
1741     status("    Link libraries:" ONNX_LIBRARIES THEN "${ONNX_LIBRARIES}" ELSE "NO")
1742   endif()
1743 endif()
1744
1745 if(WITH_CANN)
1746   status("")
1747   status("  CANN:"    HAVE_CANN THEN "YES" ELSE "NO")
1748   if(HAVE_CANN)
1749     status("    Include path"     CANN_INCLUDE_DIRS THEN "${CANN_INCLUDE_DIRS}" ELSE "NO")
1750     status("    Link libraries:"  CANN_LIBRARIES    THEN "${CANN_LIBRARIES}"    ELSE "NO")
1751   endif()
1752 endif()
1753
1754 # ========================== python ==========================
1755 if(BUILD_opencv_python2)
1756   status("")
1757   status("  Python 2:")
1758   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1759   if(PYTHON2LIBS_VERSION_STRING)
1760     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1761   else()
1762     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1763   endif()
1764   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1765   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1766 endif()
1767
1768 if(BUILD_opencv_python3)
1769   status("")
1770   status("  Python 3:")
1771   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1772   if(PYTHON3LIBS_VERSION_STRING)
1773     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1774   else()
1775     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1776   endif()
1777   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1778   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1779 endif()
1780
1781 status("")
1782 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1783
1784 # ========================== java ==========================
1785 if(BUILD_JAVA)
1786   status("")
1787   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1788   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1789   if(NOT ANDROID)
1790     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1791   endif()
1792   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1793   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1794 endif()
1795
1796 # ========================== Objective-C =======================
1797 if(BUILD_OBJC)
1798   status("")
1799   status("  Objective-C wrappers:" HAVE_opencv_objc                                                       THEN YES ELSE NO)
1800 endif()
1801
1802 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1803
1804 # ========================== auxiliary ==========================
1805 status("")
1806 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1807 status("-----------------------------------------------------------------")
1808 status("")
1809
1810
1811 ocv_finalize_status()
1812
1813 if(ENABLE_CONFIG_VERIFICATION)
1814   ocv_verify_config()
1815 endif()
1816
1817 if(HAVE_CUDA AND COMMAND CUDA_BUILD_CLEAN_TARGET)
1818   CUDA_BUILD_CLEAN_TARGET()
1819 endif()
1820
1821 ocv_cmake_hook(POST_FINALIZE)
1822
1823 # ----------------------------------------------------------------------------
1824 # CPack stuff
1825 # ----------------------------------------------------------------------------
1826
1827 include(cmake/OpenCVPackaging.cmake)
1828
1829 # This should be the last command
1830 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1831 ocv_cmake_eval(DEBUG_POST ONCE)