CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0066)
  60   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  61 endif()
  62
  63 if(POLICY CMP0067)
  64   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  65 endif()
  66
  67 if(POLICY CMP0068)
  68   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  69 endif()
  70
  71 if(POLICY CMP0075)
  72   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  73 endif()
  74
  75 if(POLICY CMP0077)
  76   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  77 endif()
  78
  79 #
  80 # Configure OpenCV CMake hooks
  81 #
  82 include(cmake/OpenCVUtils.cmake)
  83 ocv_cmake_reset_hooks()
  84 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  85 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  86   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  87     get_filename_component(__dir "${__dir}" ABSOLUTE)
  88     ocv_cmake_hook_register_dir(${__dir})
  89   endforeach()
  90 endif()
  91
  92 ocv_cmake_hook(CMAKE_INIT)
  93
  94 # must go before the project()/enable_language() commands
  95 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  96 if(DEFINED CMAKE_BUILD_TYPE)
  97   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  98 endif()
  99
 100 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 101 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 102
 103 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 104
 105 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 106 if(OPENCV_WORKAROUND_CMAKE_20989)
 107   set(CMAKE_SYSTEM_PROCESSOR_BACKUP ${CMAKE_SYSTEM_PROCESSOR})
 108 endif()
 109 enable_language(CXX C)
 110 if(OPENCV_WORKAROUND_CMAKE_20989)
 111   set(CMAKE_SYSTEM_PROCESSOR ${CMAKE_SYSTEM_PROCESSOR_BACKUP})
 112 endif()
 113
 114 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 115
 116 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 117   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 118   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 119     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 120   endif()
 121 endif()
 122
 123 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 124   if(NOT CMAKE_TOOLCHAIN_FILE)
 125     if(WIN32)
 126       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 127     else()
 128       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 129     endif()
 130   else()
 131     # any cross-compiling
 132     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 133   endif()
 134 endif()
 135
 136 enable_testing()
 137
 138 project(OpenCV CXX C)
 139
 140 if(MSVC)
 141   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 142 endif()
 143
 144 ocv_cmake_eval(DEBUG_PRE ONCE)
 145
 146 ocv_clear_vars(OpenCVModules_TARGETS)
 147
 148 include(cmake/OpenCVDownload.cmake)
 149
 150 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 151
 152 # ----------------------------------------------------------------------------
 153 # Break in case of popular CMake configuration mistakes
 154 # ----------------------------------------------------------------------------
 155 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 156   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 157   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 158 endif()
 159
 160 # ----------------------------------------------------------------------------
 161 # Detect compiler and target platform architecture
 162 # ----------------------------------------------------------------------------
 163 include(cmake/OpenCVDetectCXXCompiler.cmake)
 164 ocv_cmake_hook(POST_DETECT_COMPILER)
 165
 166 # Add these standard paths to the search paths for FIND_LIBRARY
 167 # to find libraries from these locations first
 168 if(UNIX AND NOT ANDROID)
 169   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 170     if(EXISTS /lib64)
 171       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 172     else()
 173       list(APPEND CMAKE_LIBRARY_PATH /lib)
 174     endif()
 175     if(EXISTS /usr/lib64)
 176       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 179     endif()
 180   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 181     if(EXISTS /lib32)
 182       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 183     else()
 184       list(APPEND CMAKE_LIBRARY_PATH /lib)
 185     endif()
 186     if(EXISTS /usr/lib32)
 187       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 188     else()
 189       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 190     endif()
 191   endif()
 192 endif()
 193
 194 # Add these standard paths to the search paths for FIND_PATH
 195 # to find include files from these locations first
 196 if(MINGW)
 197   if(EXISTS /mingw)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 199   endif()
 200   if(EXISTS /mingw32)
 201       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 202   endif()
 203   if(EXISTS /mingw64)
 204       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 205   endif()
 206 endif()
 207
 208 # ----------------------------------------------------------------------------
 209 # OpenCV cmake options
 210 # ----------------------------------------------------------------------------
 211
 212 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 213
 214 # 3rd party libs
 215 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 216 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_OPENJPEG           "Build OpenJPEG from source"         (WIN32 OR ANDRIOD OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 219 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 220 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 221 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 222 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 223 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 224 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 225 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 226 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 227     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 228     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 229 )
 230
 231 # Optional 3rd party components
 232 # ===================================================
 233 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 234   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 235   VERIFY HAVE_DC1394_2)
 236 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 237   VISIBLE_IF APPLE
 238   VERIFY HAVE_AVFOUNDATION)
 239 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 240   VISIBLE_IF IOS
 241   VERIFY HAVE_CAP_IOS)
 242 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 243   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 244 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 245   VISIBLE_IF ANDROID
 246   VERIFY HAVE_CPUFEATURES)
 247 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 248   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 249   VERIFY HAVE_VTK)
 250 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 251   VISIBLE_IF NOT IOS AND NOT WINRT
 252   VERIFY HAVE_CUDA)
 253 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 254   VISIBLE_IF WITH_CUDA
 255   VERIFY HAVE_CUFFT)
 256 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 257   VISIBLE_IF WITH_CUDA
 258   VERIFY HAVE_CUBLAS)
 259 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 260   VISIBLE_IF WITH_CUDA
 261   VERIFY HAVE_CUDNN)
 262 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 263   VISIBLE_IF WITH_CUDA
 264   VERIFY HAVE_NVCUVID)
 265 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 266   VISIBLE_IF NOT WINRT
 267   VERIFY HAVE_EIGEN)
 268 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 269   VISIBLE_IF NOT IOS AND NOT WINRT
 270   VERIFY HAVE_FFMPEG)
 271 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 272   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 273   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 274 OCV_OPTION(WITH_GTK "Include GTK support" ON
 275   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 276   VERIFY HAVE_GTK)
 277 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 278   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 279   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 280 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 281   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 282   VERIFY HAVE_IPP)
 283 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 284   VISIBLE_IF TRUE
 285   VERIFY HAVE_HALIDE)
 286 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 287   VISIBLE_IF TRUE
 288   VERIFY HAVE_VULKAN)
 289 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 290   VISIBLE_IF TRUE
 291   VERIFY INF_ENGINE_TARGET)
 292 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 293   VISIBLE_IF TRUE
 294   VERIFY TARGET ngraph::ngraph)
 295 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 296   VISIBLE_IF NOT IOS
 297   VERIFY HAVE_JASPER)
 298 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 299   VISIBLE_IF NOT IOS
 300   VERIFY HAVE_OPENJPEG)
 301 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 302   VISIBLE_IF TRUE
 303   VERIFY HAVE_JPEG)
 304 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 305   VISIBLE_IF NOT WINRT
 306   VERIFY HAVE_WEBP)
 307 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 308   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 309   VERIFY HAVE_OPENEXR)
 310 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 311   VISIBLE_IF NOT ANDROID AND NOT WINRT
 312   VERIFY HAVE_OPENGL)
 313 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 314   VISIBLE_IF TRUE
 315   VERIFY HAVE_OPENVX)
 316 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 317   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 318   VERIFY HAVE_OPENNI)
 319 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 320   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 321   VERIFY HAVE_OPENNI2)
 322 OCV_OPTION(WITH_PNG "Include PNG support" ON
 323   VISIBLE_IF TRUE
 324   VERIFY HAVE_PNG)
 325 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 326   VISIBLE_IF TRUE
 327   VERIFY HAVE_GDCM)
 328 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 329   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 330   VERIFY HAVE_PVAPI)
 331 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 332   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 333   VERIFY HAVE_ARAVIS_API)
 334 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 335   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 336   VERIFY HAVE_QT)
 337 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 338   VISIBLE_IF WIN32 AND NOT WINRT
 339   VERIFY HAVE_WIN32UI)
 340 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 341   VISIBLE_IF NOT IOS AND NOT WINRT
 342   VERIFY HAVE_TBB)
 343 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 344   VISIBLE_IF TRUE
 345   VERIFY HAVE_HPX)
 346 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 347   VISIBLE_IF TRUE
 348   VERIFY HAVE_OPENMP)
 349 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 350   VISIBLE_IF NOT WIN32 OR MINGW
 351   VERIFY HAVE_PTHREADS_PF)
 352 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 353   VISIBLE_IF NOT IOS
 354   VERIFY HAVE_TIFF)
 355 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 356   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 357   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 358 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 359   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 360   VERIFY HAVE_DSHOW)
 361 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 362   VISIBLE_IF WIN32
 363   VERIFY HAVE_MSMF)
 364 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 365   VISIBLE_IF WIN32
 366   VERIFY HAVE_MSMF_DXVA)
 367 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 368   VISIBLE_IF NOT ANDROID AND NOT WINRT
 369   VERIFY HAVE_XIMEA)
 370 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 371   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 372   VERIFY HAVE_XINE)
 373 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 374   VISIBLE_IF TRUE
 375   VERIFY HAVE_CLP)
 376 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 377   VISIBLE_IF NOT IOS AND NOT WINRT
 378   VERIFY HAVE_OPENCL)
 379 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 380   VISIBLE_IF TRUE
 381   VERIFY HAVE_OPENCL_SVM) # experimental
 382 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 383   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 384   VERIFY HAVE_CLAMDFFT)
 385 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 386   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 387   VERIFY HAVE_CLAMDBLAS)
 388 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 389   VISIBLE_IF WIN32 AND NOT WINRT
 390   VERIFY HAVE_DIRECTX)
 391 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 392   VISIBLE_IF WIN32 AND NOT WINRT
 393   VERIFY HAVE_OPENCL_D3D11_NV)
 394 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 395   VISIBLE_IF NOT WITH_INTELPERC
 396   VERIFY HAVE_LIBREALSENSE)
 397 OCV_OPTION(WITH_VA "Include VA support" OFF
 398   VISIBLE_IF UNIX AND NOT ANDROID
 399   VERIFY HAVE_VA)
 400 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 401   VISIBLE_IF UNIX AND NOT ANDROID
 402   VERIFY HAVE_VA_INTEL)
 403 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 404   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 405   VERIFY HAVE_MFX)
 406 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 407   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 408   VERIFY HAVE_GDAL)
 409 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 410   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 411   VERIFY HAVE_GPHOTO2)
 412 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 413   VISIBLE_IF NOT ANDROID AND NOT IOS
 414   VERIFY HAVE_LAPACK)
 415 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 416   VISIBLE_IF NOT APPLE_FRAMEWORK
 417   VERIFY HAVE_ITT)
 418 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 419   VISIBLE_IF TRUE
 420   VERIFY HAVE_PROTOBUF)
 421 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 422   VISIBLE_IF TRUE
 423   VERIFY HAVE_IMGCODEC_HDR)
 424 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 425   VISIBLE_IF TRUE
 426   VERIFY HAVE_IMGCODEC_SUNRASTER)
 427 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 428   VISIBLE_IF TRUE
 429   VERIFY HAVE_IMGCODEC_PXM)
 430 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 431   VISIBLE_IF TRUE
 432   VERIFY HAVE_IMGCODEC_PFM)
 433 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 434   VISIBLE_IF TRUE
 435   VERIFY HAVE_QUIRC)
 436 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 437   VISIBLE_IF ANDROID
 438   VERIFY HAVE_ANDROID_MEDIANDK)
 439 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 440   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 441   VERIFY HAVE_TENGINE)
 442
 443 # OpenCV build components
 444 # ===================================================
 445 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 446 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 447 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 448 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 449 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 450 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 451 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 452 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 453 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 455 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 456 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 457 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 458 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 459 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 460 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 461 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 462 OCV_OPTION(BUILD_OBJC               "Enable Objective-C support"                  ON  IF APPLE_FRAMEWORK )
 463
 464 # OpenCV installation options
 465 # ===================================================
 466 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 467 OCV_OPTION(INSTALL_BIN_EXAMPLES     "Install prebuilt examples" WIN32 IF BUILD_EXAMPLES)
 468 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 469 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 470 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 471 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 472 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 473
 474 # OpenCV build options
 475 # ===================================================
 476 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 477 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 478 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 479 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 480 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 481 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 482 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 483 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 484 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 485 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 486 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 487 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 488 endif()
 489 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 490 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 491 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 492 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 493 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 494 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 495 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 496 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 497 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 498 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 499 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 500 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 501 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 502 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 503 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 504 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 505 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 506
 507 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 508 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 509
 510 if(ENABLE_IMPL_COLLECTION)
 511   add_definitions(-DCV_COLLECT_IMPL_DATA)
 512 endif()
 513
 514 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 515
 516 # ----------------------------------------------------------------------------
 517 #  Get actual OpenCV version number from sources
 518 # ----------------------------------------------------------------------------
 519 include(cmake/OpenCVVersion.cmake)
 520
 521 ocv_cmake_hook(POST_OPTIONS)
 522
 523 # ----------------------------------------------------------------------------
 524 #  Build & install layouts
 525 # ----------------------------------------------------------------------------
 526
 527 if(OPENCV_TEST_DATA_PATH)
 528   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 529 endif()
 530
 531 # Save libs and executables in the same place
 532 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 533
 534 if(ANDROID)
 535   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 536   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 537 else()
 538   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 539   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 540 endif()
 541
 542 if(ANDROID)
 543   if(ANDROID_ABI MATCHES "NEON")
 544     set(ENABLE_NEON ON)
 545   endif()
 546   if(ANDROID_ABI MATCHES "VFPV3")
 547     set(ENABLE_VFPV3 ON)
 548   endif()
 549 endif()
 550
 551 if(WIN32)
 552   # Postfix of DLLs:
 553   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 554   ocv_update(OPENCV_DEBUG_POSTFIX d)
 555 else()
 556   # Postfix of so's:
 557   ocv_update(OPENCV_DLLVERSION "")
 558   ocv_update(OPENCV_DEBUG_POSTFIX "")
 559 endif()
 560
 561 if(DEFINED CMAKE_DEBUG_POSTFIX)
 562   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 563 endif()
 564
 565 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 566   set(BUILD_opencv_world ON CACHE INTERNAL "")
 567 endif()
 568
 569 include(cmake/OpenCVInstallLayout.cmake)
 570
 571 # ----------------------------------------------------------------------------
 572 #  Path for build/platform -specific headers
 573 # ----------------------------------------------------------------------------
 574 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 575 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 576
 577 # ----------------------------------------------------------------------------
 578 #  Path for additional modules
 579 # ----------------------------------------------------------------------------
 580 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 581
 582 # ----------------------------------------------------------------------------
 583 #  Autodetect if we are in a GIT repository
 584 # ----------------------------------------------------------------------------
 585 find_host_package(Git QUIET)
 586
 587 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 588   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 589 elseif(NOT DEFINED OPENCV_VCSVERSION)
 590   # We don't have git:
 591   set(OPENCV_VCSVERSION "unknown")
 592 endif()
 593
 594
 595 # ----------------------------------------------------------------------------
 596 # OpenCV compiler and linker options
 597 # ----------------------------------------------------------------------------
 598 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 599 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 600   set(CMAKE_BUILD_TYPE Release)
 601 endif()
 602
 603 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 604
 605 # --- Python Support ---
 606 if(NOT IOS)
 607   include(cmake/OpenCVDetectPython.cmake)
 608 endif()
 609
 610 include(cmake/OpenCVCompilerOptions.cmake)
 611
 612 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 613
 614 # ----------------------------------------------------------------------------
 615 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 616 # ----------------------------------------------------------------------------
 617 if(UNIX)
 618   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 619     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 620         AND NOT OPENCV_ENABLE_PKG_CONFIG
 621     )
 622       if(NOT PkgConfig_FOUND)
 623         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 624       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 625         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 626       endif()
 627     elseif(OPENCV_DISABLE_PKG_CONFIG)
 628       if(PkgConfig_FOUND)
 629         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 630       endif()
 631     else()
 632       find_package(PkgConfig QUIET)
 633     endif()
 634   endif()
 635   include(CheckFunctionExists)
 636   include(CheckIncludeFile)
 637   include(CheckSymbolExists)
 638
 639   if(NOT APPLE)
 640     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 641     if(ANDROID)
 642       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 643     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 644       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 645     elseif(EMSCRIPTEN)
 646       # no need to link to system libs with emscripten
 647     else()
 648       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 649     endif()
 650   else()
 651     set(HAVE_PTHREAD 1)
 652   endif()
 653
 654   if(OPENCV_ENABLE_MEMALIGN)
 655     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 656     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 657     if(HAVE_MALLOC_H)
 658       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 659     endif()
 660     # TODO:
 661     # - _aligned_malloc() on Win32
 662     # - std::aligned_alloc() C++17 / C11
 663   endif()
 664 endif()
 665
 666 include(cmake/OpenCVPCHSupport.cmake)
 667 include(cmake/OpenCVModule.cmake)
 668
 669 # ----------------------------------------------------------------------------
 670 #  Detect endianness of build platform
 671 # ----------------------------------------------------------------------------
 672
 673 if(IOS)
 674   # test_big_endian needs try_compile, which doesn't work for iOS
 675   # http://public.kitware.com/Bug/view.php?id=12288
 676   set(WORDS_BIGENDIAN 0)
 677 else()
 678   include(TestBigEndian)
 679   test_big_endian(WORDS_BIGENDIAN)
 680 endif()
 681
 682 # ----------------------------------------------------------------------------
 683 #  Detect 3rd-party libraries
 684 # ----------------------------------------------------------------------------
 685
 686 if(ANDROID AND WITH_CPUFEATURES)
 687   add_subdirectory(3rdparty/cpufeatures)
 688   set(HAVE_CPUFEATURES 1)
 689 endif()
 690
 691 include(cmake/OpenCVFindFrameworks.cmake)
 692
 693 include(cmake/OpenCVFindLibsGrfmt.cmake)
 694 include(cmake/OpenCVFindLibsGUI.cmake)
 695 include(cmake/OpenCVFindLibsVideo.cmake)
 696 include(cmake/OpenCVFindLibsPerf.cmake)
 697 include(cmake/OpenCVFindLAPACK.cmake)
 698 include(cmake/OpenCVFindProtobuf.cmake)
 699 if(WITH_TENGINE)
 700   include(cmake/OpenCVFindTengine.cmake)
 701 endif()
 702
 703 # ----------------------------------------------------------------------------
 704 #  Detect other 3rd-party libraries/tools
 705 # ----------------------------------------------------------------------------
 706
 707 # --- Java Support ---
 708 if(BUILD_JAVA)
 709   if(ANDROID)
 710     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 711   else()
 712     include(cmake/OpenCVDetectApacheAnt.cmake)
 713     find_package(JNI)
 714   endif()
 715 endif()
 716
 717 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 718   include(cmake/OpenCVPylint.cmake)
 719 endif()
 720 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 721   find_package(Flake8 QUIET)
 722   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 723     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 724   endif()
 725   if(FLAKE8_FOUND)
 726     add_custom_target(check_flake8
 727         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 728         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 729         COMMENT "Running flake8"
 730     )
 731   endif()
 732 endif()
 733
 734
 735 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 736   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 737 else()
 738   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 739 endif()
 740
 741 # --- OpenCL ---
 742 if(WITH_OPENCL)
 743   include(cmake/OpenCVDetectOpenCL.cmake)
 744 endif()
 745
 746 # --- Halide ---
 747 if(WITH_HALIDE)
 748   include(cmake/OpenCVDetectHalide.cmake)
 749 endif()
 750
 751 # --- VkCom ---
 752 if(WITH_VULKAN)
 753   include(cmake/OpenCVDetectVulkan.cmake)
 754 endif()
 755
 756 # --- Inference Engine ---
 757 if(WITH_INF_ENGINE)
 758   include(cmake/OpenCVDetectInferenceEngine.cmake)
 759 endif()
 760
 761 # --- DirectX ---
 762 if(WITH_DIRECTX)
 763   include(cmake/OpenCVDetectDirectX.cmake)
 764 endif()
 765
 766 if(WITH_VTK)
 767   include(cmake/OpenCVDetectVTK.cmake)
 768 endif()
 769
 770 if(WITH_OPENVX)
 771   include(cmake/FindOpenVX.cmake)
 772 endif()
 773
 774 if(WITH_QUIRC)
 775   add_subdirectory(3rdparty/quirc)
 776   set(HAVE_QUIRC TRUE)
 777 endif()
 778 # ----------------------------------------------------------------------------
 779 # OpenCV HAL
 780 # ----------------------------------------------------------------------------
 781 set(_hal_includes "")
 782 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 783   # 1. libraries
 784   foreach (l ${${HAL_LIBRARIES_VAR}})
 785     if(NOT TARGET ${l})
 786       get_filename_component(l "${l}" ABSOLUTE)
 787     endif()
 788     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 789   endforeach()
 790   # 2. headers
 791   foreach (h ${${HAL_HEADERS_VAR}})
 792     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 793   endforeach()
 794   # 3. include paths
 795   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 796 endmacro()
 797
 798 if(NOT DEFINED OpenCV_HAL)
 799   set(OpenCV_HAL "OpenCV_HAL")
 800 endif()
 801
 802 if(HAVE_OPENVX)
 803   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 804     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 805   endif()
 806 endif()
 807
 808 if(WITH_CAROTENE)
 809   ocv_debug_message(STATUS "Enable carotene acceleration")
 810   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 811     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 812   endif()
 813 endif()
 814
 815 foreach(hal ${OpenCV_HAL})
 816   if(hal STREQUAL "carotene")
 817     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 818       add_subdirectory(3rdparty/carotene/hal)
 819       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 820       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 821     else()
 822       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 823     endif()
 824   elseif(hal STREQUAL "openvx")
 825     add_subdirectory(3rdparty/openvx)
 826     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 827     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 828   else()
 829     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 830     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 831     find_package(${hal} NO_MODULE QUIET)
 832     if(${hal}_FOUND)
 833       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 834       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 835     endif()
 836   endif()
 837 endforeach()
 838 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 839 unset(_hal_includes)
 840
 841
 842 # ----------------------------------------------------------------------------
 843 # Code trace support
 844 # ----------------------------------------------------------------------------
 845 if(CV_TRACE)
 846   include(cmake/OpenCVDetectTrace.cmake)
 847 endif()
 848
 849 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 850 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 851
 852 # ----------------------------------------------------------------------------
 853 # Solution folders:
 854 # ----------------------------------------------------------------------------
 855 if(ENABLE_SOLUTION_FOLDERS)
 856   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 857   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 858 endif()
 859
 860 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 861 include(cmake/OpenCVExtraTargets.cmake)
 862
 863 # ----------------------------------------------------------------------------
 864 # Process subdirectories
 865 # ----------------------------------------------------------------------------
 866
 867 # opencv.hpp and legacy headers
 868 add_subdirectory(include)
 869
 870 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 871 ocv_add_modules_compiler_options()
 872
 873 # OpenCV modules
 874 add_subdirectory(modules)
 875
 876 # Generate targets for documentation
 877 add_subdirectory(doc)
 878
 879 # various data that is used by cv libraries and/or demo applications.
 880 add_subdirectory(data)
 881
 882 # extra applications
 883 if(BUILD_opencv_apps)
 884   add_subdirectory(apps)
 885 endif()
 886
 887 # examples
 888 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 889   add_subdirectory(samples)
 890 endif()
 891
 892 if(ANDROID)
 893   add_subdirectory(platforms/android/service)
 894 endif()
 895
 896 # ----------------------------------------------------------------------------
 897 # Finalization: generate configuration-based files
 898 # ----------------------------------------------------------------------------
 899
 900 ocv_cmake_hook(PRE_FINALIZE)
 901
 902 # Generate platform-dependent and configuration-dependent headers
 903 include(cmake/OpenCVGenHeaders.cmake)
 904
 905 # Generate opencv.pc for pkg-config command
 906 if(OPENCV_GENERATE_PKGCONFIG)
 907   include(cmake/OpenCVGenPkgconfig.cmake)
 908 endif()
 909
 910 # Generate OpenCV.mk for ndk-build (Android build tool)
 911 include(cmake/OpenCVGenAndroidMK.cmake)
 912
 913 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 914 include(cmake/OpenCVGenConfig.cmake)
 915
 916 # Generate Info.plist for the IOS framework
 917 if(APPLE_FRAMEWORK)
 918   include(cmake/OpenCVGenInfoPlist.cmake)
 919 endif()
 920
 921 # Generate ABI descriptor
 922 include(cmake/OpenCVGenABI.cmake)
 923
 924 # Generate environment setup file
 925 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 926   if(ANDROID)
 927     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 928     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 929                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 930     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 931             DESTINATION ./ COMPONENT tests)
 932   elseif(WIN32)
 933     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 934                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 935     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 936             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 937   elseif(UNIX)
 938     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 939                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 940     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 941             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 942   endif()
 943 endif()
 944
 945 if(NOT OPENCV_README_FILE)
 946   if(ANDROID)
 947     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 948   endif()
 949 endif()
 950
 951 if(NOT OPENCV_LICENSE_FILE)
 952   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 953 endif()
 954
 955 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 956 if(ANDROID OR NOT UNIX)
 957   install(FILES ${OPENCV_LICENSE_FILE}
 958         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 959         DESTINATION ./ COMPONENT libs)
 960   if(OPENCV_README_FILE)
 961     install(FILES ${OPENCV_README_FILE}
 962             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 963             DESTINATION ./ COMPONENT libs)
 964   endif()
 965 endif()
 966
 967 if(COMMAND ocv_pylint_finalize)
 968   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 969   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 970   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 971   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 972   ocv_pylint_finalize()
 973 endif()
 974
 975 if(OPENCV_GENERATE_SETUPVARS)
 976   include(cmake/OpenCVGenSetupVars.cmake)
 977 endif()
 978
 979 # ----------------------------------------------------------------------------
 980 # Summary:
 981 # ----------------------------------------------------------------------------
 982 status("")
 983 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 984 if(OPENCV_VCSVERSION)
 985   status("  Version control:" ${OPENCV_VCSVERSION})
 986 endif()
 987 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 988   set(__dump_extra_header OFF)
 989   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 990     if(EXISTS ${p})
 991       if(NOT __dump_extra_header)
 992         set(__dump_extra_header ON)
 993         status("")
 994         status("  Extra modules:")
 995       else()
 996         status("")
 997       endif()
 998       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 999       status("    Location (extra):" ${p})
1000       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1001     endif()
1002   endforeach()
1003   unset(__dump_extra_header)
1004 endif()
1005
1006 # ========================== build platform ==========================
1007 status("")
1008 status("  Platform:")
1009 if(NOT DEFINED OPENCV_TIMESTAMP
1010     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1011     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1012 )
1013   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1014   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1015 endif()
1016 if(OPENCV_TIMESTAMP)
1017   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1018 endif()
1019 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1020 if(CMAKE_CROSSCOMPILING)
1021   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1022 endif()
1023 status("    CMake:"            ${CMAKE_VERSION})
1024 status("    CMake generator:"  ${CMAKE_GENERATOR})
1025 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1026 if(MSVC)
1027   status("    MSVC:"           ${MSVC_VERSION})
1028 endif()
1029 if(CMAKE_GENERATOR MATCHES Xcode)
1030   status("    Xcode:"          ${XCODE_VERSION})
1031 endif()
1032 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1033   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1034 endif()
1035
1036
1037 # ========================= CPU code generation mode =========================
1038 status("")
1039 status("  CPU/HW features:")
1040 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1041 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1042   status("      requested:"  "${CPU_BASELINE}")
1043 endif()
1044 if(CPU_BASELINE_REQUIRE)
1045   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1046 endif()
1047 if(CPU_BASELINE_DISABLE)
1048   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1049 endif()
1050 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1051   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1052   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1053     status("      requested:"  "${CPU_DISPATCH}")
1054   endif()
1055   if(CPU_DISPATCH_REQUIRE)
1056     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1057   endif()
1058   foreach(OPT ${CPU_DISPATCH_FINAL})
1059     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1060   endforeach()
1061 endif()
1062
1063 # ========================== C/C++ options ==========================
1064 if(CMAKE_CXX_COMPILER_VERSION)
1065   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1066 else()
1067   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1068 endif()
1069 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1070
1071 status("")
1072 status("  C/C++:")
1073 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1074 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1075   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1076 endif()
1077 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1078 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1079 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1080 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1081 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1082 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1083 if(WIN32)
1084   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1085   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1086 else()
1087   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1088   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1089 endif()
1090 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1091 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1092
1093 # ========================== Dependencies ============================
1094 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1095 status("    Extra dependencies:" ${deps_extra})
1096 status("    3rdparty dependencies:" ${deps_3rdparty})
1097
1098 # ========================== OpenCV modules ==========================
1099 status("")
1100 status("  OpenCV modules:")
1101 set(OPENCV_MODULES_BUILD_ST "")
1102 foreach(the_module ${OPENCV_MODULES_BUILD})
1103   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1104     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1105   endif()
1106 endforeach()
1107 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1108 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1109 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1110 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1111 list(SORT OPENCV_MODULES_BUILD_ST)
1112 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1113 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1114 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1115 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1116 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1117 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1118 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1119
1120 ocv_build_features_string(apps_status
1121   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1122   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1123   IF BUILD_EXAMPLES THEN "examples"
1124   IF BUILD_opencv_apps THEN "apps"
1125   IF BUILD_ANDROID_SERVICE THEN "android_service"
1126   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1127   ELSE "-")
1128 status("    Applications:" "${apps_status}")
1129 ocv_build_features_string(docs_status
1130     IF TARGET doxygen_cpp THEN "doxygen"
1131     IF TARGET doxygen_python THEN "python"
1132     IF TARGET doxygen_javadoc THEN "javadoc"
1133     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1134     ELSE "NO"
1135 )
1136 status("    Documentation:" "${docs_status}")
1137 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1138
1139 # ========================== Android details ==========================
1140 if(ANDROID)
1141   status("")
1142   if(DEFINED ANDROID_NDK_REVISION)
1143     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1144   else()
1145     set(__msg "location: ${ANDROID_NDK}")
1146   endif()
1147   status("  Android NDK: " ${__msg})
1148   status("    Android ABI:" ${ANDROID_ABI})
1149   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1150     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1151   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1152     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1153   endif()
1154   status("    STL type:" ${ANDROID_STL})
1155   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1156
1157   if(BUILD_ANDROID_PROJECTS)
1158     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1159     if(ANDROID_EXECUTABLE)
1160       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1161     endif()
1162   else()
1163     status("  Android SDK: " "not used, projects are not built")
1164   endif()
1165   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1166     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1167   endif()
1168   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1169     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1170       status("    Projects build scripts:" "Ant/Eclipse compatible")
1171     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1172       status("    Projects build scripts:" "Gradle")
1173     endif()
1174   endif()
1175 endif()
1176
1177 # ================== Windows RT features ==================
1178 if(WIN32)
1179 status("")
1180 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1181   if(WINRT)
1182     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1183     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1184     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1185     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1186       status("    Building for C++ without CX extensions")
1187     endif()
1188   endif()
1189 endif(WIN32)
1190
1191 # ========================== GUI ==========================
1192 status("")
1193 status("  GUI: ")
1194
1195 if(WITH_QT OR HAVE_QT)
1196   if(HAVE_QT5)
1197     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1198     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1199   elseif(HAVE_QT)
1200     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1201     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1202   else()
1203     status("    QT:" "NO")
1204   endif()
1205 endif()
1206
1207 if(WITH_WIN32UI)
1208   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1209 endif()
1210
1211 if(HAVE_COCOA)  # APPLE
1212   status("    Cocoa:"  YES)
1213 endif()
1214
1215 if(WITH_GTK OR HAVE_GTK)
1216   if(HAVE_GTK3)
1217     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1218   elseif(HAVE_GTK)
1219     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1220   else()
1221     status("    GTK+:" "NO")
1222   endif()
1223   if(HAVE_GTK)
1224     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1225     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1226   endif()
1227 endif()
1228
1229 if(WITH_OPENGL OR HAVE_OPENGL)
1230   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1231 endif()
1232
1233 if(WITH_VTK OR HAVE_VTK)
1234   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1235 endif()
1236
1237 # ========================== MEDIA IO ==========================
1238 status("")
1239 status("  Media I/O: ")
1240 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1241
1242 if(WITH_JPEG OR HAVE_JPEG)
1243   if(NOT HAVE_JPEG)
1244     status("    JPEG:" NO)
1245   elseif(BUILD_JPEG)
1246     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1247   else()
1248     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1249   endif()
1250 endif()
1251
1252 if(WITH_WEBP OR HAVE_WEBP)
1253   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1254 endif()
1255
1256 if(WITH_PNG OR HAVE_PNG)
1257   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1258 endif()
1259
1260 if(WITH_TIFF OR HAVE_TIFF)
1261   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1262 endif()
1263
1264 if(HAVE_OPENJPEG)
1265   status("    JPEG 2000:" OpenJPEG_FOUND
1266       THEN "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})"
1267       ELSE "build (ver ${OPENJPEG_VERSION})"
1268   )
1269 elseif(HAVE_JASPER)
1270   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1271 elseif(WITH_OPENJPEG OR WITH_JASPER)
1272   status("    JPEG 2000:" "NO")
1273 endif()
1274
1275 if(WITH_OPENEXR OR HAVE_OPENEXR)
1276   if(HAVE_OPENEXR)
1277     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1278   else()
1279     status("    OpenEXR:" "NO")
1280   endif()
1281 endif()
1282
1283 if(WITH_GDAL OR HAVE_GDAL)
1284   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1285 endif()
1286
1287 if(WITH_GDCM OR HAVE_GDCM)
1288   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1289 endif()
1290
1291 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1292   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1293 endif()
1294
1295 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1296   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1297 endif()
1298
1299 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1300   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1301 endif()
1302
1303 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1304   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1305 endif()
1306
1307 # ========================== VIDEO IO ==========================
1308 status("")
1309 status("  Video I/O:")
1310
1311 if(WITH_1394 OR HAVE_DC1394_2)
1312   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1313 endif()
1314
1315 if(WITH_FFMPEG OR HAVE_FFMPEG)
1316   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1317     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1318   elseif(WIN32)
1319     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1320   else()
1321     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1322   endif()
1323   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1324   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1325   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1326   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1327   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1328 endif()
1329
1330 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1331   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1332 endif()
1333
1334 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1335   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1336 endif()
1337
1338 if(WITH_PVAPI OR HAVE_PVAPI)
1339   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1340 endif()
1341
1342 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1343   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1344 endif()
1345
1346 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1347   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1348 endif()
1349
1350 if(HAVE_CAP_IOS)
1351   status("    iOS capture:" YES)
1352 endif()
1353
1354 if(WITH_V4L OR HAVE_V4L)
1355   ocv_build_features_string(v4l_status
1356     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1357     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1358     ELSE "NO")
1359   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1360 endif()
1361
1362 if(WITH_DSHOW OR HAVE_DSHOW)
1363   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1364 endif()
1365
1366 if(WITH_MSMF OR HAVE_MSMF)
1367   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1368   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1369 endif()
1370
1371 if(WITH_XIMEA OR HAVE_XIMEA)
1372   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1373 endif()
1374
1375 if(WITH_XINE OR HAVE_XINE)
1376   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1377 endif()
1378
1379 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1380   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1381 endif()
1382
1383 if(WITH_MFX OR HAVE_MFX)
1384   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1385 endif()
1386
1387 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1388   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1389 endif()
1390
1391 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1392 ocv_build_features_string(parallel_status EXCLUSIVE
1393   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1394   IF HAVE_HPX THEN "HPX"
1395   IF HAVE_OPENMP THEN "OpenMP"
1396   IF HAVE_GCD THEN "GCD"
1397   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1398   IF HAVE_PTHREADS_PF THEN "pthreads"
1399   ELSE "none")
1400 status("")
1401 status("  Parallel framework:" "${parallel_status}")
1402
1403 if(CV_TRACE OR OPENCV_TRACE)
1404   ocv_build_features_string(trace_status EXCLUSIVE
1405     IF HAVE_ITT THEN "with Intel ITT"
1406     ELSE "built-in")
1407   status("")
1408   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1409 endif()
1410
1411 # ========================== Other third-party libraries ==========================
1412 status("")
1413 status("  Other third-party libraries:")
1414
1415 if(WITH_IPP AND HAVE_IPP)
1416   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1417   status("           at:" "${IPP_ROOT_DIR}")
1418   if(NOT HAVE_IPP_ICV)
1419     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1420   endif()
1421   if(HAVE_IPP_IW)
1422     if(BUILD_IPP_IW)
1423       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1424     else()
1425       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1426     endif()
1427     status("              at:" "${IPP_IW_PATH}")
1428   else()
1429     status("    Intel IPP IW:"   NO)
1430   endif()
1431 endif()
1432
1433 if(WITH_VA OR HAVE_VA)
1434   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1435 endif()
1436
1437 if(WITH_TENGINE OR HAVE_TENGINE)
1438   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1439 endif()
1440
1441 if(WITH_LAPACK OR HAVE_LAPACK)
1442   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1443 endif()
1444
1445 if(WITH_HALIDE OR HAVE_HALIDE)
1446   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1447 endif()
1448
1449 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1450   if(INF_ENGINE_TARGET)
1451     list(GET INF_ENGINE_TARGET 0 ie_target)
1452     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1453     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1454     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1455     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1456     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1457     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1458     ocv_build_features_string(_lib
1459       IF _lib THEN "${_lib}"
1460       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1461       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1462       IF _lib_rel  THEN "${_lib_rel}"
1463       IF _lib_dbg  THEN "${_lib_dbg}"
1464       ELSE "unknown"
1465     )
1466     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1467     status("    Inference Engine:" "${__msg}")
1468     status("        * libs:" "${_lib}")
1469     status("        * includes:" "${_inc}")
1470   else()
1471     status("    Inference Engine:"     "NO")
1472   endif()
1473 endif()
1474 if(WITH_NGRAPH OR HAVE_NGRAPH)
1475   if(HAVE_NGRAPH)
1476     set(__target ngraph::ngraph)
1477     set(__msg "YES (${ngraph_VERSION})")
1478     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1479     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1480     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1481     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1482     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1483     ocv_build_features_string(_lib
1484       IF _lib THEN "${_lib}"
1485       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1486       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1487       IF _lib_rel  THEN "${_lib_rel}"
1488       IF _lib_dbg  THEN "${_lib_dbg}"
1489       ELSE "unknown"
1490     )
1491     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1492     status("    nGraph:" "${__msg}")
1493     status("        * libs:" "${_lib}")
1494     status("        * includes:" "${_inc}")
1495   else()
1496     status("    nGraph:"     "NO")
1497   endif()
1498 endif()
1499
1500 if(WITH_EIGEN OR HAVE_EIGEN)
1501   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1502 endif()
1503
1504 if(WITH_OPENVX OR HAVE_OPENVX)
1505   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1506 endif()
1507
1508 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1509
1510 foreach(s ${CUSTOM_STATUS})
1511   status(${CUSTOM_STATUS_${s}})
1512 endforeach()
1513
1514 if(WITH_CUDA OR HAVE_CUDA)
1515   ocv_build_features_string(cuda_features
1516     IF HAVE_CUFFT THEN "CUFFT"
1517     IF HAVE_CUBLAS THEN "CUBLAS"
1518     IF HAVE_NVCUVID THEN "NVCUVID"
1519     IF CUDA_FAST_MATH THEN "FAST_MATH"
1520     ELSE "no extra features")
1521   status("")
1522   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1523   if(HAVE_CUDA)
1524     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1525     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1526   endif()
1527  endif()
1528
1529  if(WITH_CUDNN OR HAVE_CUDNN)
1530     status("")
1531     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1532 endif()
1533
1534 if(WITH_VULKAN OR HAVE_VULKAN)
1535   status("")
1536   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1537   if(HAVE_VULKAN)
1538     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1539     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1540   endif()
1541 endif()
1542
1543 if(WITH_OPENCL OR HAVE_OPENCL)
1544   ocv_build_features_string(opencl_features
1545     IF HAVE_OPENCL_SVM THEN "SVM"
1546     IF HAVE_CLAMDFFT THEN "AMDFFT"
1547     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1548     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1549     IF HAVE_VA_INTEL THEN "INTELVA"
1550     ELSE "no extra features")
1551   status("")
1552   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1553   if(HAVE_OPENCL)
1554     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1555     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1556   endif()
1557 endif()
1558
1559 # ========================== python ==========================
1560 if(BUILD_opencv_python2)
1561   status("")
1562   status("  Python 2:")
1563   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1564   if(PYTHON2LIBS_VERSION_STRING)
1565     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1566   else()
1567     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1568   endif()
1569   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1570   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1571 endif()
1572
1573 if(BUILD_opencv_python3)
1574   status("")
1575   status("  Python 3:")
1576   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1577   if(PYTHON3LIBS_VERSION_STRING)
1578     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1579   else()
1580     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1581   endif()
1582   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1583   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1584 endif()
1585
1586 status("")
1587 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1588 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1589   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1590 endif()
1591 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1592   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1593 endif()
1594
1595 # ========================== java ==========================
1596 if(BUILD_JAVA)
1597   status("")
1598   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1599   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1600   if(NOT ANDROID)
1601     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1602   endif()
1603   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1604   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1605 endif()
1606
1607 # ========================== Objective-C =======================
1608 if(BUILD_OBJC)
1609   status("")
1610   status("  Objective-C wrappers:" HAVE_opencv_objc                                                       THEN YES ELSE NO)
1611 endif()
1612
1613 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1614
1615 # ========================== auxiliary ==========================
1616 status("")
1617 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1618 status("-----------------------------------------------------------------")
1619 status("")
1620
1621
1622 ocv_finalize_status()
1623
1624 if(ENABLE_CONFIG_VERIFICATION)
1625   ocv_verify_config()
1626 endif()
1627
1628 if(HAVE_CUDA AND COMMAND CUDA_BUILD_CLEAN_TARGET)
1629   CUDA_BUILD_CLEAN_TARGET()
1630 endif()
1631
1632 ocv_cmake_hook(POST_FINALIZE)
1633
1634 # ----------------------------------------------------------------------------
1635 # CPack stuff
1636 # ----------------------------------------------------------------------------
1637
1638 include(cmake/OpenCVPackaging.cmake)
1639
1640 # This should be the last command
1641 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1642 ocv_cmake_eval(DEBUG_POST ONCE)