m4/sys_socket_h.m4

   1 # sys_socket_h.m4 serial 24
   2 dnl Copyright (C) 2005-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson.
   8
   9 AC_DEFUN([gl_HEADER_SYS_SOCKET],
  10 [
  11   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13
  14   dnl On OSF/1, the functions recv(), send(), recvfrom(), sendto() have
  15   dnl old-style declarations (with return type 'int' instead of 'ssize_t')
  16   dnl unless _POSIX_PII_SOCKET is defined.
  17   case "$host_os" in
  18     osf*)
  19       AC_DEFINE([_POSIX_PII_SOCKET], [1],
  20         [Define to 1 in order to get the POSIX compatible declarations
  21          of socket functions.])
  22       ;;
  23   esac
  24
  25   AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
  26     [gl_cv_header_sys_socket_h_selfcontained],
  27     [
  28       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]], [[]])],
  29         [gl_cv_header_sys_socket_h_selfcontained=yes],
  30         [gl_cv_header_sys_socket_h_selfcontained=no])
  31     ])
  32   if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
  33     dnl If the shutdown function exists, <sys/socket.h> should define
  34     dnl SHUT_RD, SHUT_WR, SHUT_RDWR.
  35     AC_CHECK_FUNCS([shutdown])
  36     if test $ac_cv_func_shutdown = yes; then
  37       AC_CACHE_CHECK([whether <sys/socket.h> defines the SHUT_* macros],
  38         [gl_cv_header_sys_socket_h_shut],
  39         [
  40           AC_COMPILE_IFELSE(
  41             [AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  42                [[int a[] = { SHUT_RD, SHUT_WR, SHUT_RDWR };]])],
  43             [gl_cv_header_sys_socket_h_shut=yes],
  44             [gl_cv_header_sys_socket_h_shut=no])
  45         ])
  46       if test $gl_cv_header_sys_socket_h_shut = no; then
  47         SYS_SOCKET_H='sys/socket.h'
  48       fi
  49     fi
  50   fi
  51   # We need to check for ws2tcpip.h now.
  52   gl_PREREQ_SYS_H_SOCKET
  53   AC_CHECK_TYPES([struct sockaddr_storage, sa_family_t],,,[
  54   /* sys/types.h is not needed according to POSIX, but the
  55      sys/socket.h in i386-unknown-freebsd4.10 and
  56      powerpc-apple-darwin5.5 required it. */
  57 #include <sys/types.h>
  58 #ifdef HAVE_SYS_SOCKET_H
  59 #include <sys/socket.h>
  60 #endif
  61 #ifdef HAVE_WS2TCPIP_H
  62 #include <ws2tcpip.h>
  63 #endif
  64 ])
  65   if test $ac_cv_type_struct_sockaddr_storage = no; then
  66     HAVE_STRUCT_SOCKADDR_STORAGE=0
  67   fi
  68   if test $ac_cv_type_sa_family_t = no; then
  69     HAVE_SA_FAMILY_T=0
  70   fi
  71   if test $ac_cv_type_struct_sockaddr_storage != no; then
  72     AC_CHECK_MEMBERS([struct sockaddr_storage.ss_family],
  73       [],
  74       [HAVE_STRUCT_SOCKADDR_STORAGE_SS_FAMILY=0],
  75       [#include <sys/types.h>
  76        #ifdef HAVE_SYS_SOCKET_H
  77        #include <sys/socket.h>
  78        #endif
  79        #ifdef HAVE_WS2TCPIP_H
  80        #include <ws2tcpip.h>
  81        #endif
  82       ])
  83   fi
  84   if test $HAVE_STRUCT_SOCKADDR_STORAGE = 0 || test $HAVE_SA_FAMILY_T = 0 \
  85      || test $HAVE_STRUCT_SOCKADDR_STORAGE_SS_FAMILY = 0; then
  86     SYS_SOCKET_H='sys/socket.h'
  87   fi
  88   gl_PREREQ_SYS_H_WINSOCK2
  89
  90   dnl Check for declarations of anything we want to poison if the
  91   dnl corresponding gnulib module is not in use.
  92   gl_WARN_ON_USE_PREPARE([[
  93 /* Some systems require prerequisite headers.  */
  94 #include <sys/types.h>
  95 #include <sys/socket.h>
  96     ]], [socket connect accept bind getpeername getsockname getsockopt
  97     listen recv send recvfrom sendto setsockopt shutdown accept4])
  98 ])
  99
 100 AC_DEFUN([gl_PREREQ_SYS_H_SOCKET],
 101 [
 102   dnl Check prerequisites of the <sys/socket.h> replacement.
 103   AC_REQUIRE([gl_CHECK_SOCKET_HEADERS])
 104   gl_CHECK_NEXT_HEADERS([sys/socket.h])
 105   if test $ac_cv_header_sys_socket_h = yes; then
 106     HAVE_SYS_SOCKET_H=1
 107   else
 108     HAVE_SYS_SOCKET_H=0
 109   fi
 110   AC_SUBST([HAVE_SYS_SOCKET_H])
 111   gl_PREREQ_SYS_H_WS2TCPIP
 112 ])
 113
 114 # Common prerequisites of the <sys/socket.h> replacement and of the
 115 # <sys/select.h> replacement.
 116 # Sets and substitutes HAVE_WINSOCK2_H.
 117 AC_DEFUN([gl_PREREQ_SYS_H_WINSOCK2],
 118 [
 119   m4_ifdef([gl_UNISTD_H_DEFAULTS], [AC_REQUIRE([gl_UNISTD_H_DEFAULTS])])
 120   m4_ifdef([gl_SYS_IOCTL_H_DEFAULTS], [AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])])
 121   AC_CHECK_HEADERS_ONCE([sys/socket.h])
 122   if test $ac_cv_header_sys_socket_h != yes; then
 123     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
 124     dnl the check for those headers unconditional; yet cygwin reports
 125     dnl that the headers are present but cannot be compiled (since on
 126     dnl cygwin, all socket information should come from sys/socket.h).
 127     AC_CHECK_HEADERS([winsock2.h])
 128   fi
 129   if test "$ac_cv_header_winsock2_h" = yes; then
 130     HAVE_WINSOCK2_H=1
 131     UNISTD_H_HAVE_WINSOCK2_H=1
 132     SYS_IOCTL_H_HAVE_WINSOCK2_H=1
 133   else
 134     HAVE_WINSOCK2_H=0
 135   fi
 136   AC_SUBST([HAVE_WINSOCK2_H])
 137 ])
 138
 139 # Common prerequisites of the <sys/socket.h> replacement and of the
 140 # <arpa/inet.h> replacement.
 141 # Sets and substitutes HAVE_WS2TCPIP_H.
 142 AC_DEFUN([gl_PREREQ_SYS_H_WS2TCPIP],
 143 [
 144   AC_REQUIRE([gl_CHECK_SOCKET_HEADERS])
 145   if test $ac_cv_header_sys_socket_h = yes; then
 146     HAVE_WS2TCPIP_H=0
 147   else
 148     if test $ac_cv_header_ws2tcpip_h = yes; then
 149       HAVE_WS2TCPIP_H=1
 150     else
 151       HAVE_WS2TCPIP_H=0
 152     fi
 153   fi
 154   AC_SUBST([HAVE_WS2TCPIP_H])
 155 ])
 156
 157 AC_DEFUN([gl_SYS_SOCKET_MODULE_INDICATOR],
 158 [
 159   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 160   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
 161   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 162   dnl Define it also as a C macro, for the benefit of the unit tests.
 163   gl_MODULE_INDICATOR_FOR_TESTS([$1])
 164 ])
 165
 166 AC_DEFUN([gl_SYS_SOCKET_H_DEFAULTS],
 167 [
 168   GNULIB_SOCKET=0;      AC_SUBST([GNULIB_SOCKET])
 169   GNULIB_CONNECT=0;     AC_SUBST([GNULIB_CONNECT])
 170   GNULIB_ACCEPT=0;      AC_SUBST([GNULIB_ACCEPT])
 171   GNULIB_BIND=0;        AC_SUBST([GNULIB_BIND])
 172   GNULIB_GETPEERNAME=0; AC_SUBST([GNULIB_GETPEERNAME])
 173   GNULIB_GETSOCKNAME=0; AC_SUBST([GNULIB_GETSOCKNAME])
 174   GNULIB_GETSOCKOPT=0;  AC_SUBST([GNULIB_GETSOCKOPT])
 175   GNULIB_LISTEN=0;      AC_SUBST([GNULIB_LISTEN])
 176   GNULIB_RECV=0;        AC_SUBST([GNULIB_RECV])
 177   GNULIB_SEND=0;        AC_SUBST([GNULIB_SEND])
 178   GNULIB_RECVFROM=0;    AC_SUBST([GNULIB_RECVFROM])
 179   GNULIB_SENDTO=0;      AC_SUBST([GNULIB_SENDTO])
 180   GNULIB_SETSOCKOPT=0;  AC_SUBST([GNULIB_SETSOCKOPT])
 181   GNULIB_SHUTDOWN=0;    AC_SUBST([GNULIB_SHUTDOWN])
 182   GNULIB_ACCEPT4=0;     AC_SUBST([GNULIB_ACCEPT4])
 183   HAVE_STRUCT_SOCKADDR_STORAGE=1; AC_SUBST([HAVE_STRUCT_SOCKADDR_STORAGE])
 184   HAVE_STRUCT_SOCKADDR_STORAGE_SS_FAMILY=1;
 185                         AC_SUBST([HAVE_STRUCT_SOCKADDR_STORAGE_SS_FAMILY])
 186   HAVE_SA_FAMILY_T=1;   AC_SUBST([HAVE_SA_FAMILY_T])
 187   HAVE_ACCEPT4=1;       AC_SUBST([HAVE_ACCEPT4])
 188 ])