m4/snprintf.m4

   1 # snprintf.m4 serial 5
   2 dnl Copyright (C) 2002-2004, 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   gl_cv_func_snprintf_usable=no
  11   AC_CHECK_FUNCS([snprintf])
  12   if test $ac_cv_func_snprintf = yes; then
  13     gl_SNPRINTF_SIZE1
  14     case "$gl_cv_func_snprintf_size1" in
  15       *yes)
  16         gl_SNPRINTF_RETVAL_C99
  17         case "$gl_cv_func_snprintf_retval_c99" in
  18           *yes)
  19             gl_cv_func_snprintf_usable=yes
  20             ;;
  21         esac
  22         ;;
  23     esac
  24   fi
  25   if test $gl_cv_func_snprintf_usable = no; then
  26     gl_REPLACE_SNPRINTF
  27   fi
  28   AC_CHECK_DECLS_ONCE([snprintf])
  29   if test $ac_cv_have_decl_snprintf = no; then
  30     HAVE_DECL_SNPRINTF=0
  31   fi
  32 ])
  33
  34 AC_DEFUN([gl_REPLACE_SNPRINTF],
  35 [
  36   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  37   AC_LIBOBJ([snprintf])
  38   if test $ac_cv_func_snprintf = yes; then
  39     REPLACE_SNPRINTF=1
  40   fi
  41   gl_PREREQ_SNPRINTF
  42 ])
  43
  44 # Prerequisites of lib/snprintf.c.
  45 AC_DEFUN([gl_PREREQ_SNPRINTF], [:])