m4/printf-frexpl.m4

   1 # printf-frexpl.m4 serial 7
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check how to define printf_frexpl() without linking with libm.
   8
   9 AC_DEFUN([gl_FUNC_PRINTF_FREXPL],
  10 [
  11   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  12   dnl Subset of gl_FUNC_FREXPL_NO_LIBM.
  13   gl_CHECK_FREXPL_NO_LIBM
  14   if test $gl_cv_func_frexpl_no_libm = yes; then
  15     gl_FUNC_FREXPL_WORKS
  16     case "$gl_cv_func_frexpl_works" in
  17       *yes) gl_func_frexpl_no_libm=yes ;;
  18       *)    gl_func_frexpl_no_libm=no; REPLACE_FREXPL=1 ;;
  19     esac
  20   else
  21     gl_func_frexpl_no_libm=no
  22     dnl Set REPLACE_FREXPL here because the system may have frexpl in libm.
  23     REPLACE_FREXPL=1
  24   fi
  25   if test $gl_func_frexpl_no_libm = yes; then
  26     AC_DEFINE([HAVE_FREXPL_IN_LIBC], [1],
  27       [Define if the frexpl function is available in libc.])
  28     dnl Also check whether it's declared.
  29     dnl MacOS X 10.3 has frexpl() in libc but doesn't declare it in <math.h>.
  30     AC_CHECK_DECL([frexpl], , [HAVE_DECL_FREXPL=0], [#include <math.h>])
  31   fi
  32
  33   gl_CHECK_LDEXPL_NO_LIBM
  34   if test $gl_cv_func_ldexpl_no_libm = yes; then
  35     gl_FUNC_LDEXPL_WORKS
  36     case "$gl_cv_func_ldexpl_works" in
  37       *yes)
  38         AC_DEFINE([HAVE_LDEXPL_IN_LIBC], [1],
  39           [Define if the ldexpl function is available in libc.])
  40         dnl Also check whether it's declared.
  41         dnl MacOS X 10.3 has ldexpl() in libc but doesn't declare it in <math.h>.
  42         AC_CHECK_DECL([ldexpl], , [HAVE_DECL_LDEXPL=0], [#include <math.h>])
  43         ;;
  44     esac
  45   fi
  46 ])