CMakeLists.txt

   1 PROJECT(LIBZYPP)
   2 SET( PACKAGE "libzypp" )
   3 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   4 SET( CMAKE_MODULE_PATH ${LIBZYPP_SOURCE_DIR}/cmake/modules )
   5
   6 cmake_minimum_required(VERSION 2.6)
   7
   8 OPTION (ENABLE_BUILD_DOCS "Build documentation by default?" OFF)
   9 OPTION (ENABLE_BUILD_TRANS "Build translation files by default?" OFF)
  10 OPTION (ENABLE_BUILD_TESTS "Build and run test suite by default?" OFF)
  11 OPTION (ENABLE_USE_THREADS "Enable using threads (NOT being used by threads!)?" OFF)
  12 OPTION (ENABLE_ZCHUNK_COMPRESSION "Build with zchunk compression support?" OFF)
  13
  14 OPTION (DISABLE_LIBPROXY "Build without libproxy support even if package is installed?" OFF)
  15 OPTION (DISABLE_AUTODOCS "Do not require doxygen being installed (required to build autodocs)?" OFF)
  16 #--------------------------------------------------------------------------------
  17 SET (have_system x)
  18
  19 set (CMAKE_CXX_STANDARD 14)
  20
  21 IF (DEBIAN)
  22   MESSAGE (STATUS "Building for Debian")
  23   SET (ENABLE_BUILD_DOCS ON)
  24   SET (ENABLE_BUILD_TRANS ON)
  25   SET (ENABLE_BUILD_TESTS ON)
  26   SET (have_system ${have_system}x)
  27 ENDIF (DEBIAN)
  28
  29 IF (${have_system} STREQUAL x)
  30   MESSAGE (STATUS "Building for SUSE")
  31 ENDIF (${have_system} STREQUAL x)
  32
  33 IF (${have_system} STRGREATER xx)
  34   MESSAGE (FATAL_ERROR "Can only build for one system type.")
  35 ENDIF (${have_system} STRGREATER xx)
  36 #--------------------------------------------------------------------------------
  37
  38 # allow name libraries by name mixed with full
  39 # paths
  40 if(COMMAND cmake_policy)
  41   cmake_policy(SET CMP0003 NEW)
  42 endif(COMMAND cmake_policy)
  43
  44 INCLUDE(ZyppCommon)
  45 find_package(FindPkgConfig)
  46 INCLUDE( ${LIBZYPP_SOURCE_DIR}/VERSION.cmake )
  47
  48 MATH( EXPR LIBZYPP_NUMVERSION "${LIBZYPP_MAJOR} * 10000 + ${LIBZYPP_MINOR} * 100 + ${LIBZYPP_PATCH}" )
  49 MATH( EXPR LIBZYPP_CURRENT "${LIBZYPP_MAJOR} * 100 + ${LIBZYPP_MINOR}" )
  50 MATH( EXPR LIBZYPP_AGE     "${LIBZYPP_MINOR} - ${LIBZYPP_COMPATMINOR}" )
  51 # Libtool wanted current:patch:age
  52 # But cmake is not libtool, it wants the verbatim suffix to libzypp.so
  53 MATH( EXPR LIBZYPP_SO_FIRST  "${LIBZYPP_CURRENT}-${LIBZYPP_AGE}" )
  54 SET( VERSION "${LIBZYPP_MAJOR}.${LIBZYPP_MINOR}.${LIBZYPP_PATCH}" )
  55 CONFIGURE_FILE ( zypp/APIConfig.h.in zypp/APIConfig.h )
  56
  57 include(CheckCCompilerFlag)
  58 include(CheckCXXCompilerFlag)
  59 CHECK_C_COMPILER_FLAG("-Werror=format-security" CC_FORMAT_SECURITY)
  60 CHECK_CXX_COMPILER_FLAG("-Werror=format-security" CXX_FORMAT_SECURITY)
  61
  62 SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Wp,-D_GLIBCXX_ASSERTIONS" )
  63 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Wp,-D_GLIBCXX_ASSERTIONS" )
  64
  65 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden -Woverloaded-virtual -Wnon-virtual-dtor" )
  66
  67 set( CMAKE_C_FLAGS_RELEASE     "${CMAKE_C_FLAGS} -O3 -DZYPP_NDEBUG" )
  68 set( CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS} -O3 -DZYPP_NDEBUG" )
  69
  70 IF(${CC_FORMAT_SECURITY})
  71   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=format-security")
  72 ENDIF(${CC_FORMAT_SECURITY})
  73
  74 IF(${CXX_FORMAT_SECURITY})
  75   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror=format-security")
  76 ENDIF(${CXX_FORMAT_SECURITY})
  77
  78 if ( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  79   #cli args ignored by clang, it still prints a noisy warning though
  80   SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -rdynamic -Wl,-as-needed" )
  81   SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -rdynamic -Wl,-as-needed" )
  82 endif()
  83
  84 INCLUDE(CheckFunctionExists)
  85 CHECK_FUNCTION_EXISTS(pipe2 PIPE2_FOUND)
  86 IF(${PIPE2_FOUND})
  87   ADD_DEFINITIONS(-DHAVE_PIPE2)
  88 ENDIF(${PIPE2_FOUND})
  89
  90 ADD_DEFINITIONS( -D_FILE_OFFSET_BITS=64 )
  91 SET( LIBZYPP_VERSION_INFO "${LIBZYPP_SO_FIRST}.${LIBZYPP_AGE}.${LIBZYPP_PATCH}" )
  92 SET( LIBZYPP_SOVERSION_INFO "${LIBZYPP_SO_FIRST}" )
  93
  94 GENERATE_PACKAGING(${PACKAGE} ${VERSION})
  95
  96 INCLUDE(CPack)
  97
  98 MACRO(ADD_TESTS)
  99   FOREACH( loop_var ${ARGV} )
 100     SET_SOURCE_FILES_PROPERTIES( ${loop_var}_test.cc COMPILE_FLAGS "-DBOOST_TEST_DYN_LINK -DBOOST_TEST_MAIN -DBOOST_AUTO_TEST_MAIN=\"\" " )
 101     ADD_EXECUTABLE( ${loop_var}_test ${loop_var}_test.cc )
 102     TARGET_LINK_LIBRARIES( ${loop_var}_test  zypp ${Boost_UNIT_TEST_FRAMEWORK_LIBRARY} zypp_test_utils)
 103     ADD_TEST( ${loop_var}_test ${CMAKE_CURRENT_BINARY_DIR}/${loop_var}_test --catch_system_errors=no)
 104   ENDFOREACH( loop_var )
 105 ENDMACRO(ADD_TESTS)
 106
 107 ####################################################################
 108
 109 IF ( ENABLE_USE_THREADS )
 110   SET( CMAKE_THREAD_PREFER_PTHREAD TRUE )
 111   FIND_PACKAGE( Threads REQUIRED )
 112   IF ( CMAKE_USE_PTHREADS_INIT )
 113     MESSAGE( STATUS "May use threads." )
 114     SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -pthread -DZYPP_USE_THREADS" )
 115     SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread -DZYPP_USE_THREADS" )
 116   ENDIF ( CMAKE_USE_PTHREADS_INIT )
 117 ENDIF ( ENABLE_USE_THREADS )
 118
 119 INCLUDE(CheckSymbolExists)
 120 FIND_PACKAGE(Rpm REQUIRED)
 121 IF ( NOT RPM_FOUND)
 122   MESSAGE( FATAL_ERROR " rpm-devel not found" )
 123 ELSE ( NOT RPM_FOUND)
 124   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR})
 125   # fix includes not relative to rpm
 126   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR}/rpm)
 127
 128   # rpmtsSetVfyFlags were introduced in rpm-4.15
 129   UNSET( RPMTSSETVFYFLAGS_FOUND CACHE )
 130   SET( CMAKE_REQUIRED_LIBRARIES "-lrpm" )
 131   CHECK_SYMBOL_EXISTS( rpmtsSetVfyFlags rpm/rpmts.h RPMTSSETVFYFLAGS_FOUND )
 132   IF ( NOT RPMTSSETVFYFLAGS_FOUND )
 133     ADD_DEFINITIONS( -DHAVE_NO_RPMTSSETVFYFLAGS )
 134   ENDIF ()
 135
 136   if ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 137         MESSAGE( STATUS "rpm found: enable rpm-4 compat interface." )
 138         ADD_DEFINITIONS(-D_RPM_5)
 139   endif ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 140 ENDIF( NOT RPM_FOUND)
 141
 142 FIND_PACKAGE(Boost REQUIRED COMPONENTS program_options unit_test_framework thread)
 143 IF (Boost_FOUND)
 144   MESSAGE( STATUS "boost found: includes in ${Boost_INCLUDE_DIRS}, library in ${Boost_LIBRARY_DIRS}")
 145   INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
 146   LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
 147 ENDIF(Boost_FOUND)
 148
 149 FIND_PACKAGE(Gettext REQUIRED)
 150 IF (GETTEXT_FOUND)
 151   MESSAGE(STATUS "Found Gettext: ${GETTEXT_SOURCE}")
 152   INCLUDE_DIRECTORIES(${GETTEXT_INCLUDE_DIR})
 153 ELSE (GETTEXT_FOUND)
 154   MESSAGE( FATAL_ERROR "Gettext not found" )
 155 ENDIF (GETTEXT_FOUND)
 156
 157 FIND_PACKAGE(CURL REQUIRED)
 158 IF ( NOT CURL_FOUND)
 159   MESSAGE( FATAL_ERROR " curl not found" )
 160 ELSE ( NOT CURL_FOUND)
 161   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 162 ENDIF( NOT CURL_FOUND)
 163
 164 FIND_PACKAGE(LibXml2 REQUIRED)
 165 IF ( NOT LIBXML2_FOUND)
 166   MESSAGE( FATAL_ERROR " libxml not found" )
 167 ELSE ( NOT LIBXML2_FOUND)
 168   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
 169 ENDIF( NOT LIBXML2_FOUND)
 170
 171 FIND_PACKAGE(ZLIB REQUIRED)
 172 IF ( NOT ZLIB_FOUND)
 173   MESSAGE( FATAL_ERROR " zlib not found" )
 174 ELSE ( NOT ZLIB_FOUND)
 175   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 176 ENDIF( NOT ZLIB_FOUND)
 177
 178
 179 #Allow to override the libsolv install location
 180 IF( LIBSOLV_SRCDIR AND LIBSOLV_BUILDDIR )
 181   execute_process(
 182     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv
 183     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/include
 184     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/ext
 185     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/solvversion
 186     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_SRCDIR}/src ${CMAKE_BINARY_DIR}/libsolv/include/solv
 187     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_SRCDIR}/ext ${CMAKE_BINARY_DIR}/libsolv/ext/solv
 188     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_BUILDDIR}/src ${CMAKE_BINARY_DIR}/libsolv/solvversion/solv
 189   )
 190
 191   INCLUDE_DIRECTORIES( ${CMAKE_BINARY_DIR}/libsolv/include ${CMAKE_BINARY_DIR}/libsolv/ext ${CMAKE_BINARY_DIR}/libsolv/solvversion ${CMAKE_BINARY_DIR}/libsolv/solvversion/solv ${CMAKE_BINARY_DIR}/libsolv/ext/solv ${CMAKE_BINARY_DIR}/libsolv/include/solv )
 192   SET( LibSolv_LIBRARIES ${LIBSOLV_BUILDDIR}/src/libsolv.a ${LIBSOLV_BUILDDIR}/ext/libsolvext.a )
 193
 194 ELSE()
 195   FIND_PACKAGE(LibSolv REQUIRED ext)
 196   #SET(LibSolv_USE_STATIC_LIBS ON)
 197   IF ( NOT LibSolv_FOUND )
 198     MESSAGE( FATAL_ERROR " libsolv not found" )
 199   ELSE()
 200     INCLUDE_DIRECTORIES( ${LibSolv_INCLUDE_DIRS} )
 201   ENDIF()
 202 ENDIF( LIBSOLV_SRCDIR AND LIBSOLV_BUILDDIR )
 203
 204 FIND_PACKAGE(Gpgme REQUIRED)
 205 IF ( NOT GPGME_PTHREAD_FOUND )
 206   MESSAGE( FATAL_ERROR " gpgme not found" )
 207 ELSE()
 208   INCLUDE_DIRECTORIES( ${GPGME_INCLUDES} )
 209   LINK_DIRECTORIES(${GPGME_LIBRARY_DIR})
 210 ENDIF()
 211
 212 FIND_PACKAGE(OpenSSL REQUIRED)
 213
 214 FIND_PACKAGE(Udev)
 215 IF ( NOT UDEV_FOUND )
 216   MESSAGE(WARNING "No udev found. CD device detection will be poor")
 217 ELSE ( NOT UDEV_FOUND )
 218   ADD_DEFINITIONS(-DHAVE_UDEV)
 219 ENDIF ( NOT UDEV_FOUND )
 220
 221 IF( DISABLE_LIBPROXY )
 222   MESSAGE( STATUS "libproxy support disabled" )
 223 ELSE( DISABLE_LIBPROXY )
 224   FIND_PACKAGE(libproxy)
 225   IF ( NOT LIBPROXY_FOUND )
 226     MESSAGE( STATUS "libproxy not found" )
 227   ELSE ( NOT LIBPROXY_FOUND )
 228     INCLUDE_DIRECTORIES( ${LIBPROXY_INCLUDE_DIR} )
 229     ADD_DEFINITIONS(-DWITH_LIBPROXY_SUPPORT)
 230   ENDIF( NOT LIBPROXY_FOUND )
 231 ENDIF( DISABLE_LIBPROXY )
 232
 233 FIND_PROGRAM( DOXYGEN doxygen )
 234 IF ( NOT DOXYGEN )
 235   IF ( DISABLE_AUTODOCS )
 236     MESSAGE( STATUS "doxygen is not available. Can't build the documentation." )
 237   ELSE ( DISABLE_AUTODOCS )
 238     MESSAGE( FATAL_ERROR "doxygen not found: install doxygen to build the documentation!" )
 239   ENDIF ( DISABLE_AUTODOCS )
 240 ELSE ( NOT DOXYGEN )
 241   MESSAGE( STATUS "doxygen found: ${DOXYGEN}" )
 242 ENDIF ( NOT DOXYGEN )
 243
 244 IF (ENABLE_ZCHUNK_COMPRESSION)
 245   MESSAGE("Building with zchunk support enabled.")
 246   PKG_CHECK_MODULES (ZCHUNK zck REQUIRED)
 247   SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} ${ZCHUNK_CFLAGS}" )
 248   SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ZCHUNK_CFLAGS}" )
 249   ADD_DEFINITIONS (-DENABLE_ZCHUNK_COMPRESSION=1)
 250 ENDIF(ENABLE_ZCHUNK_COMPRESSION)
 251
 252 MESSAGE(STATUS "soname: ${LIBZYPP_VERSION_INFO}")
 253 MESSAGE(STATUS "version: ${VERSION}")
 254
 255 MESSAGE(STATUS "Writing pkg-config file...")
 256 CONFIGURE_FILE(${LIBZYPP_SOURCE_DIR}/libzypp.pc.cmake ${LIBZYPP_BINARY_DIR}/libzypp.pc @ONLY)
 257 INSTALL( FILES ${LIBZYPP_BINARY_DIR}/libzypp.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 258
 259 MESSAGE(STATUS "FindZypp.cmake will be installed in ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules")
 260 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/FindZypp.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 261 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/ZyppCommon.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 262
 263 ####################################################################
 264 # config templates
 265 # (don't forget to mention them in the .spec file)
 266 ####################################################################
 267
 268 MESSAGE(STATUS "zypp.conf will be installed in ${SYSCONFDIR}/zypp")
 269 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp.conf DESTINATION ${SYSCONFDIR}/zypp )
 270
 271 MESSAGE(STATUS "needreboot will be installed in ${SYSCONFDIR}/zypp/")
 272 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/needreboot DESTINATION ${SYSCONFDIR}/zypp )
 273
 274 #install systemCheck
 275 MESSAGE(STATUS "systemCheck will be installed in ${SYSCONFDIR}/zypp")
 276 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/systemCheck DESTINATION ${SYSCONFDIR}/zypp )
 277
 278 # logrotate config file
 279 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp-history.lr DESTINATION ${SYSCONFDIR}/logrotate.d )
 280
 281 ####################################################################
 282 # SUBDIRECTORIES                                                   #
 283 ####################################################################
 284
 285 ADD_SUBDIRECTORY( zypp )
 286 # do not build devel by default
 287 ADD_SUBDIRECTORY( devel EXCLUDE_FROM_ALL )
 288 ADD_SUBDIRECTORY( tools )
 289 ADD_SUBDIRECTORY( doc )
 290 ADD_SUBDIRECTORY( vendor )
 291
 292 IF ( ENABLE_BUILD_TRANS )
 293   ADD_SUBDIRECTORY( po )
 294 ELSE ( ENABLE_BUILD_TRANS )
 295   ADD_SUBDIRECTORY( po EXCLUDE_FROM_ALL )
 296 ENDIF ( ENABLE_BUILD_TRANS )
 297
 298 IF ( ENABLE_BUILD_TESTS )
 299   ADD_SUBDIRECTORY( tests )
 300 ELSE ( ENABLE_BUILD_TESTS )
 301   ADD_SUBDIRECTORY( tests EXCLUDE_FROM_ALL )
 302 ENDIF ( ENABLE_BUILD_TESTS )
 303 INCLUDE(CTest)
 304 ENABLE_TESTING()