CMakeLists.txt

   1 PROJECT(LIBZYPP)
   2 SET( PACKAGE "libzypp" )
   3 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   4 SET( CMAKE_MODULE_PATH ${LIBZYPP_SOURCE_DIR}/cmake/modules )
   5
   6 cmake_minimum_required(VERSION 2.6)
   7
   8 OPTION (ENABLE_BUILD_DOCS "Build documentation by default?" OFF)
   9 OPTION (ENABLE_BUILD_TRANS "Build translation files by default?" OFF)
  10 OPTION (ENABLE_BUILD_TESTS "Build and run test suite by default?" OFF)
  11 OPTION (ENABLE_USE_THREADS "Enable using threads (NOT being used by threads!)?" OFF)
  12
  13 OPTION (DISABLE_LIBPROXY "Build without libproxy support even if package is installed?" OFF)
  14 OPTION (DISABLE_AUTODOCS "Do not require doxygen being installed (required to build autodocs)?" OFF)
  15 #--------------------------------------------------------------------------------
  16 SET (have_system x)
  17
  18 IF (DEBIAN)
  19   MESSAGE (STATUS "Building for Debian")
  20   SET (ENABLE_BUILD_DOCS ON)
  21   SET (ENABLE_BUILD_TRANS ON)
  22   SET (ENABLE_BUILD_TESTS ON)
  23   SET (have_system ${have_system}x)
  24 ENDIF (DEBIAN)
  25
  26 IF (${have_system} STREQUAL x)
  27   MESSAGE (STATUS "Building for SUSE")
  28 ENDIF (${have_system} STREQUAL x)
  29
  30 IF (${have_system} STRGREATER xx)
  31   MESSAGE (FATAL_ERROR "Can only build for one system type.")
  32 ENDIF (${have_system} STRGREATER xx)
  33 #--------------------------------------------------------------------------------
  34
  35 # allow name libraries by name mixed with full
  36 # paths
  37 if(COMMAND cmake_policy)
  38   cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 INCLUDE(ZyppCommon)
  42 INCLUDE( ${LIBZYPP_SOURCE_DIR}/VERSION.cmake )
  43
  44 MATH( EXPR LIBZYPP_CURRENT "${LIBZYPP_MAJOR} * 100 + ${LIBZYPP_MINOR}" )
  45 MATH( EXPR LIBZYPP_AGE     "${LIBZYPP_MINOR} - ${LIBZYPP_COMPATMINOR}" )
  46 # Libtool wanted current:patch:age
  47 # But cmake is not libtool, it wants the verbatim suffix to libzypp.so
  48 MATH( EXPR LIBZYPP_SO_FIRST  "${LIBZYPP_CURRENT}-${LIBZYPP_AGE}" )
  49 SET( VERSION "${LIBZYPP_MAJOR}.${LIBZYPP_MINOR}.${LIBZYPP_PATCH}" )
  50
  51 include(CheckCCompilerFlag)
  52 include(CheckCXXCompilerFlag)
  53 CHECK_C_COMPILER_FLAG("-Werror=format-security" CC_FORMAT_SECURITY)
  54 CHECK_CXX_COMPILER_FLAG("-Werror=format-security" CXX_FORMAT_SECURITY)
  55
  56 SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -fno-strict-aliasing -fPIC -g -rdynamic -Wall -Wl,-as-needed -Wp,-D_GLIBCXX_ASSERTIONS" )
  57 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing -fPIC -g -rdynamic -Wall -Wl,-as-needed -Wp,-D_GLIBCXX_ASSERTIONS" )
  58
  59 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fvisibility-inlines-hidden -Woverloaded-virtual -Wnon-virtual-dtor" )
  60
  61 set( CMAKE_C_FLAGS_RELEASE     "${CMAKE_C_FLAGS} -O3 -DZYPP_NDEBUG" )
  62 set( CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS} -O3 -DZYPP_NDEBUG" )
  63
  64 IF(${CC_FORMAT_SECURITY})
  65   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=format-security")
  66 ENDIF(${CC_FORMAT_SECURITY})
  67
  68 IF(${CXX_FORMAT_SECURITY})
  69   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror=format-security")
  70 ENDIF(${CXX_FORMAT_SECURITY})
  71
  72 INCLUDE(CheckFunctionExists)
  73 CHECK_FUNCTION_EXISTS(pipe2 PIPE2_FOUND)
  74 IF(${PIPE2_FOUND})
  75   ADD_DEFINITIONS(-DHAVE_PIPE2)
  76 ENDIF(${PIPE2_FOUND})
  77
  78 ADD_DEFINITIONS( -D_FILE_OFFSET_BITS=64 )
  79 ADD_DEFINITIONS( -DVERSION="${VERSION}" )
  80 SET( LIBZYPP_VERSION_INFO "${LIBZYPP_SO_FIRST}.${LIBZYPP_AGE}.${LIBZYPP_PATCH}" )
  81 SET( LIBZYPP_SOVERSION_INFO "${LIBZYPP_SO_FIRST}" )
  82
  83 GENERATE_PACKAGING(${PACKAGE} ${VERSION})
  84
  85 INCLUDE(CPack)
  86
  87 MACRO(ADD_TESTS)
  88   FOREACH( loop_var ${ARGV} )
  89     SET_SOURCE_FILES_PROPERTIES( ${loop_var}_test.cc COMPILE_FLAGS "-DBOOST_TEST_DYN_LINK -DBOOST_TEST_MAIN -DBOOST_AUTO_TEST_MAIN=\"\" " )
  90     ADD_EXECUTABLE( ${loop_var}_test ${loop_var}_test.cc )
  91     TARGET_LINK_LIBRARIES( ${loop_var}_test  zypp ${Boost_UNIT_TEST_FRAMEWORK_LIBRARY} zypp_test_utils)
  92     ADD_TEST( ${loop_var}_test ${CMAKE_CURRENT_BINARY_DIR}/${loop_var}_test --catch_system_errors=no)
  93   ENDFOREACH( loop_var )
  94 ENDMACRO(ADD_TESTS)
  95
  96 ####################################################################
  97
  98 IF ( ENABLE_USE_THREADS )
  99   SET( CMAKE_THREAD_PREFER_PTHREAD TRUE )
 100   FIND_PACKAGE( Threads REQUIRED )
 101   IF ( CMAKE_USE_PTHREADS_INIT )
 102     MESSAGE( STATUS "May use threads." )
 103     SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -pthread -DZYPP_USE_THREADS" )
 104     SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread -DZYPP_USE_THREADS" )
 105   ENDIF ( CMAKE_USE_PTHREADS_INIT )
 106 ENDIF ( ENABLE_USE_THREADS )
 107
 108 FIND_PACKAGE(Rpm REQUIRED)
 109 IF ( NOT RPM_FOUND)
 110   MESSAGE( FATAL_ERROR " rpm-devel not found" )
 111 ELSE ( NOT RPM_FOUND)
 112   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR})
 113   # fix includes not relative to rpm
 114   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR}/rpm)
 115   if ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 116         MESSAGE( STATUS "rpm found: enable rpm-4 compat interface." )
 117         ADD_DEFINITIONS(-D_RPM_5)
 118   endif ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 119 ENDIF( NOT RPM_FOUND)
 120
 121 FIND_PACKAGE(Boost REQUIRED COMPONENTS program_options unit_test_framework thread)
 122 IF (Boost_FOUND)
 123   MESSAGE( STATUS "boost found: includes in ${Boost_INCLUDE_DIRS}, library in ${Boost_LIBRARY_DIRS}")
 124   INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
 125   LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
 126 ENDIF(Boost_FOUND)
 127
 128 FIND_PACKAGE(Gettext REQUIRED)
 129 IF (GETTEXT_FOUND)
 130   MESSAGE(STATUS "Found Gettext: ${GETTEXT_SOURCE}")
 131   INCLUDE_DIRECTORIES(${GETTEXT_INCLUDE_DIR})
 132 ELSE (GETTEXT_FOUND)
 133   MESSAGE( FATAL_ERROR "Gettext not found" )
 134 ENDIF (GETTEXT_FOUND)
 135
 136 FIND_PACKAGE(CURL REQUIRED)
 137 IF ( NOT CURL_FOUND)
 138   MESSAGE( FATAL_ERROR " curl not found" )
 139 ELSE ( NOT CURL_FOUND)
 140   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 141 ENDIF( NOT CURL_FOUND)
 142
 143 FIND_PACKAGE(LibXml2 REQUIRED)
 144 IF ( NOT LIBXML2_FOUND)
 145   MESSAGE( FATAL_ERROR " libxml not found" )
 146 ELSE ( NOT LIBXML2_FOUND)
 147   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
 148 ENDIF( NOT LIBXML2_FOUND)
 149
 150 FIND_PACKAGE(ZLIB REQUIRED)
 151 IF ( NOT ZLIB_FOUND)
 152   MESSAGE( FATAL_ERROR " zlib not found" )
 153 ELSE ( NOT ZLIB_FOUND)
 154   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 155 ENDIF( NOT ZLIB_FOUND)
 156
 157 #SET(LibSolv_USE_STATIC_LIBS ON)
 158 FIND_PACKAGE(LibSolv REQUIRED ext)
 159 IF ( NOT LibSolv_FOUND )
 160   MESSAGE( FATAL_ERROR " libsolv not found" )
 161 ELSE()
 162   INCLUDE_DIRECTORIES( ${LibSolv_INCLUDE_DIRS} )
 163 ENDIF()
 164
 165 FIND_PACKAGE(Gpgme REQUIRED)
 166 IF ( NOT GPGME_PTHREAD_FOUND )
 167   MESSAGE( FATAL_ERROR " gpgme not found" )
 168 ELSE()
 169   INCLUDE_DIRECTORIES( ${GPGME_INCLUDES} )
 170   LINK_DIRECTORIES(${GPGME_LIBRARY_DIR})
 171 ENDIF()
 172
 173 FIND_PACKAGE(OpenSSL REQUIRED)
 174
 175 FIND_PACKAGE(Udev)
 176 IF ( NOT UDEV_FOUND )
 177   FIND_PACKAGE(Hal)
 178   IF ( NOT HAL_FOUND )
 179     MESSAGE(WARNING "No udev or HAL. CD device detection will be poor")
 180   ELSE ( NOT HAL_FOUND )
 181       ADD_DEFINITIONS(-DHAVE_HAL)
 182       INCLUDE_DIRECTORIES(${HAL_INCLUDE_DIR})
 183       INCLUDE_DIRECTORIES(${HAL_INCLUDE_DIR}/hal)
 184       # HAL requires working dbus
 185       FIND_PACKAGE(Dbus REQUIRED)
 186       IF(DBUS_FOUND)
 187         INCLUDE_DIRECTORIES(${DBUS_INCLUDE_DIR})
 188         INCLUDE_DIRECTORIES(${DBUS_ARCH_INCLUDE_DIR})
 189       ENDIF(DBUS_FOUND)
 190   ENDIF ( NOT HAL_FOUND )
 191 ELSE ( NOT UDEV_FOUND )
 192   ADD_DEFINITIONS(-DHAVE_UDEV)
 193 ENDIF ( NOT UDEV_FOUND )
 194
 195 IF( DISABLE_LIBPROXY )
 196   MESSAGE( STATUS "libproxy support disabled" )
 197 ELSE( DISABLE_LIBPROXY )
 198   FIND_PACKAGE(libproxy)
 199   IF ( NOT LIBPROXY_FOUND )
 200     MESSAGE( STATUS "libproxy not found" )
 201   ELSE ( NOT LIBPROXY_FOUND )
 202     INCLUDE_DIRECTORIES( ${LIBPROXY_INCLUDE_DIR} )
 203     ADD_DEFINITIONS(-DWITH_LIBPROXY_SUPPORT)
 204   ENDIF( NOT LIBPROXY_FOUND )
 205 ENDIF( DISABLE_LIBPROXY )
 206
 207 FIND_PROGRAM( DOXYGEN doxygen )
 208 IF ( NOT DOXYGEN )
 209   IF ( DISABLE_AUTODOCS )
 210     MESSAGE( STATUS "doxygen is not available. Can't build the documentation." )
 211   ELSE ( DISABLE_AUTODOCS )
 212     MESSAGE( FATAL_ERROR "doxygen not found: install doxygen to build the documentation!" )
 213   ENDIF ( DISABLE_AUTODOCS )
 214 ELSE ( NOT DOXYGEN )
 215   MESSAGE( STATUS "doxygen found: ${DOXYGEN}" )
 216 ENDIF ( NOT DOXYGEN )
 217
 218 MESSAGE(STATUS "soname: ${LIBZYPP_VERSION_INFO}")
 219 MESSAGE(STATUS "version: ${VERSION}")
 220
 221 MESSAGE(STATUS "Writing pkg-config file...")
 222 CONFIGURE_FILE(${LIBZYPP_SOURCE_DIR}/libzypp.pc.cmake ${LIBZYPP_BINARY_DIR}/libzypp.pc @ONLY)
 223 INSTALL( FILES ${LIBZYPP_BINARY_DIR}/libzypp.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 224
 225 MESSAGE(STATUS "FindZypp.cmake will be installed in ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules")
 226 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/FindZypp.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 227 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/ZyppCommon.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 228
 229 ####################################################################
 230 # config templates
 231 # (don't forget to mention them in the .spec file)
 232 ####################################################################
 233
 234 MESSAGE(STATUS "zypp.conf will be installed in ${SYSCONFDIR}/zypp")
 235 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp.conf DESTINATION ${SYSCONFDIR}/zypp )
 236
 237 MESSAGE(STATUS "needreboot will be installed in /var/lib/zypp/")
 238 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/needreboot DESTINATION /var/lib/zypp )
 239
 240 #install systemCheck
 241 MESSAGE(STATUS "systemCheck will be installed in ${SYSCONFDIR}/zypp")
 242 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/systemCheck DESTINATION ${SYSCONFDIR}/zypp )
 243
 244 # logrotate config file
 245 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp-history.lr DESTINATION ${SYSCONFDIR}/logrotate.d )
 246
 247 ####################################################################
 248 # SUBDIRECTORIES                                                   #
 249 ####################################################################
 250
 251 ADD_SUBDIRECTORY( zypp )
 252 # do not build devel by default
 253 ADD_SUBDIRECTORY( devel EXCLUDE_FROM_ALL )
 254 ADD_SUBDIRECTORY( tools )
 255 ADD_SUBDIRECTORY( doc )
 256 ADD_SUBDIRECTORY( vendor )
 257
 258 IF ( ENABLE_BUILD_TRANS )
 259   ADD_SUBDIRECTORY( po )
 260 ELSE ( ENABLE_BUILD_TRANS )
 261   ADD_SUBDIRECTORY( po EXCLUDE_FROM_ALL )
 262 ENDIF ( ENABLE_BUILD_TRANS )
 263
 264 IF ( ENABLE_BUILD_TESTS )
 265   ADD_SUBDIRECTORY( tests )
 266 ELSE ( ENABLE_BUILD_TESTS )
 267   ADD_SUBDIRECTORY( tests EXCLUDE_FROM_ALL )
 268 ENDIF ( ENABLE_BUILD_TESTS )
 269 INCLUDE(CTest)
 270 ENABLE_TESTING()