CMakeLists.txt

   1 PROJECT(LIBZYPP)
   2 SET( PACKAGE "libzypp" )
   3 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   4 SET( CMAKE_MODULE_PATH ${LIBZYPP_SOURCE_DIR}/cmake/modules )
   5 cmake_minimum_required(VERSION 2.6)
   6
   7 # allow name libraries by name mixed with full
   8 # paths
   9 if(COMMAND cmake_policy)
  10   cmake_policy(SET CMP0003 NEW)
  11 endif(COMMAND cmake_policy)
  12
  13 INCLUDE(ZyppCommon)
  14 INCLUDE( ${LIBZYPP_SOURCE_DIR}/VERSION.cmake )
  15
  16 MATH( EXPR LIBZYPP_CURRENT "${LIBZYPP_MAJOR} * 100 + ${LIBZYPP_MINOR}" )
  17 MATH( EXPR LIBZYPP_AGE     "${LIBZYPP_MINOR} - ${LIBZYPP_COMPATMINOR}" )
  18 # Libtool wanted current:patch:age
  19 # But cmake is not libtool, it wants the verbatim suffix to libzypp.so
  20 MATH( EXPR LIBZYPP_SO_FIRST  "${LIBZYPP_CURRENT}-${LIBZYPP_AGE}" )
  21 SET( VERSION "${LIBZYPP_MAJOR}.${LIBZYPP_MINOR}.${LIBZYPP_PATCH}" )
  22
  23 include(CheckCCompilerFlag)
  24 include(CheckCXXCompilerFlag)
  25 CHECK_C_COMPILER_FLAG("-Werror=format-security" CC_FORMAT_SECURITY)
  26 CHECK_CXX_COMPILER_FLAG("-Werror=format-security" CXX_FORMAT_SECURITY)
  27
  28 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Woverloaded-virtual -Wnon-virtual-dtor -Wl,-as-needed" )
  29 SET( CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -fno-strict-aliasing -fPIC -g -Wall -Wl,-as-needed" )
  30
  31 set( CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3" )
  32 set( CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS} -O3" )
  33
  34 IF(${CC_FORMAT_SECURITY})
  35   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=format-security")
  36 ENDIF(${CC_FORMAT_SECURITY})
  37
  38 IF(${CXX_FORMAT_SECURITY})
  39   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror=format-security")
  40 ENDIF(${CXX_FORMAT_SECURITY})
  41
  42 ADD_DEFINITIONS( -D_FILE_OFFSET_BITS=64 )
  43 ADD_DEFINITIONS( -DVERSION="${VERSION}" )
  44 SET( LIBZYPP_VERSION_INFO "${LIBZYPP_SO_FIRST}.${LIBZYPP_AGE}.${LIBZYPP_PATCH}" )
  45 SET( LIBZYPP_SOVERSION_INFO "${LIBZYPP_SO_FIRST}" )
  46
  47 GENERATE_PACKAGING(${PACKAGE} ${VERSION})
  48
  49 INCLUDE(CPack)
  50
  51 MACRO(ADD_TESTS)
  52   FOREACH( loop_var ${ARGV} )
  53     SET_SOURCE_FILES_PROPERTIES( ${loop_var}_test.cc COMPILE_FLAGS "-DBOOST_TEST_DYN_LINK -DBOOST_TEST_MAIN -DBOOST_AUTO_TEST_MAIN=\"\" " )
  54     ADD_EXECUTABLE( ${loop_var}_test ${loop_var}_test.cc )
  55     TARGET_LINK_LIBRARIES( ${loop_var}_test  zypp boost_unit_test_framework zypp_test_utils)
  56     ADD_TEST( ${loop_var}_test ${CMAKE_CURRENT_BINARY_DIR}/${loop_var}_test --catch_system_errors=no)
  57   ENDFOREACH( loop_var )
  58 ENDMACRO(ADD_TESTS)
  59
  60 ####################################################################
  61
  62 FIND_PACKAGE(Rpm REQUIRED)
  63 IF ( NOT RPM_FOUND)
  64   MESSAGE( FATAL_ERROR " rpm-devel not found" )
  65 ELSE ( NOT RPM_FOUND)
  66   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR})
  67   # fix includes not relative to rpm
  68   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR}/rpm)
  69   if ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
  70         MESSAGE( STATUS "rpm found: enable rpm-4 compat interface." )
  71         ADD_DEFINITIONS(-D_RPM_5)
  72   elseif ( RPM_SUSPECT_VERSION STREQUAL "4.x" )
  73         MESSAGE( STATUS "rpm found: enable rpm-4.4 legacy interface." )
  74         ADD_DEFINITIONS(-D_RPM_4_4_COMPAT)
  75   endif ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
  76 ENDIF( NOT RPM_FOUND)
  77
  78 FIND_PACKAGE(Boost REQUIRED)
  79 IF (Boost_FOUND)
  80   MESSAGE( STATUS "boost found: includes in ${Boost_INCLUDE_DIRS}, library in ${Boost_LIBRARY_DIRS}")
  81   INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
  82   LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  83 ENDIF(Boost_FOUND)
  84
  85 FIND_PACKAGE(Gettext REQUIRED)
  86 IF (GETTEXT_FOUND)
  87   MESSAGE(STATUS "Found Gettext: ${GETTEXT_SOURCE}")
  88   INCLUDE_DIRECTORIES(${GETTEXT_INCLUDE_DIR})
  89 ELSE (GETTEXT_FOUND)
  90   MESSAGE( FATAL_ERROR "Gettext not found" )
  91 ENDIF (GETTEXT_FOUND)
  92
  93 FIND_PACKAGE(Curl REQUIRED)
  94 IF ( NOT CURL_FOUND)
  95   MESSAGE( FATAL_ERROR " curl not found" )
  96 ELSE ( NOT CURL_FOUND)
  97   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
  98 ENDIF( NOT CURL_FOUND)
  99
 100 FIND_PACKAGE(Libxml REQUIRED)
 101 IF ( NOT LIBXML_FOUND)
 102   MESSAGE( FATAL_ERROR " libxml not found" )
 103 ELSE ( NOT LIBXML_FOUND)
 104   INCLUDE_DIRECTORIES(${LIBXML_INCLUDE_DIR})
 105 ENDIF( NOT LIBXML_FOUND)
 106
 107 FIND_PACKAGE(ZLIB REQUIRED)
 108 IF ( NOT ZLIB_FOUND)
 109   MESSAGE( FATAL_ERROR " zlib not found" )
 110 ELSE ( NOT ZLIB_FOUND)
 111   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 112 ENDIF( NOT ZLIB_FOUND)
 113
 114 FIND_PACKAGE(Satsolver REQUIRED)
 115 IF ( NOT SATSOLVER_FOUND )
 116   MESSAGE( FATAL_ERROR " libsatsolver not found" )
 117 ELSE ( NOT SATSOLVER_FOUND )
 118   INCLUDE_DIRECTORIES( ${SATSOLVER_INCLUDE_DIR} )
 119 ENDIF( NOT SATSOLVER_FOUND )
 120
 121 # satsolver uses expat and has open references to it:
 122 FIND_PACKAGE(EXPAT REQUIRED)
 123
 124 FIND_PACKAGE(OpenSSL REQUIRED)
 125 FIND_PACKAGE(Udev REQUIRED)
 126
 127 FIND_PACKAGE(libproxy)
 128 IF ( NOT LIBPROXY_FOUND )
 129   MESSAGE( STATUS " libproxy not found" )
 130 ELSE ( NOT LIBPROXY_FOUND )
 131   INCLUDE_DIRECTORIES( ${LIBPROXY_INCLUDE_DIR} )
 132   ADD_DEFINITIONS(-D_WITH_LIBPROXY_SUPPORT_)
 133 ENDIF( NOT LIBPROXY_FOUND )
 134
 135 FIND_PROGRAM( DOXYGEN doxygen )
 136 IF ( NOT DOXYGEN )
 137   MESSAGE( FATAL_ERROR "doxygen not found: install doxygen to build the documentation." )
 138 ELSE ( NOT DOXYGEN )
 139   MESSAGE( STATUS "doxygen found: ${DOXYGEN}" )
 140 ENDIF ( NOT DOXYGEN )
 141
 142 MESSAGE(STATUS "soname: ${LIBZYPP_VERSION_INFO}")
 143 MESSAGE(STATUS "version: ${VERSION}")
 144
 145 MESSAGE(STATUS "Writing pkg-config file...")
 146 CONFIGURE_FILE(${LIBZYPP_SOURCE_DIR}/libzypp.pc.cmake ${LIBZYPP_BINARY_DIR}/libzypp.pc @ONLY)
 147 INSTALL( FILES ${LIBZYPP_BINARY_DIR}/libzypp.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 148
 149 MESSAGE(STATUS "FindZypp.cmake will be installed in ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules")
 150 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/FindZypp.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 151 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/ZyppCommon.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 152
 153 ####################################################################
 154 # config templates
 155 # (don't forget to mention them in the .spec file)
 156 ####################################################################
 157
 158 MESSAGE(STATUS "zypp.conf will be installed in ${SYSCONFDIR}/zypp")
 159 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp.conf DESTINATION ${SYSCONFDIR}/zypp )
 160
 161 #install systemCheck
 162 MESSAGE(STATUS "systemCheck will be installed in ${SYSCONFDIR}/zypp")
 163 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/systemCheck DESTINATION ${SYSCONFDIR}/zypp )
 164
 165 # logrotate config file
 166 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp-history.lr DESTINATION ${SYSCONFDIR}/logrotate.d )
 167
 168 ####################################################################
 169 # SUBDIRECTORIES                                                   #
 170 ####################################################################
 171
 172 ADD_SUBDIRECTORY( zypp )
 173 #ADD_SUBDIRECTORY( zypp2 )
 174 # do not build devel by default
 175 ADD_SUBDIRECTORY( devel EXCLUDE_FROM_ALL )
 176 ADD_SUBDIRECTORY( tools )
 177 ADD_SUBDIRECTORY( examples )
 178 ADD_SUBDIRECTORY( po EXCLUDE_FROM_ALL )
 179 ADD_SUBDIRECTORY( doc )
 180 ADD_SUBDIRECTORY( vendor )
 181 ADD_SUBDIRECTORY( tests EXCLUDE_FROM_ALL )
 182
 183 INCLUDE(CTest)
 184 ENABLE_TESTING()