CMakeLists.txt

   1 PROJECT(LIBZYPP)
   2 SET( PACKAGE "libzypp" )
   3 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   4 SET( CMAKE_MODULE_PATH ${LIBZYPP_SOURCE_DIR}/cmake/modules )
   5 cmake_minimum_required(VERSION 2.6)
   6
   7 # allow name libraries by name mixed with full
   8 # paths
   9 if(COMMAND cmake_policy)
  10   cmake_policy(SET CMP0003 NEW)
  11 endif(COMMAND cmake_policy)
  12
  13 INCLUDE(ZyppCommon)
  14 INCLUDE( ${LIBZYPP_SOURCE_DIR}/VERSION.cmake )
  15
  16 MATH( EXPR LIBZYPP_CURRENT "${LIBZYPP_MAJOR} * 100 + ${LIBZYPP_MINOR}" )
  17 MATH( EXPR LIBZYPP_AGE     "${LIBZYPP_MINOR} - ${LIBZYPP_COMPATMINOR}" )
  18 # Libtool wanted current:patch:age
  19 # But cmake is not libtool, it wants the verbatim suffix to libzypp.so
  20 MATH( EXPR LIBZYPP_SO_FIRST  "${LIBZYPP_CURRENT}-${LIBZYPP_AGE}" )
  21 SET( VERSION "${LIBZYPP_MAJOR}.${LIBZYPP_MINOR}.${LIBZYPP_PATCH}" )
  22
  23 include(CheckCCompilerFlag)
  24 include(CheckCXXCompilerFlag)
  25 CHECK_C_COMPILER_FLAG("-Werror=format-security" CC_FORMAT_SECURITY)
  26 CHECK_CXX_COMPILER_FLAG("-Werror=format-security" CXX_FORMAT_SECURITY)
  27
  28 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Woverloaded-virtual -Wnon-virtual-dtor -Wl,-as-needed" )
  29 SET( CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -fno-strict-aliasing -fPIC -g -Wall -Wl,-as-needed" )
  30
  31 set( CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3" )
  32 set( CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS} -O3" )
  33
  34 IF(${CC_FORMAT_SECURITY})
  35   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=format-security")
  36 ENDIF(${CC_FORMAT_SECURITY})
  37
  38 IF(${CXX_FORMAT_SECURITY})
  39   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror=format-security")
  40 ENDIF(${CXX_FORMAT_SECURITY})
  41
  42 INCLUDE(CheckFunctionExists)
  43 CHECK_FUNCTION_EXISTS(pipe2 PIPE2_FOUND)
  44 IF(${PIPE2_FOUND})
  45   ADD_DEFINITIONS(-DHAVE_PIPE2)
  46 ENDIF(${PIPE2_FOUND})
  47
  48 ADD_DEFINITIONS( -D_FILE_OFFSET_BITS=64 )
  49 ADD_DEFINITIONS( -DVERSION="${VERSION}" )
  50 SET( LIBZYPP_VERSION_INFO "${LIBZYPP_SO_FIRST}.${LIBZYPP_AGE}.${LIBZYPP_PATCH}" )
  51 SET( LIBZYPP_SOVERSION_INFO "${LIBZYPP_SO_FIRST}" )
  52
  53 GENERATE_PACKAGING(${PACKAGE} ${VERSION})
  54
  55 INCLUDE(CPack)
  56
  57 MACRO(ADD_TESTS)
  58   FOREACH( loop_var ${ARGV} )
  59     SET_SOURCE_FILES_PROPERTIES( ${loop_var}_test.cc COMPILE_FLAGS "-DBOOST_TEST_DYN_LINK -DBOOST_TEST_MAIN -DBOOST_AUTO_TEST_MAIN=\"\" " )
  60     ADD_EXECUTABLE( ${loop_var}_test ${loop_var}_test.cc )
  61     TARGET_LINK_LIBRARIES( ${loop_var}_test  zypp boost_unit_test_framework zypp_test_utils)
  62     ADD_TEST( ${loop_var}_test ${CMAKE_CURRENT_BINARY_DIR}/${loop_var}_test --catch_system_errors=no)
  63   ENDFOREACH( loop_var )
  64 ENDMACRO(ADD_TESTS)
  65
  66 ####################################################################
  67
  68 FIND_PACKAGE(Rpm REQUIRED)
  69 IF ( NOT RPM_FOUND)
  70   MESSAGE( FATAL_ERROR " rpm-devel not found" )
  71 ELSE ( NOT RPM_FOUND)
  72   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR})
  73   # fix includes not relative to rpm
  74   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR}/rpm)
  75   if ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
  76         MESSAGE( STATUS "rpm found: enable rpm-4 compat interface." )
  77         ADD_DEFINITIONS(-D_RPM_5)
  78   elseif ( RPM_SUSPECT_VERSION STREQUAL "4.x" )
  79         MESSAGE( STATUS "rpm found: enable rpm-4.4 legacy interface." )
  80         ADD_DEFINITIONS(-D_RPM_4_4_COMPAT)
  81   endif ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
  82 ENDIF( NOT RPM_FOUND)
  83
  84 FIND_PACKAGE(Boost REQUIRED COMPONENTS program_options unit_test_framework)
  85 IF (Boost_FOUND)
  86   MESSAGE( STATUS "boost found: includes in ${Boost_INCLUDE_DIRS}, library in ${Boost_LIBRARY_DIRS}")
  87   INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
  88   LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  89 ENDIF(Boost_FOUND)
  90
  91 FIND_PACKAGE(Gettext REQUIRED)
  92 IF (GETTEXT_FOUND)
  93   MESSAGE(STATUS "Found Gettext: ${GETTEXT_SOURCE}")
  94   INCLUDE_DIRECTORIES(${GETTEXT_INCLUDE_DIR})
  95 ELSE (GETTEXT_FOUND)
  96   MESSAGE( FATAL_ERROR "Gettext not found" )
  97 ENDIF (GETTEXT_FOUND)
  98
  99 FIND_PACKAGE(Curl REQUIRED)
 100 IF ( NOT CURL_FOUND)
 101   MESSAGE( FATAL_ERROR " curl not found" )
 102 ELSE ( NOT CURL_FOUND)
 103   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 104 ENDIF( NOT CURL_FOUND)
 105
 106 FIND_PACKAGE(Libxml REQUIRED)
 107 IF ( NOT LIBXML_FOUND)
 108   MESSAGE( FATAL_ERROR " libxml not found" )
 109 ELSE ( NOT LIBXML_FOUND)
 110   INCLUDE_DIRECTORIES(${LIBXML_INCLUDE_DIR})
 111 ENDIF( NOT LIBXML_FOUND)
 112
 113 FIND_PACKAGE(ZLIB REQUIRED)
 114 IF ( NOT ZLIB_FOUND)
 115   MESSAGE( FATAL_ERROR " zlib not found" )
 116 ELSE ( NOT ZLIB_FOUND)
 117   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 118 ENDIF( NOT ZLIB_FOUND)
 119
 120 FIND_PACKAGE(Satsolver REQUIRED)
 121 IF ( NOT SATSOLVER_FOUND )
 122   MESSAGE( FATAL_ERROR " libsatsolver not found" )
 123 ELSE ( NOT SATSOLVER_FOUND )
 124   INCLUDE_DIRECTORIES( ${SATSOLVER_INCLUDE_DIR} )
 125 ENDIF( NOT SATSOLVER_FOUND )
 126
 127 # satsolver uses expat and has open references to it:
 128 FIND_PACKAGE(EXPAT REQUIRED)
 129
 130 FIND_PACKAGE(OpenSSL REQUIRED)
 131
 132 FIND_PACKAGE(Udev)
 133 IF ( NOT UDEV_FOUND )
 134   FIND_PACKAGE(Hal)
 135   IF ( NOT HAL_FOUND )
 136     MESSAGE(WARNING "No udev or HAL. CD device detection will be poor")
 137   ELSE ( NOT HAL_FOUND )
 138       ADD_DEFINITIONS(-DHAVE_HAL)
 139       INCLUDE_DIRECTORIES(${HAL_INCLUDE_DIR})
 140       INCLUDE_DIRECTORIES(${HAL_INCLUDE_DIR}/hal)
 141       # HAL requires working dbus
 142       FIND_PACKAGE(Dbus REQUIRED)
 143       IF(DBUS_FOUND)
 144         INCLUDE_DIRECTORIES(${DBUS_INCLUDE_DIR})
 145         INCLUDE_DIRECTORIES(${DBUS_ARCH_INCLUDE_DIR})
 146       ENDIF(DBUS_FOUND)
 147   ENDIF ( NOT HAL_FOUND )
 148 ELSE ( NOT UDEV_FOUND )
 149   ADD_DEFINITIONS(-DHAVE_UDEV)
 150 ENDIF ( NOT UDEV_FOUND )
 151
 152 FIND_PACKAGE(libproxy)
 153 IF ( NOT LIBPROXY_FOUND )
 154   MESSAGE( STATUS " libproxy not found" )
 155 ELSE ( NOT LIBPROXY_FOUND )
 156   INCLUDE_DIRECTORIES( ${LIBPROXY_INCLUDE_DIR} )
 157   ADD_DEFINITIONS(-D_WITH_LIBPROXY_SUPPORT_)
 158 ENDIF( NOT LIBPROXY_FOUND )
 159
 160 FIND_PROGRAM( DOXYGEN doxygen )
 161 IF ( NOT DOXYGEN )
 162   MESSAGE( FATAL_ERROR "doxygen not found: install doxygen to build the documentation." )
 163 ELSE ( NOT DOXYGEN )
 164   MESSAGE( STATUS "doxygen found: ${DOXYGEN}" )
 165 ENDIF ( NOT DOXYGEN )
 166
 167 MESSAGE(STATUS "soname: ${LIBZYPP_VERSION_INFO}")
 168 MESSAGE(STATUS "version: ${VERSION}")
 169
 170 MESSAGE(STATUS "Writing pkg-config file...")
 171 CONFIGURE_FILE(${LIBZYPP_SOURCE_DIR}/libzypp.pc.cmake ${LIBZYPP_BINARY_DIR}/libzypp.pc @ONLY)
 172 INSTALL( FILES ${LIBZYPP_BINARY_DIR}/libzypp.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 173
 174 MESSAGE(STATUS "FindZypp.cmake will be installed in ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules")
 175 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/FindZypp.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 176 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/ZyppCommon.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 177
 178 ####################################################################
 179 # config templates
 180 # (don't forget to mention them in the .spec file)
 181 ####################################################################
 182
 183 MESSAGE(STATUS "zypp.conf will be installed in ${SYSCONFDIR}/zypp")
 184 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp.conf DESTINATION ${SYSCONFDIR}/zypp )
 185
 186 #install systemCheck
 187 MESSAGE(STATUS "systemCheck will be installed in ${SYSCONFDIR}/zypp")
 188 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/systemCheck DESTINATION ${SYSCONFDIR}/zypp )
 189
 190 # logrotate config file
 191 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp-history.lr DESTINATION ${SYSCONFDIR}/logrotate.d )
 192
 193 ####################################################################
 194 # SUBDIRECTORIES                                                   #
 195 ####################################################################
 196
 197 ADD_SUBDIRECTORY( zypp )
 198 #ADD_SUBDIRECTORY( zypp2 )
 199 # do not build devel by default
 200 ADD_SUBDIRECTORY( devel EXCLUDE_FROM_ALL )
 201 ADD_SUBDIRECTORY( tools )
 202 ADD_SUBDIRECTORY( examples )
 203 ADD_SUBDIRECTORY( po EXCLUDE_FROM_ALL )
 204 ADD_SUBDIRECTORY( doc )
 205 ADD_SUBDIRECTORY( vendor )
 206 ADD_SUBDIRECTORY( tests EXCLUDE_FROM_ALL )
 207
 208 INCLUDE(CTest)
 209 ENABLE_TESTING()