CMakeLists.txt

   1 PROJECT(LIBZYPP)
   2 SET( PACKAGE "libzypp" )
   3 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   4 SET( CMAKE_MODULE_PATH ${LIBZYPP_SOURCE_DIR}/cmake/modules )
   5
   6 cmake_minimum_required(VERSION 2.6)
   7
   8 OPTION (ENABLE_BUILD_DOCS "Build documentation by default?" OFF)
   9 OPTION (ENABLE_BUILD_TRANS "Build translation files by default?" OFF)
  10 OPTION (ENABLE_BUILD_TESTS "Build and run test suite by default?" OFF)
  11 OPTION (ENABLE_USE_THREADS "Enable using threads (NOT being used by threads!)?" OFF)
  12 OPTION (ENABLE_ZCHUNK_COMPRESSION "Build with zchunk compression support?" OFF)
  13
  14 OPTION (DISABLE_LIBPROXY "Build without libproxy support even if package is installed?" OFF)
  15 OPTION (DISABLE_AUTODOCS "Do not require doxygen being installed (required to build autodocs)?" OFF)
  16 OPTION (EXPORT_NG_API "Export experimental libzypp API" OFF)
  17 #--------------------------------------------------------------------------------
  18 SET (have_system x)
  19
  20 set (CMAKE_CXX_STANDARD 14)
  21
  22 IF (DEBIAN)
  23   MESSAGE (STATUS "Building for Debian")
  24   SET (ENABLE_BUILD_DOCS ON)
  25   SET (ENABLE_BUILD_TRANS ON)
  26   SET (ENABLE_BUILD_TESTS ON)
  27   SET (have_system ${have_system}x)
  28 ENDIF (DEBIAN)
  29
  30 IF (${have_system} STREQUAL x)
  31   MESSAGE (STATUS "Building for SUSE")
  32 ENDIF (${have_system} STREQUAL x)
  33
  34 IF (${have_system} STRGREATER xx)
  35   MESSAGE (FATAL_ERROR "Can only build for one system type.")
  36 ENDIF (${have_system} STRGREATER xx)
  37 #--------------------------------------------------------------------------------
  38
  39 # allow name libraries by name mixed with full
  40 # paths
  41 if(COMMAND cmake_policy)
  42   cmake_policy(SET CMP0003 NEW)
  43 endif(COMMAND cmake_policy)
  44
  45 INCLUDE(ZyppCommon)
  46 find_package(FindPkgConfig)
  47 INCLUDE( ${LIBZYPP_SOURCE_DIR}/VERSION.cmake )
  48
  49 MATH( EXPR LIBZYPP_NUMVERSION "${LIBZYPP_MAJOR} * 10000 + ${LIBZYPP_MINOR} * 100 + ${LIBZYPP_PATCH}" )
  50 MATH( EXPR LIBZYPP_CURRENT "${LIBZYPP_MAJOR} * 100 + ${LIBZYPP_MINOR}" )
  51 MATH( EXPR LIBZYPP_AGE     "${LIBZYPP_MINOR} - ${LIBZYPP_COMPATMINOR}" )
  52 # Libtool wanted current:patch:age
  53 # But cmake is not libtool, it wants the verbatim suffix to libzypp.so
  54 MATH( EXPR LIBZYPP_SO_FIRST  "${LIBZYPP_CURRENT}-${LIBZYPP_AGE}" )
  55 SET( VERSION "${LIBZYPP_MAJOR}.${LIBZYPP_MINOR}.${LIBZYPP_PATCH}" )
  56 CONFIGURE_FILE ( zypp/APIConfig.h.in zypp/APIConfig.h )
  57
  58 include(CheckCCompilerFlag)
  59 include(CheckCXXCompilerFlag)
  60 CHECK_C_COMPILER_FLAG("-Werror=format-security" CC_FORMAT_SECURITY)
  61 CHECK_CXX_COMPILER_FLAG("-Werror=format-security" CXX_FORMAT_SECURITY)
  62
  63 SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Wp,-D_GLIBCXX_ASSERTIONS" )
  64 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing -fPIC -g -Wall -Wp,-D_GLIBCXX_ASSERTIONS" )
  65
  66 SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden -Woverloaded-virtual -Wnon-virtual-dtor" )
  67
  68 set( CMAKE_C_FLAGS_RELEASE     "${CMAKE_C_FLAGS} -O3 -DZYPP_NDEBUG" )
  69 set( CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS} -O3 -DZYPP_NDEBUG" )
  70
  71 IF(${CC_FORMAT_SECURITY})
  72   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=format-security")
  73 ENDIF(${CC_FORMAT_SECURITY})
  74
  75 IF(${CXX_FORMAT_SECURITY})
  76   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror=format-security")
  77 ENDIF(${CXX_FORMAT_SECURITY})
  78
  79 if ( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  80   #cli args ignored by clang, it still prints a noisy warning though
  81   SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -rdynamic -Wl,-as-needed" )
  82   SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -rdynamic -Wl,-as-needed" )
  83 endif()
  84
  85 INCLUDE(CheckFunctionExists)
  86 CHECK_FUNCTION_EXISTS(pipe2 PIPE2_FOUND)
  87 IF(${PIPE2_FOUND})
  88   ADD_DEFINITIONS(-DHAVE_PIPE2)
  89 ENDIF(${PIPE2_FOUND})
  90
  91 ADD_DEFINITIONS( -D_FILE_OFFSET_BITS=64 )
  92 SET( LIBZYPP_VERSION_INFO "${LIBZYPP_SO_FIRST}.${LIBZYPP_AGE}.${LIBZYPP_PATCH}" )
  93 SET( LIBZYPP_SOVERSION_INFO "${LIBZYPP_SO_FIRST}" )
  94
  95 GENERATE_PACKAGING(${PACKAGE} ${VERSION})
  96
  97 INCLUDE(CPack)
  98
  99 MACRO(ADD_TESTS)
 100   FOREACH( loop_var ${ARGV} )
 101     SET_SOURCE_FILES_PROPERTIES( ${loop_var}_test.cc COMPILE_FLAGS "-DBOOST_TEST_DYN_LINK -DBOOST_TEST_MAIN -DBOOST_AUTO_TEST_MAIN=\"\" " )
 102     ADD_EXECUTABLE( ${loop_var}_test ${loop_var}_test.cc )
 103     TARGET_LINK_LIBRARIES( ${loop_var}_test zypp-allsym ${Boost_UNIT_TEST_FRAMEWORK_LIBRARY} zypp_test_utils)
 104     ADD_TEST( ${loop_var}_test ${CMAKE_CURRENT_BINARY_DIR}/${loop_var}_test --catch_system_errors=no)
 105   ENDFOREACH( loop_var )
 106 ENDMACRO(ADD_TESTS)
 107
 108 ####################################################################
 109
 110 IF ( ENABLE_USE_THREADS )
 111   SET( CMAKE_THREAD_PREFER_PTHREAD TRUE )
 112   FIND_PACKAGE( Threads REQUIRED )
 113   IF ( CMAKE_USE_PTHREADS_INIT )
 114     MESSAGE( STATUS "May use threads." )
 115     SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -pthread -DZYPP_USE_THREADS" )
 116     SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread -DZYPP_USE_THREADS" )
 117   ENDIF ( CMAKE_USE_PTHREADS_INIT )
 118 ENDIF ( ENABLE_USE_THREADS )
 119
 120 INCLUDE(CheckSymbolExists)
 121 FIND_PACKAGE(Rpm REQUIRED)
 122 IF ( NOT RPM_FOUND)
 123   MESSAGE( FATAL_ERROR " rpm-devel not found" )
 124 ELSE ( NOT RPM_FOUND)
 125   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR})
 126   # fix includes not relative to rpm
 127   INCLUDE_DIRECTORIES(${RPM_INCLUDE_DIR}/rpm)
 128
 129   # rpmtsSetVfyFlags were introduced in rpm-4.15
 130   UNSET( RPMTSSETVFYFLAGS_FOUND CACHE )
 131   SET( CMAKE_REQUIRED_LIBRARIES "-lrpm" )
 132   CHECK_SYMBOL_EXISTS( rpmtsSetVfyFlags rpm/rpmts.h RPMTSSETVFYFLAGS_FOUND )
 133   IF ( NOT RPMTSSETVFYFLAGS_FOUND )
 134     ADD_DEFINITIONS( -DHAVE_NO_RPMTSSETVFYFLAGS )
 135   ENDIF ()
 136
 137   if ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 138         MESSAGE( STATUS "rpm found: enable rpm-4 compat interface." )
 139         ADD_DEFINITIONS(-D_RPM_5)
 140   endif ( RPM_SUSPECT_VERSION STREQUAL "5.x" )
 141 ENDIF( NOT RPM_FOUND)
 142
 143 FIND_PACKAGE(Boost REQUIRED COMPONENTS program_options unit_test_framework thread)
 144 IF (Boost_FOUND)
 145   MESSAGE( STATUS "boost found: includes in ${Boost_INCLUDE_DIRS}, library in ${Boost_LIBRARY_DIRS}")
 146   INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
 147   LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
 148 ENDIF(Boost_FOUND)
 149
 150 FIND_PACKAGE(Gettext REQUIRED)
 151 IF (GETTEXT_FOUND)
 152   MESSAGE(STATUS "Found Gettext: ${GETTEXT_SOURCE}")
 153   INCLUDE_DIRECTORIES(${GETTEXT_INCLUDE_DIR})
 154 ELSE (GETTEXT_FOUND)
 155   MESSAGE( FATAL_ERROR "Gettext not found" )
 156 ENDIF (GETTEXT_FOUND)
 157
 158 FIND_PACKAGE(CURL REQUIRED)
 159 IF ( NOT CURL_FOUND)
 160   MESSAGE( FATAL_ERROR " curl not found" )
 161 ELSE ( NOT CURL_FOUND)
 162   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 163 ENDIF( NOT CURL_FOUND)
 164
 165 FIND_PACKAGE(LibXml2 REQUIRED)
 166 IF ( NOT LIBXML2_FOUND)
 167   MESSAGE( FATAL_ERROR " libxml not found" )
 168 ELSE ( NOT LIBXML2_FOUND)
 169   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
 170 ENDIF( NOT LIBXML2_FOUND)
 171
 172 FIND_PACKAGE(ZLIB REQUIRED)
 173 IF ( NOT ZLIB_FOUND)
 174   MESSAGE( FATAL_ERROR " zlib not found" )
 175 ELSE ( NOT ZLIB_FOUND)
 176   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 177 ENDIF( NOT ZLIB_FOUND)
 178
 179
 180 #Allow to override the libsolv install location
 181 IF( LIBSOLV_SRCDIR AND LIBSOLV_BUILDDIR )
 182   execute_process(
 183     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv
 184     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/include
 185     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/ext
 186     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/libsolv/solvversion
 187     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_SRCDIR}/src ${CMAKE_BINARY_DIR}/libsolv/include/solv
 188     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_SRCDIR}/ext ${CMAKE_BINARY_DIR}/libsolv/ext/solv
 189     COMMAND ${CMAKE_COMMAND} -E create_symlink ${LIBSOLV_BUILDDIR}/src ${CMAKE_BINARY_DIR}/libsolv/solvversion/solv
 190   )
 191
 192   INCLUDE_DIRECTORIES( ${CMAKE_BINARY_DIR}/libsolv/include ${CMAKE_BINARY_DIR}/libsolv/ext ${CMAKE_BINARY_DIR}/libsolv/solvversion ${CMAKE_BINARY_DIR}/libsolv/solvversion/solv ${CMAKE_BINARY_DIR}/libsolv/ext/solv ${CMAKE_BINARY_DIR}/libsolv/include/solv )
 193   SET( LibSolv_LIBRARIES ${LIBSOLV_BUILDDIR}/src/libsolv.a ${LIBSOLV_BUILDDIR}/ext/libsolvext.a )
 194
 195 ELSE()
 196   FIND_PACKAGE(LibSolv REQUIRED ext)
 197   #SET(LibSolv_USE_STATIC_LIBS ON)
 198   IF ( NOT LibSolv_FOUND )
 199     MESSAGE( FATAL_ERROR " libsolv not found" )
 200   ELSE()
 201     INCLUDE_DIRECTORIES( ${LibSolv_INCLUDE_DIRS} )
 202   ENDIF()
 203 ENDIF( LIBSOLV_SRCDIR AND LIBSOLV_BUILDDIR )
 204
 205 FIND_PACKAGE(Gpgme REQUIRED)
 206 IF ( NOT GPGME_PTHREAD_FOUND )
 207   MESSAGE( FATAL_ERROR " gpgme not found" )
 208 ELSE()
 209   INCLUDE_DIRECTORIES( ${GPGME_INCLUDES} )
 210   LINK_DIRECTORIES(${GPGME_LIBRARY_DIR})
 211 ENDIF()
 212
 213 FIND_PACKAGE(OpenSSL REQUIRED)
 214
 215 FIND_PACKAGE(Udev)
 216 IF ( NOT UDEV_FOUND )
 217   MESSAGE(WARNING "No udev found. CD device detection will be poor")
 218 ELSE ( NOT UDEV_FOUND )
 219   ADD_DEFINITIONS(-DHAVE_UDEV)
 220 ENDIF ( NOT UDEV_FOUND )
 221
 222 IF( DISABLE_LIBPROXY )
 223   MESSAGE( STATUS "libproxy support disabled" )
 224 ELSE( DISABLE_LIBPROXY )
 225   FIND_PACKAGE(libproxy)
 226   IF ( NOT LIBPROXY_FOUND )
 227     MESSAGE( STATUS "libproxy not found" )
 228   ELSE ( NOT LIBPROXY_FOUND )
 229     INCLUDE_DIRECTORIES( ${LIBPROXY_INCLUDE_DIR} )
 230     ADD_DEFINITIONS(-DWITH_LIBPROXY_SUPPORT)
 231   ENDIF( NOT LIBPROXY_FOUND )
 232 ENDIF( DISABLE_LIBPROXY )
 233
 234 FIND_PROGRAM( DOXYGEN doxygen )
 235 IF ( NOT DOXYGEN )
 236   IF ( DISABLE_AUTODOCS )
 237     MESSAGE( STATUS "doxygen is not available. Can't build the documentation." )
 238   ELSE ( DISABLE_AUTODOCS )
 239     MESSAGE( FATAL_ERROR "doxygen not found: install doxygen to build the documentation!" )
 240   ENDIF ( DISABLE_AUTODOCS )
 241 ELSE ( NOT DOXYGEN )
 242   MESSAGE( STATUS "doxygen found: ${DOXYGEN}" )
 243 ENDIF ( NOT DOXYGEN )
 244
 245 IF (ENABLE_ZCHUNK_COMPRESSION)
 246   MESSAGE("Building with zchunk support enabled.")
 247   PKG_CHECK_MODULES (ZCHUNK zck REQUIRED)
 248   SET( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} ${ZCHUNK_CFLAGS}" )
 249   SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ZCHUNK_CFLAGS}" )
 250   ADD_DEFINITIONS (-DENABLE_ZCHUNK_COMPRESSION=1)
 251 ENDIF(ENABLE_ZCHUNK_COMPRESSION)
 252
 253 pkg_check_modules ( SIGCPP REQUIRED sigc++-2.0 )
 254 INCLUDE_DIRECTORIES( ${SIGCPP_INCLUDE_DIRS} )
 255
 256 pkg_check_modules ( LIBGLIB REQUIRED glib-2.0 )
 257 INCLUDE_DIRECTORIES( ${LIBGLIB_INCLUDE_DIRS} )
 258
 259 MESSAGE(STATUS "soname: ${LIBZYPP_VERSION_INFO}")
 260 MESSAGE(STATUS "version: ${VERSION}")
 261
 262 MESSAGE(STATUS "Writing pkg-config file...")
 263 CONFIGURE_FILE(${LIBZYPP_SOURCE_DIR}/libzypp.pc.cmake ${LIBZYPP_BINARY_DIR}/libzypp.pc @ONLY)
 264 INSTALL( FILES ${LIBZYPP_BINARY_DIR}/libzypp.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 265
 266 MESSAGE(STATUS "FindZypp.cmake will be installed in ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules")
 267 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/FindZypp.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 268 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/cmake/modules/ZyppCommon.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
 269
 270 ####################################################################
 271 # config templates
 272 # (don't forget to mention them in the .spec file)
 273 ####################################################################
 274
 275 MESSAGE(STATUS "zypp.conf will be installed in ${SYSCONFDIR}/zypp")
 276 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp.conf DESTINATION ${SYSCONFDIR}/zypp )
 277
 278 MESSAGE(STATUS "needreboot will be installed in ${SYSCONFDIR}/zypp/")
 279 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/needreboot DESTINATION ${SYSCONFDIR}/zypp )
 280
 281 #install systemCheck
 282 MESSAGE(STATUS "systemCheck will be installed in ${SYSCONFDIR}/zypp")
 283 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/systemCheck DESTINATION ${SYSCONFDIR}/zypp )
 284
 285 # logrotate config file
 286 INSTALL( FILES ${LIBZYPP_SOURCE_DIR}/zypp-history.lr DESTINATION ${SYSCONFDIR}/logrotate.d )
 287
 288 ####################################################################
 289 # SUBDIRECTORIES                                                   #
 290 ####################################################################
 291
 292 ADD_SUBDIRECTORY( zypp )
 293 # do not build devel by default
 294 ADD_SUBDIRECTORY( devel EXCLUDE_FROM_ALL )
 295 ADD_SUBDIRECTORY( tools )
 296 ADD_SUBDIRECTORY( doc )
 297
 298 IF ( ENABLE_BUILD_TRANS )
 299   ADD_SUBDIRECTORY( po )
 300 ELSE ( ENABLE_BUILD_TRANS )
 301   ADD_SUBDIRECTORY( po EXCLUDE_FROM_ALL )
 302 ENDIF ( ENABLE_BUILD_TRANS )
 303
 304 IF ( ENABLE_BUILD_TESTS )
 305   ADD_SUBDIRECTORY( tests )
 306 ELSE ( ENABLE_BUILD_TESTS )
 307   ADD_SUBDIRECTORY( tests EXCLUDE_FROM_ALL )
 308 ENDIF ( ENABLE_BUILD_TESTS )
 309 INCLUDE(CTest)
 310 ENABLE_TESTING()