meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.5.0',
   5     default_options: [
   6         'c_std=c11',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.52.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-Wno-unused-parameter',
  21     '-Wno-missing-field-initializers',
  22     '-Wpointer-arith',
  23     '-Wmissing-declarations',
  24     '-Wformat=2',
  25     '-Wstrict-prototypes',
  26     '-Wmissing-prototypes',
  27     '-Wnested-externs',
  28     '-Wbad-function-cast',
  29     '-Wshadow',
  30     '-Wlogical-op',
  31     '-Wdate-time',
  32     '-Wwrite-strings',
  33     '-Wno-documentation-deprecated-sync',
  34 ]
  35 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  36
  37
  38 # The XKB config root.
  39 XKBCONFIGROOT = get_option('xkb-config-root')
  40 if XKBCONFIGROOT == ''
  41     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  42     if xkeyboard_config_dep.found()
  43         XKBCONFIGROOT = xkeyboard_config_dep.get_variable(pkgconfig: 'xkb_base')
  44     else
  45         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  46   endif
  47 endif
  48
  49 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  50 if XKBCONFIGEXTRAPATH == ''
  51     XKBCONFIGEXTRAPATH = get_option('prefix')/get_option('sysconfdir')/'xkb'
  52 endif
  53
  54 # The X locale directory for compose.
  55 XLOCALEDIR = get_option('x-locale-root')
  56 if XLOCALEDIR == ''
  57     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  58 endif
  59
  60
  61 # config.h.
  62 configh_data = configuration_data()
  63 configh_data.set('EXIT_INVALID_USAGE', '2')
  64 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  65 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  66 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  67 # beyond the base POSIX function set.
  68 if host_machine.system() == 'sunos'
  69   system_extensions = '__EXTENSIONS__'
  70 else
  71   system_extensions = '_GNU_SOURCE'
  72 endif
  73 configh_data.set(system_extensions, 1)
  74 system_ext_define = '#define ' + system_extensions
  75 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  77 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  78 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  79 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  80 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  81 if get_option('default-variant') != ''
  82     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  83 else
  84     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  85 endif
  86 if get_option('default-options') != ''
  87     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  88 else
  89     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  90 endif
  91 if cc.has_header('unistd.h')
  92     configh_data.set('HAVE_UNISTD_H', 1)
  93 endif
  94 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  95     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  96 endif
  97 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  98     configh_data.set('HAVE_EACCESS', 1)
  99 endif
 100 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 101     configh_data.set('HAVE_EUIDACCESS', 1)
 102 endif
 103 if cc.has_header_symbol('sys/mman.h', 'mmap')
 104     configh_data.set('HAVE_MMAP', 1)
 105 endif
 106 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 107     configh_data.set('HAVE_MKOSTEMP', 1)
 108 endif
 109 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 110     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 111 endif
 112 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 113     configh_data.set('HAVE_STRNDUP', 1)
 114 endif
 115 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 116     configh_data.set('HAVE_ASPRINTF', 1)
 117 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 118     configh_data.set('HAVE_VASPRINTF', 1)
 119 endif
 120 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 121     configh_data.set('HAVE_SECURE_GETENV', 1)
 122 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 123     configh_data.set('HAVE___SECURE_GETENV', 1)
 124 else
 125     message('C library does not support secure_getenv, using getenv instead')
 126 endif
 127 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 128     if host_machine.system() == 'windows'
 129         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 130         configh_data.set('PATH_MAX', 260)
 131     else
 132         configh_data.set('PATH_MAX', 4096)
 133     endif
 134 endif
 135
 136 # Silence some security & deprecation warnings on MSVC
 137 # for some unix/C functions we use.
 138 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 139 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 140 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 141 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 142 # Reduce unnecessary includes on MSVC.
 143 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 144
 145 # Supports -Wl,--version-script?
 146 have_version_script = cc.links(
 147     'int main(){}',
 148     args: '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map',
 149     name: '-Wl,--version-script',
 150 )
 151
 152 map_to_def = find_program('scripts/map-to-def')
 153
 154 # libxkbcommon.
 155 # Note: we use some yacc extensions, which work with either GNU bison
 156 # (preferred) or byacc (with backtracking enabled).
 157 bison = find_program('bison', 'win_bison', required: false, version: '>= 2.3a')
 158 if bison.found()
 159     yacc = bison
 160     yacc_gen = generator(
 161         bison,
 162         output: ['@BASENAME@.c', '@BASENAME@.h'],
 163         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 164     )
 165 else
 166     byacc = find_program('byacc', required: false)
 167     if byacc.found()
 168         yacc = byacc
 169         yacc_gen = generator(
 170             byacc,
 171             output: ['@BASENAME@.c', '@BASENAME@.h'],
 172             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 173         )
 174     else
 175         error('Could not find a compatible YACC program (bison or byacc)')
 176     endif
 177 endif
 178 libxkbcommon_sources = [
 179     'src/compose/parser.c',
 180     'src/compose/parser.h',
 181     'src/compose/paths.c',
 182     'src/compose/paths.h',
 183     'src/compose/state.c',
 184     'src/compose/table.c',
 185     'src/compose/table.h',
 186     'src/xkbcomp/action.c',
 187     'src/xkbcomp/action.h',
 188     'src/xkbcomp/ast.h',
 189     'src/xkbcomp/ast-build.c',
 190     'src/xkbcomp/ast-build.h',
 191     'src/xkbcomp/compat.c',
 192     'src/xkbcomp/expr.c',
 193     'src/xkbcomp/expr.h',
 194     'src/xkbcomp/include.c',
 195     'src/xkbcomp/include.h',
 196     'src/xkbcomp/keycodes.c',
 197     'src/xkbcomp/keymap.c',
 198     'src/xkbcomp/keymap-dump.c',
 199     'src/xkbcomp/keywords.c',
 200     yacc_gen.process('src/xkbcomp/parser.y'),
 201     'src/xkbcomp/parser-priv.h',
 202     'src/xkbcomp/rules.c',
 203     'src/xkbcomp/rules.h',
 204     'src/xkbcomp/scanner.c',
 205     'src/xkbcomp/symbols.c',
 206     'src/xkbcomp/types.c',
 207     'src/xkbcomp/vmod.c',
 208     'src/xkbcomp/vmod.h',
 209     'src/xkbcomp/xkbcomp.c',
 210     'src/xkbcomp/xkbcomp-priv.h',
 211     'src/atom.c',
 212     'src/atom.h',
 213     'src/context.c',
 214     'src/context.h',
 215     'src/context-priv.c',
 216     'src/darray.h',
 217     'src/keysym.c',
 218     'src/keysym.h',
 219     'src/keysym-utf.c',
 220     'src/ks_tables.h',
 221     'src/keymap.c',
 222     'src/keymap.h',
 223     'src/keymap-priv.c',
 224     'src/messages-codes.h',
 225     'src/scanner-utils.h',
 226     'src/state.c',
 227     'src/text.c',
 228     'src/text.h',
 229     'src/utf8.c',
 230     'src/utf8.h',
 231     'src/utils.c',
 232     'src/utils.h',
 233 ]
 234 libxkbcommon_link_args = []
 235 libxkbcommon_link_deps = []
 236 if have_version_script
 237     libxkbcommon_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map'
 238     libxkbcommon_link_deps += 'xkbcommon.map'
 239 elif cc.get_argument_syntax() == 'msvc'
 240     libxkbcommon_def = custom_target('xkbcommon.def',
 241         command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 242         input: 'xkbcommon.map',
 243         output: 'kxbcommon.def',
 244     )
 245     libxkbcommon_link_deps += libxkbcommon_def
 246     libxkbcommon_link_args += '/DEF:' + libxkbcommon_def.full_path()
 247 endif
 248 libxkbcommon = library(
 249     'xkbcommon',
 250     'include/xkbcommon/xkbcommon.h',
 251     libxkbcommon_sources,
 252     link_args: libxkbcommon_link_args,
 253     link_depends: libxkbcommon_link_deps,
 254     gnu_symbol_visibility: 'hidden',
 255     version: '0.0.0',
 256     install: true,
 257     include_directories: include_directories('src', 'include'),
 258 )
 259 install_headers(
 260     'include/xkbcommon/xkbcommon.h',
 261     'include/xkbcommon/xkbcommon-compat.h',
 262     'include/xkbcommon/xkbcommon-compose.h',
 263     'include/xkbcommon/xkbcommon-keysyms.h',
 264     'include/xkbcommon/xkbcommon-names.h',
 265     subdir: 'xkbcommon',
 266 )
 267
 268 dep_libxkbcommon = declare_dependency(
 269     link_with: libxkbcommon,
 270     include_directories: include_directories('include'),
 271 )
 272 if meson.version().version_compare('>= 0.54.0')
 273     meson.override_dependency('xkbcommon', dep_libxkbcommon)
 274 endif
 275 pkgconfig.generate(
 276     libxkbcommon,
 277     name: 'xkbcommon',
 278     filebase: 'xkbcommon',
 279     version: meson.project_version(),
 280     description: 'XKB API common to servers and clients',
 281 )
 282
 283
 284 # libxkbcommon-x11.
 285 if get_option('enable-x11')
 286     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 287     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 288     if not xcb_dep.found() or not xcb_xkb_dep.found()
 289         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 290 You can disable X11 support with -Denable-x11=false.''')
 291     endif
 292
 293     libxkbcommon_x11_sources = [
 294         'src/x11/keymap.c',
 295         'src/x11/state.c',
 296         'src/x11/util.c',
 297         'src/x11/x11-priv.h',
 298         'src/context.h',
 299         'src/context-priv.c',
 300         'src/keymap.h',
 301         'src/keymap-priv.c',
 302         'src/atom.h',
 303         'src/atom.c',
 304     ]
 305     libxkbcommon_x11_link_args = []
 306     libxkbcommon_x11_link_deps = []
 307     if have_version_script
 308         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon-x11.map'
 309         libxkbcommon_x11_link_deps += 'xkbcommon-x11.map'
 310     elif cc.get_argument_syntax() == 'msvc'
 311         libxkbcommon_x11_def = custom_target('xkbcommon-x11.def',
 312             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 313             input: 'xkbcommon-x11.map',
 314             output: 'xkbcommon-x11.def',
 315         )
 316         libxkbcommon_x11_link_deps += libxkbcommon_x11_def
 317         libxkbcommon_x11_link_args += '/DEF:' + libxkbcommon_x11_def.full_path()
 318     endif
 319     libxkbcommon_x11 = library(
 320         'xkbcommon-x11',
 321         'include/xkbcommon/xkbcommon-x11.h',
 322         libxkbcommon_x11_sources,
 323         link_args: libxkbcommon_x11_link_args,
 324         link_depends: libxkbcommon_x11_link_deps,
 325         gnu_symbol_visibility: 'hidden',
 326         version: '0.0.0',
 327         install: true,
 328         include_directories: include_directories('src', 'include'),
 329         link_with: libxkbcommon,
 330         dependencies: [
 331             xcb_dep,
 332             xcb_xkb_dep,
 333         ],
 334     )
 335     install_headers(
 336         'include/xkbcommon/xkbcommon-x11.h',
 337         subdir: 'xkbcommon',
 338     )
 339     dep_libxkbcommon_x11 = declare_dependency(
 340         link_with: libxkbcommon_x11,
 341         include_directories: include_directories('include'),
 342     )
 343     if meson.version().version_compare('>= 0.54.0')
 344         meson.override_dependency('xkbcommon-x11', dep_libxkbcommon_x11)
 345     endif
 346     pkgconfig.generate(
 347         libxkbcommon_x11,
 348         name: 'xkbcommon-x11',
 349         filebase: 'xkbcommon-x11',
 350         version: meson.project_version(),
 351         description: 'XKB API common to servers and clients - X11 support',
 352         requires: ['xkbcommon'],
 353         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 354     )
 355 endif
 356
 357 # libxkbregistry
 358 if get_option('enable-xkbregistry')
 359     dep_libxml = dependency('libxml-2.0')
 360     deps_libxkbregistry = [dep_libxml]
 361     libxkbregistry_sources = [
 362         'src/registry.c',
 363         'src/utils.h',
 364         'src/utils.c',
 365         'src/util-list.h',
 366         'src/util-list.c',
 367     ]
 368     libxkbregistry_link_args = []
 369     libxkbregistry_link_deps = []
 370     if have_version_script
 371         libxkbregistry_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbregistry.map'
 372         libxkbregistry_link_deps += 'xkbregistry.map'
 373     elif cc.get_argument_syntax() == 'msvc'
 374         libxkbregistry_def = custom_target('xkbregistry.def',
 375             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 376             input: 'xkbregistry.map',
 377             output: 'xkbregistry.def',
 378         )
 379         libxkbregistry_link_deps += libxkbregistry_def
 380         libxkbregistry_link_args += '/DEF:' + libxkbregistry_def.full_path()
 381     endif
 382     libxkbregistry = library(
 383         'xkbregistry',
 384         'include/xkbcommon/xkbregistry.h',
 385         libxkbregistry_sources,
 386         link_args: libxkbregistry_link_args,
 387         link_depends: libxkbregistry_link_deps,
 388         gnu_symbol_visibility: 'hidden',
 389         dependencies: deps_libxkbregistry,
 390         version: '0.0.0',
 391         install: true,
 392         include_directories: include_directories('src', 'include'),
 393     )
 394     install_headers(
 395         'include/xkbcommon/xkbregistry.h',
 396         subdir: 'xkbcommon',
 397     )
 398     pkgconfig.generate(
 399         libxkbregistry,
 400         name: 'xkbregistry',
 401         filebase: 'xkbregistry',
 402         version: meson.project_version(),
 403         description: 'XKB API to query available rules, models, layouts, variants and options',
 404     )
 405
 406     dep_libxkbregistry = declare_dependency(
 407         link_with: libxkbregistry,
 408         include_directories: include_directories('include'),
 409     )
 410     if meson.version().version_compare('>= 0.54.0')
 411         meson.override_dependency('xkbregistry', dep_libxkbregistry)
 412     endif
 413 endif
 414
 415 man_pages = []
 416
 417 # Tools
 418 build_tools = get_option('enable-tools') and cc.has_header_symbol('getopt.h', 'getopt_long', prefix: '#define _GNU_SOURCE')
 419 if build_tools
 420     libxkbcommon_tools_internal_sources = [
 421         'tools/tools-common.h',
 422         'tools/tools-common.c',
 423     ]
 424     libxkbcommon_tools_internal = static_library(
 425         'tools-internal',
 426         libxkbcommon_tools_internal_sources,
 427         dependencies: dep_libxkbcommon,
 428     )
 429     tools_dep = declare_dependency(
 430         include_directories: [include_directories('tools', 'include')],
 431         link_with: libxkbcommon_tools_internal,
 432         dependencies: dep_libxkbcommon,
 433     )
 434
 435     executable('xkbcli', 'tools/xkbcli.c',
 436                dependencies: tools_dep, install: true)
 437     install_man('tools/xkbcli.1')
 438
 439     xkbcli_compile_keymap = executable('xkbcli-compile-keymap',
 440                                        'tools/compile-keymap.c',
 441                                        dependencies: tools_dep,
 442                                        install: true,
 443                                        install_dir: dir_libexec)
 444     install_man('tools/xkbcli-compile-keymap.1')
 445     # The same tool again, but with access to some private APIs.
 446     executable('compile-keymap',
 447                'tools/compile-keymap.c',
 448                libxkbcommon_sources,
 449                dependencies: [tools_dep],
 450                c_args: ['-DENABLE_PRIVATE_APIS'],
 451                include_directories: [include_directories('src', 'include')],
 452                install: false)
 453     executable('compose',
 454                'tools/compose.c',
 455                dependencies: tools_dep,
 456                include_directories: [include_directories('src', 'include')],
 457                install: false)
 458     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 459     executable('xkbcli-how-to-type',
 460                'tools/how-to-type.c',
 461                dependencies: tools_dep,
 462                install: true,
 463                install_dir: dir_libexec)
 464     install_man('tools/xkbcli-how-to-type.1')
 465     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 466     if cc.has_header('linux/input.h')
 467         executable('xkbcli-interactive-evdev',
 468                    'tools/interactive-evdev.c',
 469                    dependencies: tools_dep,
 470                    install: true,
 471                    install_dir: dir_libexec)
 472         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 473         install_man('tools/xkbcli-interactive-evdev.1')
 474         # The same tool again, but with access to some private APIs.
 475         executable('interactive-evdev',
 476                 'tools/interactive-evdev.c',
 477                 libxkbcommon_sources,
 478                 libxkbcommon_tools_internal_sources,
 479                 dependencies: [tools_dep],
 480                 c_args: ['-DENABLE_PRIVATE_APIS'],
 481                 include_directories: [include_directories('src', 'include')],
 482                 install: false)
 483     endif
 484     if get_option('enable-x11')
 485         x11_tools_dep = declare_dependency(
 486             link_with: libxkbcommon_x11,
 487             dependencies: [
 488                 tools_dep,
 489                 xcb_dep,
 490                 xcb_xkb_dep,
 491             ],
 492         )
 493         executable('xkbcli-interactive-x11',
 494                    'tools/interactive-x11.c',
 495                    dependencies: x11_tools_dep,
 496                    install: true,
 497                    install_dir: dir_libexec)
 498         install_man('tools/xkbcli-interactive-x11.1')
 499         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 500     endif
 501     if get_option('enable-wayland')
 502         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 503         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 504         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 505         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 506             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 507 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 508         endif
 509
 510         wayland_scanner = find_program(wayland_scanner_dep.get_variable(pkgconfig: 'wayland_scanner'))
 511         wayland_scanner_code_gen = generator(
 512             wayland_scanner,
 513             output: '@BASENAME@-protocol.c',
 514             arguments: ['private-code', '@INPUT@', '@OUTPUT@'],
 515         )
 516         wayland_scanner_client_header_gen = generator(
 517             wayland_scanner,
 518             output: '@BASENAME@-client-protocol.h',
 519             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 520         )
 521         wayland_protocols_datadir = wayland_protocols_dep.get_variable(pkgconfig: 'pkgdatadir')
 522         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 523         xdg_shell_sources = [
 524             wayland_scanner_code_gen.process(xdg_shell_xml),
 525             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 526         ]
 527         executable('xkbcli-interactive-wayland',
 528                    'tools/interactive-wayland.c',
 529                    xdg_shell_sources,
 530                    dependencies: [tools_dep, wayland_client_dep],
 531                    install: true,
 532                    install_dir: dir_libexec)
 533         install_man('tools/xkbcli-interactive-wayland.1')
 534         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 535     endif
 536
 537     if get_option('enable-xkbregistry')
 538         configh_data.set10('HAVE_XKBCLI_LIST', true)
 539         executable('xkbcli-list',
 540                    'tools/registry-list.c',
 541                    dependencies: dep_libxkbregistry,
 542                    install: true,
 543                    install_dir: dir_libexec)
 544         install_man('tools/xkbcli-list.1')
 545     endif
 546
 547     executable('xkb-check-messages',
 548                'tools/check-messages.c',
 549                'tools/messages.c',
 550                'tools/messages.h',
 551                'src/messages-codes.h',
 552                dependencies: [tools_dep],
 553                include_directories: [include_directories('src', 'include', 'tools')],
 554                install: false)
 555 endif
 556
 557
 558 # xkeyboard-config "verifier"
 559 xkct_config = configuration_data()
 560 xkct_config.set('MESON_BUILD_ROOT', meson.current_build_dir())
 561 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 562 configure_file(input: 'test/xkeyboard-config-test.py.in',
 563                output: 'xkeyboard-config-test',
 564                configuration: xkct_config)
 565
 566 # Tests
 567 test_env = environment()
 568 test_env.set('XKB_LOG_LEVEL', 'debug')
 569 test_env.set('XKB_LOG_VERBOSITY', '10')
 570 test_env.set('top_srcdir', meson.current_source_dir())
 571 test_env.set('top_builddir', meson.current_build_dir())
 572 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 573 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 574 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 575 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 576
 577 test_configh_data = configuration_data()
 578 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 579 configure_file(output: 'test-config.h', configuration: test_configh_data)
 580
 581 # Some tests need to use unexported symbols, so we link them against
 582 # an internal copy of libxkbcommon with all symbols exposed.
 583 libxkbcommon_test_internal = static_library(
 584     'xkbcommon-test-internal',
 585     'test/common.c',
 586     'test/test.h',
 587     'test/evdev-scancodes.h',
 588     'bench/bench.c',
 589     'bench/bench.h',
 590     libxkbcommon_sources,
 591     include_directories: include_directories('src', 'include'),
 592 )
 593 test_dep = declare_dependency(
 594     include_directories: include_directories('src', 'include'),
 595     link_with: libxkbcommon_test_internal,
 596 )
 597 if get_option('enable-x11')
 598     libxkbcommon_x11_test_internal = static_library(
 599         'xkbcommon-x11-internal',
 600         libxkbcommon_x11_sources,
 601         'test/xvfb-wrapper.c',
 602         'test/xvfb-wrapper.h',
 603         include_directories: include_directories('src', 'include'),
 604         link_with: libxkbcommon_test_internal,
 605         dependencies: [
 606             xcb_dep,
 607             xcb_xkb_dep,
 608         ],
 609     )
 610     x11_test_dep = declare_dependency(
 611         link_with: libxkbcommon_x11_test_internal,
 612         dependencies: [
 613             test_dep,
 614             xcb_dep,
 615             xcb_xkb_dep,
 616         ],
 617     )
 618 endif
 619 test(
 620     'keysym',
 621     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 622     env: test_env,
 623 )
 624 test(
 625     'keymap',
 626     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 627     env: test_env,
 628 )
 629 test(
 630     'filecomp',
 631     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 632     env: test_env,
 633 )
 634 test(
 635     'context',
 636     executable('test-context', 'test/context.c', dependencies: test_dep),
 637     env: test_env,
 638 )
 639 test(
 640     'rules-file',
 641     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 642     env: test_env,
 643 )
 644 test(
 645     'rules-file-includes',
 646     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 647     env: test_env,
 648 )
 649 test(
 650     'stringcomp',
 651     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 652     env: test_env,
 653 )
 654 test(
 655     'buffercomp',
 656     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 657     env: test_env,
 658 )
 659 test(
 660     'log',
 661     executable('test-log', 'test/log.c', dependencies: test_dep),
 662     env: test_env,
 663 )
 664 test(
 665     'atom',
 666     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 667     env: test_env,
 668 )
 669 test(
 670     'utf8',
 671     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 672     env: test_env,
 673 )
 674 test(
 675     'state',
 676     executable('test-state', 'test/state.c', dependencies: test_dep),
 677     env: test_env,
 678 )
 679 test(
 680     'keyseq',
 681     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 682     env: test_env,
 683 )
 684 test(
 685     'rulescomp',
 686     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 687     env: test_env,
 688 )
 689 test(
 690     'compose',
 691     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 692     env: test_env,
 693 )
 694 test(
 695     'utils',
 696     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 697     env: test_env,
 698 )
 699 test(
 700     'symbols-leak-test',
 701     find_program('test/symbols-leak-test.py'),
 702     env: test_env,
 703     suite: ['python-tests'],
 704 )
 705 test(
 706     'modifiers',
 707     executable('test-modifiers', 'test/modifiers.c', dependencies: test_dep),
 708     env: test_env,
 709 )
 710 test(
 711     'messages',
 712     executable(
 713         'test-messages',
 714         'test/messages.c',
 715         'tools/messages.c',
 716         'tools/messages.h',
 717         include_directories: include_directories('src', 'include', 'tools'),
 718         dependencies: test_dep),
 719     env: test_env,
 720 )
 721 if get_option('enable-x11')
 722     test(
 723         'x11',
 724         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 725         env: test_env,
 726     )
 727     test(
 728         'x11comp',
 729         executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep),
 730         env: test_env,
 731     )
 732 endif
 733 if get_option('enable-xkbregistry')
 734     test(
 735         'registry',
 736         executable('test-registry', 'test/registry.c',
 737                    include_directories: include_directories('src'),
 738                    dependencies: [dep_libxkbregistry, test_dep]),
 739         env: test_env,
 740     )
 741 endif
 742 if build_tools
 743     test('tool-option-parsing',
 744          find_program('test/tool-option-parsing.py'),
 745          env: test_env,
 746          suite: ['python-tests'])
 747
 748     # A set of keysyms to test for. Add one or two symbols to this array
 749     # whenever the xorgproto gets updated to make sure we resolve them.
 750     keysyms_to_test = [
 751         'XF86Macro23',
 752     ]
 753
 754     env = environment()
 755     env.set('XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 756     foreach keysym: keysyms_to_test
 757         test('keysym-test-@0@'.format(keysym),
 758              find_program('test/test-keysym.py'),
 759              env: env,
 760              args: [keysym, '--tool', xkbcli_compile_keymap],
 761              suite: ['python-tests'])
 762     endforeach
 763 endif
 764
 765 valgrind = find_program('valgrind', required: false)
 766 if valgrind.found()
 767     add_test_setup('valgrind',
 768         exe_wrapper: [valgrind,
 769                        '--leak-check=full',
 770                        '--track-origins=yes',
 771                        '--gen-suppressions=all',
 772                        '--error-exitcode=99'],
 773         timeout_multiplier : 10)
 774 else
 775     message('valgrind not found, disabling valgrind test setup')
 776 endif
 777
 778
 779 # Fuzzing target programs.
 780 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 781 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 782
 783
 784 # Benchmarks.
 785 bench_env = environment()
 786 bench_env.set('top_srcdir', meson.current_source_dir())
 787 benchmark(
 788     'key-proc',
 789     executable('bench-key-proc', 'bench/key-proc.c', dependencies: test_dep),
 790     env: bench_env,
 791 )
 792 benchmark(
 793     'rules',
 794     executable('bench-rules', 'bench/rules.c', dependencies: test_dep),
 795     env: bench_env,
 796 )
 797 benchmark(
 798     'rulescomp',
 799     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: test_dep),
 800     env: bench_env,
 801 )
 802 benchmark(
 803     'compose',
 804     executable('bench-compose', 'bench/compose.c', dependencies: test_dep),
 805     env: bench_env,
 806 )
 807 benchmark(
 808     'atom',
 809     executable('bench-atom', 'bench/atom.c', dependencies: test_dep),
 810     env: bench_env,
 811 )
 812 if get_option('enable-x11')
 813   benchmark(
 814       'x11',
 815       executable('bench-x11', 'bench/x11.c', dependencies: x11_test_dep),
 816       env: bench_env,
 817   )
 818 endif
 819
 820
 821 # Documentation.
 822 if get_option('enable-docs')
 823     doxygen = find_program('doxygen', required: false)
 824     if not doxygen.found()
 825         error('''Documentation requires doxygen which was not found.
 826 You can disable the documentation with -Denable-docs=false.''')
 827     endif
 828     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 829
 830     doxygen_input = [
 831         'README.md',
 832         'doc/diagrams/xkb-configuration.dot',
 833         'doc/doxygen-extra.css',
 834         'doc/introduction-to-xkb.md',
 835         'doc/quick-guide.md',
 836         'doc/compatibility.md',
 837         'doc/user-configuration.md',
 838         'doc/rules-format.md',
 839         'doc/keymap-format-text-v1.md',
 840         'doc/message-registry.md',
 841         'include/xkbcommon/xkbcommon.h',
 842         'include/xkbcommon/xkbcommon-compose.h',
 843         'include/xkbcommon/xkbcommon-keysyms.h',
 844         'include/xkbcommon/xkbcommon-names.h',
 845         'include/xkbcommon/xkbcommon-x11.h',
 846         'include/xkbcommon/xkbregistry.h',
 847     ]
 848     doxygen_data = configuration_data()
 849     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 850     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 851     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 852     doxygen_data.set('OUTPUT_DIRECTORY', meson.current_build_dir())
 853     doxyfile = configure_file(
 854         input: 'doc/Doxyfile.in',
 855         output: 'Doxyfile',
 856         configuration: doxygen_data,
 857     )
 858     # TODO: Meson should provide this.
 859     docdir = get_option('datadir')/'doc'/meson.project_name()
 860     doc_gen = custom_target(
 861         'doc',
 862         input: [doxyfile] + doxygen_input,
 863         output: 'html',
 864         command: [
 865             doxygen_wrapper,
 866             doxygen,
 867             meson.current_build_dir()/'Doxyfile',
 868             meson.current_source_dir(),
 869         ],
 870         install: true,
 871         install_dir: docdir,
 872         build_by_default: true,
 873     )
 874     if get_option('enable-cool-uris')
 875         ensure_stable_urls = find_program('scripts'/'ensure-stable-doc-urls.py')
 876         custom_target(
 877             'doc-cool-uris',
 878             input: [doc_gen, 'doc'/'cool-uris.yaml'],
 879             output: 'html-xtra',
 880             command: [
 881                 ensure_stable_urls,
 882                 'generate-redirections',
 883                 meson.current_source_dir()/'doc'/'cool-uris.yaml',
 884                 meson.current_build_dir()/'html'
 885             ],
 886             install: false,
 887             build_by_default: true,
 888         )
 889     endif
 890 endif
 891
 892 configure_file(output: 'config.h', configuration: configh_data)
 893
 894
 895 # Stable variables for projects using xkbcommon as a subproject.
 896 # These variables should not be renamed.
 897 libxkbcommon_dep = dep_libxkbcommon
 898 if get_option('enable-x11')
 899   libxkbcommon_x11_dep = dep_libxkbcommon_x11
 900 endif
 901 if get_option('enable-xkbregistry')
 902   libxkbregistry_dep = dep_libxkbregistry
 903 endif
 904
 905 if meson.version().version_compare('>=0.62.0')
 906     summary({
 907       'backend': meson.backend(),
 908       'buildtype': get_option('buildtype'),
 909       'c_args': get_option('c_args'),
 910       'c_link_args': get_option('c_link_args'),
 911       'yacc': yacc.full_path() + ' ' + yacc.version(),
 912     }, section: 'Compiler')
 913     summary({
 914       'prefix': get_option('prefix'),
 915       'bindir': get_option('bindir'),
 916       'libdir': get_option('libdir'),
 917       'datadir': get_option('datadir'),
 918       'xkb-config-root': XKBCONFIGROOT,
 919       'xkb-config-extra-path': XKBCONFIGEXTRAPATH,
 920       'xlocaledir': XLOCALEDIR,
 921     }, section: 'Directories')
 922     summary({
 923       'docs': get_option('enable-docs'),
 924       'tools': get_option('enable-tools'),
 925       'wayland': get_option('enable-wayland'),
 926       'x11': get_option('enable-x11'),
 927     }, section: 'Features')
 928     summary({
 929       'layout': get_option('default-layout'),
 930       'model': get_option('default-model'),
 931       'options': get_option('default-options'),
 932       'rules': get_option('default-rules'),
 933       'variant': get_option('default-variant'),
 934     }, section: 'Defaults')
 935 endif