meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.6.0',
   5     default_options: [
   6         'c_std=c11',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.52.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-Wno-unused-parameter',
  21     '-Wno-missing-field-initializers',
  22     '-Wpointer-arith',
  23     '-Wmissing-declarations',
  24     '-Wformat=2',
  25     '-Wstrict-prototypes',
  26     '-Wmissing-prototypes',
  27     '-Wnested-externs',
  28     '-Wbad-function-cast',
  29     '-Wshadow',
  30     '-Wlogical-op',
  31     '-Wdate-time',
  32     '-Wwrite-strings',
  33     '-Wno-documentation-deprecated-sync',
  34 ]
  35 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  36
  37
  38 # The XKB config root.
  39 XKBCONFIGROOT = get_option('xkb-config-root')
  40 if XKBCONFIGROOT == ''
  41     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  42     if xkeyboard_config_dep.found()
  43         XKBCONFIGROOT = xkeyboard_config_dep.get_variable(pkgconfig: 'xkb_base')
  44     else
  45         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  46   endif
  47 endif
  48
  49 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  50 if XKBCONFIGEXTRAPATH == ''
  51     XKBCONFIGEXTRAPATH = get_option('prefix')/get_option('sysconfdir')/'xkb'
  52 endif
  53
  54 # The X locale directory for compose.
  55 XLOCALEDIR = get_option('x-locale-root')
  56 if XLOCALEDIR == ''
  57     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  58 endif
  59
  60
  61 # config.h.
  62 configh_data = configuration_data()
  63 configh_data.set('EXIT_INVALID_USAGE', '2')
  64 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  65 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  66 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  67 # beyond the base POSIX function set.
  68 if host_machine.system() == 'sunos'
  69   system_extensions = '__EXTENSIONS__'
  70 else
  71   system_extensions = '_GNU_SOURCE'
  72 endif
  73 configh_data.set(system_extensions, 1)
  74 system_ext_define = '#define ' + system_extensions
  75 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  77 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  78 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  79 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  80 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  81 if get_option('default-variant') != ''
  82     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  83 else
  84     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  85 endif
  86 if get_option('default-options') != ''
  87     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  88 else
  89     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  90 endif
  91 if cc.has_header('unistd.h')
  92     configh_data.set('HAVE_UNISTD_H', 1)
  93 endif
  94 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  95     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  96 endif
  97 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  98     configh_data.set('HAVE_EACCESS', 1)
  99 endif
 100 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 101     configh_data.set('HAVE_EUIDACCESS', 1)
 102 endif
 103 if cc.has_header_symbol('sys/mman.h', 'mmap')
 104     configh_data.set('HAVE_MMAP', 1)
 105 endif
 106 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 107     configh_data.set('HAVE_MKOSTEMP', 1)
 108 endif
 109 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 110     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 111 endif
 112 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 113     configh_data.set('HAVE_STRNDUP', 1)
 114 endif
 115 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 116     configh_data.set('HAVE_ASPRINTF', 1)
 117 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 118     configh_data.set('HAVE_VASPRINTF', 1)
 119 endif
 120 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 121     configh_data.set('HAVE_SECURE_GETENV', 1)
 122 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 123     configh_data.set('HAVE___SECURE_GETENV', 1)
 124 else
 125     message('C library does not support secure_getenv, using getenv instead')
 126 endif
 127 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 128     if host_machine.system() == 'windows'
 129         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 130         configh_data.set('PATH_MAX', 260)
 131     else
 132         configh_data.set('PATH_MAX', 4096)
 133     endif
 134 endif
 135
 136 # Silence some security & deprecation warnings on MSVC
 137 # for some unix/C functions we use.
 138 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 139 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 140 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 141 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 142 # Reduce unnecessary includes on MSVC.
 143 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 144
 145 # Supports -Wl,--version-script?
 146 have_version_script = cc.links(
 147     'int main(){}',
 148     args: '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map',
 149     name: '-Wl,--version-script',
 150 )
 151
 152 map_to_def = find_program('scripts/map-to-def')
 153
 154 # libxkbcommon.
 155 # Note: we use some yacc extensions, which work with either GNU bison
 156 # (preferred) or byacc (with backtracking enabled).
 157 bison = find_program('bison', 'win_bison', required: false, version: '>= 2.3a')
 158 if bison.found()
 159     yacc = bison
 160     yacc_gen = generator(
 161         bison,
 162         output: ['@BASENAME@.c', '@BASENAME@.h'],
 163         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 164     )
 165 else
 166     byacc = find_program('byacc', required: false)
 167     if byacc.found()
 168         yacc = byacc
 169         yacc_gen = generator(
 170             byacc,
 171             output: ['@BASENAME@.c', '@BASENAME@.h'],
 172             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 173         )
 174     else
 175         error('Could not find a compatible YACC program (bison or byacc)')
 176     endif
 177 endif
 178 libxkbcommon_sources = [
 179     'src/compose/parser.c',
 180     'src/compose/parser.h',
 181     'src/compose/paths.c',
 182     'src/compose/paths.h',
 183     'src/compose/state.c',
 184     'src/compose/table.c',
 185     'src/compose/table.h',
 186     'src/xkbcomp/action.c',
 187     'src/xkbcomp/action.h',
 188     'src/xkbcomp/ast.h',
 189     'src/xkbcomp/ast-build.c',
 190     'src/xkbcomp/ast-build.h',
 191     'src/xkbcomp/compat.c',
 192     'src/xkbcomp/expr.c',
 193     'src/xkbcomp/expr.h',
 194     'src/xkbcomp/include.c',
 195     'src/xkbcomp/include.h',
 196     'src/xkbcomp/keycodes.c',
 197     'src/xkbcomp/keymap.c',
 198     'src/xkbcomp/keymap-dump.c',
 199     'src/xkbcomp/keywords.c',
 200     yacc_gen.process('src/xkbcomp/parser.y'),
 201     'src/xkbcomp/parser-priv.h',
 202     'src/xkbcomp/rules.c',
 203     'src/xkbcomp/rules.h',
 204     'src/xkbcomp/scanner.c',
 205     'src/xkbcomp/symbols.c',
 206     'src/xkbcomp/types.c',
 207     'src/xkbcomp/vmod.c',
 208     'src/xkbcomp/vmod.h',
 209     'src/xkbcomp/xkbcomp.c',
 210     'src/xkbcomp/xkbcomp-priv.h',
 211     'src/atom.c',
 212     'src/atom.h',
 213     'src/context.c',
 214     'src/context.h',
 215     'src/context-priv.c',
 216     'src/darray.h',
 217     'src/keysym.c',
 218     'src/keysym.h',
 219     'src/keysym-utf.c',
 220     'src/ks_tables.h',
 221     'src/keymap.c',
 222     'src/keymap.h',
 223     'src/keymap-priv.c',
 224     'src/messages-codes.h',
 225     'src/scanner-utils.h',
 226     'src/state.c',
 227     'src/text.c',
 228     'src/text.h',
 229     'src/utf8.c',
 230     'src/utf8.h',
 231     'src/utils.c',
 232     'src/utils.h',
 233 ]
 234 libxkbcommon_link_args = []
 235 libxkbcommon_link_deps = []
 236 if have_version_script
 237     libxkbcommon_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map'
 238     libxkbcommon_link_deps += 'xkbcommon.map'
 239 elif cc.get_argument_syntax() == 'msvc'
 240     libxkbcommon_def = custom_target('xkbcommon.def',
 241         command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 242         input: 'xkbcommon.map',
 243         output: 'kxbcommon.def',
 244     )
 245     libxkbcommon_link_deps += libxkbcommon_def
 246     libxkbcommon_link_args += '/DEF:' + libxkbcommon_def.full_path()
 247 endif
 248
 249 libxkbcommon = library(
 250     'xkbcommon',
 251     'include/xkbcommon/xkbcommon.h',
 252     libxkbcommon_sources,
 253     link_args: libxkbcommon_link_args,
 254     link_depends: libxkbcommon_link_deps,
 255     gnu_symbol_visibility: 'hidden',
 256     version: '0.0.0',
 257     install: true,
 258     include_directories: include_directories('src', 'include'),
 259 )
 260 install_headers(
 261     'include/xkbcommon/xkbcommon.h',
 262     'include/xkbcommon/xkbcommon-compat.h',
 263     'include/xkbcommon/xkbcommon-compose.h',
 264     'include/xkbcommon/xkbcommon-keysyms.h',
 265     'include/xkbcommon/xkbcommon-names.h',
 266     subdir: 'xkbcommon',
 267 )
 268
 269 dep_libxkbcommon = declare_dependency(
 270     link_with: libxkbcommon,
 271     include_directories: include_directories('include'),
 272 )
 273 if meson.version().version_compare('>= 0.54.0')
 274     meson.override_dependency('xkbcommon', dep_libxkbcommon)
 275 endif
 276 pkgconfig.generate(
 277     libxkbcommon,
 278     name: 'xkbcommon',
 279     filebase: 'xkbcommon',
 280     version: meson.project_version(),
 281     description: 'XKB API common to servers and clients',
 282 )
 283
 284
 285 # libxkbcommon-x11.
 286 if get_option('enable-x11')
 287     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 288     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 289     if not xcb_dep.found() or not xcb_xkb_dep.found()
 290         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 291 You can disable X11 support with -Denable-x11=false.''')
 292     endif
 293
 294     libxkbcommon_x11_sources = [
 295         'src/x11/keymap.c',
 296         'src/x11/state.c',
 297         'src/x11/util.c',
 298         'src/x11/x11-priv.h',
 299         'src/context.h',
 300         'src/context-priv.c',
 301         'src/keymap.h',
 302         'src/keymap-priv.c',
 303         'src/atom.h',
 304         'src/atom.c',
 305     ]
 306     libxkbcommon_x11_link_args = []
 307     libxkbcommon_x11_link_deps = []
 308     if have_version_script
 309         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon-x11.map'
 310         libxkbcommon_x11_link_deps += 'xkbcommon-x11.map'
 311     elif cc.get_argument_syntax() == 'msvc'
 312         libxkbcommon_x11_def = custom_target('xkbcommon-x11.def',
 313             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 314             input: 'xkbcommon-x11.map',
 315             output: 'xkbcommon-x11.def',
 316         )
 317         libxkbcommon_x11_link_deps += libxkbcommon_x11_def
 318         libxkbcommon_x11_link_args += '/DEF:' + libxkbcommon_x11_def.full_path()
 319     endif
 320     libxkbcommon_x11 = library(
 321         'xkbcommon-x11',
 322         'include/xkbcommon/xkbcommon-x11.h',
 323         libxkbcommon_x11_sources,
 324         link_args: libxkbcommon_x11_link_args,
 325         link_depends: libxkbcommon_x11_link_deps,
 326         gnu_symbol_visibility: 'hidden',
 327         version: '0.0.0',
 328         install: true,
 329         include_directories: include_directories('src', 'include'),
 330         link_with: libxkbcommon,
 331         dependencies: [
 332             xcb_dep,
 333             xcb_xkb_dep,
 334         ],
 335     )
 336     install_headers(
 337         'include/xkbcommon/xkbcommon-x11.h',
 338         subdir: 'xkbcommon',
 339     )
 340     dep_libxkbcommon_x11 = declare_dependency(
 341         link_with: libxkbcommon_x11,
 342         include_directories: include_directories('include'),
 343     )
 344     if meson.version().version_compare('>= 0.54.0')
 345         meson.override_dependency('xkbcommon-x11', dep_libxkbcommon_x11)
 346     endif
 347     pkgconfig.generate(
 348         libxkbcommon_x11,
 349         name: 'xkbcommon-x11',
 350         filebase: 'xkbcommon-x11',
 351         version: meson.project_version(),
 352         description: 'XKB API common to servers and clients - X11 support',
 353         requires: ['xkbcommon'],
 354         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 355     )
 356 endif
 357
 358 # libxkbregistry
 359 if get_option('enable-xkbregistry')
 360     dep_libxml = dependency('libxml-2.0')
 361     deps_libxkbregistry = [dep_libxml]
 362     libxkbregistry_sources = [
 363         'src/registry.c',
 364         'src/utils.h',
 365         'src/utils.c',
 366         'src/util-list.h',
 367         'src/util-list.c',
 368     ]
 369     libxkbregistry_link_args = []
 370     libxkbregistry_link_deps = []
 371     if have_version_script
 372         libxkbregistry_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbregistry.map'
 373         libxkbregistry_link_deps += 'xkbregistry.map'
 374     elif cc.get_argument_syntax() == 'msvc'
 375         libxkbregistry_def = custom_target('xkbregistry.def',
 376             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 377             input: 'xkbregistry.map',
 378             output: 'xkbregistry.def',
 379         )
 380         libxkbregistry_link_deps += libxkbregistry_def
 381         libxkbregistry_link_args += '/DEF:' + libxkbregistry_def.full_path()
 382     endif
 383     libxkbregistry = library(
 384         'xkbregistry',
 385         'include/xkbcommon/xkbregistry.h',
 386         libxkbregistry_sources,
 387         link_args: libxkbregistry_link_args,
 388         link_depends: libxkbregistry_link_deps,
 389         gnu_symbol_visibility: 'hidden',
 390         dependencies: deps_libxkbregistry,
 391         version: '0.0.0',
 392         install: true,
 393         include_directories: include_directories('src', 'include'),
 394     )
 395     install_headers(
 396         'include/xkbcommon/xkbregistry.h',
 397         subdir: 'xkbcommon',
 398     )
 399     pkgconfig.generate(
 400         libxkbregistry,
 401         name: 'xkbregistry',
 402         filebase: 'xkbregistry',
 403         version: meson.project_version(),
 404         description: 'XKB API to query available rules, models, layouts, variants and options',
 405     )
 406
 407     dep_libxkbregistry = declare_dependency(
 408         link_with: libxkbregistry,
 409         include_directories: include_directories('include'),
 410     )
 411     if meson.version().version_compare('>= 0.54.0')
 412         meson.override_dependency('xkbregistry', dep_libxkbregistry)
 413     endif
 414 endif
 415
 416 man_pages = []
 417
 418 # Tools
 419 build_tools = get_option('enable-tools') and cc.has_header_symbol('getopt.h', 'getopt_long', prefix: '#define _GNU_SOURCE')
 420 if build_tools
 421     # Common resources
 422     libxkbcommon_tools_internal_sources = [
 423         'tools/tools-common.h',
 424         'tools/tools-common.c',
 425     ]
 426     libxkbcommon_tools_internal = static_library(
 427         'tools-internal',
 428         libxkbcommon_tools_internal_sources,
 429         dependencies: dep_libxkbcommon,
 430     )
 431     tools_dep = declare_dependency(
 432         include_directories: [include_directories('tools', 'include')],
 433         link_with: libxkbcommon_tools_internal,
 434         dependencies: dep_libxkbcommon,
 435     )
 436
 437     # Tool: xkbcli
 438     executable('xkbcli', 'tools/xkbcli.c',
 439                dependencies: tools_dep, install: true)
 440     install_man('tools/xkbcli.1')
 441
 442     if get_option('enable-bash-completion')
 443         bash_completion_path = get_option('bash-completion-path')
 444         if bash_completion_path == ''
 445             bash_completion = dependency('bash-completion', required: false)
 446             if bash_completion.found()
 447                 bash_completion_path = bash_completion.get_variable(pkgconfig: 'completionsdir')
 448             else
 449                 bash_completion_path = get_option('datadir') / 'bash-completion/completions'
 450             endif
 451         endif
 452         install_data('tools/xkbcli-bash-completion.sh',
 453                      rename: 'xkbcli',
 454                      install_dir: bash_completion_path)
 455     endif
 456
 457     # Tool: compile-keymap
 458     xkbcli_compile_keymap = executable('xkbcli-compile-keymap',
 459                                        'tools/compile-keymap.c',
 460                                        dependencies: tools_dep,
 461                                        install: true,
 462                                        install_dir: dir_libexec)
 463     install_man('tools/xkbcli-compile-keymap.1')
 464     # The same tool again, but with access to some private APIs.
 465     executable('compile-keymap',
 466                'tools/compile-keymap.c',
 467                libxkbcommon_sources,
 468                dependencies: [tools_dep],
 469                c_args: ['-DENABLE_PRIVATE_APIS'],
 470                include_directories: [include_directories('src', 'include')],
 471                install: false)
 472
 473     # Tool: compose
 474     executable('compose',
 475                'tools/compose.c',
 476                dependencies: tools_dep,
 477                include_directories: [include_directories('src', 'include')],
 478                install: false)
 479     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 480
 481     # Tool: how-to-type
 482     executable('xkbcli-how-to-type',
 483                'tools/how-to-type.c',
 484                dependencies: tools_dep,
 485                install: true,
 486                install_dir: dir_libexec)
 487     install_man('tools/xkbcli-how-to-type.1')
 488     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 489
 490     # Tool: interactive-evdev
 491     if cc.has_header('linux/input.h')
 492         executable('xkbcli-interactive-evdev',
 493                    'tools/interactive-evdev.c',
 494                    dependencies: tools_dep,
 495                    install: true,
 496                    install_dir: dir_libexec)
 497         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 498         install_man('tools/xkbcli-interactive-evdev.1')
 499         # The same tool again, but with access to some private APIs.
 500         executable('interactive-evdev',
 501                 'tools/interactive-evdev.c',
 502                 libxkbcommon_sources,
 503                 libxkbcommon_tools_internal_sources,
 504                 dependencies: [tools_dep],
 505                 c_args: ['-DENABLE_PRIVATE_APIS'],
 506                 include_directories: [include_directories('src', 'include')],
 507                 install: false)
 508     endif
 509
 510     # Tool: interactive-x11
 511     if get_option('enable-x11')
 512         x11_tools_dep = declare_dependency(
 513             link_with: libxkbcommon_x11,
 514             dependencies: [
 515                 tools_dep,
 516                 xcb_dep,
 517                 xcb_xkb_dep,
 518             ],
 519         )
 520         executable('xkbcli-interactive-x11',
 521                    'tools/interactive-x11.c',
 522                    dependencies: x11_tools_dep,
 523                    install: true,
 524                    install_dir: dir_libexec)
 525         install_man('tools/xkbcli-interactive-x11.1')
 526         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 527     endif
 528
 529     # Tool: interactive-wayland
 530     if get_option('enable-wayland')
 531         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 532         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 533         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 534         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 535             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 536 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 537         endif
 538
 539         wayland_scanner = find_program(wayland_scanner_dep.get_variable(pkgconfig: 'wayland_scanner'))
 540         wayland_scanner_code_gen = generator(
 541             wayland_scanner,
 542             output: '@BASENAME@-protocol.c',
 543             arguments: ['private-code', '@INPUT@', '@OUTPUT@'],
 544         )
 545         wayland_scanner_client_header_gen = generator(
 546             wayland_scanner,
 547             output: '@BASENAME@-client-protocol.h',
 548             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 549         )
 550         wayland_protocols_datadir = wayland_protocols_dep.get_variable(pkgconfig: 'pkgdatadir')
 551         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 552         xdg_shell_sources = [
 553             wayland_scanner_code_gen.process(xdg_shell_xml),
 554             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 555         ]
 556         executable('xkbcli-interactive-wayland',
 557                    'tools/interactive-wayland.c',
 558                    xdg_shell_sources,
 559                    dependencies: [tools_dep, wayland_client_dep],
 560                    install: true,
 561                    install_dir: dir_libexec)
 562         install_man('tools/xkbcli-interactive-wayland.1')
 563         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 564     endif
 565
 566     # Tool: list
 567     if get_option('enable-xkbregistry')
 568         configh_data.set10('HAVE_XKBCLI_LIST', true)
 569         executable('xkbcli-list',
 570                    'tools/registry-list.c',
 571                    dependencies: dep_libxkbregistry,
 572                    install: true,
 573                    install_dir: dir_libexec)
 574         install_man('tools/xkbcli-list.1')
 575     endif
 576
 577     # Tool: check-messages
 578     executable('xkb-check-messages',
 579                'tools/check-messages.c',
 580                'tools/messages.c',
 581                'tools/messages.h',
 582                'src/messages-codes.h',
 583                dependencies: [tools_dep],
 584                include_directories: [include_directories('src', 'include', 'tools')],
 585                install: false)
 586 endif
 587
 588
 589 # xkeyboard-config "verifier"
 590 xkct_config = configuration_data()
 591 xkct_config.set('MESON_BUILD_ROOT', meson.current_build_dir())
 592 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 593 configure_file(input: 'test/xkeyboard-config-test.py.in',
 594                output: 'xkeyboard-config-test',
 595                configuration: xkct_config)
 596
 597 # Tests
 598 test_env = environment()
 599 test_env.set('XKB_LOG_LEVEL', 'debug')
 600 test_env.set('XKB_LOG_VERBOSITY', '10')
 601 test_env.set('top_srcdir', meson.current_source_dir())
 602 test_env.set('top_builddir', meson.current_build_dir())
 603 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 604 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 605 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 606 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 607
 608 test_configh_data = configuration_data()
 609 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 610 configure_file(output: 'test-config.h', configuration: test_configh_data)
 611
 612 # Some tests need to use unexported symbols, so we link them against
 613 # an internal copy of libxkbcommon with all symbols exposed.
 614 libxkbcommon_test_internal = static_library(
 615     'xkbcommon-test-internal',
 616     'test/common.c',
 617     'test/test.h',
 618     'test/evdev-scancodes.h',
 619     'bench/bench.c',
 620     'bench/bench.h',
 621     libxkbcommon_sources,
 622     include_directories: include_directories('src', 'include'),
 623 )
 624 test_dep = declare_dependency(
 625     include_directories: include_directories('src', 'include'),
 626     link_with: libxkbcommon_test_internal,
 627 )
 628 if get_option('enable-x11')
 629     libxkbcommon_x11_test_internal = static_library(
 630         'xkbcommon-x11-internal',
 631         libxkbcommon_x11_sources,
 632         'test/xvfb-wrapper.c',
 633         'test/xvfb-wrapper.h',
 634         include_directories: include_directories('src', 'include'),
 635         link_with: libxkbcommon_test_internal,
 636         dependencies: [
 637             xcb_dep,
 638             xcb_xkb_dep,
 639         ],
 640     )
 641     x11_test_dep = declare_dependency(
 642         link_with: libxkbcommon_x11_test_internal,
 643         dependencies: [
 644             test_dep,
 645             xcb_dep,
 646             xcb_xkb_dep,
 647         ],
 648     )
 649 endif
 650 test(
 651     'keysym',
 652     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 653     env: test_env,
 654 )
 655 test(
 656     'keymap',
 657     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 658     env: test_env,
 659 )
 660 test(
 661     'filecomp',
 662     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 663     env: test_env,
 664 )
 665 test(
 666     'context',
 667     executable('test-context', 'test/context.c', dependencies: test_dep),
 668     env: test_env,
 669 )
 670 test(
 671     'rules-file',
 672     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 673     env: test_env,
 674 )
 675 test(
 676     'rules-file-includes',
 677     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 678     env: test_env,
 679 )
 680 test(
 681     'stringcomp',
 682     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 683     env: test_env,
 684 )
 685 test(
 686     'buffercomp',
 687     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 688     env: test_env,
 689 )
 690 test(
 691     'log',
 692     executable('test-log', 'test/log.c', dependencies: test_dep),
 693     env: test_env,
 694 )
 695 test(
 696     'atom',
 697     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 698     env: test_env,
 699 )
 700 test(
 701     'utf8',
 702     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 703     env: test_env,
 704 )
 705 test(
 706     'state',
 707     executable('test-state', 'test/state.c', dependencies: test_dep),
 708     env: test_env,
 709 )
 710 test(
 711     'keyseq',
 712     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 713     env: test_env,
 714 )
 715 test(
 716     'rulescomp',
 717     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 718     env: test_env,
 719 )
 720 test(
 721     'compose',
 722     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 723     env: test_env,
 724 )
 725 test(
 726     'utils',
 727     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 728     env: test_env,
 729 )
 730 test(
 731     'symbols-leak-test',
 732     find_program('test/symbols-leak-test.py'),
 733     env: test_env,
 734     suite: ['python-tests'],
 735 )
 736 test(
 737     'modifiers',
 738     executable('test-modifiers', 'test/modifiers.c', dependencies: test_dep),
 739     env: test_env,
 740 )
 741 test(
 742     'messages',
 743     executable(
 744         'test-messages',
 745         'test/messages.c',
 746         'tools/messages.c',
 747         'tools/messages.h',
 748         include_directories: include_directories('src', 'include', 'tools'),
 749         dependencies: test_dep),
 750     env: test_env,
 751 )
 752 if get_option('enable-x11')
 753     test(
 754         'x11',
 755         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 756         env: test_env,
 757     )
 758     test(
 759         'x11comp',
 760         executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep),
 761         env: test_env,
 762     )
 763 endif
 764 if get_option('enable-xkbregistry')
 765     test(
 766         'registry',
 767         executable('test-registry', 'test/registry.c',
 768                    include_directories: include_directories('src'),
 769                    dependencies: [dep_libxkbregistry, test_dep]),
 770         env: test_env,
 771     )
 772 endif
 773 if build_tools
 774     test('tool-option-parsing',
 775          find_program('test/tool-option-parsing.py'),
 776          env: test_env,
 777          suite: ['python-tests'])
 778
 779     # A set of keysyms to test for. Add one or two symbols to this array
 780     # whenever the xorgproto gets updated to make sure we resolve them.
 781     keysyms_to_test = [
 782         'XF86Macro23',
 783     ]
 784
 785     env = environment()
 786     env.set('XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 787     foreach keysym: keysyms_to_test
 788         test('keysym-test-@0@'.format(keysym),
 789              find_program('test/test-keysym.py'),
 790              env: env,
 791              args: [keysym, '--tool', xkbcli_compile_keymap],
 792              suite: ['python-tests'])
 793     endforeach
 794 endif
 795
 796 valgrind = find_program('valgrind', required: false)
 797 if valgrind.found()
 798     add_test_setup('valgrind',
 799         exe_wrapper: [valgrind,
 800                        '--leak-check=full',
 801                        '--track-origins=yes',
 802                        '--gen-suppressions=all',
 803                        '--error-exitcode=99'],
 804         timeout_multiplier : 10)
 805 else
 806     message('valgrind not found, disabling valgrind test setup')
 807 endif
 808
 809
 810 # Fuzzing target programs.
 811 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 812 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 813
 814
 815 # Benchmarks.
 816 bench_env = environment()
 817 bench_env.set('top_srcdir', meson.current_source_dir())
 818 benchmark(
 819     'key-proc',
 820     executable('bench-key-proc', 'bench/key-proc.c', dependencies: test_dep),
 821     env: bench_env,
 822 )
 823 benchmark(
 824     'rules',
 825     executable('bench-rules', 'bench/rules.c', dependencies: test_dep),
 826     env: bench_env,
 827 )
 828 benchmark(
 829     'rulescomp',
 830     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: test_dep),
 831     env: bench_env,
 832 )
 833 benchmark(
 834     'compose',
 835     executable('bench-compose', 'bench/compose.c', dependencies: test_dep),
 836     env: bench_env,
 837 )
 838 benchmark(
 839     'compose-traversal',
 840     executable('bench-compose-traversal', 'bench/compose-traversal.c', dependencies: test_dep),
 841     env: bench_env,
 842 )
 843 benchmark(
 844     'atom',
 845     executable('bench-atom', 'bench/atom.c', dependencies: test_dep),
 846     env: bench_env,
 847 )
 848 if get_option('enable-x11')
 849   benchmark(
 850       'x11',
 851       executable('bench-x11', 'bench/x11.c', dependencies: x11_test_dep),
 852       env: bench_env,
 853   )
 854 endif
 855
 856
 857 # Documentation.
 858 if get_option('enable-docs')
 859     doxygen = find_program('doxygen', required: false)
 860     if not doxygen.found()
 861         error('''Documentation requires doxygen which was not found.
 862 You can disable the documentation with -Denable-docs=false.''')
 863     endif
 864     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 865
 866     doxygen_input = [
 867         'README.md',
 868         'doc/diagrams/xkb-configuration.dot',
 869         'doc/doxygen-extra.css',
 870         'doc/introduction-to-xkb.md',
 871         'doc/quick-guide.md',
 872         'doc/compatibility.md',
 873         'doc/user-configuration.md',
 874         'doc/rules-format.md',
 875         'doc/keymap-format-text-v1.md',
 876         'doc/message-registry.md',
 877         'include/xkbcommon/xkbcommon.h',
 878         'include/xkbcommon/xkbcommon-compose.h',
 879         'include/xkbcommon/xkbcommon-keysyms.h',
 880         'include/xkbcommon/xkbcommon-names.h',
 881         'include/xkbcommon/xkbcommon-x11.h',
 882         'include/xkbcommon/xkbregistry.h',
 883     ]
 884     doxygen_data = configuration_data()
 885     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 886     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 887     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 888     doxygen_data.set('OUTPUT_DIRECTORY', meson.current_build_dir())
 889     doxyfile = configure_file(
 890         input: 'doc/Doxyfile.in',
 891         output: 'Doxyfile',
 892         configuration: doxygen_data,
 893     )
 894     # TODO: Meson should provide this.
 895     docdir = get_option('datadir')/'doc'/meson.project_name()
 896     doc_gen = custom_target(
 897         'doc',
 898         input: [doxyfile] + doxygen_input,
 899         output: 'html',
 900         command: [
 901             doxygen_wrapper,
 902             doxygen,
 903             meson.current_build_dir()/'Doxyfile',
 904             meson.current_source_dir(),
 905         ],
 906         install: true,
 907         install_dir: docdir,
 908         build_by_default: true,
 909     )
 910     if get_option('enable-cool-uris')
 911         ensure_stable_urls = find_program('scripts'/'ensure-stable-doc-urls.py')
 912         custom_target(
 913             'doc-cool-uris',
 914             input: [doc_gen, 'doc'/'cool-uris.yaml'],
 915             output: 'html-xtra',
 916             command: [
 917                 ensure_stable_urls,
 918                 'generate-redirections',
 919                 meson.current_source_dir()/'doc'/'cool-uris.yaml',
 920                 meson.current_build_dir()/'html'
 921             ],
 922             install: false,
 923             build_by_default: true,
 924         )
 925     endif
 926 endif
 927
 928 configure_file(output: 'config.h', configuration: configh_data)
 929
 930
 931 # Stable variables for projects using xkbcommon as a subproject.
 932 # These variables should not be renamed.
 933 libxkbcommon_dep = dep_libxkbcommon
 934 if get_option('enable-x11')
 935   libxkbcommon_x11_dep = dep_libxkbcommon_x11
 936 endif
 937 if get_option('enable-xkbregistry')
 938   libxkbregistry_dep = dep_libxkbregistry
 939 endif
 940
 941 if meson.version().version_compare('>=0.62.0')
 942     summary({
 943       'backend': meson.backend(),
 944       'buildtype': get_option('buildtype'),
 945       'c_args': get_option('c_args'),
 946       'c_link_args': get_option('c_link_args'),
 947       'yacc': yacc.full_path() + ' ' + yacc.version(),
 948     }, section: 'Compiler')
 949     summary({
 950       'prefix': get_option('prefix'),
 951       'bindir': get_option('bindir'),
 952       'libdir': get_option('libdir'),
 953       'datadir': get_option('datadir'),
 954       'xkb-config-root': XKBCONFIGROOT,
 955       'xkb-config-extra-path': XKBCONFIGEXTRAPATH,
 956       'xlocaledir': XLOCALEDIR,
 957     }, section: 'Directories')
 958     summary({
 959       'docs': get_option('enable-docs'),
 960       'tools': get_option('enable-tools'),
 961       'wayland': get_option('enable-wayland'),
 962       'x11': get_option('enable-x11'),
 963     }, section: 'Features')
 964     summary({
 965       'layout': get_option('default-layout'),
 966       'model': get_option('default-model'),
 967       'options': get_option('default-options'),
 968       'rules': get_option('default-rules'),
 969       'variant': get_option('default-variant'),
 970     }, section: 'Defaults')
 971 endif