CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.9)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "7")
  13 set(CPACK_PACKAGE_VERSION_PATCH "9")
  14 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
  15 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  16 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  17 set(SOVERSION "7.1")
  18 set(CPACK_SOURCE_GENERATOR "TGZ")
  19 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  20 set(VERSION "${CPACK_PACKAGE_VERSION}")
  21
  22 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  23 set(LWS_LIBRARY_VERSION_MAJOR ${CPACK_PACKAGE_VERSION_MAJOR})
  24 set(LWS_LIBRARY_VERSION_MINOR ${CPACK_PACKAGE_VERSION_MINOR})
  25 set(LWS_LIBRARY_VERSION_PATCH ${CPACK_PACKAGE_VERSION_PATCH})
  26
  27 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  28
  29 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  30
  31 # Try to find the current Git hash.
  32 find_package(Git)
  33 if(GIT_EXECUTABLE)
  34         execute_process(
  35     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  36     COMMAND "${GIT_EXECUTABLE}" describe
  37     OUTPUT_VARIABLE GIT_HASH
  38     OUTPUT_STRIP_TRAILING_WHITESPACE
  39     )
  40         execute_process(
  41     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  42     COMMAND "whoami"
  43     OUTPUT_VARIABLE GIT_USER
  44     OUTPUT_STRIP_TRAILING_WHITESPACE
  45     )
  46         execute_process(
  47     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  48     COMMAND "hostname"
  49     OUTPUT_VARIABLE GIT_HOST
  50     OUTPUT_STRIP_TRAILING_WHITESPACE
  51     )
  52     set(LWS_BUILD_HASH ${GIT_USER}@${GIT_HOST}-${GIT_HASH})
  53     message("Git commit hash: ${LWS_BUILD_HASH}")
  54 endif()
  55
  56 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  57 if(WIN32)
  58         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  59 endif()
  60
  61 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  62 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  63 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, wolfSSL if LWS_USE_WOLFSSL is set)" ON)
  64 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When setting this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  65 option(LWS_USE_WOLFSSL "Use wolfSSL replacement for OpenSSL. When setting this, you also need to specify LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS" OFF)
  66 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  67 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  68 option(LWS_WITH_LIBUV "Compile with support for libuv" OFF)
  69 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  70 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of the OS-installed CA root certs" ON)
  71 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use the BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... The default is to assume that your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  72 option(LWS_WITHOUT_BUILTIN_SHA1 "Don't build the lws sha-1 (eg, because openssl will provide it" OFF)
  73 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  74 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  75 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  76 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  77 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  78 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  79 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  80 option(LWS_WITHOUT_TEST_ECHO "Don't build the echo test application" OFF)
  81 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  82 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  83 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  84 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  85 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  86 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  87 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  88 option(LWS_MBED3 "Platform is MBED3" OFF)
  89 option(LWS_SSL_SERVER_WITH_ECDH_CERT "Include SSL server use ECDH certificate" OFF)
  90 option(LWS_STATIC_PIC "Build the static version of the library with position-independent code" OFF)
  91
  92 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  93
  94 set(LWS_WITH_SHARED OFF)
  95 set(LWS_WITH_SSL OFF)
  96 set(LWS_WITH_ZLIB OFF)
  97 set(LWS_WITHOUT_CLIENT ON)
  98 set(LWS_WITHOUT_TESTAPPS ON)
  99 set(LWS_WITHOUT_EXTENSIONS ON)
 100 set(LWS_MBED3 ON)
 101 # this implies no pthreads in the lib
 102 set(LWS_MAX_SMP 1)
 103
 104 endif()
 105
 106 if (WIN32)
 107 # this implies no pthreads in the lib
 108 set(LWS_MAX_SMP 1)
 109 endif()
 110
 111
 112 # Allow the user to override installation directories.
 113 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
 114 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
 115 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
 116 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
 117
 118 # Allow the user to use the old CyaSSL options/library in stead of wolfSSL
 119 if (LWS_USE_CYASSL AND LWS_USE_WOLFSSL)
 120         message(FATAL_ERROR "LWS_USE_CYASSL and LWS_USE_WOLFSSL are mutually exclusive!")
 121 endif()
 122 if (LWS_USE_CYASSL)
 123         # Copy CyaSSL options to the wolfSSL options
 124         set(LWS_USE_WOLFSSL ${LWS_USE_CYASSL} CACHE BOOL "Use wolfSSL/CyaSSL instead of OpenSSL" FORCE)
 125         set(LWS_WOLFSSL_LIBRARIES ${LWS_CYASSL_LIBRARIES} CACHE PATH "Path to wolfSSL/CyaSSL libraries" FORCE)
 126         set(LWS_WOLFSSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS} CACHE PATH "Path to wolfSSL/CyaSSL header files" FORCE)
 127 endif()
 128
 129 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
 130         message(FATAL_ERROR "Makes no sense to compile with neither client nor server.")
 131 endif()
 132
 133 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
 134         message(FATAL_ERROR "Makes no sense to compile with neither static nor shared libraries.")
 135 endif()
 136
 137 if (NOT LWS_WITHOUT_EXTENSIONS)
 138         if (NOT LWS_WITH_ZLIB)
 139                 message(FATAL_ERROR "zlib is required for extensions.")
 140         endif()
 141 endif()
 142
 143 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
 144 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
 145 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
 146 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
 147 set(LWS_WOLFSSL_LIBRARIES CACHE PATH "Path to the wolfSSL library")
 148 set(LWS_WOLFSSL_INCLUDE_DIRS CACHE PATH "Path to the wolfSSL include directory")
 149 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
 150 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
 151 set(LWS_LIBUV_LIBRARIES CACHE PATH "Path to the libuv library")
 152 set(LWS_LIBUV_INCLUDE_DIRS CACHE PATH "Path to the libuv include directory")
 153
 154 if (NOT LWS_WITH_SSL)
 155         set(LWS_WITHOUT_BUILTIN_SHA1 OFF)
 156 endif()
 157
 158 if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 159         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 160         else()
 161                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 162                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 163                 set(OPENSSL_FOUND 1)
 164         endif()
 165 endif()
 166
 167 if (LWS_WITH_SSL AND LWS_USE_WOLFSSL)
 168         if ("${LWS_WOLFSSL_LIBRARIES}" STREQUAL "" OR "${LWS_WOLFSSL_INCLUDE_DIRS}" STREQUAL "")
 169                 if (NOT WOLFSSL_FOUND)
 170                         if (LWS_USE_CYASSL)
 171                                 message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 172                         else()
 173                                 message(FATAL_ERROR "You must set LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS when LWS_USE_WOLFSSL is turned on.")
 174                         endif()
 175                 endif()
 176         else()
 177                 set(WOLFSSL_LIBRARIES ${LWS_WOLFSSL_LIBRARIES})
 178                 set(WOLFSSL_INCLUDE_DIRS ${LWS_WOLFSSL_INCLUDE_DIRS})
 179                 set(WOLFSSL_FOUND 1)
 180         endif()
 181         set(USE_WOLFSSL 1)
 182         if (LWS_USE_CYASSL)
 183                 set(USE_OLD_CYASSL 1)
 184         endif()
 185 endif()
 186
 187 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 188         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 189         else()
 190                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 191                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 192                 set(ZLIB_FOUND 1)
 193         endif()
 194 endif()
 195
 196 if (LWS_WITH_LIBEV)
 197         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 198         else()
 199                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 200                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 201                 set(LIBEV_FOUND 1)
 202         endif()
 203 endif()
 204
 205 if (LWS_WITH_LIBUV)
 206         if ("${LWS_LIBUV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBUV_INCLUDE_DIRS}" STREQUAL "")
 207         else()
 208                 set(LIBUV_LIBRARIES ${LWS_LIBUV_LIBRARIES})
 209                 set(LIBUV_INCLUDE_DIRS ${LWS_LIBUV_INCLUDE_DIRS})
 210                 set(LIBUV_FOUND 1)
 211         endif()
 212 endif()
 213
 214 # FIXME: This must be runtime-only option.
 215 # The base dir where the test-apps look for the SSL certs.
 216 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 217 if (WIN32)
 218         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 219
 220         if (LWS_IPV6)
 221                 set(LWS_IPV6 OFF)
 222                 message(WARNING "IPv6 does not currently work on Windows!")
 223         endif()
 224 else()
 225         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 226 endif()
 227
 228 if (LWS_WITHOUT_EXTENSIONS)
 229         set(LWS_NO_EXTENSIONS 1)
 230 endif()
 231
 232 if (LWS_WITH_SSL)
 233         set(LWS_OPENSSL_SUPPORT 1)
 234 endif()
 235
 236 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 237         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 238 endif()
 239
 240 if (LWS_WITH_LATENCY)
 241         set(LWS_LATENCY 1)
 242 endif()
 243
 244 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 245         set(LWS_NO_DAEMONIZE 1)
 246 endif()
 247
 248 if (LWS_WITHOUT_SERVER)
 249         set(LWS_NO_SERVER 1)
 250 endif()
 251
 252 if (LWS_WITHOUT_CLIENT)
 253         set(LWS_NO_CLIENT 1)
 254 endif()
 255
 256 if (LWS_WITH_LIBEV)
 257         set(LWS_USE_LIBEV 1)
 258 endif()
 259
 260 if (LWS_WITH_LIBUV)
 261         set(LWS_USE_LIBUV 1)
 262 endif()
 263
 264 if (LWS_IPV6)
 265         set(LWS_USE_IPV6 1)
 266 endif()
 267
 268 if (LWS_WITH_HTTP2)
 269         set(LWS_USE_HTTP2 1)
 270 endif()
 271
 272 if ("${LWS_MAX_SMP}" STREQUAL "")
 273         set(LWS_MAX_SMP 32)
 274 endif()
 275
 276 #if (LWS_MBED3)
 277 #       set(CMAKE_C_FLAGS "-D_DEBUG ${CMAKE_C_FLAGS}")
 278 #endif()
 279
 280 if (MINGW)
 281         set(LWS_MINGW_SUPPORT 1)
 282         set(CMAKE_C_FLAGS "-D__USE_MINGW_ANSI_STDIO ${CMAKE_C_FLAGS}")
 283 endif()
 284
 285 if (LWS_SSL_SERVER_WITH_ECDH_CERT)
 286         set(LWS_SSL_SERVER_WITH_ECDH_CERT 1)
 287 endif()
 288
 289 include_directories("${PROJECT_BINARY_DIR}")
 290
 291 include(CheckCSourceCompiles)
 292
 293 # Check for different inline keyword versions.
 294 foreach(KEYWORD "inline" "__inline__" "__inline")
 295         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 296         CHECK_C_SOURCE_COMPILES(
 297                 "
 298                 #include <stdio.h>
 299                 static KEYWORD void a() {}
 300                 int main(int argc, char **argv) { a(); return 0; }
 301                 " LWS_HAVE_${KEYWORD})
 302 endforeach()
 303
 304 if (NOT LWS_HAVE_inline)
 305         if (LWS_HAVE___inline__)
 306                 set(inline __inline__)
 307         elseif(LWS_HAVE___inline)
 308                 set(inline __inline)
 309         endif()
 310 endif()
 311
 312 # Put the libaries and binaries that get built into directories at the
 313 # top of the build tree rather than in hard-to-find leaf directories.
 314 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 315 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 316 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 317
 318 # Put absolute path of dynamic libraries into the object code. Some
 319 # architectures, notably Mac OS X, need this.
 320 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 321
 322 include(CheckFunctionExists)
 323 include(CheckIncludeFile)
 324 include(CheckIncludeFiles)
 325 include(CheckLibraryExists)
 326 include(CheckTypeSize)
 327
 328 if (LWS_WITHOUT_BUILTIN_SHA1)
 329         set(LWS_SHA1_USE_OPENSSL_NAME 1)
 330 endif()
 331
 332 CHECK_FUNCTION_EXISTS(bzero LWS_HAVE_BZERO)
 333 CHECK_FUNCTION_EXISTS(fork LWS_HAVE_FORK)
 334 CHECK_FUNCTION_EXISTS(getenv LWS_HAVE_GETENV)
 335 CHECK_FUNCTION_EXISTS(malloc LWS_HAVE_MALLOC)
 336 CHECK_FUNCTION_EXISTS(memset LWS_HAVE_MEMSET)
 337 CHECK_FUNCTION_EXISTS(realloc LWS_HAVE_REALLOC)
 338 CHECK_FUNCTION_EXISTS(socket LWS_HAVE_SOCKET)
 339 CHECK_FUNCTION_EXISTS(strerror LWS_HAVE_STRERROR)
 340 CHECK_FUNCTION_EXISTS(vfork LWS_HAVE_VFORK)
 341 CHECK_FUNCTION_EXISTS(getifaddrs LWS_HAVE_GETIFADDRS)
 342 CHECK_FUNCTION_EXISTS(snprintf LWS_HAVE_SNPRINTF)
 343 CHECK_FUNCTION_EXISTS(_snprintf LWS_HAVE__SNPRINTF)
 344 CHECK_FUNCTION_EXISTS(_vsnprintf LWS_HAVE__VSNPRINTF)
 345
 346 if (NOT LWS_HAVE_GETIFADDRS)
 347         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 348                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 349         endif()
 350         set(LWS_BUILTIN_GETIFADDRS 1)
 351 endif()
 352
 353 CHECK_INCLUDE_FILE(dlfcn.h LWS_HAVE_DLFCN_H)
 354 CHECK_INCLUDE_FILE(fcntl.h LWS_HAVE_FCNTL_H)
 355 CHECK_INCLUDE_FILE(in6addr.h LWS_HAVE_IN6ADDR_H)
 356 CHECK_INCLUDE_FILE(inttypes.h LWS_HAVE_INTTYPES_H)
 357 CHECK_INCLUDE_FILE(memory.h LWS_HAVE_MEMORY_H)
 358 CHECK_INCLUDE_FILE(netinet/in.h LWS_HAVE_NETINET_IN_H)
 359 CHECK_INCLUDE_FILE(stdint.h LWS_HAVE_STDINT_H)
 360 CHECK_INCLUDE_FILE(stdlib.h LWS_HAVE_STDLIB_H)
 361 CHECK_INCLUDE_FILE(strings.h LWS_HAVE_STRINGS_H)
 362 CHECK_INCLUDE_FILE(string.h LWS_HAVE_STRING_H)
 363 CHECK_INCLUDE_FILE(sys/prctl.h LWS_HAVE_SYS_PRCTL_H)
 364 CHECK_INCLUDE_FILE(sys/socket.h LWS_HAVE_SYS_SOCKET_H)
 365 CHECK_INCLUDE_FILE(sys/stat.h LWS_HAVE_SYS_STAT_H)
 366 CHECK_INCLUDE_FILE(sys/types.h LWS_HAVE_SYS_TYPES_H)
 367 CHECK_INCLUDE_FILE(unistd.h LWS_HAVE_UNISTD_H)
 368 CHECK_INCLUDE_FILE(vfork.h LWS_HAVE_VFORK_H)
 369
 370 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 371         CHECK_INCLUDE_FILE(zlib.h LWS_HAVE_ZLIB_H)
 372 endif()
 373
 374 # TODO: These can also be tested to see whether they actually work...
 375 set(LWS_HAVE_WORKING_FORK LWS_HAVE_FORK)
 376 set(LWS_HAVE_WORKING_VFORK LWS_HAVE_VFORK)
 377
 378 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 379
 380 # These don't work Cross...
 381 #CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 382 #CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 383 #CHECK_TYPE_SIZE("void *" LWS_SIZEOFPTR LANGUAGE C)
 384
 385 if (NOT PID_T_SIZE)
 386         set(pid_t int)
 387 endif()
 388
 389 if (NOT SIZE_T_SIZE)
 390         set(size_t "unsigned int")
 391 endif()
 392
 393 if (NOT LWS_HAVE_MALLOC)
 394         set(malloc rpl_malloc)
 395 endif()
 396
 397 if (NOT LWS_HAVE_REALLOC)
 398         set(realloc rpl_realloc)
 399 endif()
 400
 401 if (MSVC)
 402         # Turn off stupid microsoft security warnings.
 403         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 404 endif(MSVC)
 405
 406 include_directories("${PROJECT_SOURCE_DIR}/lib")
 407
 408 # Group headers and sources.
 409 # Some IDEs use this for nicer file structure.
 410 set(HDR_PRIVATE
 411         lib/private-libwebsockets.h)
 412
 413 set(HDR_PUBLIC
 414         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 415         "${PROJECT_BINARY_DIR}/lws_config.h")
 416
 417 set(SOURCES
 418         lib/base64-decode.c
 419         lib/handshake.c
 420         lib/libwebsockets.c
 421         lib/service.c
 422         lib/pollfd.c
 423         lib/output.c
 424         lib/parsers.c
 425         lib/context.c
 426         lib/alloc.c
 427         lib/header.c)
 428
 429 if (NOT LWS_WITHOUT_CLIENT)
 430         list(APPEND SOURCES
 431                 lib/client.c
 432                 lib/client-handshake.c
 433                 lib/client-parser.c)
 434 endif()
 435
 436 if (LWS_WITH_SSL)
 437         list(APPEND SOURCES
 438                 lib/ssl.c)
 439 endif()
 440
 441 if (NOT LWS_WITHOUT_BUILTIN_SHA1)
 442         list(APPEND SOURCES
 443                 lib/sha-1.c)
 444 endif()
 445
 446 if (LWS_WITH_HTTP2)
 447         list(APPEND SOURCES
 448                 lib/http2.c
 449                 lib/hpack.c
 450                 lib/ssl-http2.c)
 451 endif()
 452 # select the active platform files
 453
 454 if (WIN32)
 455         list(APPEND SOURCES
 456                 lib/lws-plat-win.c)
 457 else()
 458         if (LWS_MBED3)
 459                 list(APPEND SOURCES
 460                         lib/lws-plat-mbed3.cpp
 461                         lib/lws-plat-mbed3.c)
 462         else()
 463                 list(APPEND SOURCES
 464                         lib/lws-plat-unix.c)
 465         endif()
 466 endif()
 467
 468 if (NOT LWS_WITHOUT_SERVER)
 469         list(APPEND SOURCES
 470                 lib/server.c
 471                 lib/server-handshake.c)
 472 endif()
 473
 474 if (NOT LWS_WITHOUT_EXTENSIONS)
 475         list(APPEND HDR_PRIVATE
 476                 lib/extension-permessage-deflate.h)
 477         list(APPEND SOURCES
 478                 lib/extension.c
 479                 lib/extension-permessage-deflate.c)
 480 endif()
 481
 482 if (LWS_WITH_LIBEV)
 483         list(APPEND SOURCES
 484                 lib/libev.c)
 485 endif()
 486
 487 if (LWS_WITH_LIBUV)
 488         list(APPEND SOURCES
 489                 lib/libuv.c)
 490 endif()
 491
 492 # Add helper files for Windows.
 493 if (WIN32)
 494         set(WIN32_HELPERS_PATH win32port/win32helpers)
 495         include_directories(${WIN32_HELPERS_PATH})
 496 else()
 497         # Unix.
 498         if (NOT LWS_WITHOUT_DAEMONIZE)
 499                 list(APPEND SOURCES
 500                         lib/daemonize.c)
 501         endif()
 502 endif()
 503
 504 if (UNIX)
 505         if (NOT LWS_HAVE_GETIFADDRS)
 506                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 507                 list(APPEND SOURCES lib/getifaddrs.c)
 508         endif()
 509 endif()
 510
 511 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 512     include (CheckCCompilerFlag)
 513     CHECK_C_COMPILER_FLAG(-fvisibility=hidden LWS_HAVE_VISIBILITY)
 514     if (LWS_HAVE_VISIBILITY)
 515                 set(VISIBILITY_FLAG -fvisibility=hidden)
 516     endif()
 517     if (UNIX)
 518                set(CMAKE_C_FLAGS "-Wall -Werror ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 519     else(UNIX)
 520                set(CMAKE_C_FLAGS "-Wall ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 521     endif(UNIX)
 522 endif ()
 523
 524 if ((CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX) AND NOT LWS_WITHOUT_TESTAPPS)
 525     if (UNIX)
 526         # jeez clang understands -pthread but dies if he sees it at link time!
 527         # http://stackoverflow.com/questions/2391194/what-is-gs-pthread-equiv-in-clang
 528         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread" )
 529     endif()
 530 endif()
 531
 532 if ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 533         # otherwise osx blows a bunch of openssl deprecated api errors
 534         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations" )
 535 endif()
 536
 537 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 538 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 539 source_group("Sources"          FILES ${SOURCES})
 540
 541 #
 542 # Create the lib.
 543 #
 544 set(LWS_LIBRARIES)
 545
 546 if (LWS_WITH_STATIC)
 547     if (LWS_STATIC_PIC)
 548         set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 549     endif()
 550         add_library(websockets STATIC
 551                                 ${HDR_PRIVATE}
 552                                 ${HDR_PUBLIC}
 553                                 ${SOURCES})
 554         list(APPEND LWS_LIBRARIES websockets)
 555
 556         if (WIN32)
 557                 # Windows uses the same .lib ending for static libraries and shared
 558                 # library linker files, so rename the static library.
 559                 set_target_properties(websockets
 560                         PROPERTIES
 561                         OUTPUT_NAME websockets_static)
 562         endif()
 563 endif()
 564
 565 if (LWS_WITH_SHARED)
 566         add_library(websockets_shared SHARED
 567                                 ${HDR_PRIVATE}
 568                                 ${HDR_PUBLIC}
 569                                 ${SOURCES})
 570         list(APPEND LWS_LIBRARIES websockets_shared)
 571
 572         # We want the shared lib to be named "libwebsockets"
 573         # not "libwebsocket_shared".
 574         set_target_properties(websockets_shared
 575                 PROPERTIES
 576                 OUTPUT_NAME websockets)
 577
 578         if (WIN32)
 579                 # Compile as DLL (export function declarations)
 580                 set_property(
 581                         TARGET websockets_shared
 582                         PROPERTY COMPILE_DEFINITIONS
 583                         LWS_DLL
 584                         LWS_INTERNAL)
 585         endif()
 586
 587         if (APPLE)
 588                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 589         endif()
 590 endif()
 591
 592 # Set the so version of the lib.
 593 # Equivalent to LDFLAGS=-version-info x:x:x
 594 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 595         foreach(lib ${LWS_LIBRARIES})
 596                 set_target_properties(${lib}
 597                         PROPERTIES
 598                         SOVERSION ${SOVERSION})
 599         endforeach()
 600 endif()
 601
 602 set(LIB_LIST)
 603
 604 #
 605 # Find libraries.
 606 #
 607
 608 #
 609 # ZLIB (Only needed for deflate extensions).
 610 #
 611 if (LWS_WITH_ZLIB)
 612         if (LWS_USE_BUNDLED_ZLIB)
 613                 if (WIN32)
 614                         set(WIN32_ZLIB_PATH "win32port/zlib")
 615                         set(ZLIB_SRCS
 616                                 ${WIN32_ZLIB_PATH}/adler32.c
 617                                 ${WIN32_ZLIB_PATH}/compress.c
 618                                 ${WIN32_ZLIB_PATH}/crc32.c
 619                                 ${WIN32_ZLIB_PATH}/deflate.c
 620                                 ${WIN32_ZLIB_PATH}/gzclose.c
 621                                 ${WIN32_ZLIB_PATH}/gzio.c
 622                                 ${WIN32_ZLIB_PATH}/gzlib.c
 623                                 ${WIN32_ZLIB_PATH}/gzread.c
 624                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 625                                 ${WIN32_ZLIB_PATH}/infback.c
 626                                 ${WIN32_ZLIB_PATH}/inffast.c
 627                                 ${WIN32_ZLIB_PATH}/inflate.c
 628                                 ${WIN32_ZLIB_PATH}/inftrees.c
 629                                 ${WIN32_ZLIB_PATH}/trees.c
 630                                 ${WIN32_ZLIB_PATH}/uncompr.c
 631                                 ${WIN32_ZLIB_PATH}/zutil.c)
 632                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 633                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 634                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 635                         set(ZLIB_FOUND 1)
 636                         # Make sure zlib_internal is compiled before the libs.
 637                         foreach (lib ${LWS_LIBRARIES})
 638                                 add_dependencies(${lib} zlib_internal)
 639                         endforeach()
 640                 else()
 641                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 642                 endif()
 643         elseif (NOT ZLIB_FOUND)
 644                 find_package(ZLIB REQUIRED)
 645         endif()
 646         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 647         message("zlib libraries: ${ZLIB_LIBRARIES}")
 648         include_directories(${ZLIB_INCLUDE_DIRS})
 649         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 650 endif()
 651
 652 #
 653 # OpenSSL
 654 #
 655 if (LWS_WITH_SSL)
 656         message("Compiling with SSL support")
 657
 658         if (LWS_USE_WOLFSSL)
 659                 # Use wolfSSL as OpenSSL replacement.
 660                 # TODO: Add a find_package command for this also.
 661                 message("wolfSSL include dir: ${WOLFSSL_INCLUDE_DIRS}")
 662                 message("wolfSSL libraries: ${WOLFSSL_LIBRARIES}")
 663
 664                 # Additional to the root directory we need to include
 665                 # the wolfssl/ subdirectory which contains the OpenSSL
 666                 # compatibility layer headers.
 667
 668                 if (LWS_USE_CYASSL)
 669                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 670                                 include_directories("${inc}" "${inc}/cyassl")
 671                         endforeach()
 672                 else()
 673                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 674                                 include_directories("${inc}" "${inc}/wolfssl")
 675                         endforeach()
 676                 endif()
 677
 678                 list(APPEND LIB_LIST "${WOLFSSL_LIBRARIES}")
 679         else()
 680                 if (NOT OPENSSL_FOUND)
 681                         # TODO: Add support for STATIC also.
 682                         find_package(OpenSSL REQUIRED)
 683                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 684                 endif()
 685
 686                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 687                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 688
 689                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 690                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 691         endif()
 692
 693         # older (0.98) Openssl lacks this
 694         set(CMAKE_REQUIRED_INCLUDES ${OPENSSL_INCLUDE_DIRS})
 695         check_include_file(openssl/ecdh.h LWS_HAVE_OPENSSL_ECDH_H)
 696
 697         if (LWS_SSL_SERVER_WITH_ECDH_CERT AND NOT LWS_HAVE_OPENSSL_ECDH_H)
 698                 message(FATAL_ERROR "Missing openssl/ecdh.h, so cannot use LWS_SSL_SERVER_WITH_ECDH_CERT")
 699         endif()
 700
 701 endif(LWS_WITH_SSL)
 702
 703 if (LWS_WITH_LIBEV)
 704         if (NOT LIBEV_FOUND)
 705                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 706                 find_library(LIBEV_LIBRARIES NAMES ev)
 707                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 708                         set(LIBEV_FOUND 1)
 709                 endif()
 710         endif()
 711         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 712         message("libev libraries: ${LIBEV_LIBRARIES}")
 713         include_directories("${LIBEV_INCLUDE_DIRS}")
 714         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 715 endif(LWS_WITH_LIBEV)
 716
 717 if (LWS_WITH_LIBUV)
 718         if (NOT LIBUV_FOUND)
 719                 find_path(LIBUV_INCLUDE_DIRS NAMES uv.h)
 720                 find_library(LIBUV_LIBRARIES NAMES uv)
 721                 if(LIBUV_INCLUDE_DIRS AND LIBUV_LIBRARIES)
 722                         set(LIBUV_FOUND 1)
 723                 endif()
 724         endif()
 725         message("libuv include dir: ${LIBUV_INCLUDE_DIRS}")
 726         message("libuv libraries: ${LIBUV_LIBRARIES}")
 727         include_directories("${LIBUV_INCLUDE_DIRS}")
 728         list(APPEND LIB_LIST ${LIBUV_LIBRARIES})
 729 endif()
 730
 731
 732 # Generate the lws_config.h that includes all the public compilation settings.
 733 configure_file(
 734        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 735        "${PROJECT_BINARY_DIR}/lws_config.h")
 736
 737 # Generate the lws_config.h that includes all the private compilation settings.
 738 configure_file(
 739        "${PROJECT_SOURCE_DIR}/lws_config_private.h.in"
 740        "${PROJECT_BINARY_DIR}/lws_config_private.h")
 741
 742
 743 #
 744 # Platform specific libs.
 745 #
 746 if (WINCE)
 747         list(APPEND LIB_LIST ws2.lib)
 748 elseif (WIN32)
 749         list(APPEND LIB_LIST ws2_32.lib)
 750 endif()
 751
 752 if (UNIX)
 753         list(APPEND LIB_LIST m)
 754 endif()
 755
 756 # Setup the linking for all libs.
 757 foreach (lib ${LWS_LIBRARIES})
 758         target_link_libraries(${lib} ${LIB_LIST})
 759 endforeach()
 760
 761 #
 762 # Test applications
 763 #
 764 set(TEST_APP_LIST)
 765 if (NOT LWS_WITHOUT_TESTAPPS)
 766         #
 767         # Helper function for adding a test app.
 768         #
 769         macro(create_test_app TEST_NAME MAIN_SRC S2 S3 S4 S5 S6)
 770
 771                 set(TEST_SRCS ${MAIN_SRC})
 772                 set(TEST_HDR)
 773                 if ("${S2}" STREQUAL "")
 774                 else()
 775                         list(APPEND TEST_SRCS ${S2})
 776                 endif()
 777                 if ("${S3}" STREQUAL "")
 778                 else()
 779                         list(APPEND TEST_SRCS ${S3})
 780                 endif()
 781                 if ("${S4}" STREQUAL "")
 782                 else()
 783                         list(APPEND TEST_SRCS ${S4})
 784                 endif()
 785                 if ("${S5}" STREQUAL "")
 786                 else()
 787                         list(APPEND TEST_SRCS ${S5})
 788                 endif()
 789                 if ("${S6}" STREQUAL "")
 790                 else()
 791                         list(APPEND TEST_SRCS ${S6})
 792                 endif()
 793                 if (WIN32)
 794                         list(APPEND TEST_SRCS
 795                                 ${WIN32_HELPERS_PATH}/getopt.c
 796                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 797                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 798                         )
 799
 800                         list(APPEND TEST_HDR
 801                                 ${WIN32_HELPERS_PATH}/getopt.h
 802                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 803                         )
 804                 endif(WIN32)
 805
 806                 source_group("Headers Private"   FILES ${TEST_HDR})
 807                 source_group("Sources"   FILES ${TEST_SRCS})
 808                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 809
 810                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 811                         if (NOT LWS_WITH_SHARED)
 812                                 message(FATAL_ERROR "Build of the shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 813                         endif()
 814                         target_link_libraries(${TEST_NAME} websockets_shared)
 815                         add_dependencies(${TEST_NAME} websockets_shared)
 816                 else()
 817                         if (NOT LWS_WITH_STATIC)
 818                                 message(FATAL_ERROR "Build of the static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 819                         endif()
 820                         target_link_libraries(${TEST_NAME} websockets)
 821                         add_dependencies(${TEST_NAME} websockets)
 822                 endif()
 823
 824                 # Set test app specific defines.
 825                 set_property(TARGET ${TEST_NAME}
 826                                         PROPERTY COMPILE_DEFINITIONS
 827                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 828                                         )
 829
 830                 # Prefix the binary names with libwebsockets.
 831                 set_target_properties(${TEST_NAME}
 832                         PROPERTIES
 833                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 834
 835                 # Add to the list of tests.
 836                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 837         endmacro()
 838
 839         if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 840                 message("Searching for OpenSSL executable and dlls")
 841                 find_package(OpenSSLbins)
 842                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 843         endif()
 844
 845         if (NOT LWS_WITHOUT_SERVER)
 846                 #
 847                 # test-server
 848                 #
 849                 if (NOT LWS_WITHOUT_TEST_SERVER)
 850                         create_test_app(test-server "test-server/test-server.c"
 851                                 "test-server/test-server-http.c"
 852                                 "test-server/test-server-dumb-increment.c"
 853                                 "test-server/test-server-mirror.c"
 854                                 "test-server/test-server-status.c"
 855                                 "test-server/test-server-echogen.c")
 856                         if (UNIX)
 857                                 create_test_app(test-fuzxy "test-server/fuzxy.c"
 858                                         ""
 859                                         ""
 860                                         ""
 861                                         ""
 862                                         "")
 863                         endif()
 864                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang")))
 865                                 create_test_app(test-server-pthreads
 866                                         "test-server/test-server-pthreads.c"
 867                                         "test-server/test-server-http.c"
 868                                         "test-server/test-server-dumb-increment.c"
 869                                         "test-server/test-server-mirror.c"
 870                                         "test-server/test-server-status.c"
 871                                         "test-server/test-server-echogen.c")
 872                         endif()
 873                         if (NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 874                                 AND LWS_WITH_LIBEV)
 875                                 create_test_app(test-server-libev
 876                                         "test-server/test-server-libev.c"
 877                                         "test-server/test-server-http.c"
 878                                         "test-server/test-server-dumb-increment.c"
 879                                         "test-server/test-server-mirror.c"
 880                                         "test-server/test-server-status.c"
 881                                         "test-server/test-server-echogen.c")
 882                         endif()
 883                         if (NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 884                                 AND LWS_WITH_LIBUV)
 885                                 create_test_app(test-server-libuv
 886                                         "test-server/test-server-libuv.c"
 887                                         "test-server/test-server-http.c"
 888                                         "test-server/test-server-dumb-increment.c"
 889                                         "test-server/test-server-mirror.c"
 890                                         "test-server/test-server-status.c"
 891                                         "test-server/test-server-echogen.c")
 892                         endif()
 893                 endif()
 894
 895                 #
 896                 # test-server-extpoll
 897                 #
 898                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 899                         create_test_app(test-server-extpoll "test-server/test-server.c"
 900                                 "test-server/test-server-http.c"
 901                                 "test-server/test-server-dumb-increment.c"
 902                                 "test-server/test-server-mirror.c"
 903                                 "test-server/test-server-status.c"
 904                                 "test-server/test-server-echogen.c")
 905                         # Set defines for this executable only.
 906                         set_property(
 907                                 TARGET test-server-extpoll
 908                                 PROPERTY COMPILE_DEFINITIONS
 909                                         EXTERNAL_POLL
 910                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 911                                 )
 912
 913                         # We need to link against winsock code.
 914                         if (WIN32)
 915                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 916                         endif(WIN32)
 917                 endif()
 918
 919                 # Data files for running the test server.
 920                 set(TEST_SERVER_DATA
 921                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 922                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 923                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 924                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 925
 926                 # Generate self-signed SSL certs for the test-server.
 927                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 928                         message("Generating SSL Certificates for the test-server...")
 929
 930                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 931                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 932
 933                         if (WIN32)
 934                                 if (MINGW)
 935                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj \"/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost\" -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 936                                         execute_process(
 937                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj "/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost" -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 938                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE)
 939                                 else()
 940                                         file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 941                                                 "GB\n"
 942                                                 "Erewhon\n"
 943                                                 "All around\n"
 944                                                 "libwebsockets-test\n"
 945                                                 "localhost\n"
 946                                                 "none@invalid.org\n\n"
 947                                                 )
 948
 949                                         # The "type" command is a bit picky with paths.
 950                                         file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 951                                         message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 952                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 953
 954                                         execute_process(
 955                                                 COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 956                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 957                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE
 958                                                 OUTPUT_QUIET ERROR_QUIET)
 959
 960                                         message("\n")
 961                                 endif()
 962
 963                                 if (OPENSSL_RETURN_CODE)
 964                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 965                                 else()
 966                                         message("SUCCSESFULLY generated SSL certificate")
 967                                 endif()
 968                         else()
 969                                 # Unix.
 970                                 execute_process(
 971                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 972                                         COMMAND "${OPENSSL_EXECUTABLE}"
 973                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 974                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 975                                         OUTPUT_QUIET ERROR_QUIET)
 976
 977                                 if (OPENSSL_RETURN_CODE)
 978                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 979                                 else()
 980                                         message("SUCCESSFULLY generated SSL certificate")
 981                                 endif()
 982                         endif()
 983
 984                         list(APPEND TEST_SERVER_DATA
 985                                 "${TEST_SERVER_SSL_KEY}"
 986                                 "${TEST_SERVER_SSL_CERT}")
 987                 endif()
 988
 989                 add_custom_command(TARGET test-server
 990                                                 POST_BUILD
 991                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 992
 993                 # Copy the file needed to run the server so that the test apps can
 994                 # reach them from their default output location
 995                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 996                         if (EXISTS ${TEST_FILE})
 997                                 add_custom_command(TARGET test-server
 998                                                         POST_BUILD
 999                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
1000                         endif()
1001                 endforeach()
1002         endif(NOT LWS_WITHOUT_SERVER)
1003
1004         if (NOT LWS_WITHOUT_CLIENT)
1005                 #
1006                 # test-client
1007                 #
1008                 if (NOT LWS_WITHOUT_TEST_CLIENT)
1009                         create_test_app(test-client "test-server/test-client.c" "" "" "" "" "")
1010                 endif()
1011
1012                 #
1013                 # test-fraggle
1014                 #
1015                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
1016                         create_test_app(test-fraggle "test-server/test-fraggle.c" "" "" "" "" "")
1017                 endif()
1018
1019                 #
1020                 # test-ping
1021                 #
1022                 if (NOT LWS_WITHOUT_TEST_PING)
1023                         create_test_app(test-ping "test-server/test-ping.c" "" "" "" "" "")
1024                 endif()
1025                 #
1026                 # test-echo
1027                 #
1028                 if (NOT LWS_WITHOUT_TEST_ECHO)
1029                         create_test_app(test-echo "test-server/test-echo.c" "" "" "" "" "")
1030                 endif()
1031
1032         endif(NOT LWS_WITHOUT_CLIENT)
1033
1034         #
1035         # Copy OpenSSL dlls to the output directory on Windows.
1036         # (Otherwise we'll get an error when trying to run)
1037         #
1038         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
1039                 if(OPENSSL_BIN_FOUND)
1040                         message("OpenSSL dlls found:")
1041                         message("  Libeay: ${LIBEAY_BIN}")
1042                         message("  SSLeay: ${SSLEAY_BIN}")
1043
1044                         foreach(TARGET_BIN ${TEST_APP_LIST})
1045                                 add_custom_command(TARGET ${TARGET_BIN}
1046                                         POST_BUILD
1047                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1048                                 add_custom_command(TARGET ${TARGET_BIN}
1049                                         POST_BUILD
1050                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1051                         endforeach()
1052                 endif()
1053         endif()
1054 endif(NOT LWS_WITHOUT_TESTAPPS)
1055
1056 if (UNIX)
1057         # Generate documentation.
1058         # TODO: Fix this on Windows.
1059         message("Generating API documentation")
1060         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
1061         list(SORT C_FILES)
1062         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
1063
1064         execute_process(
1065                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
1066                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
1067                 ERROR_QUIET)
1068
1069         execute_process(
1070                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
1071                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
1072                 ERROR_QUIET)
1073
1074 # Generate and install pkgconfig.
1075 # (This is not indented, because the tabs will be part of the output)
1076 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1077 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
1078 exec_prefix=\${prefix}
1079 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
1080 includedir=\${prefix}/include
1081
1082 Name: libwebsockets
1083 Description: Websockets server and client library
1084 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}
1085
1086 Libs: -L\${libdir} -lwebsockets
1087 Cflags: -I\${includedir}"
1088 )
1089
1090         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1091                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
1092 endif(UNIX)
1093
1094 #
1095 # Installation preparations.
1096 #
1097
1098 if(WIN32 AND NOT CYGWIN)
1099   set(DEF_INSTALL_CMAKE_DIR cmake)
1100 else()
1101   set(DEF_INSTALL_CMAKE_DIR lib${LIB_SUFFIX}/cmake/libwebsockets)
1102 endif()
1103
1104 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
1105
1106 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
1107 export(TARGETS ${LWS_LIBRARIES}
1108         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
1109 export(PACKAGE libwebsockets)
1110
1111 # Generate the config file for the build-tree.
1112 set(LWS__INCLUDE_DIRS
1113     "${PROJECT_SOURCE_DIR}/lib"
1114     "${PROJECT_BINARY_DIR}")
1115 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
1116 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1117                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
1118                 @ONLY)
1119
1120 # Generate the config file for the installation tree.
1121 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
1122 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
1123 file(RELATIVE_PATH
1124     REL_INCLUDE_DIR
1125     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
1126     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
1127
1128 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
1129 # we escape it here so it's evaluated when it is included instead
1130 # so that the include dirs are given relative to where the
1131 # config file is located.
1132 set(LWS__INCLUDE_DIRS
1133     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
1134 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1135                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
1136                 @ONLY)
1137
1138 # Generate version info for both build-tree and install-tree.
1139 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
1140                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
1141                 @ONLY)
1142
1143                         set_target_properties(${LWS_LIBRARIES}
1144                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
1145
1146 #
1147 # Installation.
1148 #
1149
1150 # Install libs and headers.
1151 install(TARGETS ${LWS_LIBRARIES}
1152                 EXPORT LibwebsocketsTargets
1153                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1154                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1155                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
1156                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
1157 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
1158 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
1159
1160 # Install test apps.
1161 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
1162         install(TARGETS test-client ${TEST_APP_LIST}
1163                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
1164                         COMPONENT examples)
1165         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
1166 endif()
1167
1168 # Programs shared files used by the test-server.
1169 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
1170         install(FILES ${TEST_SERVER_DATA}
1171                         DESTINATION share/libwebsockets-test-server
1172                         COMPONENT examples)
1173 endif()
1174
1175 # Install the LibwebsocketsConfig.cmake and LibwebsocketsConfigVersion.cmake
1176 install(FILES
1177                "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake"
1178                "${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake"
1179                DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
1180
1181 # Install exports for the install-tree.
1182 install(EXPORT LibwebsocketsTargets
1183                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
1184
1185 # build subdir is not part of sources
1186 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
1187
1188 # Most people are more used to "make dist" compared to "make package_source"
1189 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
1190
1191 include(UseRPMTools)
1192 if (RPMTools_FOUND)
1193         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
1194 endif()
1195
1196 message("---------------------------------------------------------------------")
1197 message("  Settings:  (For more help do cmake -LH <srcpath>)")
1198 message("---------------------------------------------------------------------")
1199 message(" LWS_WITH_STATIC = ${LWS_WITH_STATIC}")
1200 message(" LWS_WITH_SHARED = ${LWS_WITH_SHARED}")
1201 message(" LWS_WITH_SSL = ${LWS_WITH_SSL} (SSL Support)")
1202 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
1203 message(" LWS_USE_WOLFSSL = ${LWS_USE_WOLFSSL} (wolfSSL/CyaSSL replacement for OpenSSL)")
1204 if (LWS_USE_WOLFSSL)
1205         message("   LWS_WOLFSSL_LIBRARIES = ${LWS_WOLFSSL_LIBRARIES}")
1206         message("   LWS_WOLFSSL_INCLUDE_DIRS = ${LWS_WOLFSSL_INCLUDE_DIRS}")
1207 endif()
1208 message(" LWS_WITHOUT_BUILTIN_SHA1 = ${LWS_WITHOUT_BUILTIN_SHA1}")
1209 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
1210 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
1211 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
1212 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
1213 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
1214 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
1215 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
1216 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
1217 message(" LWS_WITHOUT_TEST_ECHO = ${LWS_WITHOUT_TEST_ECHO}")
1218 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
1219 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
1220 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
1221 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
1222 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
1223 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
1224 message(" LWS_USE_LIBUV = ${LWS_USE_LIBUV}")
1225 message(" LWS_IPV6 = ${LWS_IPV6}")
1226 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
1227 message(" LWS_MBED3 = ${LWS_MBED3}")
1228 message(" LWS_SSL_SERVER_WITH_ECDH_CERT = ${LWS_SSL_SERVER_WITH_ECDH_CERT}")
1229 message(" LWS_MAX_SMP = ${LWS_MAX_SMP}")
1230 message(" LWS_HAVE_OPENSSL_ECDH_H = ${LWS_HAVE_OPENSSL_ECDH_H}")
1231 message(" LWS_STATIC_PIC = ${LWS_STATIC_PIC}")
1232 message("---------------------------------------------------------------------")
1233
1234 # These will be available to parent projects including libwebsockets using add_subdirectory()
1235 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
1236 if (LWS_WITH_STATIC)
1237         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
1238 endif()
1239 if (LWS_WITH_SHARED)
1240         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
1241 endif()
1242
1243 # This must always be last!
1244 include(CPack)