configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30
  31 AC_CONFIG_SRCDIR([libusb/core.c])
  32 AC_CONFIG_MACRO_DIR([m4])
  33 AC_CONFIG_HEADERS([config.h])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  35
  36 AC_PREREQ([2.69])
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 dnl on linux-android platform, some functions are in different places
  50 case $host in
  51 *-linux-android*)
  52         AC_MSG_RESULT([This is a Linux-Android system])
  53         is_backend_android="yes"
  54         ;;
  55 *)
  56         is_backend_android="no"
  57 esac
  58
  59 case $host in
  60 *-linux* | *-uclinux*)
  61         AC_MSG_RESULT([Linux])
  62         backend="linux"
  63         threads="posix"
  64         ;;
  65 *-darwin*)
  66         AC_MSG_RESULT([Darwin/Mac OS X])
  67         backend="darwin"
  68         threads="posix"
  69         ;;
  70 *-openbsd*)
  71         AC_MSG_RESULT([OpenBSD])
  72         backend="openbsd"
  73         threads="posix"
  74         ;;
  75 *-netbsd*)
  76         AC_MSG_RESULT([NetBSD])
  77         backend="netbsd"
  78         threads="posix"
  79         ;;
  80 *-mingw* | *msys*)
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="windows"
  84         create_import_lib="yes"
  85         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  86         ;;
  87 *-cygwin*)
  88         AC_MSG_RESULT([Cygwin (using Windows backend)])
  89         backend="windows"
  90         threads="posix"
  91         ;;
  92 *-haiku*)
  93         AC_MSG_RESULT([Haiku])
  94         backend="haiku"
  95         threads="posix"
  96         ;;
  97 *-solaris*)
  98         AC_MSG_RESULT([SunOS])
  99         backend="sunos"
 100         threads="posix"
 101         ;;
 102 *)
 103         AC_MSG_ERROR([unsupported operating system $host])
 104 esac
 105
 106 case $backend in
 107 linux)
 108         AC_DEFINE(OS_LINUX, 1, [Linux backend])
 109         AC_SUBST(OS_LINUX)
 110         AC_ARG_ENABLE([usbhost_api],
 111                 [AC_HELP_STRING([--enable-usbhost-api], [Request to deviced to obtain dev node fds [default=no]])],
 112                 [], [enable_usbhost_api="no"])
 113         if test "x$enable_usbhost_api" = "xyes"; then
 114            PKG_CHECK_MODULES([USBHOST_API], [dbus-1])
 115            AC_DEFINE(USE_USBHOST_API, 1, [Request to deviced to obtain dev node fds])
 116         fi
 117
 118         AC_SUBST(USE_USBHOST_API)
 119
 120         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 121         AC_ARG_ENABLE([udev],
 122                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 123                 [], [enable_udev="yes"])
 124                 if test "x$enable_udev" = "xyes" ; then
 125                         # system has udev. use it or fail!
 126                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 127                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 128                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 129                 else
 130                         AC_CHECK_HEADERS([asm/types.h], [], [])
 131                         AC_CHECK_HEADERS([sys/socket.h linux/netlink.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 132 #ifdef HAVE_ASM_TYPES_H
 133 #include <asm/types.h>
 134 #endif
 135 #include <sys/socket.h>
 136 ])
 137                 fi
 138                 AC_SUBST(USE_UDEV)
 139
 140 case $is_backend_android in
 141 yes)
 142         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 143         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 144         ;;
 145 *)
 146         THREAD_CFLAGS="-pthread"
 147         LIBS="${LIBS} -pthread"
 148 esac
 149
 150         AC_CHECK_HEADERS([poll.h])
 151         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 152         ;;
 153 darwin)
 154         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 155         AC_SUBST(OS_DARWIN)
 156         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 157         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 158         AC_CHECK_HEADERS([poll.h])
 159         AC_CHECK_TYPE([nfds_t],
 160                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 161                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 162                 [#include <poll.h>])
 163         ;;
 164 openbsd)
 165         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 166         AC_SUBST(OS_OPENBSD)
 167         THREAD_CFLAGS="-pthread"
 168         LIBS="-pthread"
 169         AC_CHECK_HEADERS([poll.h])
 170         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 171         ;;
 172 sunos)
 173         AC_DEFINE(OS_SUNOS, 1, [SunOS backend])
 174         AC_SUBST(OS_SUNOS)
 175         THREAD_CFLAGS="-pthread"
 176         LIBS="-pthread -ldevinfo"
 177         AC_CHECK_HEADERS([poll.h])
 178         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 179         ;;
 180 netbsd)
 181         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 182         AC_SUBST(OS_NETBSD)
 183         THREAD_CFLAGS="-pthread"
 184         LIBS="-pthread"
 185         AC_CHECK_HEADERS([poll.h])
 186         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 187         ;;
 188 windows)
 189         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 190         AC_SUBST(OS_WINDOWS)
 191         LIBS=""
 192         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 193         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 194         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 195
 196         AC_ARG_ENABLE([usbdk],
 197                 [AC_HELP_STRING([--enable-usbdk], [use UsbDk Windows backend [default=no]])],
 198                 [], [enable_usbdk="no"])
 199                 if test "x$enable_usbdk" = "xyes" ; then
 200                     AC_DEFINE(USE_USBDK, 1, [Use UsbDk Windows backend])
 201                 fi
 202                 AC_SUBST(USE_USBDK)
 203         ;;
 204 haiku)
 205         AC_DEFINE(OS_HAIKU, 1, [Haiku backend])
 206         AC_SUBST(OS_HAIKU)
 207         LIBS="${LIBS} -lbe"
 208         AC_CHECK_HEADERS([poll.h])
 209         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 210         ;;
 211 esac
 212
 213 AC_SUBST(LIBS)
 214
 215 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 216 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 217 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 218 AM_CONDITIONAL(OS_SUNOS, test "x$backend" = xsunos)
 219 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 220 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 221 AM_CONDITIONAL(OS_HAIKU, test "x$backend" = xhaiku)
 222 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 223 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 224 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 225 AM_CONDITIONAL(USE_USBDK, test "x$enable_usbdk" = xyes)
 226 AM_CONDITIONAL(USE_USBHOST_API, test "x$enable_usbhost_api" = xyes)
 227 if test "$threads" = posix; then
 228         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 229 fi
 230
 231 # timerfd
 232 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 233 AC_ARG_ENABLE([timerfd],
 234         [AS_HELP_STRING([--enable-timerfd],
 235                 [use timerfd for timing [default=auto]])],
 236         [use_timerfd=$enableval], [use_timerfd='auto'])
 237
 238 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 239         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 240 fi
 241
 242 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 243 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 244         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 245 fi
 246
 247 AC_MSG_CHECKING([whether to use timerfd for timing])
 248 if test "x$use_timerfd" = "xno"; then
 249         AC_MSG_RESULT([no (disabled by user)])
 250 else
 251         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 252                 AC_MSG_RESULT([yes])
 253                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 254         else
 255                 AC_MSG_RESULT([no (header not available)])
 256         fi
 257 fi
 258
 259 AC_CHECK_TYPES(struct timespec)
 260
 261 # Message logging
 262 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 263         [log_enabled=$enableval],
 264         [log_enabled='yes'])
 265 if test "x$log_enabled" != "xno"; then
 266         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 267 fi
 268
 269 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 270         [start with debug message logging enabled [default=no]])],
 271         [debug_log_enabled=$enableval],
 272         [debug_log_enabled='no'])
 273 if test "x$debug_log_enabled" != "xno"; then
 274         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 275 fi
 276
 277 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 278         [output logging messages to system wide log, if supported by the OS [default=no]])],
 279         [system_log_enabled=$enableval],
 280         [system_log_enabled='no'])
 281 if test "x$system_log_enabled" != "xno"; then
 282         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 283 fi
 284
 285 # Check if syslog is available in standard C library
 286 AC_CHECK_HEADERS(syslog.h)
 287 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 288 if test "x$have_syslog" != "xno"; then
 289         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 290 fi
 291
 292 # Examples build
 293 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 294         [build example applications [default=no]])],
 295         [build_examples=$enableval],
 296         [build_examples='no'])
 297 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 298
 299 # Tests build
 300 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 301         [build test applications [default=no]])],
 302         [build_tests=$enableval],
 303         [build_tests='no'])
 304 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 305
 306 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 307 saved_cflags="$CFLAGS"
 308 # -Werror required for cygwin
 309 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 310 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 311         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 312          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 313         [ VISIBILITY_CFLAGS=""
 314          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 315         ])
 316 CFLAGS="$saved_cflags"
 317
 318 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 319 saved_cflags="$CFLAGS"
 320 CFLAGS="$CFLAGS -Wno-pointer-sign"
 321 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 322         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 323 CFLAGS="$saved_cflags"
 324
 325 # sigaction not available on MinGW
 326 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 327 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 328
 329 # headers not available on all platforms but required on others
 330 AC_CHECK_HEADERS([sys/time.h])
 331 AC_CHECK_FUNCS(gettimeofday)
 332 AC_CHECK_HEADERS([signal.h])
 333
 334 # check for -std=gnu99 compiler support
 335 saved_cflags="$CFLAGS"
 336 CFLAGS="-std=gnu99"
 337 AC_MSG_CHECKING([whether CC supports -std=gnu99])
 338 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 339     [AC_MSG_RESULT([yes])]
 340     [AM_CFLAGS="${AM_CFLAGS} -std=gnu99"],
 341     [AC_MSG_RESULT([no])]
 342 )
 343 CFLAGS="$saved_cflags"
 344
 345 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 346
 347 AC_SUBST(AM_CFLAGS)
 348 AC_SUBST(LTLDFLAGS)
 349
 350 AC_CONFIG_FILES([libusb-1.0.pc])
 351 AC_CONFIG_FILES([Makefile])
 352 AC_CONFIG_FILES([libusb/Makefile])
 353 AC_CONFIG_FILES([examples/Makefile])
 354 AC_CONFIG_FILES([tests/Makefile])
 355 AC_CONFIG_FILES([doc/Makefile])
 356 AC_CONFIG_FILES([doc/doxygen.cfg])
 357 AC_OUTPUT