gnulib-m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 35
   2 dnl Copyright (C) 2007-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([_Noreturn],
  16 [/* The _Noreturn keyword of C11.  */
  17 #if ! (defined _Noreturn \
  18        || (defined __STDC_VERSION__ && 201112 <= __STDC_VERSION__))
  19 # if (3 <= __GNUC__ || (__GNUC__ == 2 && 8 <= __GNUC_MINOR__) \
  20       || 0x5110 <= __SUNPRO_C)
  21 #  define _Noreturn __attribute__ ((__noreturn__))
  22 # elif defined _MSC_VER && 1200 <= _MSC_VER
  23 #  define _Noreturn __declspec (noreturn)
  24 # else
  25 #  define _Noreturn
  26 # endif
  27 #endif
  28 ])
  29   AH_VERBATIM([isoc99_inline],
  30 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  31    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  32    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  33    __APPLE__ && __MACH__ test for Mac OS X.
  34    __APPLE_CC__ tests for the Apple compiler and its version.
  35    __STDC_VERSION__ tests for the C99 mode.  */
  36 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  37 # define __GNUC_STDC_INLINE__ 1
  38 #endif])
  39   AH_VERBATIM([unused_parameter],
  40 [/* Define as a marker that can be attached to declarations that might not
  41     be used.  This helps to reduce warnings, such as from
  42     GCC -Wunused-parameter.  */
  43 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  44 # define _GL_UNUSED __attribute__ ((__unused__))
  45 #else
  46 # define _GL_UNUSED
  47 #endif
  48 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  49    is a misnomer outside of parameter lists.  */
  50 #define _UNUSED_PARAMETER_ _GL_UNUSED
  51
  52 /* gcc supports the "unused" attribute on possibly unused labels, and
  53    g++ has since version 4.5.  Note to support C++ as well as C,
  54    _GL_UNUSED_LABEL should be used with a trailing ;  */
  55 #if !defined __cplusplus || __GNUC__ > 4 \
  56     || (__GNUC__ == 4 && __GNUC_MINOR__ >= 5)
  57 # define _GL_UNUSED_LABEL _GL_UNUSED
  58 #else
  59 # define _GL_UNUSED_LABEL
  60 #endif
  61
  62 /* The __pure__ attribute was added in gcc 2.96.  */
  63 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
  64 # define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
  65 #else
  66 # define _GL_ATTRIBUTE_PURE /* empty */
  67 #endif
  68
  69 /* The __const__ attribute was added in gcc 2.95.  */
  70 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
  71 # define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
  72 #else
  73 # define _GL_ATTRIBUTE_CONST /* empty */
  74 #endif
  75 ])
  76   dnl Preparation for running test programs:
  77   dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
  78   dnl to /dev/tty, so they can be redirected to log files.  Such diagnostics
  79   dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
  80   LIBC_FATAL_STDERR_=1
  81   export LIBC_FATAL_STDERR_
  82 ])
  83
  84 # gl_MODULE_INDICATOR_CONDITION
  85 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  86 # whether a gnulib module that has been requested shall be considered present
  87 # or not.
  88 m4_define([gl_MODULE_INDICATOR_CONDITION], [1])
  89
  90 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  91 # sets the shell variable that indicates the presence of the given module to
  92 # a C preprocessor expression that will evaluate to 1.
  93 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  94 [
  95   gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
  96     [GNULIB_[]m4_translit([[$1]],
  97                           [abcdefghijklmnopqrstuvwxyz./-],
  98                           [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
  99     [gl_MODULE_INDICATOR_CONDITION])
 100 ])
 101
 102 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
 103 # modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
 104 # The shell variable's value is a C preprocessor expression that evaluates
 105 # to 0 or 1.
 106 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
 107 [
 108   m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
 109     [
 110      dnl Simplify the expression VALUE || 1 to 1.
 111      $1=1
 112     ],
 113     [gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
 114                                              [gl_MODULE_INDICATOR_CONDITION])])
 115 ])
 116
 117 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
 118 # modifies the shell variable to include the given condition.  The shell
 119 # variable's value is a C preprocessor expression that evaluates to 0 or 1.
 120 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
 121 [
 122   dnl Simplify the expression 1 || CONDITION to 1.
 123   if test "$[]$1" != 1; then
 124     dnl Simplify the expression 0 || CONDITION to CONDITION.
 125     if test "$[]$1" = 0; then
 126       $1=$2
 127     else
 128       $1="($[]$1 || $2)"
 129     fi
 130   fi
 131 ])
 132
 133 # gl_MODULE_INDICATOR([modulename])
 134 # defines a C macro indicating the presence of the given module
 135 # in a location where it can be used.
 136 #                                             |  Value  |   Value   |
 137 #                                             | in lib/ | in tests/ |
 138 # --------------------------------------------+---------+-----------+
 139 # Module present among main modules:          |    1    |     1     |
 140 # --------------------------------------------+---------+-----------+
 141 # Module present among tests-related modules: |    0    |     1     |
 142 # --------------------------------------------+---------+-----------+
 143 # Module not present at all:                  |    0    |     0     |
 144 # --------------------------------------------+---------+-----------+
 145 AC_DEFUN([gl_MODULE_INDICATOR],
 146 [
 147   AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
 148       [abcdefghijklmnopqrstuvwxyz./-],
 149       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
 150     [gl_MODULE_INDICATOR_CONDITION],
 151     [Define to a C preprocessor expression that evaluates to 1 or 0,
 152      depending whether the gnulib module $1 shall be considered present.])
 153 ])
 154
 155 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
 156 # defines a C macro indicating the presence of the given module
 157 # in lib or tests. This is useful to determine whether the module
 158 # should be tested.
 159 #                                             |  Value  |   Value   |
 160 #                                             | in lib/ | in tests/ |
 161 # --------------------------------------------+---------+-----------+
 162 # Module present among main modules:          |    1    |     1     |
 163 # --------------------------------------------+---------+-----------+
 164 # Module present among tests-related modules: |    1    |     1     |
 165 # --------------------------------------------+---------+-----------+
 166 # Module not present at all:                  |    0    |     0     |
 167 # --------------------------------------------+---------+-----------+
 168 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
 169 [
 170   AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
 171       [abcdefghijklmnopqrstuvwxyz./-],
 172       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
 173     [Define to 1 when the gnulib module $1 should be tested.])
 174 ])
 175
 176 # gl_ASSERT_NO_GNULIB_POSIXCHECK
 177 # asserts that there will never be a need to #define GNULIB_POSIXCHECK.
 178 # and thereby enables an optimization of configure and config.h.
 179 # Used by Emacs.
 180 AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
 181 [
 182   dnl Override gl_WARN_ON_USE_PREPARE.
 183   dnl But hide this definition from 'aclocal'.
 184   AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
 185 ])
 186
 187 # gl_ASSERT_NO_GNULIB_TESTS
 188 # asserts that there will be no gnulib tests in the scope of the configure.ac
 189 # and thereby enables an optimization of config.h.
 190 # Used by Emacs.
 191 AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
 192 [
 193   dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
 194   AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
 195 ])
 196
 197 # Test whether <features.h> exists.
 198 # Set HAVE_FEATURES_H.
 199 AC_DEFUN([gl_FEATURES_H],
 200 [
 201   AC_CHECK_HEADERS_ONCE([features.h])
 202   if test $ac_cv_header_features_h = yes; then
 203     HAVE_FEATURES_H=1
 204   else
 205     HAVE_FEATURES_H=0
 206   fi
 207   AC_SUBST([HAVE_FEATURES_H])
 208 ])
 209
 210 # m4_foreach_w
 211 # is a backport of autoconf-2.59c's m4_foreach_w.
 212 # Remove this macro when we can assume autoconf >= 2.60.
 213 m4_ifndef([m4_foreach_w],
 214   [m4_define([m4_foreach_w],
 215     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
 216
 217 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 218 # ----------------------------------------------------
 219 # Backport of autoconf-2.63b's macro.
 220 # Remove this macro when we can assume autoconf >= 2.64.
 221 m4_ifndef([AS_VAR_IF],
 222 [m4_define([AS_VAR_IF],
 223 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 224
 225 # gl_PROG_CC_C99
 226 # Modifies the value of the shell variable CC in an attempt to make $CC
 227 # understand ISO C99 source code.
 228 # This is like AC_PROG_CC_C99, except that
 229 # - AC_PROG_CC_C99 did not exist in Autoconf versions < 2.60,
 230 # - AC_PROG_CC_C99 does not mix well with AC_PROG_CC_STDC
 231 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00367.html>,
 232 #   but many more packages use AC_PROG_CC_STDC than AC_PROG_CC_C99
 233 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00441.html>.
 234 # Remaining problems:
 235 # - When AC_PROG_CC_STDC is invoked twice, it adds the C99 enabling options
 236 #   to CC twice
 237 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00431.html>.
 238 # - AC_PROG_CC_STDC is likely to change now that C11 is an ISO standard.
 239 AC_DEFUN([gl_PROG_CC_C99],
 240 [
 241   dnl Change that version number to the minimum Autoconf version that supports
 242   dnl mixing AC_PROG_CC_C99 calls with AC_PROG_CC_STDC calls.
 243   m4_version_prereq([9.0],
 244     [AC_REQUIRE([AC_PROG_CC_C99])],
 245     [AC_REQUIRE([AC_PROG_CC_STDC])])
 246 ])
 247
 248 # gl_PROG_AR_RANLIB
 249 # Determines the values for AR, ARFLAGS, RANLIB that fit with the compiler.
 250 # The user can set the variables AR, ARFLAGS, RANLIB if he wants to override
 251 # the values.
 252 AC_DEFUN([gl_PROG_AR_RANLIB],
 253 [
 254   dnl Minix 3 comes with two toolchains: The Amsterdam Compiler Kit compiler
 255   dnl as "cc", and GCC as "gcc". They have different object file formats and
 256   dnl library formats. In particular, the GNU binutils programs ar, ranlib
 257   dnl produce libraries that work only with gcc, not with cc.
 258   AC_REQUIRE([AC_PROG_CC])
 259   AC_CACHE_CHECK([for Minix Amsterdam compiler], [gl_cv_c_amsterdam_compiler],
 260     [
 261       AC_EGREP_CPP([Amsterdam],
 262         [
 263 #ifdef __ACK__
 264 Amsterdam
 265 #endif
 266         ],
 267         [gl_cv_c_amsterdam_compiler=yes],
 268         [gl_cv_c_amsterdam_compiler=no])
 269     ])
 270   if test -z "$AR"; then
 271     if test $gl_cv_c_amsterdam_compiler = yes; then
 272       AR='cc -c.a'
 273       if test -z "$ARFLAGS"; then
 274         ARFLAGS='-o'
 275       fi
 276     else
 277       dnl Use the Automake-documented default values for AR and ARFLAGS,
 278       dnl but prefer ${host}-ar over ar (useful for cross-compiling).
 279       AC_CHECK_TOOL([AR], [ar], [ar])
 280       if test -z "$ARFLAGS"; then
 281         ARFLAGS='cru'
 282       fi
 283     fi
 284   else
 285     if test -z "$ARFLAGS"; then
 286       ARFLAGS='cru'
 287     fi
 288   fi
 289   AC_SUBST([AR])
 290   AC_SUBST([ARFLAGS])
 291   if test -z "$RANLIB"; then
 292     if test $gl_cv_c_amsterdam_compiler = yes; then
 293       RANLIB=':'
 294     else
 295       dnl Use the ranlib program if it is available.
 296       AC_PROG_RANLIB
 297     fi
 298   fi
 299   AC_SUBST([RANLIB])
 300 ])
 301
 302 # AC_PROG_MKDIR_P
 303 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 304 # for interoperability with automake-1.9.6 from autoconf-2.62.
 305 # Remove this macro when we can assume autoconf >= 2.62 or
 306 # autoconf >= 2.60 && automake >= 1.10.
 307 # AC_AUTOCONF_VERSION was introduced in 2.62, so use that as the witness.
 308 m4_ifndef([AC_AUTOCONF_VERSION],[
 309 m4_ifdef([AC_PROG_MKDIR_P], [
 310   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 311   m4_define([AC_PROG_MKDIR_P],
 312     m4_defn([AC_PROG_MKDIR_P])[
 313     AC_SUBST([MKDIR_P])])], [
 314   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 315   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 316     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 317      MKDIR_P='$(mkdir_p)'
 318      AC_SUBST([MKDIR_P])])])
 319 ])
 320
 321 # AC_C_RESTRICT
 322 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 323 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 324 # works.
 325 # This definition can be removed once autoconf >= 2.62 can be assumed.
 326 # AC_AUTOCONF_VERSION was introduced in 2.62, so use that as the witness.
 327 m4_ifndef([AC_AUTOCONF_VERSION],[
 328 AC_DEFUN([AC_C_RESTRICT],
 329 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 330   [ac_cv_c_restrict=no
 331    # The order here caters to the fact that C++ does not require restrict.
 332    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 333      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 334       [[typedef int * int_ptr;
 335         int foo (int_ptr $ac_kw ip) {
 336         return ip[0];
 337        }]],
 338       [[int s[1];
 339         int * $ac_kw t = s;
 340         t[0] = 0;
 341         return foo(t)]])],
 342       [ac_cv_c_restrict=$ac_kw])
 343      test "$ac_cv_c_restrict" != no && break
 344    done
 345   ])
 346  AH_VERBATIM([restrict],
 347 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 348    nothing if this is not supported.  Do not define if restrict is
 349    supported directly.  */
 350 #undef restrict
 351 /* Work around a bug in Sun C++: it does not support _Restrict, even
 352    though the corresponding Sun C compiler does, which causes
 353    "#define restrict _Restrict" in the previous line.  Perhaps some future
 354    version of Sun C++ will work with _Restrict; if so, it'll probably
 355    define __RESTRICT, just as Sun C does.  */
 356 #if defined __SUNPRO_CC && !defined __RESTRICT
 357 # define _Restrict
 358 #endif])
 359  case $ac_cv_c_restrict in
 360    restrict) ;;
 361    no) AC_DEFINE([restrict], []) ;;
 362    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 363  esac
 364 ])
 365 ])
 366
 367 # gl_BIGENDIAN
 368 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 369 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 370 # macros invoke AC_C_BIGENDIAN with arguments.
 371 AC_DEFUN([gl_BIGENDIAN],
 372 [
 373   AC_C_BIGENDIAN
 374 ])
 375
 376 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 377 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 378 # output a spurious "(cached)" mark in the midst of other configure output.
 379 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 380 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 381 AC_DEFUN([gl_CACHE_VAL_SILENT],
 382 [
 383   saved_as_echo_n="$as_echo_n"
 384   as_echo_n=':'
 385   AC_CACHE_VAL([$1], [$2])
 386   as_echo_n="$saved_as_echo_n"
 387 ])
 388
 389 # AS_VAR_COPY was added in autoconf 2.63b
 390 m4_define_default([AS_VAR_COPY],
 391 [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 392
 393 # AC_PROG_SED was added in autoconf 2.59b
 394 m4_ifndef([AC_PROG_SED],
 395 [AC_DEFUN([AC_PROG_SED],
 396 [AC_CACHE_CHECK([for a sed that does not truncate output], ac_cv_path_SED,
 397     [dnl ac_script should not contain more than 99 commands (for HP-UX sed),
 398      dnl but more than about 7000 bytes, to catch a limit in Solaris 8 /usr/ucb/sed.
 399      ac_script=s/aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa/bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb/
 400      for ac_i in 1 2 3 4 5 6 7; do
 401        ac_script="$ac_script$as_nl$ac_script"
 402      done
 403      echo "$ac_script" 2>/dev/null | sed 99q >conftest.sed
 404      AS_UNSET([ac_script])
 405      if test -z "$SED"; then
 406        ac_path_SED_found=false
 407        _AS_PATH_WALK([], [
 408          for ac_prog in sed gsed; do
 409            for ac_exec_ext in '' $ac_executable_extensions; do
 410              ac_path_SED="$as_dir/$ac_prog$ac_exec_ext"
 411              AS_EXECUTABLE_P(["$ac_path_SED"]) || continue
 412              case `"$ac_path_SED" --version 2>&1` in
 413                *GNU*) ac_cv_path_SED=$ac_path_SED ac_path_SED_found=:;;
 414                *)
 415                  ac_count=0
 416                  _AS_ECHO_N([0123456789]) >conftest.in
 417                  while :
 418                  do
 419                    cat conftest.in conftest.in >conftest.tmp
 420                    mv conftest.tmp conftest.in
 421                    cp conftest.in conftest.nl
 422                    echo >> conftest.nl
 423                    "$ac_path_SED" -f conftest.sed <conftest.nl >conftest.out 2>/dev/null || break
 424                    diff conftest.out conftest.nl >/dev/null 2>&1 || break
 425                    ac_count=`expr $ac_count + 1`
 426                    if test $ac_count -gt ${ac_path_SED_max-0}; then
 427                      # Best so far, but keep looking for better
 428                      ac_cv_path_SED=$ac_path_SED
 429                      ac_path_SED_max=$ac_count
 430                    fi
 431                    test $ac_count -gt 10 && break
 432                  done
 433                  rm -f conftest.in conftest.tmp conftest.nl conftest.out;;
 434              esac
 435              $ac_path_SED_found && break 3
 436            done
 437          done])
 438        if test -z "$ac_cv_path_SED"; then
 439          AC_ERROR([no acceptable sed could be found in \$PATH])
 440        fi
 441      else
 442        ac_cv_path_SED=$SED
 443      fi
 444  SED="$ac_cv_path_SED"
 445  AC_SUBST([SED])dnl
 446  rm -f conftest.sed
 447 ])])])