bindings/python/CMakeLists.txt

   1 IF (ENABLE_PYTHON3 AND NOT DEFINED PythonLibs_FIND_VERSION)
   2     # if we build both for python2 and python3, make this the python2 build.
   3     # see comment in the python3 CMakeLists.txt file
   4     SET (PythonLibs_FIND_VERSION 2)
   5     SET (PythonLibs_FIND_VERSION_MAJOR 2)
   6 ENDIF (ENABLE_PYTHON3 AND NOT DEFINED PythonLibs_FIND_VERSION)
   7
   8 FIND_PACKAGE (PythonLibs REQUIRED)
   9 IF(PYTHONLIBS_VERSION_STRING MATCHES "^([0-9.]+)")
  10     SET(python_version "${CMAKE_MATCH_1}")
  11 ELSE()
  12     MESSAGE(FATAL_ERROR "PythonLibs version format unknown '${PYTHONLIBS_VERSION_STRING}'")
  13 ENDIF()
  14 FIND_PACKAGE (PythonInterp ${python_version} REQUIRED)
  15
  16 EXECUTE_PROCESS(COMMAND ${PYTHON_EXECUTABLE} -c "from sys import stdout; from distutils import sysconfig; stdout.write(sysconfig.get_python_lib(True))" OUTPUT_VARIABLE PYTHON_INSTALL_DIR)
  17
  18 IF (NOT DEFINED PYTHON_VERSION_MAJOR)
  19     SET (PYTHON_VERSION_MAJOR 2)
  20 ENDIF (NOT DEFINED PYTHON_VERSION_MAJOR)
  21 IF (${PYTHON_VERSION_MAJOR} GREATER 2)
  22     SET (SWIG_PY_FLAGS -DPYTHON3=1)
  23 ENDIF (${PYTHON_VERSION_MAJOR} GREATER 2)
  24 SET (SWIG_PY_FLAGS ${SWIG_PY_FLAGS} -DSWIG_PYTHON_LEGACY_BOOL=1)
  25
  26 MESSAGE (STATUS "Python executable: ${PYTHON_EXECUTABLE}")
  27 MESSAGE (STATUS "Python installation dir: ${PYTHON_INSTALL_DIR}")
  28 MESSAGE (STATUS "Python include path: ${PYTHON_INCLUDE_PATH}")
  29
  30 ADD_CUSTOM_COMMAND (
  31     OUTPUT solv_python.c
  32     COMMAND ${SWIG_EXECUTABLE} ${SWIG_FLAGS} -python ${SWIG_PY_FLAGS} -I${CMAKE_SOURCE_DIR}/src -o solv_python.c ${CMAKE_SOURCE_DIR}/bindings/solv.i
  33     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  34     DEPENDS ${CMAKE_SOURCE_DIR}/bindings/solv.i
  35 )
  36
  37 ADD_DEFINITIONS(-Wno-unused)
  38 INCLUDE_DIRECTORIES (${PYTHON_INCLUDE_PATH})
  39
  40 ADD_LIBRARY (bindings_python MODULE solv_python.c)
  41 SET_TARGET_PROPERTIES (bindings_python PROPERTIES PREFIX "" OUTPUT_NAME "_solv")
  42 TARGET_LINK_LIBRARIES (bindings_python libsolvext libsolv ${SYSTEM_LIBRARIES})
  43
  44 INSTALL (TARGETS bindings_python LIBRARY DESTINATION ${PYTHON_INSTALL_DIR})
  45 INSTALL (FILES ${CMAKE_CURRENT_BINARY_DIR}/solv.py DESTINATION ${PYTHON_INSTALL_DIR})
  46