CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_RPMDB_PUBKEY "Build with rpmdb pubkey support?" OFF)
  16 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  17 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  18 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  19 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  20 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  21 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  22
  23 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  24
  25 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  26 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  27
  28 IF (COMMAND cmake_policy)
  29   # escape preprocessor, see -DVERSION below
  30   CMAKE_POLICY (SET CMP0005 OLD)
  31 ENDIF (COMMAND cmake_policy)
  32
  33 # Library
  34 IF (DEFINED LIB)
  35   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  36 ELSE (DEFINED  LIB)
  37   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  38     SET (LIB_SUFFIX "64")
  39   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  40   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  41 ENDIF (DEFINED  LIB)
  42 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  43 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  44
  45 ####################################################################
  46 # CONFIGURATION                                                    #
  47 ####################################################################
  48
  49 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  50 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  51 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  52
  53 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  54
  55 FIND_PACKAGE (EXPAT REQUIRED)
  56 FIND_PACKAGE (ZLIB REQUIRED)
  57
  58 IF (FEDORA)
  59 MESSAGE(STATUS "Building for Fedora")
  60 ADD_DEFINITIONS (-DFEDORA)
  61 SET (ENABLE_RPMDB ON)
  62 SET (ENABLE_RPMMD ON)
  63 ENDIF (FEDORA)
  64
  65 IF (DEBIAN)
  66 MESSAGE (STATUS "Building for Debian")
  67 ADD_DEFINITIONS (-DDEBIAN -DDEBIAN_SEMANTICS)
  68 SET (ENABLE_DEBIAN ON)
  69 ENDIF (DEBIAN)
  70
  71 IF (RPM5)
  72 MESSAGE (STATUS "Enabling RPM 5 support")
  73 ADD_DEFINITIONS (-DRPM5)
  74 SET (ENABLE_RPMDB ON)
  75 SET (ENABLE_RPMMD ON)
  76 FIND_PACKAGE (PkgConfig REQUIRED)
  77 PKG_CHECK_MODULES (RPM REQUIRED rpm)
  78 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
  79 ENDIF (RPM5)
  80
  81 IF (MULTI_SEMANTICS)
  82 MESSAGE (STATUS "Enabling multi dist support")
  83 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
  84 ENDIF (MULTI_SEMANTICS)
  85
  86 # compat: enable some database types
  87 IF (NOT ENABLE_RPMDB AND
  88     NOT ENABLE_RPMMD AND
  89     NOT ENABLE_SUSEREPO AND
  90     NOT ENABLE_HELIXREPO AND
  91     NOT ENABLE_MDKREPO AND
  92     NOT ENABLE_DEBIAN)
  93     SET (ENABLE_RPMDB ON)
  94     SET (ENABLE_RPMDB_PUBKEY ON)
  95     SET (ENABLE_RPMMD ON)
  96     SET (ENABLE_SUSEREPO ON)
  97     SET (ENABLE_HELIXREPO ON)
  98     SET (ENABLE_DEBIAN ON)
  99 ENDIF ()
 100
 101 IF (ENABLE_RPMDB)
 102   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 103
 104   IF (NOT RPMDB_LIBRARY)
 105     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 106   ENDIF (NOT RPMDB_LIBRARY)
 107
 108   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 109   IF (RPMIO_LIBRARY)
 110     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 111   ENDIF (RPMIO_LIBRARY)
 112
 113   IF (RPM5)
 114     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 115     IF (RPMMISC_LIBRARY)
 116       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 117     ENDIF (RPMMISC_LIBRARY)
 118   ENDIF (RPM5)
 119
 120   IF (RPM5 OR FEDORA)
 121     FIND_LIBRARY (DB_LIBRARY NAMES db)
 122     IF (DB_LIBRARY)
 123       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 124     ENDIF (DB_LIBRARY)
 125   ENDIF (RPM5 OR FEDORA)
 126 ENDIF (ENABLE_RPMDB)
 127
 128 INCLUDE (CheckFunctionExists)
 129 INCLUDE (TestBigEndian)
 130
 131 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 132 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 133 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 134 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 135
 136 # should create config.h with #cmakedefine instead...
 137 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 138   ENABLE_RPMDB ENABLE_RPMDB_PUBKEY ENABLE_RPMMD ENABLE_SUSEREPO ENABLE_COMPS
 139   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_DEBIAN ENABLE_LZMA_COMPRESSION)
 140   IF(${VAR})
 141     ADD_DEFINITIONS (-D${VAR}=1)
 142     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 143   ENDIF (${VAR})
 144 ENDFOREACH (VAR)
 145
 146 SET (PACKAGE "libsolv")
 147 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 148
 149 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 150 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 151 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 152
 153 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 154 SET (CPACK_PACKAGE_VENDOR "SUSE")
 155 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 156 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 157 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 158 SET (CPACK_GENERATOR "TBZ2")
 159 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 160 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 161 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 162 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 163
 164 # The following components are regex's to match anywhere (unless anchored)
 165 # in absolute path + filename to find files or directories to be excluded
 166 # from source tarball.
 167 SET (CPACK_SOURCE_IGNORE_FILES
 168 # temporary files
 169 "\\\\.swp$"
 170 # backup files
 171 "~$"
 172 # eclipse files
 173 "\\\\.cdtproject$"
 174 "\\\\.cproject$"
 175 "\\\\.project$"
 176 "\\\\.settings/"
 177 # others
 178 "\\\\.#"
 179 "/#"
 180 "/build/"
 181 "/_build/"
 182 "/\\\\.git/"
 183 # used before
 184 "/\\\\.libs/"
 185 "/\\\\.deps/"
 186 "\\\\.o$"
 187 "\\\\.lo$"
 188 "\\\\.la$"
 189 "Makefile$"
 190 "Makefile\\\\.in$"
 191 # cmake cache files
 192 "DartConfiguration.tcl$"
 193 "CMakeCache.txt"
 194 "CMakeFiles"
 195 "cmake_install.cmake$"
 196 "CMakeLists.txt.auto$"
 197 "CTestTestfile.cmake"
 198 "CPackConfig.cmake$"
 199 "CPackSourceConfig.cmake$"
 200 "libsolv.spec$"
 201 )
 202
 203 INCLUDE(CPack)
 204
 205 ####################################################################
 206 # INCLUDES                                                         #
 207 ####################################################################
 208
 209 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 210 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 211
 212 ####################################################################
 213
 214 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 215
 216 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall -Wl,--as-needed")
 217 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 218 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 219 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 220
 221 ADD_SUBDIRECTORY (src)
 222 ADD_SUBDIRECTORY (ext)
 223 ADD_SUBDIRECTORY (tools)
 224 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 225     ADD_SUBDIRECTORY (bindings)
 226 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 227 ADD_SUBDIRECTORY (examples)
 228
 229 MESSAGE (STATUS "Version: ${VERSION}")
 230
 231 ####################################################################
 232 # RPM SPEC                                                         #
 233 ####################################################################
 234
 235 MACRO (SPECFILE)
 236   MESSAGE (STATUS "Writing spec file...")
 237   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 238 ENDMACRO (SPECFILE)
 239
 240 SPECFILE ()
 241
 242 SET (AUTOBUILD_COMMAND
 243   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 244   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 245   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 246   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 247   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 248   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 249 )
 250
 251 ADD_CUSTOM_TARGET (srcpackage
 252   ${AUTOBUILD_COMMAND}
 253 )
 254
 255 ADD_CUSTOM_TARGET (srcpackage_local
 256   ${AUTOBUILD_COMMAND}
 257 )
 258
 259 ENABLE_TESTING()
 260 ADD_SUBDIRECTORY (test)