CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  16 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  17 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  18 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  19 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  20 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  21 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  22 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  23 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  24 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  25 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  26 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  27
  28 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  29 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  30
  31 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  32 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  33
  34 IF (COMMAND cmake_policy)
  35   # escape preprocessor, see -DVERSION below
  36   CMAKE_POLICY (SET CMP0005 OLD)
  37 ENDIF (COMMAND cmake_policy)
  38
  39 # Library
  40 IF (DEFINED LIB)
  41   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  42 ELSE (DEFINED  LIB)
  43   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  44     SET (LIB_SUFFIX "64")
  45   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  46   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  47 ENDIF (DEFINED  LIB)
  48 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  49 # Library
  50 IF (DEFINED INCLUDE)
  51   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  52 else (DEFINED INCLUDE)
  53   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  54 ENDIF (DEFINED  INCLUDE)
  55 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  56 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  57 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  58 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  59   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  60 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  61 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  62
  63 ####################################################################
  64 # CONFIGURATION                                                    #
  65 ####################################################################
  66
  67 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  68 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  69 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  70
  71 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  72
  73 SET (have_system x)
  74
  75 IF (FEDORA)
  76 MESSAGE(STATUS "Building for Fedora")
  77 ADD_DEFINITIONS (-DFEDORA)
  78 SET (ENABLE_RPMDB ON)
  79 SET (ENABLE_RPMMD ON)
  80 SET (have_system ${have_system}x)
  81 ENDIF (FEDORA)
  82
  83 IF (DEBIAN)
  84 MESSAGE (STATUS "Building for Debian")
  85 ADD_DEFINITIONS (-DDEBIAN)
  86 SET (ENABLE_DEBIAN ON)
  87 SET (have_system ${have_system}x)
  88 ENDIF (DEBIAN)
  89
  90 IF (SUSE)
  91 MESSAGE (STATUS "Building for SUSE")
  92 ADD_DEFINITIONS (-DSUSE)
  93 SET (ENABLE_RPMDB ON)
  94 SET (ENABLE_PUBKEY ON)
  95 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  96 SET (ENABLE_RPMMD ON)
  97 SET (ENABLE_SUSEREPO ON)
  98 SET (ENABLE_HELIXREPO ON)
  99 SET (ENABLE_LINKED_PKGS ON)
 100 SET (have_system ${have_system}x)
 101 ENDIF (SUSE)
 102
 103 IF (ARCHLINUX)
 104 MESSAGE (STATUS "Building for Archlinux")
 105 ADD_DEFINITIONS (-DARCHLINUX)
 106 SET (ENABLE_ARCHREPO ON)
 107 SET (have_system ${have_system}x)
 108 ENDIF (ARCHLINUX)
 109
 110 IF (MANDRIVA)
 111 MESSAGE (STATUS "Building for Mandriva/Mageia")
 112 ADD_DEFINITIONS (-DMANDRIVA)
 113 SET (ENABLE_MDKREPO ON)
 114 SET (ENABLE_RPMDB ON)
 115 SET (have_system ${have_system}x)
 116 ENDIF (MANDRIVA)
 117
 118 IF (HAIKU)
 119 MESSAGE(STATUS "Building for Haiku")
 120 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 121 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 122 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 123 SET (HAIKU_SYSTEM_LIBRARIES
 124     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 125 ADD_DEFINITIONS (-DHAIKU)
 126 SET (ENABLE_HAIKU ON)
 127 SET (have_system ${have_system}x)
 128 ENDIF (HAIKU)
 129
 130 IF (${have_system} STREQUAL x)
 131     MESSAGE (STATUS "Building for no system")
 132 ENDIF (${have_system} STREQUAL x)
 133 IF (${have_system} STRGREATER xx)
 134     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 135 ENDIF (${have_system} STRGREATER xx)
 136
 137 IF (ENABLE_ARCHREPO)
 138 SET (ENABLE_LZMA_COMPRESSION ON)
 139 ENDIF (ENABLE_ARCHREPO)
 140
 141 FIND_PACKAGE (EXPAT REQUIRED)
 142 FIND_PACKAGE (ZLIB REQUIRED)
 143 IF (ENABLE_LZMA_COMPRESSION)
 144 FIND_PACKAGE (LZMA REQUIRED)
 145 ENDIF (ENABLE_LZMA_COMPRESSION)
 146 IF (ENABLE_BZIP2_COMPRESSION)
 147 FIND_PACKAGE (BZip2 REQUIRED)
 148 ENDIF (ENABLE_BZIP2_COMPRESSION)
 149
 150 IF (RPM5)
 151 MESSAGE (STATUS "Enabling RPM 5 support")
 152 ADD_DEFINITIONS (-DRPM5)
 153 SET (ENABLE_RPMDB ON)
 154 SET (ENABLE_RPMMD ON)
 155 FIND_PACKAGE (PkgConfig REQUIRED)
 156 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 157 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 158 ENDIF (RPM5)
 159
 160 IF (MULTI_SEMANTICS)
 161 MESSAGE (STATUS "Enabling multi dist support")
 162 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 163 ENDIF (MULTI_SEMANTICS)
 164
 165 INCLUDE (CheckIncludeFile)
 166 IF (ENABLE_RPMDB)
 167   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 168
 169   IF (NOT RPMDB_LIBRARY)
 170     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 171   ENDIF (NOT RPMDB_LIBRARY)
 172
 173   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 174   IF (RPMIO_LIBRARY)
 175     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 176   ENDIF (RPMIO_LIBRARY)
 177
 178   IF (RPM5)
 179     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 180     IF (RPMMISC_LIBRARY)
 181       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 182     ENDIF (RPMMISC_LIBRARY)
 183   ENDIF (RPM5)
 184
 185   # check if rpm contains a bundled berkeley db
 186   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 187   IF (NOT HAVE_RPM_DB_H)
 188     FIND_LIBRARY (DB_LIBRARY NAMES db)
 189     IF (DB_LIBRARY)
 190       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 191     ENDIF (DB_LIBRARY)
 192   ENDIF (NOT HAVE_RPM_DB_H)
 193   INCLUDE (CheckLibraryExists)
 194   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 195 ENDIF (ENABLE_RPMDB)
 196
 197 IF (ENABLE_PUBKEY)
 198   SET (ENABLE_PGPVRFY ON)
 199 ENDIF (ENABLE_PUBKEY)
 200
 201 INCLUDE (CheckFunctionExists)
 202 INCLUDE (TestBigEndian)
 203
 204 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 205 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 206 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 207 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 208
 209 # should create config.h with #cmakedefine instead...
 210 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 211   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS
 212   ENABLE_RPMDB ENABLE_PUBKEY ENABLE_RPMMD ENABLE_RPMDB_BYRPMHEADER ENABLE_SUSEREPO ENABLE_COMPS
 213   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 214   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA
 215   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS)
 216   IF(${VAR})
 217     ADD_DEFINITIONS (-D${VAR}=1)
 218     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 219   ENDIF (${VAR})
 220 ENDFOREACH (VAR)
 221
 222 SET (PACKAGE "libsolv")
 223 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 224
 225 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 226 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 227 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 228
 229 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 230 SET (CPACK_PACKAGE_VENDOR "SUSE")
 231 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 232 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 233 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 234 SET (CPACK_GENERATOR "TBZ2")
 235 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 236 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 237 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 238 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 239
 240 # The following components are regex's to match anywhere (unless anchored)
 241 # in absolute path + filename to find files or directories to be excluded
 242 # from source tarball.
 243 SET (CPACK_SOURCE_IGNORE_FILES
 244 # temporary files
 245 "\\\\.swp$"
 246 # backup files
 247 "~$"
 248 # eclipse files
 249 "\\\\.cdtproject$"
 250 "\\\\.cproject$"
 251 "\\\\.project$"
 252 "\\\\.settings/"
 253 # others
 254 "\\\\.#"
 255 "/#"
 256 "/build/"
 257 "/_build/"
 258 "/\\\\.git/"
 259 # used before
 260 "/\\\\.libs/"
 261 "/\\\\.deps/"
 262 "\\\\.o$"
 263 "\\\\.lo$"
 264 "\\\\.la$"
 265 "Makefile$"
 266 "Makefile\\\\.in$"
 267 # cmake cache files
 268 "DartConfiguration.tcl$"
 269 "CMakeCache.txt"
 270 "CMakeFiles"
 271 "cmake_install.cmake$"
 272 "CMakeLists.txt.auto$"
 273 "CTestTestfile.cmake"
 274 "CPackConfig.cmake$"
 275 "CPackSourceConfig.cmake$"
 276 "libsolv.spec$"
 277 )
 278
 279 INCLUDE(CPack)
 280
 281 ####################################################################
 282 # INCLUDES                                                         #
 283 ####################################################################
 284
 285 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 286 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 287
 288 ####################################################################
 289
 290 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 291
 292 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 293 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 294 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 295 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 296
 297 SET (SYSTEM_LIBRARIES ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 298 IF (ENABLE_LZMA_COMPRESSION)
 299 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 300 ENDIF (ENABLE_LZMA_COMPRESSION)
 301 IF (ENABLE_BZIP2_COMPRESSION)
 302 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 303 ENDIF (ENABLE_BZIP2_COMPRESSION)
 304 IF (ENABLE_RPMDB)
 305 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 306 ENDIF (ENABLE_RPMDB)
 307 IF (ENABLE_HAIKU)
 308 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 309 ENDIF (ENABLE_HAIKU)
 310 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 311
 312 ADD_SUBDIRECTORY (src)
 313 ADD_SUBDIRECTORY (ext)
 314 ADD_SUBDIRECTORY (tools)
 315 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 316     ADD_SUBDIRECTORY (bindings)
 317 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 318 ADD_SUBDIRECTORY (examples)
 319 ADD_SUBDIRECTORY (doc)
 320
 321 MESSAGE (STATUS "Version: ${VERSION}")
 322
 323 ####################################################################
 324 # RPM SPEC                                                         #
 325 ####################################################################
 326
 327 MACRO (SPECFILE)
 328   MESSAGE (STATUS "Writing spec file...")
 329   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 330 ENDMACRO (SPECFILE)
 331
 332 SPECFILE ()
 333
 334 SET (AUTOBUILD_COMMAND
 335   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 336   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 337   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 338   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 339   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 340   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 341 )
 342
 343 ADD_CUSTOM_TARGET (srcpackage
 344   ${AUTOBUILD_COMMAND}
 345 )
 346
 347 ADD_CUSTOM_TARGET (srcpackage_local
 348   ${AUTOBUILD_COMMAND}
 349 )
 350
 351 ENABLE_TESTING()
 352 ADD_SUBDIRECTORY (test)