CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  16 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  17 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  18 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  19 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  20 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  21 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  22 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  23 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  24 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  25 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  26 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  27
  28 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  29 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  30
  31 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  32 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  33
  34 IF (COMMAND cmake_policy)
  35   # escape preprocessor, see -DVERSION below
  36   CMAKE_POLICY (SET CMP0005 OLD)
  37 ENDIF (COMMAND cmake_policy)
  38
  39 # Library
  40 IF (DEFINED LIB)
  41   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  42 ELSE (DEFINED  LIB)
  43   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  44     SET (LIB_SUFFIX "64")
  45   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  46   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  47 ENDIF (DEFINED  LIB)
  48 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  49 # Library
  50 IF (DEFINED INCLUDE)
  51   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  52 else (DEFINED INCLUDE)
  53   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  54 ENDIF (DEFINED  INCLUDE)
  55 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  56 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  57 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  58 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  59   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  60 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  61 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  62
  63 ####################################################################
  64 # CONFIGURATION                                                    #
  65 ####################################################################
  66
  67 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  68 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  69 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  70
  71 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  72
  73 SET (have_system x)
  74
  75 IF (FEDORA)
  76 MESSAGE(STATUS "Building for Fedora")
  77 ADD_DEFINITIONS (-DFEDORA)
  78 SET (ENABLE_RPMDB ON)
  79 SET (ENABLE_RPMMD ON)
  80 SET (have_system ${have_system}x)
  81 ENDIF (FEDORA)
  82
  83 IF (DEBIAN)
  84 MESSAGE (STATUS "Building for Debian")
  85 ADD_DEFINITIONS (-DDEBIAN)
  86 SET (ENABLE_DEBIAN ON)
  87 SET (have_system ${have_system}x)
  88 ENDIF (DEBIAN)
  89
  90 IF (SUSE)
  91 MESSAGE (STATUS "Building for SUSE")
  92 ADD_DEFINITIONS (-DSUSE)
  93 SET (ENABLE_RPMDB ON)
  94 SET (ENABLE_PUBKEY ON)
  95 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  96 SET (ENABLE_RPMMD ON)
  97 SET (ENABLE_SUSEREPO ON)
  98 SET (ENABLE_HELIXREPO ON)
  99 SET (ENABLE_LINKED_PKGS ON)
 100 SET (have_system ${have_system}x)
 101 ENDIF (SUSE)
 102
 103 IF (ARCHLINUX)
 104 MESSAGE (STATUS "Building for Archlinux")
 105 ADD_DEFINITIONS (-DARCHLINUX)
 106 SET (ENABLE_ARCHREPO ON)
 107 SET (have_system ${have_system}x)
 108 ENDIF (ARCHLINUX)
 109
 110 IF (MANDRIVA)
 111 MESSAGE (STATUS "Building for Mandriva/Mageia")
 112 ADD_DEFINITIONS (-DMANDRIVA)
 113 SET (ENABLE_MDKREPO ON)
 114 SET (ENABLE_RPMDB ON)
 115 SET (have_system ${have_system}x)
 116 ENDIF (MANDRIVA)
 117
 118 IF (HAIKU)
 119 MESSAGE(STATUS "Building for Haiku")
 120 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 121 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 122 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 123 SET (HAIKU_SYSTEM_LIBRARIES
 124     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 125 ADD_DEFINITIONS (-DHAIKU)
 126 SET (ENABLE_HAIKU ON)
 127 SET (have_system ${have_system}x)
 128 ENDIF (HAIKU)
 129
 130 IF (${have_system} STREQUAL x)
 131     MESSAGE (STATUS "Building for no system")
 132     ADD_DEFINITIONS (-DNOSYSTEM)
 133 ENDIF (${have_system} STREQUAL x)
 134 IF (${have_system} STRGREATER xx)
 135     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 136 ENDIF (${have_system} STRGREATER xx)
 137
 138 IF (ENABLE_ARCHREPO)
 139 SET (ENABLE_LZMA_COMPRESSION ON)
 140 ENDIF (ENABLE_ARCHREPO)
 141
 142 FIND_PACKAGE (EXPAT REQUIRED)
 143 FIND_PACKAGE (ZLIB REQUIRED)
 144 IF (ENABLE_LZMA_COMPRESSION)
 145 FIND_PACKAGE (LZMA REQUIRED)
 146 ENDIF (ENABLE_LZMA_COMPRESSION)
 147 IF (ENABLE_BZIP2_COMPRESSION)
 148 FIND_PACKAGE (BZip2 REQUIRED)
 149 ENDIF (ENABLE_BZIP2_COMPRESSION)
 150
 151 IF (RPM5)
 152 MESSAGE (STATUS "Enabling RPM 5 support")
 153 ADD_DEFINITIONS (-DRPM5)
 154 SET (ENABLE_RPMDB ON)
 155 SET (ENABLE_RPMMD ON)
 156 FIND_PACKAGE (PkgConfig REQUIRED)
 157 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 158 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 159 ENDIF (RPM5)
 160
 161 IF (MULTI_SEMANTICS)
 162 MESSAGE (STATUS "Enabling multi dist support")
 163 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 164 ENDIF (MULTI_SEMANTICS)
 165
 166 INCLUDE (CheckIncludeFile)
 167 IF (ENABLE_RPMDB)
 168   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 169
 170   IF (NOT RPMDB_LIBRARY)
 171     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 172   ENDIF (NOT RPMDB_LIBRARY)
 173
 174   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 175   IF (RPMIO_LIBRARY)
 176     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 177   ENDIF (RPMIO_LIBRARY)
 178
 179   IF (RPM5)
 180     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 181     IF (RPMMISC_LIBRARY)
 182       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 183     ENDIF (RPMMISC_LIBRARY)
 184   ENDIF (RPM5)
 185
 186   # check if rpm contains a bundled berkeley db
 187   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 188   IF (NOT HAVE_RPM_DB_H)
 189     FIND_LIBRARY (DB_LIBRARY NAMES db)
 190     IF (DB_LIBRARY)
 191       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 192     ENDIF (DB_LIBRARY)
 193   ENDIF (NOT HAVE_RPM_DB_H)
 194   INCLUDE (CheckLibraryExists)
 195   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 196 ENDIF (ENABLE_RPMDB)
 197
 198 IF (ENABLE_PUBKEY)
 199   SET (ENABLE_PGPVRFY ON)
 200 ENDIF (ENABLE_PUBKEY)
 201
 202 INCLUDE (CheckFunctionExists)
 203 INCLUDE (TestBigEndian)
 204
 205 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 206 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 207 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 208 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 209
 210 # should create config.h with #cmakedefine instead...
 211 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 212   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS
 213   ENABLE_RPMDB ENABLE_PUBKEY ENABLE_RPMMD ENABLE_RPMDB_BYRPMHEADER ENABLE_SUSEREPO ENABLE_COMPS
 214   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 215   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA
 216   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS)
 217   IF(${VAR})
 218     ADD_DEFINITIONS (-D${VAR}=1)
 219     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 220   ENDIF (${VAR})
 221 ENDFOREACH (VAR)
 222
 223 SET (PACKAGE "libsolv")
 224 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 225
 226 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 227 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 228 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 229
 230 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 231 SET (CPACK_PACKAGE_VENDOR "SUSE")
 232 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 233 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 234 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 235 SET (CPACK_GENERATOR "TBZ2")
 236 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 237 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 238 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 239 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 240
 241 # The following components are regex's to match anywhere (unless anchored)
 242 # in absolute path + filename to find files or directories to be excluded
 243 # from source tarball.
 244 SET (CPACK_SOURCE_IGNORE_FILES
 245 # temporary files
 246 "\\\\.swp$"
 247 # backup files
 248 "~$"
 249 # eclipse files
 250 "\\\\.cdtproject$"
 251 "\\\\.cproject$"
 252 "\\\\.project$"
 253 "\\\\.settings/"
 254 # others
 255 "\\\\.#"
 256 "/#"
 257 "/build/"
 258 "/_build/"
 259 "/\\\\.git/"
 260 # used before
 261 "/\\\\.libs/"
 262 "/\\\\.deps/"
 263 "\\\\.o$"
 264 "\\\\.lo$"
 265 "\\\\.la$"
 266 "Makefile$"
 267 "Makefile\\\\.in$"
 268 # cmake cache files
 269 "DartConfiguration.tcl$"
 270 "CMakeCache.txt"
 271 "CMakeFiles"
 272 "cmake_install.cmake$"
 273 "CMakeLists.txt.auto$"
 274 "CTestTestfile.cmake"
 275 "CPackConfig.cmake$"
 276 "CPackSourceConfig.cmake$"
 277 "libsolv.spec$"
 278 )
 279
 280 INCLUDE(CPack)
 281
 282 ####################################################################
 283 # INCLUDES                                                         #
 284 ####################################################################
 285
 286 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 287 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 288
 289 ####################################################################
 290
 291 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 292
 293 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 294 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 295 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 296 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 297
 298 SET (SYSTEM_LIBRARIES ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 299 IF (ENABLE_LZMA_COMPRESSION)
 300 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 301 ENDIF (ENABLE_LZMA_COMPRESSION)
 302 IF (ENABLE_BZIP2_COMPRESSION)
 303 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 304 ENDIF (ENABLE_BZIP2_COMPRESSION)
 305 IF (ENABLE_RPMDB)
 306 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 307 ENDIF (ENABLE_RPMDB)
 308 IF (ENABLE_HAIKU)
 309 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 310 ENDIF (ENABLE_HAIKU)
 311 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 312
 313 ADD_SUBDIRECTORY (src)
 314 ADD_SUBDIRECTORY (ext)
 315 ADD_SUBDIRECTORY (tools)
 316 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 317     ADD_SUBDIRECTORY (bindings)
 318 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 319 ADD_SUBDIRECTORY (examples)
 320 ADD_SUBDIRECTORY (doc)
 321
 322 MESSAGE (STATUS "Version: ${VERSION}")
 323
 324 ####################################################################
 325 # RPM SPEC                                                         #
 326 ####################################################################
 327
 328 MACRO (SPECFILE)
 329   MESSAGE (STATUS "Writing spec file...")
 330   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 331 ENDMACRO (SPECFILE)
 332
 333 SPECFILE ()
 334
 335 SET (AUTOBUILD_COMMAND
 336   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 337   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 338   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 339   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 340   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 341   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 342 )
 343
 344 ADD_CUSTOM_TARGET (srcpackage
 345   ${AUTOBUILD_COMMAND}
 346 )
 347
 348 ADD_CUSTOM_TARGET (srcpackage_local
 349   ${AUTOBUILD_COMMAND}
 350 )
 351
 352 ENABLE_TESTING()
 353 ADD_SUBDIRECTORY (test)