CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.8.5)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11 OPTION (ENABLE_TCL "Build the Tcl bindings?" OFF)
  12
  13 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  14
  15 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  16 OPTION (ENABLE_RPMPKG "Build with rpm package support?" OFF)
  17 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  18 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  19 OPTION (ENABLE_RPMDB_LIBRPM "Use librpm to access the rpm database?" OFF)
  20 OPTION (ENABLE_RPMDB_BDB "Use BerkeleyDB to access the rpm database?" OFF)
  21 OPTION (ENABLE_RPMPKG_LIBRPM "Use librpm to access rpm header information?" OFF)
  22 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  23 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  24 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  25 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  26 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  27 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  28 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  29 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  30 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  31 OPTION (ENABLE_CONDA "Build with conda dependency support?" OFF)
  32 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  33
  34 OPTION (MULTI_SEMANTICS "Build with support for multiple distribution types?" OFF)
  35
  36 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  37 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  38 OPTION (ENABLE_ZSTD_COMPRESSION "Build with zstd compression support?" OFF)
  39 OPTION (ENABLE_ZCHUNK_COMPRESSION "Build with zchunk compression support?" OFF)
  40 OPTION (WITH_SYSTEM_ZCHUNK "Use system zchunk library?" OFF)
  41 OPTION (WITH_LIBXML2  "Build with libxml2 instead of libexpat?" OFF)
  42 OPTION (WITHOUT_COOKIEOPEN "Disable the use of stdio cookie opens?" OFF)
  43
  44 include (GNUInstallDirs)
  45 message (STATUS "Libraries will be installed in ${CMAKE_INSTALL_FULL_LIBDIR}")
  46 message (STATUS "Header files will be installed in ${CMAKE_INSTALL_FULL_INCLUDEDIR}")
  47 message (STATUS "Binaries will be installed in ${CMAKE_INSTALL_FULL_BINDIR}")
  48 message (STATUS "Man pages will be installed in ${CMAKE_INSTALL_FULL_MANDIR}")
  49
  50 IF (NOT PKGCONFIG_INSTALL_DIR)
  51   SET (PKGCONFIG_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
  52 ENDIF (NOT PKGCONFIG_INSTALL_DIR)
  53 ####################################################################
  54 # CONFIGURATION                                                    #
  55 ####################################################################
  56
  57 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  58 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  59 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  60
  61 # for shared libraries on windows (DLLs), we just export all symbols for now
  62 SET(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON)
  63
  64 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  65
  66 SET (have_system x)
  67
  68 IF (FEDORA)
  69 MESSAGE(STATUS "Building for Fedora")
  70 ADD_DEFINITIONS (-DFEDORA)
  71 SET (ENABLE_RPMDB ON)
  72 SET (ENABLE_RPMMD ON)
  73 SET (have_system ${have_system}x)
  74 ENDIF (FEDORA)
  75
  76 IF (DEBIAN)
  77 MESSAGE (STATUS "Building for Debian")
  78 ADD_DEFINITIONS (-DDEBIAN)
  79 SET (ENABLE_DEBIAN ON)
  80 SET (have_system ${have_system}x)
  81 ENDIF (DEBIAN)
  82
  83 IF (SUSE)
  84 MESSAGE (STATUS "Building for SUSE")
  85 ADD_DEFINITIONS (-DSUSE)
  86 SET (ENABLE_RPMDB ON)
  87 SET (ENABLE_PUBKEY ON)
  88 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  89 SET (ENABLE_RPMMD ON)
  90 SET (ENABLE_SUSEREPO ON)
  91 SET (ENABLE_HELIXREPO ON)
  92 SET (ENABLE_LINKED_PKGS ON)
  93 SET (have_system ${have_system}x)
  94 ENDIF (SUSE)
  95
  96 IF (ARCHLINUX)
  97 MESSAGE (STATUS "Building for Archlinux")
  98 ADD_DEFINITIONS (-DARCHLINUX)
  99 SET (ENABLE_ARCHREPO ON)
 100 SET (have_system ${have_system}x)
 101 ENDIF (ARCHLINUX)
 102
 103 IF (MANDRIVA)
 104 MESSAGE (STATUS "Building for Mandriva")
 105 ADD_DEFINITIONS (-DMANDRIVA)
 106 SET (ENABLE_MDKREPO ON)
 107 SET (ENABLE_RPMDB ON)
 108 SET (have_system ${have_system}x)
 109 ENDIF (MANDRIVA)
 110
 111 IF (MAGEIA)
 112 MESSAGE (STATUS "Building for Mageia")
 113 ADD_DEFINITIONS (-DMAGEIA)
 114 SET (ENABLE_MDKREPO ON)
 115 SET (ENABLE_RPMDB ON)
 116 SET (ENABLE_RPMMD ON)
 117 SET (ENABLE_LZMA_COMPRESSION ON)
 118 SET (have_system ${have_system}x)
 119 ENDIF (MAGEIA)
 120
 121 IF (HAIKU)
 122 MESSAGE(STATUS "Building for Haiku")
 123 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 124 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 125 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 126 SET (HAIKU_SYSTEM_LIBRARIES
 127     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 128 ADD_DEFINITIONS (-DHAIKU)
 129 SET (ENABLE_HAIKU ON)
 130 SET (have_system ${have_system}x)
 131 ENDIF (HAIKU)
 132
 133 SET (CMAKE_MACOSX_RPATH ON)
 134
 135 IF (${have_system} STREQUAL x)
 136     MESSAGE (STATUS "Building for no system")
 137 ENDIF (${have_system} STREQUAL x)
 138 IF (${have_system} STRGREATER xx)
 139     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 140 ENDIF (${have_system} STRGREATER xx)
 141
 142 SET (ENABLE_ZLIB_COMPRESSION ON)
 143 IF (ENABLE_ARCHREPO OR ENABLE_DEBIAN)
 144 SET (ENABLE_LZMA_COMPRESSION ON)
 145 ENDIF (ENABLE_ARCHREPO OR ENABLE_DEBIAN)
 146
 147 IF (WITH_SYSTEM_ZCHUNK)
 148 SET (ENABLE_ZCHUNK_COMPRESSION ON)
 149 FIND_PACKAGE(PkgConfig REQUIRED)
 150 PKG_CHECK_MODULES(ZCHUNK zck REQUIRED)
 151 ENDIF (WITH_SYSTEM_ZCHUNK)
 152
 153 IF (ENABLE_ZCHUNK_COMPRESSION)
 154 SET (ENABLE_ZSTD_COMPRESSION ON)
 155 ENDIF (ENABLE_ZCHUNK_COMPRESSION)
 156
 157 IF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 158 IF (WITH_LIBXML2 )
 159 FIND_PACKAGE (LibXml2 REQUIRED)
 160 INCLUDE_DIRECTORIES (${LIBXML2_INCLUDE_DIR})
 161 ELSE(WITH_LIBXML2 )
 162 FIND_PACKAGE (EXPAT REQUIRED)
 163 INCLUDE_DIRECTORIES (${EXPAT_INCLUDE_DIRS})
 164 ENDIF (WITH_LIBXML2 )
 165 ENDIF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 166
 167 IF (ENABLE_ZLIB_COMPRESSION)
 168 FIND_PACKAGE (ZLIB REQUIRED)
 169 INCLUDE_DIRECTORIES (${ZLIB_INCLUDE_DIRS})
 170 ENDIF (ENABLE_ZLIB_COMPRESSION)
 171
 172 IF (ENABLE_LZMA_COMPRESSION)
 173 FIND_PACKAGE (LZMA REQUIRED)
 174 INCLUDE_DIRECTORIES (${LZMA_INCLUDE_DIR})
 175 ENDIF (ENABLE_LZMA_COMPRESSION)
 176
 177 IF (ENABLE_BZIP2_COMPRESSION)
 178 FIND_PACKAGE (BZip2 REQUIRED)
 179 INCLUDE_DIRECTORIES (${BZIP2_INCLUDE_DIRS})
 180 ENDIF (ENABLE_BZIP2_COMPRESSION)
 181
 182 IF (ENABLE_ZSTD_COMPRESSION)
 183 FIND_LIBRARY (ZSTD_LIBRARY NAMES zstd)
 184 FIND_PATH (ZSTD_INCLUDE_DIRS zstd.h)
 185 INCLUDE_DIRECTORIES (${ZSTD_INCLUDE_DIRS})
 186 ENDIF (ENABLE_ZSTD_COMPRESSION)
 187
 188 IF (RPM5)
 189 MESSAGE (STATUS "Enabling RPM 5 support")
 190 ADD_DEFINITIONS (-DRPM5)
 191 SET (ENABLE_RPMDB ON)
 192 SET (ENABLE_RPMMD ON)
 193 FIND_PACKAGE (PkgConfig REQUIRED)
 194 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 195 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 196 ENDIF (RPM5)
 197
 198 IF (ENABLE_CONDA)
 199 SET (MULTI_SEMANTICS ON)
 200 ENDIF (ENABLE_CONDA)
 201
 202 IF (MULTI_SEMANTICS)
 203 MESSAGE (STATUS "Enabling multi dist support")
 204 ENDIF (MULTI_SEMANTICS)
 205
 206 IF (ENABLE_RPMDB)
 207 SET (ENABLE_RPMPKG ON)
 208 ENDIF (ENABLE_RPMDB)
 209
 210 INCLUDE (CheckIncludeFile)
 211 IF (ENABLE_RPMDB OR ENABLE_RPMPKG_LIBRPM)
 212   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 213
 214   IF (NOT RPMDB_LIBRARY)
 215     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 216   ENDIF (NOT RPMDB_LIBRARY)
 217
 218   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 219   IF (RPMIO_LIBRARY)
 220     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 221   ENDIF (RPMIO_LIBRARY)
 222
 223   IF (RPM5)
 224     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 225     IF (RPMMISC_LIBRARY)
 226       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 227     ENDIF (RPMMISC_LIBRARY)
 228   ENDIF (RPM5)
 229
 230   IF (ENABLE_RPMDB)
 231     IF (NOT ENABLE_RPMDB_BDB)
 232       SET (ENABLE_RPMDB_LIBRPM ON)
 233     ENDIF (NOT ENABLE_RPMDB_BDB)
 234
 235     # check if rpm contains a bundled berkeley db
 236     CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 237     IF (NOT ENABLE_RPMDB_LIBRPM)
 238       IF (NOT HAVE_RPM_DB_H)
 239         FIND_LIBRARY (DB_LIBRARY NAMES db)
 240         IF (DB_LIBRARY)
 241           SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 242         ENDIF (DB_LIBRARY)
 243         IF (DB_INCLUDE_DIR)
 244           INCLUDE_DIRECTORIES (${DB_INCLUDE_DIR})
 245         ENDIF (DB_INCLUDE_DIR)
 246       ENDIF (NOT HAVE_RPM_DB_H)
 247     ENDIF (NOT ENABLE_RPMDB_LIBRPM)
 248   ENDIF (ENABLE_RPMDB)
 249
 250   INCLUDE (CheckLibraryExists)
 251   CHECK_LIBRARY_EXISTS(rpm rpmdbNextIteratorHeaderBlob "" HAVE_RPMDBNEXTITERATORHEADERBLOB)
 252   CHECK_LIBRARY_EXISTS(rpm rpmdbFStat "" HAVE_RPMDBFSTAT)
 253 ENDIF (ENABLE_RPMDB OR ENABLE_RPMPKG_LIBRPM)
 254
 255 IF (ENABLE_PUBKEY)
 256   SET (ENABLE_PGPVRFY ON)
 257 ENDIF (ENABLE_PUBKEY)
 258
 259 INCLUDE (CheckFunctionExists)
 260 INCLUDE (TestBigEndian)
 261
 262 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 263 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 264 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 265 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 266
 267 IF (${CMAKE_MAJOR_VERSION} GREATER 2)
 268 INCLUDE (CMakePushCheckState)
 269 INCLUDE (CheckCCompilerFlag)
 270 MACRO (check_linker_flag FLAG VAR)
 271         CMAKE_PUSH_CHECK_STATE (RESET)
 272         SET (CMAKE_REQUIRED_FLAGS "${FLAG}")
 273         CHECK_C_COMPILER_FLAG ("" "${VAR}")
 274         CMAKE_POP_CHECK_STATE ()
 275 ENDMACRO (check_linker_flag)
 276 check_linker_flag("-Wl,--as-needed" HAVE_LINKER_AS_NEEDED)
 277 check_linker_flag("-Wl,--version-script=${CMAKE_SOURCE_DIR}/src/libsolv.ver" HAVE_LINKER_VERSION_SCRIPT)
 278 ELSE (${CMAKE_MAJOR_VERSION} GREATER 2)
 279 SET (HAVE_LINKER_AS_NEEDED 1)
 280 SET (HAVE_LINKER_VERSION_SCRIPT 1)
 281 ENDIF (${CMAKE_MAJOR_VERSION} GREATER 2)
 282
 283 # should create config.h with #cmakedefine instead...
 284 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 285   HAVE_RPM_DB_H HAVE_RPMDBNEXTITERATORHEADERBLOB HAVE_RPMDBFSTAT
 286   WITH_LIBXML2 WITHOUT_COOKIEOPEN)
 287   IF(${VAR})
 288     ADD_DEFINITIONS (-D${VAR}=1)
 289     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 290   ENDIF (${VAR})
 291 ENDFOREACH (VAR)
 292
 293 FOREACH (VAR
 294   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS MULTI_SEMANTICS ENABLE_CONDA)
 295   IF(${VAR})
 296     ADD_DEFINITIONS (-D${VAR}=1)
 297     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 298     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 299     SET (LIBSOLV_FEATURE_${VARX} 1)
 300   ENDIF (${VAR})
 301 ENDFOREACH (VAR)
 302
 303 FOREACH (VAR
 304   ENABLE_RPMDB ENABLE_RPMPKG ENABLE_PUBKEY ENABLE_RPMMD
 305   ENABLE_RPMPKG_LIBRPM ENABLE_RPMDB_LIBRPM ENABLE_RPMDB_BYRPMHEADER
 306   ENABLE_SUSEREPO ENABLE_COMPS ENABLE_TESTCASE_HELIXREPO
 307   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 308   ENABLE_ZLIB_COMPRESSION ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION
 309   ENABLE_ZSTD_COMPRESSION ENABLE_ZCHUNK_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA
 310   WITH_SYSTEM_ZCHUNK)
 311   IF(${VAR})
 312     ADD_DEFINITIONS (-D${VAR}=1)
 313     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 314     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 315     SET (LIBSOLVEXT_FEATURE_${VARX} 1)
 316   ENDIF (${VAR})
 317 ENDFOREACH (VAR)
 318
 319 SET (PACKAGE "libsolv")
 320 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 321
 322 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 323 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 324
 325 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 326 SET (CPACK_PACKAGE_VENDOR "SUSE")
 327 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 328 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 329 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 330 SET (CPACK_GENERATOR "TBZ2")
 331 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 332 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 333 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 334 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 335
 336 # The following components are regex's to match anywhere (unless anchored)
 337 # in absolute path + filename to find files or directories to be excluded
 338 # from source tarball.
 339 SET (CPACK_SOURCE_IGNORE_FILES
 340 # temporary files
 341 "\\\\.swp$"
 342 # backup files
 343 "~$"
 344 # eclipse files
 345 "\\\\.cdtproject$"
 346 "\\\\.cproject$"
 347 "\\\\.project$"
 348 "\\\\.settings/"
 349 # others
 350 "\\\\.#"
 351 "/#"
 352 "/build/"
 353 "/_build/"
 354 "/\\\\.git/"
 355 # used before
 356 "/\\\\.libs/"
 357 "/\\\\.deps/"
 358 "\\\\.o$"
 359 "\\\\.lo$"
 360 "\\\\.la$"
 361 "Makefile$"
 362 "Makefile\\\\.in$"
 363 # cmake cache files
 364 "DartConfiguration.tcl$"
 365 "CMakeCache.txt"
 366 "CMakeFiles"
 367 "cmake_install.cmake$"
 368 "CMakeLists.txt.auto$"
 369 "CTestTestfile.cmake"
 370 "CPackConfig.cmake$"
 371 "CPackSourceConfig.cmake$"
 372 "libsolv.spec$"
 373 )
 374
 375 INCLUDE(CPack)
 376
 377 ####################################################################
 378 # INCLUDES                                                         #
 379 ####################################################################
 380
 381 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 382 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 383
 384 ####################################################################
 385
 386 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 387
 388 IF (MSVC)
 389   set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4244 /wd4267")
 390   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 391 ELSE ()
 392   set (CMAKE_C_FLAGS                "${CMAKE_C_FLAGS} -Wall")
 393   set (CMAKE_C_FLAGS_RELEASE        "${CMAKE_C_FLAGS} -O3")
 394   set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 395   set (CMAKE_C_FLAGS_DEBUG          "${CMAKE_C_FLAGS} -g3 -O0")
 396 ENDIF ()
 397
 398 # set system libraries
 399 SET (SYSTEM_LIBRARIES "")
 400 IF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 401 IF (WITH_LIBXML2 )
 402 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LIBXML2_LIBRARIES})
 403 ELSE (WITH_LIBXML2 )
 404 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${EXPAT_LIBRARY})
 405 ENDIF (WITH_LIBXML2 )
 406
 407 ENDIF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 408 IF (ENABLE_ZLIB_COMPRESSION)
 409 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZLIB_LIBRARY})
 410 ENDIF (ENABLE_ZLIB_COMPRESSION)
 411 IF (ENABLE_LZMA_COMPRESSION)
 412 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 413 ENDIF (ENABLE_LZMA_COMPRESSION)
 414 IF (ENABLE_BZIP2_COMPRESSION)
 415 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 416 ENDIF (ENABLE_BZIP2_COMPRESSION)
 417 IF (ENABLE_ZSTD_COMPRESSION)
 418 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZSTD_LIBRARY})
 419 ENDIF (ENABLE_ZSTD_COMPRESSION)
 420 IF (WITH_SYSTEM_ZCHUNK)
 421 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZCHUNK_LIBRARIES})
 422 ENDIF (WITH_SYSTEM_ZCHUNK)
 423 IF (ENABLE_RPMDB)
 424 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 425 ENDIF (ENABLE_RPMDB)
 426 IF (ENABLE_HAIKU)
 427 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 428 ENDIF (ENABLE_HAIKU)
 429 IF (HAVE_LINKER_AS_NEEDED)
 430 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 431 ENDIF (HAVE_LINKER_AS_NEEDED)
 432
 433 ADD_SUBDIRECTORY (src)
 434 ADD_SUBDIRECTORY (ext)
 435 ADD_SUBDIRECTORY (tools)
 436 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_PYTHON3 OR ENABLE_RUBY OR ENABLE_TCL)
 437     ADD_SUBDIRECTORY (bindings)
 438 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_PYTHON3 OR ENABLE_RUBY OR ENABLE_TCL)
 439 ADD_SUBDIRECTORY (examples)
 440 ADD_SUBDIRECTORY (doc)
 441
 442 MESSAGE (STATUS "Version: ${VERSION}")
 443
 444 ####################################################################
 445 # RPM SPEC                                                         #
 446 ####################################################################
 447
 448 MACRO (SPECFILE)
 449   MESSAGE (STATUS "Writing spec file...")
 450   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 451 ENDMACRO (SPECFILE)
 452
 453 MACRO (PCFILE)
 454   MESSAGE (STATUS "Writing pkg-config files...")
 455   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolv.pc.in ${CMAKE_BINARY_DIR}/libsolv.pc @ONLY)
 456   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolv.pc DESTINATION ${PKGCONFIG_INSTALL_DIR} )
 457   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolvext.pc.in ${CMAKE_BINARY_DIR}/libsolvext.pc @ONLY)
 458   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolvext.pc DESTINATION ${PKGCONFIG_INSTALL_DIR} )
 459 ENDMACRO (PCFILE)
 460
 461 SPECFILE ()
 462 PCFILE ()
 463
 464 SET (AUTOBUILD_COMMAND
 465   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 466   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 467   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 468   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 469   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 470   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 471 )
 472
 473 ADD_CUSTOM_TARGET (srcpackage
 474   ${AUTOBUILD_COMMAND}
 475 )
 476
 477 ADD_CUSTOM_TARGET (srcpackage_local
 478   ${AUTOBUILD_COMMAND}
 479 )
 480
 481 ENABLE_TESTING()
 482 ADD_SUBDIRECTORY (test)