CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11 OPTION (ENABLE_TCL "Build the Tcl bindings?" OFF)
  12
  13 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  14
  15 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  16 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  17 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  18 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  19 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  20 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  21 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  22 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  23 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  24 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  25 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  26 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  27 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  28
  29 OPTION (MULTI_SEMANTICS "Build with support for multiple distribution types?" OFF)
  30
  31 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  32 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  33
  34 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  35 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  36
  37 IF (COMMAND cmake_policy)
  38   # escape preprocessor, see -DVERSION below
  39   CMAKE_POLICY (SET CMP0005 OLD)
  40 ENDIF (COMMAND cmake_policy)
  41
  42 # Library
  43 IF (DEFINED LIB)
  44   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  45 ELSE (DEFINED  LIB)
  46   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  47     SET (LIB_SUFFIX "64")
  48   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  49   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  50 ENDIF (DEFINED  LIB)
  51 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  52 # Library
  53 IF (DEFINED INCLUDE)
  54   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  55 else (DEFINED INCLUDE)
  56   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  57 ENDIF (DEFINED  INCLUDE)
  58 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  59 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  60 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  61 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  62   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  63 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man")
  64 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  65
  66 ####################################################################
  67 # CONFIGURATION                                                    #
  68 ####################################################################
  69
  70 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  71 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  72 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  73
  74 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  75
  76 SET (have_system x)
  77
  78 IF (FEDORA)
  79 MESSAGE(STATUS "Building for Fedora")
  80 ADD_DEFINITIONS (-DFEDORA)
  81 SET (ENABLE_RPMDB ON)
  82 SET (ENABLE_RPMMD ON)
  83 SET (have_system ${have_system}x)
  84 ENDIF (FEDORA)
  85
  86 IF (DEBIAN)
  87 MESSAGE (STATUS "Building for Debian")
  88 ADD_DEFINITIONS (-DDEBIAN)
  89 SET (ENABLE_DEBIAN ON)
  90 SET (have_system ${have_system}x)
  91 ENDIF (DEBIAN)
  92
  93 IF (SUSE)
  94 MESSAGE (STATUS "Building for SUSE")
  95 ADD_DEFINITIONS (-DSUSE)
  96 SET (ENABLE_RPMDB ON)
  97 SET (ENABLE_PUBKEY ON)
  98 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  99 SET (ENABLE_RPMMD ON)
 100 SET (ENABLE_SUSEREPO ON)
 101 SET (ENABLE_HELIXREPO ON)
 102 SET (ENABLE_LINKED_PKGS ON)
 103 SET (have_system ${have_system}x)
 104 ENDIF (SUSE)
 105
 106 IF (ARCHLINUX)
 107 MESSAGE (STATUS "Building for Archlinux")
 108 ADD_DEFINITIONS (-DARCHLINUX)
 109 SET (ENABLE_ARCHREPO ON)
 110 SET (have_system ${have_system}x)
 111 ENDIF (ARCHLINUX)
 112
 113 IF (MANDRIVA)
 114 MESSAGE (STATUS "Building for Mandriva/Mageia")
 115 ADD_DEFINITIONS (-DMANDRIVA)
 116 SET (ENABLE_MDKREPO ON)
 117 SET (ENABLE_RPMDB ON)
 118 SET (have_system ${have_system}x)
 119 ENDIF (MANDRIVA)
 120
 121 IF (HAIKU)
 122 MESSAGE(STATUS "Building for Haiku")
 123 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 124 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 125 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 126 SET (HAIKU_SYSTEM_LIBRARIES
 127     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 128 ADD_DEFINITIONS (-DHAIKU)
 129 SET (ENABLE_HAIKU ON)
 130 SET (have_system ${have_system}x)
 131 ENDIF (HAIKU)
 132
 133 IF (${have_system} STREQUAL x)
 134     MESSAGE (STATUS "Building for no system")
 135 ENDIF (${have_system} STREQUAL x)
 136 IF (${have_system} STRGREATER xx)
 137     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 138 ENDIF (${have_system} STRGREATER xx)
 139
 140 IF (ENABLE_ARCHREPO)
 141 SET (ENABLE_LZMA_COMPRESSION ON)
 142 ENDIF (ENABLE_ARCHREPO)
 143
 144 FIND_PACKAGE (EXPAT REQUIRED)
 145 FIND_PACKAGE (ZLIB REQUIRED)
 146 IF (ENABLE_LZMA_COMPRESSION)
 147 FIND_PACKAGE (LZMA REQUIRED)
 148 ENDIF (ENABLE_LZMA_COMPRESSION)
 149 IF (ENABLE_BZIP2_COMPRESSION)
 150 FIND_PACKAGE (BZip2 REQUIRED)
 151 ENDIF (ENABLE_BZIP2_COMPRESSION)
 152
 153 IF (RPM5)
 154 MESSAGE (STATUS "Enabling RPM 5 support")
 155 ADD_DEFINITIONS (-DRPM5)
 156 SET (ENABLE_RPMDB ON)
 157 SET (ENABLE_RPMMD ON)
 158 FIND_PACKAGE (PkgConfig REQUIRED)
 159 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 160 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 161 ENDIF (RPM5)
 162
 163 IF (MULTI_SEMANTICS)
 164 MESSAGE (STATUS "Enabling multi dist support")
 165 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 166 ENDIF (MULTI_SEMANTICS)
 167
 168 INCLUDE (CheckIncludeFile)
 169 IF (ENABLE_RPMDB)
 170   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 171
 172   IF (NOT RPMDB_LIBRARY)
 173     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 174   ENDIF (NOT RPMDB_LIBRARY)
 175
 176   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 177   IF (RPMIO_LIBRARY)
 178     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 179   ENDIF (RPMIO_LIBRARY)
 180
 181   IF (RPM5)
 182     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 183     IF (RPMMISC_LIBRARY)
 184       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 185     ENDIF (RPMMISC_LIBRARY)
 186   ENDIF (RPM5)
 187
 188   # check if rpm contains a bundled berkeley db
 189   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 190   IF (NOT HAVE_RPM_DB_H)
 191     FIND_LIBRARY (DB_LIBRARY NAMES db)
 192     IF (DB_LIBRARY)
 193       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 194     ENDIF (DB_LIBRARY)
 195   ENDIF (NOT HAVE_RPM_DB_H)
 196   INCLUDE (CheckLibraryExists)
 197   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 198 ENDIF (ENABLE_RPMDB)
 199
 200 IF (ENABLE_PUBKEY)
 201   SET (ENABLE_PGPVRFY ON)
 202 ENDIF (ENABLE_PUBKEY)
 203
 204 INCLUDE (CheckFunctionExists)
 205 INCLUDE (TestBigEndian)
 206
 207 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 208 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 209 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 210 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 211
 212 IF (${CMAKE_MAJOR_VERSION} GREATER 2)
 213 INCLUDE (CMakePushCheckState)
 214 INCLUDE (CheckCCompilerFlag)
 215 MACRO (check_linker_flag FLAG VAR)
 216         CMAKE_PUSH_CHECK_STATE (RESET)
 217         SET (CMAKE_REQUIRED_FLAGS "${FLAG}")
 218         CHECK_C_COMPILER_FLAG ("" "${VAR}")
 219         CMAKE_POP_CHECK_STATE ()
 220 ENDMACRO (check_linker_flag)
 221 check_linker_flag("-Wl,--as-needed" HAVE_LINKER_AS_NEEDED)
 222 check_linker_flag("-Wl,--version-script=${CMAKE_SOURCE_DIR}/src/libsolv.ver" HAVE_LINKER_VERSION_SCRIPT)
 223 ELSE (${CMAKE_MAJOR_VERSION} GREATER 2)
 224 SET (HAVE_LINKER_AS_NEEDED 1)
 225 SET (HAVE_LINKER_VERSION_SCRIPT 1)
 226 ENDIF (${CMAKE_MAJOR_VERSION} GREATER 2)
 227
 228 # should create config.h with #cmakedefine instead...
 229 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 230   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS
 231   ENABLE_RPMDB ENABLE_PUBKEY ENABLE_RPMMD ENABLE_RPMDB_BYRPMHEADER ENABLE_SUSEREPO ENABLE_COMPS
 232   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 233   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA
 234   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS)
 235   IF(${VAR})
 236     ADD_DEFINITIONS (-D${VAR}=1)
 237     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 238   ENDIF (${VAR})
 239 ENDFOREACH (VAR)
 240
 241 SET (PACKAGE "libsolv")
 242 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 243
 244 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 245 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 246 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 247
 248 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 249 SET (CPACK_PACKAGE_VENDOR "SUSE")
 250 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 251 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 252 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 253 SET (CPACK_GENERATOR "TBZ2")
 254 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 255 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 256 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 257 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 258
 259 # The following components are regex's to match anywhere (unless anchored)
 260 # in absolute path + filename to find files or directories to be excluded
 261 # from source tarball.
 262 SET (CPACK_SOURCE_IGNORE_FILES
 263 # temporary files
 264 "\\\\.swp$"
 265 # backup files
 266 "~$"
 267 # eclipse files
 268 "\\\\.cdtproject$"
 269 "\\\\.cproject$"
 270 "\\\\.project$"
 271 "\\\\.settings/"
 272 # others
 273 "\\\\.#"
 274 "/#"
 275 "/build/"
 276 "/_build/"
 277 "/\\\\.git/"
 278 # used before
 279 "/\\\\.libs/"
 280 "/\\\\.deps/"
 281 "\\\\.o$"
 282 "\\\\.lo$"
 283 "\\\\.la$"
 284 "Makefile$"
 285 "Makefile\\\\.in$"
 286 # cmake cache files
 287 "DartConfiguration.tcl$"
 288 "CMakeCache.txt"
 289 "CMakeFiles"
 290 "cmake_install.cmake$"
 291 "CMakeLists.txt.auto$"
 292 "CTestTestfile.cmake"
 293 "CPackConfig.cmake$"
 294 "CPackSourceConfig.cmake$"
 295 "libsolv.spec$"
 296 )
 297
 298 INCLUDE(CPack)
 299
 300 ####################################################################
 301 # INCLUDES                                                         #
 302 ####################################################################
 303
 304 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 305 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 306
 307 ####################################################################
 308
 309 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 310
 311 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 312 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 313 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 314 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 315
 316 SET (SYSTEM_LIBRARIES ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 317 IF (ENABLE_LZMA_COMPRESSION)
 318 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 319 ENDIF (ENABLE_LZMA_COMPRESSION)
 320 IF (ENABLE_BZIP2_COMPRESSION)
 321 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 322 ENDIF (ENABLE_BZIP2_COMPRESSION)
 323 IF (ENABLE_RPMDB)
 324 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 325 ENDIF (ENABLE_RPMDB)
 326 IF (ENABLE_HAIKU)
 327 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 328 ENDIF (ENABLE_HAIKU)
 329 IF (HAVE_LINKER_AS_NEEDED)
 330 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 331 ENDIF (HAVE_LINKER_AS_NEEDED)
 332
 333 ADD_SUBDIRECTORY (src)
 334 ADD_SUBDIRECTORY (ext)
 335 ADD_SUBDIRECTORY (tools)
 336 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 337     ADD_SUBDIRECTORY (bindings)
 338 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 339 ADD_SUBDIRECTORY (examples)
 340 ADD_SUBDIRECTORY (doc)
 341
 342 MESSAGE (STATUS "Version: ${VERSION}")
 343
 344 ####################################################################
 345 # RPM SPEC                                                         #
 346 ####################################################################
 347
 348 MACRO (SPECFILE)
 349   MESSAGE (STATUS "Writing spec file...")
 350   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 351 ENDMACRO (SPECFILE)
 352
 353 MACRO (PCFILE)
 354   MESSAGE (STATUS "Writing pkg-config file...")
 355   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolv.pc.in ${CMAKE_BINARY_DIR}/libsolv.pc @ONLY)
 356   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolv.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 357 ENDMACRO (PCFILE)
 358
 359 SPECFILE ()
 360 PCFILE ()
 361
 362 SET (AUTOBUILD_COMMAND
 363   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 364   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 365   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 366   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 367   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 368   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 369 )
 370
 371 ADD_CUSTOM_TARGET (srcpackage
 372   ${AUTOBUILD_COMMAND}
 373 )
 374
 375 ADD_CUSTOM_TARGET (srcpackage_local
 376   ${AUTOBUILD_COMMAND}
 377 )
 378
 379 ENABLE_TESTING()
 380 ADD_SUBDIRECTORY (test)