CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11 OPTION (ENABLE_TCL "Build the Tcl bindings?" OFF)
  12
  13 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  14
  15 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  16 OPTION (ENABLE_RPMPKG "Build with rpm package support?" OFF)
  17 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  18 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  19 OPTION (ENABLE_RPMDB_LIBRPM "Use librpm to access the rpm database?" OFF)
  20 OPTION (ENABLE_RPMPKG_LIBRPM "Use librpm to access rpm header information?" OFF)
  21 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  22 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  23 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  24 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  25 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  26 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  27 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  28 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  29 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  30 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  31
  32 OPTION (MULTI_SEMANTICS "Build with support for multiple distribution types?" OFF)
  33
  34 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  35 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  36 OPTION (ENABLE_ZSTD_COMPRESSION "Build with zstd compression support?" OFF)
  37 OPTION (ENABLE_ZCHUNK_COMPRESSION "Build with zchunk compression support?" OFF)
  38 OPTION (WITH_SYSTEM_ZCHUNK "Use system zchunk library?" OFF)
  39 OPTION (WITH_LIBXML2  "Build with libxml2 instead of libexpat?" OFF)
  40
  41 # Library
  42 IF (DEFINED LIB)
  43   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  44 ELSE (DEFINED  LIB)
  45   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  46     SET (LIB_SUFFIX "64")
  47   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  48   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  49 ENDIF (DEFINED  LIB)
  50 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  51 # Library
  52 IF (DEFINED INCLUDE)
  53   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  54 else (DEFINED INCLUDE)
  55   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  56 ENDIF (DEFINED  INCLUDE)
  57 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  58 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  59 IF (NOT MAN_INSTALL_DIR)
  60 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  61 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  62   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  63 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  64 ENDIF (NOT MAN_INSTALL_DIR)
  65 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  66
  67 IF (NOT PKGCONFIG_INSTALL_DIR)
  68   SET (PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
  69 ENDIF (NOT PKGCONFIG_INSTALL_DIR)
  70 ####################################################################
  71 # CONFIGURATION                                                    #
  72 ####################################################################
  73
  74 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  75 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  76 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  77
  78 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  79
  80 SET (have_system x)
  81
  82 IF (FEDORA)
  83 MESSAGE(STATUS "Building for Fedora")
  84 ADD_DEFINITIONS (-DFEDORA)
  85 SET (ENABLE_RPMDB ON)
  86 SET (ENABLE_RPMMD ON)
  87 SET (have_system ${have_system}x)
  88 ENDIF (FEDORA)
  89
  90 IF (DEBIAN)
  91 MESSAGE (STATUS "Building for Debian")
  92 ADD_DEFINITIONS (-DDEBIAN)
  93 SET (ENABLE_DEBIAN ON)
  94 SET (have_system ${have_system}x)
  95 ENDIF (DEBIAN)
  96
  97 IF (SUSE)
  98 MESSAGE (STATUS "Building for SUSE")
  99 ADD_DEFINITIONS (-DSUSE)
 100 SET (ENABLE_RPMDB ON)
 101 SET (ENABLE_PUBKEY ON)
 102 SET (ENABLE_RPMDB_BYRPMHEADER ON)
 103 SET (ENABLE_RPMMD ON)
 104 SET (ENABLE_SUSEREPO ON)
 105 SET (ENABLE_HELIXREPO ON)
 106 SET (ENABLE_LINKED_PKGS ON)
 107 SET (have_system ${have_system}x)
 108 ENDIF (SUSE)
 109
 110 IF (ARCHLINUX)
 111 MESSAGE (STATUS "Building for Archlinux")
 112 ADD_DEFINITIONS (-DARCHLINUX)
 113 SET (ENABLE_ARCHREPO ON)
 114 SET (have_system ${have_system}x)
 115 ENDIF (ARCHLINUX)
 116
 117 IF (MANDRIVA)
 118 MESSAGE (STATUS "Building for Mandriva")
 119 ADD_DEFINITIONS (-DMANDRIVA)
 120 SET (ENABLE_MDKREPO ON)
 121 SET (ENABLE_RPMDB ON)
 122 SET (have_system ${have_system}x)
 123 ENDIF (MANDRIVA)
 124
 125 IF (MAGEIA)
 126 MESSAGE (STATUS "Building for Mageia")
 127 ADD_DEFINITIONS (-DMAGEIA)
 128 SET (ENABLE_MDKREPO ON)
 129 SET (ENABLE_RPMDB ON)
 130 SET (ENABLE_RPMMD ON)
 131 SET (ENABLE_LZMA_COMPRESSION ON)
 132 SET (have_system ${have_system}x)
 133 ENDIF (MAGEIA)
 134
 135 IF (HAIKU)
 136 MESSAGE(STATUS "Building for Haiku")
 137 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 138 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 139 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 140 SET (HAIKU_SYSTEM_LIBRARIES
 141     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 142 ADD_DEFINITIONS (-DHAIKU)
 143 SET (ENABLE_HAIKU ON)
 144 SET (have_system ${have_system}x)
 145 ENDIF (HAIKU)
 146
 147 IF (${have_system} STREQUAL x)
 148     MESSAGE (STATUS "Building for no system")
 149 ENDIF (${have_system} STREQUAL x)
 150 IF (${have_system} STRGREATER xx)
 151     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 152 ENDIF (${have_system} STRGREATER xx)
 153
 154 SET (ENABLE_ZLIB_COMPRESSION ON)
 155 IF (ENABLE_ARCHREPO OR ENABLE_DEBIAN)
 156 SET (ENABLE_LZMA_COMPRESSION ON)
 157 ENDIF (ENABLE_ARCHREPO OR ENABLE_DEBIAN)
 158
 159 IF (WITH_SYSTEM_ZCHUNK)
 160 SET (ENABLE_ZCHUNK_COMPRESSION ON)
 161 FIND_PACKAGE(PkgConfig REQUIRED)
 162 PKG_CHECK_MODULES(ZCHUNK zck REQUIRED)
 163 ENDIF (WITH_SYSTEM_ZCHUNK)
 164
 165 IF (ENABLE_ZCHUNK_COMPRESSION)
 166 SET (ENABLE_ZSTD_COMPRESSION ON)
 167 ENDIF (ENABLE_ZCHUNK_COMPRESSION)
 168
 169 IF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 170 IF (WITH_LIBXML2 )
 171 FIND_PACKAGE (LibXml2 REQUIRED)
 172 INCLUDE_DIRECTORIES (${LIBXML2_INCLUDE_DIR})
 173 ELSE(WITH_LIBXML2 )
 174 FIND_PACKAGE (EXPAT REQUIRED)
 175 INCLUDE_DIRECTORIES (${EXPAT_INCLUDE_DIRS})
 176 ENDIF (WITH_LIBXML2 )
 177 ENDIF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 178
 179 IF (ENABLE_ZLIB_COMPRESSION)
 180 FIND_PACKAGE (ZLIB REQUIRED)
 181 ENDIF (ENABLE_ZLIB_COMPRESSION)
 182
 183 IF (ENABLE_LZMA_COMPRESSION)
 184 FIND_PACKAGE (LZMA REQUIRED)
 185 ENDIF (ENABLE_LZMA_COMPRESSION)
 186
 187 IF (ENABLE_BZIP2_COMPRESSION)
 188 FIND_PACKAGE (BZip2 REQUIRED)
 189 ENDIF (ENABLE_BZIP2_COMPRESSION)
 190
 191 IF (ENABLE_ZSTD_COMPRESSION)
 192 FIND_LIBRARY (ZSTD_LIBRARY NAMES zstd)
 193 ENDIF (ENABLE_ZSTD_COMPRESSION)
 194
 195 IF (RPM5)
 196 MESSAGE (STATUS "Enabling RPM 5 support")
 197 ADD_DEFINITIONS (-DRPM5)
 198 SET (ENABLE_RPMDB ON)
 199 SET (ENABLE_RPMMD ON)
 200 FIND_PACKAGE (PkgConfig REQUIRED)
 201 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 202 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 203 ENDIF (RPM5)
 204
 205 IF (MULTI_SEMANTICS)
 206 MESSAGE (STATUS "Enabling multi dist support")
 207 ENDIF (MULTI_SEMANTICS)
 208
 209 IF (ENABLE_RPMDB)
 210 SET (ENABLE_RPMPKG ON)
 211 ENDIF (ENABLE_RPMDB)
 212
 213 INCLUDE (CheckIncludeFile)
 214 IF (ENABLE_RPMDB OR ENABLE_RPMPKG_LIBRPM)
 215   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 216
 217   IF (NOT RPMDB_LIBRARY)
 218     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 219   ENDIF (NOT RPMDB_LIBRARY)
 220
 221   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 222   IF (RPMIO_LIBRARY)
 223     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 224   ENDIF (RPMIO_LIBRARY)
 225
 226   IF (RPM5)
 227     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 228     IF (RPMMISC_LIBRARY)
 229       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 230     ENDIF (RPMMISC_LIBRARY)
 231   ENDIF (RPM5)
 232
 233   # check if rpm contains a bundled berkeley db
 234   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 235   IF (NOT ENABLE_RPMDB_LIBRPM)
 236     IF (NOT HAVE_RPM_DB_H)
 237       FIND_LIBRARY (DB_LIBRARY NAMES db)
 238       IF (DB_LIBRARY)
 239         SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 240       ENDIF (DB_LIBRARY)
 241       IF (DB_INCLUDE_DIR)
 242         INCLUDE_DIRECTORIES (${DB_INCLUDE_DIR})
 243       ENDIF (DB_INCLUDE_DIR)
 244     ENDIF (NOT HAVE_RPM_DB_H)
 245   ENDIF (NOT ENABLE_RPMDB_LIBRPM)
 246   INCLUDE (CheckLibraryExists)
 247   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 248 ENDIF (ENABLE_RPMDB OR ENABLE_RPMPKG_LIBRPM)
 249
 250 IF (ENABLE_PUBKEY)
 251   SET (ENABLE_PGPVRFY ON)
 252 ENDIF (ENABLE_PUBKEY)
 253
 254 INCLUDE (CheckFunctionExists)
 255 INCLUDE (TestBigEndian)
 256
 257 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 258 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 259 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 260 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 261
 262 IF (${CMAKE_MAJOR_VERSION} GREATER 2)
 263 INCLUDE (CMakePushCheckState)
 264 INCLUDE (CheckCCompilerFlag)
 265 MACRO (check_linker_flag FLAG VAR)
 266         CMAKE_PUSH_CHECK_STATE (RESET)
 267         SET (CMAKE_REQUIRED_FLAGS "${FLAG}")
 268         CHECK_C_COMPILER_FLAG ("" "${VAR}")
 269         CMAKE_POP_CHECK_STATE ()
 270 ENDMACRO (check_linker_flag)
 271 check_linker_flag("-Wl,--as-needed" HAVE_LINKER_AS_NEEDED)
 272 check_linker_flag("-Wl,--version-script=${CMAKE_SOURCE_DIR}/src/libsolv.ver" HAVE_LINKER_VERSION_SCRIPT)
 273 ELSE (${CMAKE_MAJOR_VERSION} GREATER 2)
 274 SET (HAVE_LINKER_AS_NEEDED 1)
 275 SET (HAVE_LINKER_VERSION_SCRIPT 1)
 276 ENDIF (${CMAKE_MAJOR_VERSION} GREATER 2)
 277
 278 # should create config.h with #cmakedefine instead...
 279 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 280   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS WITH_LIBXML2 )
 281   IF(${VAR})
 282     ADD_DEFINITIONS (-D${VAR}=1)
 283     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 284   ENDIF (${VAR})
 285 ENDFOREACH (VAR)
 286
 287 FOREACH (VAR
 288   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS MULTI_SEMANTICS)
 289   IF(${VAR})
 290     ADD_DEFINITIONS (-D${VAR}=1)
 291     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 292     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 293     SET (LIBSOLV_FEATURE_${VARX} 1)
 294   ENDIF (${VAR})
 295 ENDFOREACH (VAR)
 296
 297 FOREACH (VAR
 298   ENABLE_RPMDB ENABLE_RPMPKG ENABLE_PUBKEY ENABLE_RPMMD
 299   ENABLE_RPMPKG_LIBRPM ENABLE_RPMDB_LIBRPM ENABLE_RPMDB_BYRPMHEADER
 300   ENABLE_SUSEREPO ENABLE_COMPS ENABLE_TESTCASE_HELIXREPO
 301   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 302   ENABLE_ZLIB_COMPRESSION ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION
 303   ENABLE_ZSTD_COMPRESSION ENABLE_ZCHUNK_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA
 304   WITH_SYSTEM_ZCHUNK)
 305   IF(${VAR})
 306     ADD_DEFINITIONS (-D${VAR}=1)
 307     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 308     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 309     SET (LIBSOLVEXT_FEATURE_${VARX} 1)
 310   ENDIF (${VAR})
 311 ENDFOREACH (VAR)
 312
 313 SET (PACKAGE "libsolv")
 314 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 315
 316 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 317 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 318
 319 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 320 SET (CPACK_PACKAGE_VENDOR "SUSE")
 321 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 322 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 323 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 324 SET (CPACK_GENERATOR "TBZ2")
 325 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 326 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 327 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 328 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 329
 330 # The following components are regex's to match anywhere (unless anchored)
 331 # in absolute path + filename to find files or directories to be excluded
 332 # from source tarball.
 333 SET (CPACK_SOURCE_IGNORE_FILES
 334 # temporary files
 335 "\\\\.swp$"
 336 # backup files
 337 "~$"
 338 # eclipse files
 339 "\\\\.cdtproject$"
 340 "\\\\.cproject$"
 341 "\\\\.project$"
 342 "\\\\.settings/"
 343 # others
 344 "\\\\.#"
 345 "/#"
 346 "/build/"
 347 "/_build/"
 348 "/\\\\.git/"
 349 # used before
 350 "/\\\\.libs/"
 351 "/\\\\.deps/"
 352 "\\\\.o$"
 353 "\\\\.lo$"
 354 "\\\\.la$"
 355 "Makefile$"
 356 "Makefile\\\\.in$"
 357 # cmake cache files
 358 "DartConfiguration.tcl$"
 359 "CMakeCache.txt"
 360 "CMakeFiles"
 361 "cmake_install.cmake$"
 362 "CMakeLists.txt.auto$"
 363 "CTestTestfile.cmake"
 364 "CPackConfig.cmake$"
 365 "CPackSourceConfig.cmake$"
 366 "libsolv.spec$"
 367 )
 368
 369 INCLUDE(CPack)
 370
 371 ####################################################################
 372 # INCLUDES                                                         #
 373 ####################################################################
 374
 375 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 376 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 377
 378 ####################################################################
 379
 380 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 381
 382 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 383 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 384 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 385 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 386
 387 # set system libraries
 388 SET (SYSTEM_LIBRARIES "")
 389 IF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 390 IF (WITH_LIBXML2 )
 391 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LIBXML2_LIBRARIES})
 392 ELSE (WITH_LIBXML2 )
 393 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${EXPAT_LIBRARY})
 394 ENDIF (WITH_LIBXML2 )
 395
 396 ENDIF (ENABLE_RPMMD OR ENABLE_SUSEREPO OR ENABLE_APPDATA OR ENABLE_COMPS OR ENABLE_HELIXREPO OR ENABLE_MDKREPO)
 397 IF (ENABLE_ZLIB_COMPRESSION)
 398 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZLIB_LIBRARY})
 399 ENDIF (ENABLE_ZLIB_COMPRESSION)
 400 IF (ENABLE_LZMA_COMPRESSION)
 401 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 402 ENDIF (ENABLE_LZMA_COMPRESSION)
 403 IF (ENABLE_BZIP2_COMPRESSION)
 404 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 405 ENDIF (ENABLE_BZIP2_COMPRESSION)
 406 IF (ENABLE_ZSTD_COMPRESSION)
 407 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZSTD_LIBRARY})
 408 ENDIF (ENABLE_ZSTD_COMPRESSION)
 409 IF (WITH_SYSTEM_ZCHUNK)
 410 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${ZCHUNK_LIBRARIES})
 411 ENDIF (WITH_SYSTEM_ZCHUNK)
 412 IF (ENABLE_RPMDB)
 413 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 414 ENDIF (ENABLE_RPMDB)
 415 IF (ENABLE_HAIKU)
 416 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 417 ENDIF (ENABLE_HAIKU)
 418 IF (HAVE_LINKER_AS_NEEDED)
 419 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 420 ENDIF (HAVE_LINKER_AS_NEEDED)
 421
 422 ADD_SUBDIRECTORY (src)
 423 ADD_SUBDIRECTORY (ext)
 424 ADD_SUBDIRECTORY (tools)
 425 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 426     ADD_SUBDIRECTORY (bindings)
 427 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 428 ADD_SUBDIRECTORY (examples)
 429 ADD_SUBDIRECTORY (doc)
 430
 431 MESSAGE (STATUS "Version: ${VERSION}")
 432
 433 ####################################################################
 434 # RPM SPEC                                                         #
 435 ####################################################################
 436
 437 MACRO (SPECFILE)
 438   MESSAGE (STATUS "Writing spec file...")
 439   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 440 ENDMACRO (SPECFILE)
 441
 442 MACRO (PCFILE)
 443   MESSAGE (STATUS "Writing pkg-config files...")
 444   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolv.pc.in ${CMAKE_BINARY_DIR}/libsolv.pc @ONLY)
 445   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolv.pc DESTINATION ${PKGCONFIG_INSTALL_DIR} )
 446   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolvext.pc.in ${CMAKE_BINARY_DIR}/libsolvext.pc @ONLY)
 447   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolvext.pc DESTINATION ${PKGCONFIG_INSTALL_DIR} )
 448 ENDMACRO (PCFILE)
 449
 450 SPECFILE ()
 451 PCFILE ()
 452
 453 SET (AUTOBUILD_COMMAND
 454   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 455   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 456   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 457   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 458   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 459   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 460 )
 461
 462 ADD_CUSTOM_TARGET (srcpackage
 463   ${AUTOBUILD_COMMAND}
 464 )
 465
 466 ADD_CUSTOM_TARGET (srcpackage_local
 467   ${AUTOBUILD_COMMAND}
 468 )
 469
 470 ENABLE_TESTING()
 471 ADD_SUBDIRECTORY (test)