cpp/CMakeLists.txt

   1 # Copyright (C) 2011 The Libphonenumber Authors
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Author: Philippe Liard
  16
  17 cmake_minimum_required (VERSION 2.8)
  18
  19 project (libphonenumber)
  20 set (libphonenumber_VERSION_MAJOR 7)
  21 set (libphonenumber_VERSION_MINOR 0)
  22 set (libphonenumber_VERSION_PATCH 2)
  23
  24 if (32BIT)
  25   set_property (GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS FALSE)
  26   set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
  27   set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
  28   set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
  29   set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
  30 endif ()
  31
  32 # Helper functions dealing with finding libraries and programs this library
  33 # depends on.
  34
  35 include (../tools/cpp/gtest.cmake)
  36
  37 function (print_error DESCRIPTION FILE)
  38   message (FATAL_ERROR
  39     "Can't find ${DESCRIPTION}: can't locate ${FILE}. Please read the README.")
  40 endfunction ()
  41
  42 # Find a library. If it has not been found, stop CMake with a fatal error
  43 # message.
  44 function (find_required_library NAME HEADER LIBRARY DESCRIPTION)
  45   # Check the header.
  46   find_path (${NAME}_INCLUDE_DIR ${HEADER})
  47   set (INCLUDE_DIR ${${NAME}_INCLUDE_DIR})
  48
  49   if (${INCLUDE_DIR} STREQUAL "${INCLUDE_DIR}-NOTFOUND")
  50     print_error (${DESCRIPTION} ${HEADER})
  51   endif ()
  52   include_directories (${INCLUDE_DIR})
  53   # Check the binary.
  54   find_library (${NAME}_LIB ${LIBRARY})
  55   set (LIB ${NAME}_LIB)
  56
  57   if (${LIB} STREQUAL "${LIB}-NOTFOUND")
  58     print_error (${DESCRIPTION} ${LIBRARY})
  59   endif ()
  60 endfunction (find_required_library)
  61
  62 # Check the library version (if pkg-config available).
  63 find_package (PkgConfig)
  64 function (check_library_version VARNAME LIBRARY_WITH_VERSION)
  65   if (PKG_CONFIG_FOUND)
  66     pkg_check_modules (${VARNAME} ${LIBRARY_WITH_VERSION})
  67   endif ()
  68 endfunction ()
  69
  70 # Find a program. If it has not been found, stop CMake with a fatal error
  71 # message.
  72 function (find_required_program NAME FILENAME DESCRIPTION)
  73   find_program (${NAME}_BIN NAMES ${FILENAME})
  74
  75   if (${NAME}_BIN STREQUAL "${${NAME}_BIN}-NOTFOUND")
  76     print_error (${DESCRIPTION} ${FILENAME})
  77   endif ()
  78 endfunction (find_required_program)
  79
  80 # Options that can be passed to CMake using 'cmake -DKEY=VALUE'.
  81 option ("BUILD_GEOCODER" "Build the offline phone number geocoder" "ON")
  82 option ("USE_ALTERNATE_FORMATS" "Use alternate formats" "ON")
  83 option ("USE_BOOST" "Use Boost" "ON")
  84 option ("USE_ICU_REGEXP" "Use ICU regexp engine" "ON")
  85 option ("USE_LITE_METADATA" "Use lite metadata" "OFF")
  86 option ("USE_RE2" "Use RE2" "OFF")
  87 option ("USE_STD_MAP" "Force the use of std::map" "OFF")
  88 option ("BUILD_STATIC_LIB" "Build static libraries" "ON")
  89
  90 if (${USE_ALTERNATE_FORMATS} STREQUAL "ON")
  91   add_definitions ("-DI18N_PHONENUMBERS_USE_ALTERNATE_FORMATS")
  92 endif ()
  93
  94 # Find all the required libraries and programs.
  95 if (${USE_BOOST} STREQUAL "ON")
  96   add_definitions ("-DI18N_PHONENUMBERS_USE_BOOST")
  97   if (WIN32)
  98     set (Boost_USE_STATIC_LIBS ON)
  99   endif ()
 100   find_package (Boost 1.40.0 COMPONENTS date_time system thread)
 101   if (NOT Boost_FOUND)
 102     print_error ("Boost Date_Time/System/Thread" "Boost")
 103   endif ()
 104   include_directories (${Boost_INCLUDE_DIRS})
 105 endif ()
 106
 107 find_or_build_gtest ()
 108
 109 if (${USE_RE2} STREQUAL "ON")
 110   find_required_library (RE2 re2/re2.h re2 "Google RE2")
 111 endif ()
 112
 113 find_required_library (PROTOBUF google/protobuf/message_lite.h protobuf
 114                        "Google Protocol Buffers")
 115 check_library_version (PC_PROTOBUF protobuf>=2.4)
 116
 117 find_required_library (ICU_UC unicode/uchar.h icuuc "ICU")
 118 check_library_version (PC_ICU_UC icu-uc>=4.4)
 119
 120 set (ICU_INCLUDE_DIR ${ICU_UC_INCLUDE_DIR})
 121 set (ICU_LIB ${ICU_UC_LIB})
 122 # If ICU regexp engine is used or if the geocoder is built, use icui18n as well.
 123 if (${USE_ICU_REGEXP} STREQUAL "ON" OR ${BUILD_GEOCODER} STREQUAL "ON")
 124   find_required_library (ICU_I18N unicode/regex.h icui18n "ICU")
 125   check_library_version (PC_ICU_I18N icu-i18n>=4.4)
 126   list (APPEND ICU_INCLUDE_DIR ${ICU_I18N_INCLUDE_DIR})
 127   list (APPEND ICU_LIB ${ICU_I18N_LIB})
 128 endif ()
 129
 130 find_required_program (PROTOC protoc
 131                        "Google Protocol Buffers compiler (protoc)")
 132
 133 find_required_program (JAVA java
 134                        "Java Runtime Environment")
 135
 136 if (APPLE)
 137   FIND_LIBRARY (COREFOUNDATION_LIB CoreFoundation)
 138   FIND_LIBRARY (FOUNDATION_LIB Foundation)
 139 endif ()
 140
 141 if (${USE_STD_MAP} STREQUAL "OFF")
 142   INCLUDE (CheckIncludeFileCXX)
 143   CHECK_INCLUDE_FILE_CXX ("tr1/unordered_map" HAVE_CXX_TR1_UNORDERED_MAP)
 144   if (HAVE_CXX_TR1_UNORDERED_MAP)
 145     add_definitions ("-DI18N_PHONENUMBERS_USE_TR1_UNORDERED_MAP")
 146   endif ()
 147 endif ()
 148
 149 # Add protoc (Protocol Buffers compiler) target.
 150 set (RESOURCES_DIR "${CMAKE_SOURCE_DIR}/../resources")
 151
 152 set (
 153   PROTOBUF_SOURCES "${RESOURCES_DIR}/phonemetadata.proto"
 154                    "${RESOURCES_DIR}/phonenumber.proto"
 155 )
 156
 157 set (
 158   PROTOBUF_OUTPUT "${CMAKE_SOURCE_DIR}/src/phonenumbers/phonemetadata.pb.cc"
 159                   "${CMAKE_SOURCE_DIR}/src/phonenumbers/phonemetadata.pb.h"
 160                   "${CMAKE_SOURCE_DIR}/src/phonenumbers/phonenumber.pb.cc"
 161                   "${CMAKE_SOURCE_DIR}/src/phonenumbers/phonenumber.pb.h"
 162 )
 163
 164 add_custom_command (
 165   COMMAND ${PROTOC_BIN} --cpp_out=${CMAKE_SOURCE_DIR}/src/phonenumbers/
 166     --proto_path=${RESOURCES_DIR} ${PROTOBUF_SOURCES}
 167
 168   OUTPUT ${PROTOBUF_OUTPUT}
 169   DEPENDS ${PROTOBUF_SOURCES}
 170 )
 171
 172 if (${BUILD_GEOCODER} STREQUAL "ON")
 173   # Geocoding data cpp file generation
 174   set (TOOLS_DIR "${CMAKE_CURRENT_BINARY_DIR}/tools")
 175   add_subdirectory("${CMAKE_SOURCE_DIR}/../tools/cpp" "${TOOLS_DIR}")
 176
 177   set (GEOCODING_DIR "${RESOURCES_DIR}/geocoding")
 178   file (GLOB_RECURSE GEOCODING_SOURCES "${GEOCODING_DIR}/*.txt")
 179
 180   set (GEOCODING_DATA_OUTPUT
 181     "${CMAKE_SOURCE_DIR}/src/phonenumbers/geocoding/geocoding_data.cc"
 182   )
 183
 184   add_custom_command (
 185     COMMAND generate_geocoding_data "${GEOCODING_DIR}"
 186       "${GEOCODING_DATA_OUTPUT}"
 187
 188     OUTPUT ${GEOCODING_DATA_OUTPUT}
 189     DEPENDS ${GEOCODING_SOURCES}
 190             generate_geocoding_data
 191     COMMENT "Generating geocoding data code"
 192   )
 193 endif ()
 194
 195 set (
 196   SOURCES
 197   "src/phonenumbers/asyoutypeformatter.cc"
 198   "src/phonenumbers/base/strings/string_piece.cc"
 199   "src/phonenumbers/default_logger.cc"
 200   "src/phonenumbers/logger.cc"
 201   "src/phonenumbers/phonemetadata.pb.cc" # Generated by Protocol Buffers.
 202   "src/phonenumbers/phonenumber.cc"
 203   "src/phonenumbers/phonenumber.pb.cc"   # Generated by Protocol Buffers.
 204   "src/phonenumbers/phonenumberutil.cc"
 205   "src/phonenumbers/regex_based_matcher.cc"
 206   "src/phonenumbers/regexp_cache.cc"
 207   "src/phonenumbers/shortnumberinfo.cc"
 208   "src/phonenumbers/string_byte_sink.cc"
 209   "src/phonenumbers/stringutil.cc"
 210   "src/phonenumbers/unicodestring.cc"
 211   "src/phonenumbers/utf/rune.c"
 212   "src/phonenumbers/utf/unicodetext.cc"
 213   "src/phonenumbers/utf/unilib.cc"
 214 )
 215
 216 if (${BUILD_GEOCODER} STREQUAL "ON")
 217   set (
 218     GEOCODING_SOURCES
 219     "src/phonenumbers/geocoding/area_code_map.cc"
 220     "src/phonenumbers/geocoding/default_map_storage.cc"
 221     "src/phonenumbers/geocoding/geocoding_data.cc"
 222     "src/phonenumbers/geocoding/mapping_file_provider.cc"
 223     "src/phonenumbers/geocoding/phonenumber_offline_geocoder.cc"
 224     "src/phonenumbers/phonenumber.pb.h"  # Forces proto buffer generation.
 225   )
 226 endif ()
 227
 228 # Add regexp engine-dependent sources. ICU is used by default.
 229 if (${USE_RE2} STREQUAL "ON")
 230   # Add a flag to select the right regexp factory implementation used by
 231   # regexp_factory.h and regexp_adapter_test.cc.
 232   # When both ICU regexp and RE2 are defined, the regexp engine adapter defaults
 233   # to RE2 unless the ICU implementation is instantiated explictly obviously.
 234   add_definitions ("-DI18N_PHONENUMBERS_USE_RE2")
 235   list (APPEND SOURCES "src/phonenumbers/regexp_adapter_re2.cc")
 236 endif ()
 237
 238 if (${USE_ICU_REGEXP} STREQUAL "ON")
 239   add_definitions ("-DI18N_PHONENUMBERS_USE_ICU_REGEXP")
 240   list (APPEND SOURCES "src/phonenumbers/regexp_adapter_icu.cc")
 241   # The phone number matcher needs ICU.
 242   list (APPEND SOURCES "src/phonenumbers/phonenumbermatch.cc")
 243   list (APPEND SOURCES "src/phonenumbers/phonenumbermatcher.cc")
 244   if (${USE_ALTERNATE_FORMATS} STREQUAL "ON")
 245     list (APPEND SOURCES "src/phonenumbers/alternate_format.cc")
 246   endif ()
 247 endif ()
 248
 249 # Library sources excluding the metadata files, since special metadata is used
 250 # for unit-testing. Note that a single testing library is built for both
 251 # libphonenumber and geocoding.
 252 set (TESTING_LIBRARY_SOURCES ${SOURCES})
 253 if (${BUILD_GEOCODER} STREQUAL "ON")
 254   list (APPEND TESTING_LIBRARY_SOURCES ${GEOCODING_SOURCES})
 255 endif ()
 256
 257 # Add metadata code generation targets.
 258
 259 # This function is invoked to create metadata, test metadata and lite metadata
 260 # code generation targets.
 261 function (add_metadata_gen_target TARGET_NAME
 262                                   XML_FILE
 263                                   METADATA_TYPE
 264                                   METADATA_HEADER)
 265   set (METADATA_SOURCE_DIR "${CMAKE_SOURCE_DIR}/src/phonenumbers")
 266   set (GEN_OUTPUT "${METADATA_SOURCE_DIR}/${METADATA_TYPE}.cc"
 267                   "${METADATA_SOURCE_DIR}/${METADATA_HEADER}.h")
 268   set (JAR_PATH "${CMAKE_SOURCE_DIR}/../tools/java/cpp-build/target")
 269   set (JAR_PATH "${JAR_PATH}/cpp-build-1.0-SNAPSHOT-jar-with-dependencies.jar")
 270
 271   add_custom_command (
 272     COMMAND ${JAVA_BIN} -jar
 273       ${JAR_PATH} BuildMetadataCppFromXml ${XML_FILE}
 274       ${CMAKE_SOURCE_DIR}/src/phonenumbers ${METADATA_TYPE}
 275
 276     OUTPUT ${GEN_OUTPUT}
 277     DEPENDS ${XML_FILE}
 278   )
 279   add_custom_target (
 280     ${TARGET_NAME}
 281     DEPENDS ${GEN_OUTPUT}
 282     COMMENT "Generating Metadata code"
 283   )
 284 endfunction (add_metadata_gen_target)
 285
 286 if (${USE_LITE_METADATA} STREQUAL "ON")
 287   # Add the lite metadata generation target.
 288   set (METADATA_TARGET "generate-lite-metadata")
 289   add_metadata_gen_target (
 290     ${METADATA_TARGET}
 291     "${RESOURCES_DIR}/PhoneNumberMetadata.xml"
 292     "lite_metadata"
 293     "metadata"
 294   )
 295   list (APPEND SOURCES "src/phonenumbers/lite_metadata.cc")
 296 else ()
 297   # Add the metadata generation target.
 298   set (METADATA_TARGET "generate-metadata")
 299   add_metadata_gen_target (
 300     ${METADATA_TARGET}
 301     "${RESOURCES_DIR}/PhoneNumberMetadata.xml"
 302     "metadata"
 303     "metadata"
 304   )
 305   list (APPEND SOURCES "src/phonenumbers/metadata.cc")
 306 endif ()
 307
 308 # Add the test metadata generation target.
 309 set (TEST_METADATA_TARGET "generate-test-metadata")
 310 add_metadata_gen_target (
 311   ${TEST_METADATA_TARGET}
 312   "${RESOURCES_DIR}/PhoneNumberMetadataForTesting.xml"
 313   "test_metadata"
 314   "metadata"
 315 )
 316 list (APPEND TESTING_LIBRARY_SOURCES "src/phonenumbers/test_metadata.cc")
 317
 318 # Add the short metadata generation target.
 319 set (SHORT_METADATA_TARGET "generate-short-number-metadata")
 320 add_metadata_gen_target (
 321   ${SHORT_METADATA_TARGET}
 322   "${RESOURCES_DIR}/ShortNumberMetadata.xml"
 323   "short_metadata"
 324   "short_metadata"
 325 )
 326 # This is used both for the real library and for testing.
 327 list (APPEND SOURCES "src/phonenumbers/short_metadata.cc")
 328 list (APPEND TESTING_LIBRARY_SOURCES "src/phonenumbers/short_metadata.cc")
 329
 330 if (${USE_ICU_REGEXP} STREQUAL "ON")
 331   if (${USE_ALTERNATE_FORMATS} STREQUAL "ON")
 332     # Add alternate format metadata generation for the phone number matcher.
 333     set (ALT_FORMAT_METADATA_TARGET "generate-alt-format-metadata")
 334     add_metadata_gen_target (
 335       ${ALT_FORMAT_METADATA_TARGET}
 336       "${RESOURCES_DIR}/PhoneNumberAlternateFormats.xml"
 337       "alternate_format"
 338       "alternate_format"
 339     )
 340   endif ()
 341 endif ()
 342
 343 if (NOT WIN32)
 344   add_definitions ("-Wall -Werror")
 345 endif ()
 346
 347 include_directories ("src")
 348
 349 if ($BUILD_STATIC_LIB STREQUAL "ON")
 350   # Build a static library (without -fPIC).
 351   add_library (phonenumber STATIC ${SOURCES})
 352   if (${USE_ICU_REGEXP} STREQUAL "ON")
 353     if (${USE_ALTERNATE_FORMATS} STREQUAL "ON")
 354       add_dependencies (phonenumber ${ALT_FORMAT_METADATA_TARGET})
 355     endif ()
 356   endif ()
 357 endif ()
 358
 359 if (${BUILD_GEOCODER} STREQUAL "ON")
 360   if ($BUILD_STATIC_LIB STREQUAL "ON")
 361     add_library (geocoding STATIC ${GEOCODING_SOURCES})
 362   endif ()
 363   # The geocoder doesn't use RE2 so there is no reason not to build a shared
 364   # library for it.
 365   add_library (geocoding-shared SHARED ${GEOCODING_SOURCES})
 366   set_target_properties (geocoding-shared
 367     PROPERTIES
 368       OUTPUT_NAME "geocoding"
 369       PREFIX "lib"
 370       SOVERSION ${libphonenumber_VERSION_MAJOR}
 371       VERSION ${libphonenumber_VERSION_MAJOR}.${libphonenumber_VERSION_MINOR})
 372 endif ()
 373
 374 # Build a shared library (with -fPIC).
 375 set (BUILD_SHARED_LIB true)
 376
 377 if (${USE_RE2} STREQUAL "ON")
 378   # RE2 is not always available as a shared library (e.g: package provided by
 379   # Ubuntu) therefore disable the shared library build in this case.
 380   if (${RE2_LIB} MATCHES ".*\\.a")
 381     message (WARNING
 382       "RE2 not available as a shared library, shared library build disabled")
 383     set (BUILD_SHARED_LIB false)
 384   endif ()
 385 endif ()
 386
 387 if (BUILD_SHARED_LIB)
 388   add_library (phonenumber-shared SHARED ${SOURCES})
 389   if (${USE_ICU_REGEXP} STREQUAL "ON")
 390     if (${USE_ALTERNATE_FORMATS} STREQUAL "ON")
 391       add_dependencies (phonenumber-shared ${ALT_FORMAT_METADATA_TARGET})
 392     endif ()
 393   endif ()
 394   set_target_properties (phonenumber-shared
 395     PROPERTIES
 396       OUTPUT_NAME "phonenumber"
 397       PREFIX "lib"
 398       SOVERSION ${libphonenumber_VERSION_MAJOR}
 399       VERSION ${libphonenumber_VERSION_MAJOR}.${libphonenumber_VERSION_MINOR})
 400 endif ()
 401
 402 # Libraries used by both libphonenumber and libgeocoding.
 403 set (COMMON_DEPS ${ICU_LIB})
 404
 405 set (LIBRARY_DEPS ${PROTOBUF_LIB})
 406
 407 if (${USE_BOOST} STREQUAL "ON")
 408   list (APPEND LIBRARY_DEPS ${Boost_LIBRARIES})
 409 endif ()
 410
 411 if (${USE_RE2} STREQUAL "ON")
 412   list (APPEND LIBRARY_DEPS ${RE2_LIB})
 413 endif ()
 414
 415 if (APPLE)
 416   list (APPEND COMMON_DEPS ${COREFOUNDATION_LIB} ${FOUNDATION_LIB})
 417 endif ()
 418
 419 list (APPEND LIBRARY_DEPS ${COMMON_DEPS})
 420
 421 if (${BUILD_STATIC_LIB} STREQUAL "ON")
 422   target_link_libraries (phonenumber ${LIBRARY_DEPS})
 423 endif ()
 424
 425 if (BUILD_SHARED_LIB)
 426   target_link_libraries (phonenumber-shared ${LIBRARY_DEPS})
 427 endif ()
 428
 429 if (${BUILD_GEOCODER} STREQUAL "ON")
 430   list (APPEND GEOCODER_DEPS ${COMMON_DEPS})
 431   # Note that the subset of base/ on which the geocoder relies is implemented
 432   # on top of Boost header-only libraries (e.g. scoped_ptr.hpp).
 433   target_link_libraries (geocoding ${LIBRARY_DEPS})
 434   target_link_libraries (geocoding-shared ${LIBRARY_DEPS})
 435 endif ()
 436
 437 # Build a specific library for testing purposes.
 438 add_library (phonenumber_testing STATIC ${TESTING_LIBRARY_SOURCES})
 439 target_link_libraries (phonenumber_testing ${LIBRARY_DEPS})
 440
 441 if (${BUILD_GEOCODER} STREQUAL "ON")
 442   # Test geocoding data cpp files generation.
 443   set (GEOCODING_TEST_DIR "${RESOURCES_DIR}/test/geocoding")
 444   file (GLOB_RECURSE GEOCODING_TEST_SOURCES "${GEOCODING_TEST_DIR}/*.txt")
 445
 446   set (GEOCODING_TEST_DATA_OUTPUT
 447     "${CMAKE_SOURCE_DIR}/test/phonenumbers/geocoding/geocoding_test_data.cc"
 448   )
 449
 450   add_custom_command (
 451     COMMAND generate_geocoding_data "${GEOCODING_TEST_DIR}"
 452       "${GEOCODING_TEST_DATA_OUTPUT}" "_test"
 453
 454     OUTPUT ${GEOCODING_TEST_DATA_OUTPUT}
 455     DEPENDS ${GEOCODING_TEST_SOURCES} generate_geocoding_data
 456     COMMENT "Generating geocoding test data code"
 457   )
 458 endif ()
 459
 460
 461 set (TEST_SOURCES
 462   "test/phonenumbers/asyoutypeformatter_test.cc"
 463   "test/phonenumbers/logger_test.cc"
 464   "test/phonenumbers/phonenumberutil_test.cc"
 465   "test/phonenumbers/regexp_adapter_test.cc"
 466   "test/phonenumbers/regexp_cache_test.cc"
 467   "test/phonenumbers/run_tests.cc"
 468   "test/phonenumbers/shortnumberinfo_test.cc"
 469   "test/phonenumbers/stringutil_test.cc"
 470   "test/phonenumbers/test_util.cc"
 471   "test/phonenumbers/unicodestring_test.cc"
 472   "test/phonenumbers/utf/unicodetext_test.cc"
 473 )
 474
 475 if (${BUILD_GEOCODER} STREQUAL "ON")
 476   set (GEOCODING_TEST_SOURCES
 477     "test/phonenumbers/geocoding/area_code_map_test.cc"
 478     "test/phonenumbers/geocoding/geocoding_data_test.cc"
 479     "test/phonenumbers/geocoding/geocoding_test_data.cc"
 480     "test/phonenumbers/geocoding/mapping_file_provider_test.cc"
 481     "test/phonenumbers/geocoding/phonenumber_offline_geocoder_test.cc"
 482   )
 483   list (APPEND TEST_SOURCES ${GEOCODING_TEST_SOURCES})
 484 endif ()
 485
 486 if (${USE_ICU_REGEXP} STREQUAL "ON")
 487   # Add the phone number matcher tests.
 488   list (APPEND TEST_SOURCES "test/phonenumbers/phonenumbermatch_test.cc")
 489   list (APPEND TEST_SOURCES "test/phonenumbers/phonenumbermatcher_test.cc")
 490 endif ()
 491
 492 # Build the testing binary.
 493 include_directories ("test")
 494 add_executable (libphonenumber_test ${TEST_SOURCES})
 495 set (TEST_LIBS phonenumber_testing ${GTEST_LIB})
 496
 497 if (NOT WIN32)
 498   list (APPEND TEST_LIBS pthread)
 499 endif ()
 500
 501 target_link_libraries (libphonenumber_test ${TEST_LIBS})
 502
 503 # Unfortunately add_custom_target() can't accept a single command provided as a
 504 # list of commands.
 505 if (${BUILD_GEOCODER} STREQUAL "ON")
 506   add_custom_target (test
 507     COMMAND generate_geocoding_data_test
 508     COMMAND libphonenumber_test
 509     DEPENDS generate_geocoding_data_test libphonenumber_test
 510   )
 511 else ()
 512   add_custom_target (test
 513     COMMAND libphonenumber_test
 514     DEPENDS libphonenumber_test
 515   )
 516 endif ()
 517
 518 # Install rules.
 519 install (FILES
 520   "src/phonenumbers/asyoutypeformatter.h"
 521   "src/phonenumbers/callback.h"
 522   "src/phonenumbers/logger.h"
 523   "src/phonenumbers/matcher_api.h"
 524   "src/phonenumbers/phonenumber.pb.h"
 525   "src/phonenumbers/phonemetadata.pb.h"
 526   "src/phonenumbers/phonenumberutil.h"
 527   "src/phonenumbers/regexp_adapter.h"
 528   "src/phonenumbers/regexp_cache.h"
 529   "src/phonenumbers/shortnumberinfo.h"
 530   "src/phonenumbers/unicodestring.h"
 531   DESTINATION include/phonenumbers/
 532 )
 533
 534 install (FILES "src/phonenumbers/utf/unicodetext.h"
 535          DESTINATION include/phonenumbers/utf/)
 536
 537 if (${USE_ICU_REGEXP} STREQUAL "ON")
 538   # Install the phone number matcher headers.
 539   install (FILES
 540     "src/phonenumbers/phonenumbermatch.h"
 541     "src/phonenumbers/phonenumbermatcher.h"
 542     "src/phonenumbers/regexp_adapter.h"
 543     DESTINATION include/phonenumbers/
 544   )
 545 endif ()
 546
 547 if (${BUILD_GEOCODER} STREQUAL "ON")
 548   install (FILES
 549     "src/phonenumbers/geocoding/phonenumber_offline_geocoder.h"
 550     DESTINATION include/phonenumbers/geocoding
 551   )
 552 endif ()
 553
 554 install (
 555   FILES
 556   "src/phonenumbers/base/basictypes.h"
 557   "src/phonenumbers/base/template_util.h"
 558   "src/phonenumbers/base/logging.h"
 559   "src/phonenumbers/base/thread_checker.h"
 560   DESTINATION include/phonenumbers/base/
 561 )
 562
 563 install (FILES
 564   "src/phonenumbers/base/memory/scoped_ptr.h"
 565   "src/phonenumbers/base/memory/singleton.h"
 566   "src/phonenumbers/base/memory/singleton_posix.h"
 567   DESTINATION include/phonenumbers/base/memory/
 568 )
 569
 570 install (FILES "src/phonenumbers/base/synchronization/lock.h"
 571          DESTINATION include/phonenumbers/base/synchronization/)
 572
 573 get_property (LIB64 GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS)
 574
 575 if ("${LIB64}" STREQUAL "TRUE")
 576     set (LIBDIR lib64)
 577 else ()
 578     set (LIBDIR lib)
 579 endif ()
 580
 581 if (${BUILD_STATIC_LIB} STREQUAL "ON")
 582   install (TARGETS phonenumber LIBRARY DESTINATION ${LIBDIR} ARCHIVE DESTINATION ${LIBDIR})
 583 endif ()
 584
 585 if (BUILD_SHARED_LIB)
 586   install (TARGETS phonenumber-shared LIBRARY DESTINATION ${LIBDIR} ARCHIVE
 587            DESTINATION ${LIBDIR})
 588 endif ()
 589
 590 if (${BUILD_GEOCODER} STREQUAL "ON")
 591   install (TARGETS geocoding LIBRARY DESTINATION ${LIBDIR} ARCHIVE DESTINATION ${LIBDIR})
 592   install (TARGETS geocoding-shared LIBRARY DESTINATION ${LIBDIR} ARCHIVE
 593            DESTINATION ${LIBDIR})
 594 endif ()
 595
 596 # Build an example program using geocoding, mainly to make sure that both
 597 # libraries are built properly.
 598 if (${BUILD_GEOCODER} STREQUAL "ON")
 599   add_executable (
 600     geocoding_test_program
 601     "test/phonenumbers/geocoding/geocoding_test_program.cc"
 602   )
 603   target_link_libraries (geocoding_test_program geocoding phonenumber)
 604 endif ()
 605
 606 # Build an RPM
 607 set (CPACK_PACKAGE_VERSION ${libphonenumber_VERSION_MAJOR}.${libphonenumber_VERSION_MINOR}.${libphonenumber_VERSION_PATCH})
 608 set (CPACK_GENERATOR "RPM")
 609 set (CPACK_PACKAGE_NAME "libphonenumber")
 610 set (CPACK_RPM_PACKAGE_RELEASE 1)
 611 set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Google's phone number handling library")
 612 if (32BIT)
 613   set (CPACK_RPM_PACKAGE_ARCHITECTURE i686)
 614 else ()
 615   set (CPACK_RPM_PACKAGE_ARCHITECTURE x86_64)
 616 endif ()
 617 set (CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_RPM_PACKAGE_RELEASE}.${CPACK_RPM_PACKAGE_ARCHITECTURE}")
 618 include (CPack)