configure.ac

   1 # Copyright © 2013 Red Hat, Inc.
   2 #
   3 # Permission to use, copy, modify, distribute, and sell this software and its
   4 # documentation for any purpose is hereby granted without fee, provided that
   5 # the above copyright notice appear in all copies and that both that copyright
   6 # notice and this permission notice appear in supporting documentation, and
   7 # that the name of the copyright holders not be used in advertising or
   8 # publicity pertaining to distribution of the software without specific,
   9 # written prior permission.  The copyright holders make no representations
  10 # about the suitability of this software for any purpose.  It is provided "as
  11 # is" without express or implied warranty.
  12 #
  13 # THE COPYRIGHT HOLDERS DISCLAIM ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 # INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 # EVENT SHALL THE COPYRIGHT HOLDERS BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 # CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 # DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 # TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE
  19 # OF THIS SOFTWARE.
  20
  21 AC_PREREQ([2.62])
  22
  23 AC_INIT([libevdev],
  24         [0.6],
  25         [https://bugs.freedesktop.org/enter_bug.cgi?product=libevdev],
  26         [libevdev],
  27         [])
  28
  29 AC_CONFIG_SRCDIR([libevdev/libevdev.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_USE_SYSTEM_EXTENSIONS
  34
  35 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  36
  37 # Before making a release, the LIBEVDEV_LT_VERSION string should be
  38 # modified.
  39 # The string is of the form C:R:A.
  40 # - If interfaces have been changed or added, but binary compatibility has
  41 #   been preserved, change to C+1:0:A+1
  42 # - If binary compatibility has been broken (eg removed or changed interfaces)
  43 #   change to C+1:0:0
  44 # - If the interface is the same as the previous version, change to C:R+1:A
  45 LIBEVDEV_LT_VERSION=1:0:0
  46 AC_SUBST(LIBEVDEV_LT_VERSION)
  47
  48
  49 AM_SILENT_RULES([yes])
  50
  51 # Check for programs
  52 AC_PROG_CC_C99
  53
  54 # Initialize libtool
  55 LT_PREREQ([2.2])
  56 LT_INIT
  57 LT_PATH_LD
  58
  59 with_ldflags=""
  60 if test "x$lt_cv_prog_gnu_ld" = "xyes"; then
  61         CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
  62                                 -Wl,--as-needed \
  63                                 -Wl,--gc-sections \
  64                                 -Wl,-z,relro \
  65                                 -Wl,-z,now])
  66 fi
  67 AC_SUBST([GNU_LD_FLAGS], $with_ldflags)
  68
  69 PKG_PROG_PKG_CONFIG()
  70 PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
  71 if test "x$HAVE_CHECK" != "xyes"; then
  72        AC_MSG_WARN([check not found - skipping building unit tests])
  73 fi
  74 AM_CONDITIONAL(BUILD_TESTS, [test "x$HAVE_CHECK" = "xyes"])
  75
  76 with_cflags=""
  77 if test "x$GCC" = "xyes"; then
  78         CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  79                                 -Wall \
  80                                 -Wextra \
  81                                 -Wno-unused-parameter \
  82                                 -Wstrict-prototypes \
  83                                 -Wmissing-prototypes \
  84                                 -fvisibility=hidden \
  85                                 -pipe \
  86                                 -fno-strict-aliasing \
  87                                 -ffunction-sections \
  88                                 -fdata-sections \
  89                                 -fno-strict-aliasing \
  90                                 -fdiagnostics-show-option \
  91                                 -fno-common])
  92 fi
  93 AC_SUBST([GCC_CFLAGS], $with_cflags)
  94
  95 AC_PATH_PROG(DOXYGEN, [doxygen])
  96 if test "x$DOXYGEN" = "x"; then
  97         AC_MSG_WARN([doxygen not found - required for documentation])
  98         have_doxygen="no"
  99 else
 100         have_doxygen="yes"
 101 fi
 102 AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
 103
 104 AC_MSG_CHECKING([whether to build with gcov])
 105 AC_ARG_ENABLE([gcov],
 106               [AS_HELP_STRING([--enable-gcov],
 107                               [Whether to enable coverage testing (default:disabled)])],
 108               [],
 109               [enable_gcov=no],
 110               )
 111 AS_IF([test "x$enable_gcov" != "xno"],
 112       [
 113        GCOV_CFLAGS="-fprofile-arcs -ftest-coverage"
 114        GCOV_LDFLAGS="-fprofile-arcs -ftest-coverage"
 115        enable_gcov=yes
 116        ],
 117 )
 118
 119 AM_PATH_PYTHON([2.6])
 120 AS_IF([$($PYTHON -c "import argparse")], [:],
 121        AC_MSG_ERROR([python argparse module is missing]))
 122
 123 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" != "xno"])
 124 AC_SUBST([GCOV_CFLAGS])
 125 AC_SUBST([GCOV_LDFLAGS])
 126 AC_MSG_RESULT([$enable_gcov])
 127
 128 AC_CONFIG_FILES([Makefile
 129                  libevdev/Makefile
 130                  doc/Makefile
 131                  doc/libevdev.doxygen
 132                  doc/libevdev.man
 133                  tools/Makefile
 134                  test/Makefile
 135                  libevdev.pc])
 136 AC_OUTPUT
 137
 138 AC_MSG_RESULT([
 139                Build documentation      ${have_doxygen}
 140                Build unit-tests         ${HAVE_CHECK}
 141                Enable profiling         ${enable_gcov}
 142                ])