configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.25],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2])
  47 LT_INIT([disable-static])
  48
  49
  50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  51 AC_SUBST(PTHREADSTUBS_CFLAGS)
  52 AC_SUBST(PTHREADSTUBS_LIBS)
  53
  54 pkgconfigdir=${libdir}/pkgconfig
  55 AC_SUBST(pkgconfigdir)
  56 AC_ARG_ENABLE([udev],
  57               [AS_HELP_STRING([--enable-udev],
  58                               [Enable support for using udev instead of mknod (default: disabled)])],
  59               [UDEV=$enableval], [UDEV=no])
  60
  61 AC_ARG_ENABLE(libkms,
  62               AS_HELP_STRING([--disable-libkms],
  63               [Disable KMS mm abstraction library (default: auto)]),
  64               [LIBKMS=$enableval], [LIBKMS=auto])
  65
  66 AC_ARG_ENABLE(intel,
  67               AS_HELP_STRING([--disable-intel],
  68               [Enable support for intel's KMS API (default: auto)]),
  69               [INTEL=$enableval], [INTEL=auto])
  70
  71 AC_ARG_ENABLE(radeon,
  72               AS_HELP_STRING([--disable-radeon],
  73               [Enable support for radeon's KMS API (default: auto)]),
  74               [RADEON=$enableval], [RADEON=auto])
  75
  76 AC_ARG_ENABLE(vmwgfx-experimental-api,
  77               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
  78               [Install vmwgfx's experimental kernel API header (default: disabled)]),
  79               [VMWGFX=$enableval], [VMWGFX=no])
  80
  81 AC_ARG_ENABLE(nouveau-experimental-api,
  82               AS_HELP_STRING([--enable-nouveau-experimental-api],
  83               [Enable support for nouveau's experimental API (default: disabled)]),
  84               [NOUVEAU=$enableval], [NOUVEAU=no])
  85
  86
  87 dnl ===========================================================================
  88 dnl check compiler flags
  89 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  90   AC_MSG_CHECKING([whether $CC supports $1])
  91
  92   libdrm_save_CFLAGS="$CFLAGS"
  93   CFLAGS="$CFLAGS $1"
  94
  95   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  96   CFLAGS="$libdrm_save_CFLAGS"
  97
  98   if test "x$libdrm_cc_flag" = "xyes"; then
  99     ifelse([$2], , :, [$2])
 100   else
 101     ifelse([$3], , :, [$3])
 102   fi
 103   AC_MSG_RESULT([$libdrm_cc_flag])
 104 ])
 105
 106 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 107
 108 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 109                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 110                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 111 AC_SUBST([CLOCK_LIB])
 112
 113 dnl Use lots of warning flags with with gcc and compatible compilers
 114
 115 dnl Note: if you change the following variable, the cache is automatically
 116 dnl skipped and all flags rechecked.  So there's no need to do anything
 117 dnl else.  If for any reason you need to force a recheck, just change
 118 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 119
 120 MAYBE_WARN="-Wall -Wextra \
 121 -Wsign-compare -Werror-implicit-function-declaration \
 122 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 123 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 124 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 125 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 126 -Wdeclaration-after-statement -Wold-style-definition \
 127 -Wno-missing-field-initializers -Wno-unused-parameter \
 128 -Wno-attributes -Wno-long-long -Winline"
 129
 130 # invalidate cached value if MAYBE_WARN has changed
 131 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 132         unset libdrm_cv_warn_cflags
 133 fi
 134 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 135         echo
 136         WARN_CFLAGS=""
 137
 138         # Some warning options are not supported by all versions of
 139         # gcc, so test all desired options against the current
 140         # compiler.
 141         #
 142         # Note that there are some order dependencies
 143         # here. Specifically, an option that disables a warning will
 144         # have no net effect if a later option then enables that
 145         # warnings, (perhaps implicitly). So we put some grouped
 146         # options (-Wall and -Wextra) up front and the -Wno options
 147         # last.
 148
 149         for W in $MAYBE_WARN; do
 150                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 151         done
 152
 153         libdrm_cv_warn_cflags=$WARN_CFLAGS
 154         libdrm_cv_warn_maybe=$MAYBE_WARN
 155
 156         AC_MSG_CHECKING([which warning flags were supported])])
 157 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 158
 159 if test "x$UDEV" = xyes; then
 160         AC_DEFINE(UDEV, 1, [Have UDEV support])
 161 fi
 162
 163 AC_CANONICAL_HOST
 164 if test "x$LIBKMS" = xauto ; then
 165         case $host_os in
 166                 linux*)         LIBKMS="yes" ;;
 167                 *)              LIBKMS="no" ;;
 168         esac
 169 fi
 170
 171 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 172
 173 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 174 if test "x$VMWGFX" = xyes; then
 175         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 176 fi
 177
 178 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 179 if test "x$NOUVEAU" = xyes; then
 180         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 181 fi
 182
 183 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 184 if test "x$HAVE_CAIRO" = xyes; then
 185         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 186 fi
 187 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 188
 189 # For enumerating devices in test case
 190 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 191 if test "x$HAVE_LIBUDEV" = xyes; then
 192         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 193 fi
 194 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 195
 196 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
 197     # Check for atomic intrinsics
 198     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 199     [
 200             drm_cv_atomic_primitives="none"
 201
 202             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 203     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 204     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 205                                             ]],[[]])],
 206                            [drm_cv_atomic_primitives="Intel"],[])
 207
 208             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 209                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 210             fi
 211
 212             # atomic functions defined in <atomic.h> & libc on Solaris
 213             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 214                     AC_CHECK_FUNC([atomic_cas_uint],
 215                                   drm_cv_atomic_primitives="Solaris")
 216             fi
 217
 218     ])
 219     if test "x$drm_cv_atomic_primitives" = xIntel; then
 220             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 221                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 222     fi
 223     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 224             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 225     fi
 226
 227     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 228            if test "x$INTEL" != "xauto"; then
 229                    if test "x$INTEL" != "xno"; then
 230                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 231                    fi
 232            else
 233                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 234                    INTEL=no
 235            fi
 236            if test "x$RADEON" != "xauto"; then
 237                    if test "x$RADEON" != "xno"; then
 238                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
 239                    fi
 240            else
 241                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 242                    RADEON=no
 243            fi
 244
 245     else
 246            if test "x$INTEL" != "xno"; then
 247                    INTEL=yes
 248            fi
 249            if test "x$RADEON" != "xno"; then
 250                    RADEON=yes
 251            fi
 252     fi
 253 fi
 254
 255 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 256 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
 257 if test "x$RADEON" = xyes; then
 258         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 259 fi
 260
 261 AC_ARG_WITH([kernel-source],
 262             [AS_HELP_STRING([--with-kernel-source],
 263               [specify path to linux kernel source])],
 264             [kernel_source="$with_kernel_source"])
 265 AC_SUBST(kernel_source)
 266
 267 AC_SUBST(WARN_CFLAGS)
 268 AC_CONFIG_FILES([
 269         Makefile
 270         libkms/Makefile
 271         libkms/libkms.pc
 272         intel/Makefile
 273         intel/libdrm_intel.pc
 274         radeon/Makefile
 275         radeon/libdrm_radeon.pc
 276         nouveau/Makefile
 277         nouveau/libdrm_nouveau.pc
 278         tests/Makefile
 279         tests/modeprint/Makefile
 280         tests/modetest/Makefile
 281         tests/kmstest/Makefile
 282         tests/vbltest/Makefile
 283         include/Makefile
 284         include/drm/Makefile
 285         libdrm.pc])
 286 AC_OUTPUT
 287
 288 echo ""
 289 echo "$PACKAGE_STRING will be compiled with:"
 290 echo ""
 291 echo "  libkms         $LIBKMS"
 292 echo "  Intel API      $INTEL"
 293 echo "  vmwgfx API     $VMWGFX"
 294 echo "  Radeon API     $RADEON"
 295 echo "  Nouveau API    $NOUVEAU"
 296 echo ""