configure.ac

   1
   2 # Initialize Autoconf
   3 AC_PREREQ([2.60])
   4 AC_INIT([libXi], [1.6.1],
   5         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg], [libXi])
   6 AC_CONFIG_SRCDIR([Makefile.am])
   7 AC_CONFIG_HEADERS([src/config.h])
   8
   9 # Initialize Automake
  10 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  11 AM_MAINTAINER_MODE
  12
  13 # Initialize libtool
  14 AC_PROG_LIBTOOL
  15
  16 # Require xorg-macros minimum of 1.12 for DocBook external references
  17 m4_ifndef([XORG_MACROS_VERSION],
  18           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  19 XORG_MACROS_VERSION(1.12)
  20 XORG_DEFAULT_OPTIONS
  21 XORG_ENABLE_DOCS
  22 XORG_ENABLE_SPECS
  23 XORG_WITH_XMLTO(0.0.22)
  24 XORG_WITH_FOP
  25 XORG_WITH_XSLTPROC
  26 XORG_CHECK_SGML_DOCTOOLS(1.8)
  27 XORG_WITH_ASCIIDOC(8.4.5)
  28 XORG_CHECK_MALLOC_ZERO
  29
  30 # Obtain compiler/linker options for dependencies
  31 PKG_CHECK_MODULES(XI, [xproto >= 7.0.13] [x11 >= 1.4.99.1] [xextproto >= 7.0.3] [xext >= 1.0.99.1] [inputproto >= 2.1.99.6])
  32
  33 # Check for xmlto and asciidoc for man page conversion
  34 # (only needed by people building tarballs)
  35 if test "$have_xmlto" = yes && test "$have_asciidoc" = yes; then
  36         have_doctools=yes
  37 else
  38         have_doctools=no
  39 fi
  40 AM_CONDITIONAL([HAVE_DOCTOOLS], [test $have_doctools = yes])
  41 if test $have_doctools = no; then
  42         AC_MSG_WARN([xmlto or asciidoc not found - cannot create man pages without it])
  43 fi
  44
  45 # Determine if the source for man pages is available
  46 # It may already be present (tarball) or can be generated using doctools
  47 AM_CONDITIONAL([INSTALL_MANPAGES],
  48         [test -f "$srcdir/man/XAllowDeviceEvents.man" || \
  49           test $have_doctools = yes])
  50
  51 AC_CONFIG_FILES([Makefile
  52                 src/Makefile
  53                 man/Makefile
  54                 specs/Makefile
  55                 xi.pc])
  56 AC_OUTPUT