run.bat

   1 @echo off
   2 REM Helper script to build and run IoTivity on Windows
   3 SETLOCAL ENABLEDELAYEDEXPANSION
   4
   5 if [%1]==[] goto USAGE
   6
   7 set IOTIVITY_DIR=%~dp0
   8 set HOME=%USERPROFILE%
   9
  10 IF "%1" == "msys" (
  11   set BUILD_MSYS="YES"
  12   SHIFT
  13 ) ELSE (
  14   set BUILD_MSYS=
  15 )
  16
  17 set CURRENT_ARG=%1
  18 set SECOND_ARG=%2
  19 set DEBUG=
  20
  21 if "!SECOND_ARG!"=="debug" (
  22   set DEBUG="%ProgramFiles(x86)%\Windows Kits\10\Debuggers\x64\cdb.exe" -2 -c "g"
  23 )
  24
  25 IF "%BUILD_MSYS%" == "" (
  26   IF NOT "%VS140COMNTOOLS%" == "" (
  27     CALL "%VS140COMNTOOLS%"vsvars32.bat
  28   ) ELSE (
  29     IF NOT "%VS120COMNTOOLS%" == "" (
  30       CALL "%VS120COMNTOOLS%"vsvars32.bat
  31       )
  32     )
  33
  34   IF NOT "!VSINSTALLDIR!" == "" (
  35       CALL "!VSINSTALLDIR!VC\vcvarsall.bat" amd64
  36   ) ELSE (
  37     @ECHO WARNING: Could not find vsvarsall.bat.
  38     @ECHO WARNING: VISUAL STUDIO 2013/2015 DOES NOT APPEAR TO BE INSTALLED ON THIS MACHINE
  39     GOTO :EOF
  40   )
  41 )
  42
  43 REM We need to append the "PATH" so the octbstack.dll can be found by executables
  44 IF "%BUILD_MSYS%" == "" (
  45   set BUILD_DIR=out\windows\amd64\debug
  46   set PATH=!PATH!;!BUILD_DIR!;
  47 ) ELSE (
  48   set BUILD_DIR=out\msys_nt\x86_64\debug
  49   set PATH=!PATH!;!BUILD_DIR!;C:\msys64\mingw64\bin
  50 )
  51
  52 REM *** BUILD OPTIONS ***
  53 set TARGET_OS=windows
  54 set TARGET_ARCH=amd64
  55 set SECURED=1
  56 set TEST=1
  57 set LOGGING=OFF
  58 set WITH_RD=1
  59 REM *** BUILD OPTIONS ***
  60
  61 if "!CURRENT_ARG!"=="server" (
  62   %DEBUG% %BUILD_DIR%\resource\examples\simpleserver.exe
  63 ) else if "!CURRENT_ARG!"=="client" (
  64   %DEBUG% %BUILD_DIR%\resource\examples\simpleclient.exe
  65 ) else if "!CURRENT_ARG!"=="mediaclient" (
  66   %DEBUG% %BUILD_DIR%\debug\resource\examples\mediaclient.exe
  67 ) else if "!CURRENT_ARG!"=="mediaserver" (
  68   %DEBUG% %BUILD_DIR%\resource\examples\mediaserver.exe
  69 ) else if "!CURRENT_ARG!"=="winuiclient" (
  70   %DEBUG% %BUILD_DIR%\resource\examples\winuiclient.exe
  71 ) else if "!CURRENT_ARG!"=="occlient" (
  72   %DEBUG% %BUILD_DIR%\resource\csdk\stack\samples\linux\SimpleClientServer\occlientbasicops.exe -u 0 -t 3 -c 1
  73 ) else if "!CURRENT_ARG!"=="ocserver" (
  74   %DEBUG% %BUILD_DIR%\resource\csdk\stack\samples\linux\SimpleClientServer\ocserverbasicops.exe
  75 ) else if "!CURRENT_ARG!"=="test" (
  76   %DEBUG% %BUILD_DIR%\resource\csdk\connectivity\test\catests.exe
  77   %DEBUG% %BUILD_DIR%\resource\csdk\stack\test\stacktests.exe
  78   %DEBUG% %BUILD_DIR%\resource\csdk\stack\test\cbortests.exe
  79   %DEBUG% %BUILD_DIR%\resource\csdk\security\unittest\unittest.exe
  80 ) else if "!CURRENT_ARG!"=="build" (
  81   echo Starting IoTivity build with these options:
  82   echo   TARGET_OS=%TARGET_OS%
  83   echo   TARGET_ARCH=%TARGET_ARCH%
  84   echo   SECURED=%SECURED%
  85   echo   LOGGING=%LOGGING%
  86   echo   WITH_RD=%WITH_RD%
  87   CL.exe | findstr "Compiler Verison"
  88   echo.scons VERBOSE=1 TARGET_OS=%TARGET_OS% TARGET_ARCH=%TARGET_ARCH% RELEASE=0 WITH_RA=0 TARGET_TRANSPORT=IP SECURED=%SECURED% WITH_TCP=0 BUILD_SAMPLE=ON LOGGING=%LOGGING% TEST=%TEST% WITH_RD=%WITH_RD%
  89   scons VERBOSE=1 TARGET_OS=%TARGET_OS% TARGET_ARCH=%TARGET_ARCH% RELEASE=0 WITH_RA=0 TARGET_TRANSPORT=IP SECURED=%SECURED% WITH_TCP=0 BUILD_SAMPLE=ON LOGGING=%LOGGING% TEST=%TEST% WITH_RD=%WITH_RD%
  90 ) else if "!CURRENT_ARG!"=="clean" (
  91   scons VERBOSE=1 TARGET_OS=%TARGET_OS% TARGET_ARCH=%TARGET_ARCH% RELEASE=0 WITH_RA=0 TARGET_TRANSPORT=IP SECURED=%SECURED% WITH_TCP=0 BUILD_SAMPLE=ON LOGGING=%LOGGING% TEST=%TEST% WITH_RD=%WITH_RD% -c clean
  92   rd /s /q out
  93   del .sconsign.dblite
  94 ) else if "!CURRENT_ARG!"=="cleangtest" (
  95   rd /s /q extlibs\gtest\gtest-1.7.0
  96   del extlibs\gtest\gtest-1.7.0.zip
  97 ) else (
  98     echo %0 - Script requires a valid argument!
  99     goto :EOF
 100 )
 101
 102 echo Done!
 103
 104 goto EOF
 105
 106 :USAGE
 107 echo %0 - Helper to build/test iotivity.  Requires an argument.
 108 echo Installation: Drop this into your iotivity root directory to use it.
 109 echo.
 110 echo. Usage examples:
 111 echo   Launch SimpleClient with debugger:
 112 echo      %0 client debug
 113 echo.
 114 echo   Launch SimpleServer:
 115 echo      %0 server
 116 echo.
 117 echo   Launch WinUIClient built in msys:
 118 echo      %0 msys winuiclient
 119 echo.
 120 echo   Build:
 121 echo      %0 build
 122 echo.
 123 echo   Run all tests:
 124 echo      %0 test
 125 echo.
 126 echo   Clean:
 127 echo      %0 clean
 128
 129 :EOF