m4/gconf-2.m4

   1 dnl AM_GCONF_SOURCE_2
   2 dnl Copied from /usr/share/aclocal/gconf-2.m4 so that ibus build does not
   3 dnl need GConf2-devel
   4
   5 AC_DEFUN([AM_GCONF_SOURCE_2],
   6 [
   7   if test "x$GCONF_SCHEMA_INSTALL_SOURCE" = "x"; then
   8     GCONF_SCHEMA_CONFIG_SOURCE=`gconftool-2 --get-default-source`
   9   else
  10     GCONF_SCHEMA_CONFIG_SOURCE=$GCONF_SCHEMA_INSTALL_SOURCE
  11   fi
  12
  13   AC_ARG_WITH([gconf-source],
  14               AC_HELP_STRING([--with-gconf-source=sourceaddress],
  15                              [Config database for installing schema files.]),
  16               [GCONF_SCHEMA_CONFIG_SOURCE="$withval"],)
  17
  18   AC_SUBST(GCONF_SCHEMA_CONFIG_SOURCE)
  19   AC_MSG_RESULT([Using config source $GCONF_SCHEMA_CONFIG_SOURCE for schema installation])
  20
  21   if test "x$GCONF_SCHEMA_FILE_DIR" = "x"; then
  22     GCONF_SCHEMA_FILE_DIR='$(sysconfdir)/gconf/schemas'
  23   fi
  24
  25   AC_ARG_WITH([gconf-schema-file-dir],
  26               AC_HELP_STRING([--with-gconf-schema-file-dir=dir],
  27                              [Directory for installing schema files.]),
  28               [GCONF_SCHEMA_FILE_DIR="$withval"],)
  29
  30   AC_SUBST(GCONF_SCHEMA_FILE_DIR)
  31   AC_MSG_RESULT([Using $GCONF_SCHEMA_FILE_DIR as install directory for schema files])
  32
  33   AC_ARG_ENABLE(schemas-install,
  34         AC_HELP_STRING([--disable-schemas-install],
  35                        [Disable the schemas installation]),
  36      [case ${enableval} in
  37        yes|no) ;;
  38        *) AC_MSG_ERROR([bad value ${enableval} for --enable-schemas-install]) ;;
  39       esac])
  40   AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL], [test "$enable_schemas_install" != no])
  41 ])