docs/meson.build

   1 if build_machine.system() == 'windows'
   2   message('Skipping gtk-doc while building on Windows')
   3   subdir_done()
   4 endif
   5
   6 if not find_program('gtkdoc-scan', required: get_option('gtk_doc')).found()
   7   message('Not building documentation as gtk-doc was not found')
   8   subdir_done()
   9 endif
  10
  11 conf.set('HAVE_GTK_DOC', 1)
  12
  13 gnome = import('gnome')
  14
  15 docconf = configuration_data()
  16 docconf.set('HB_VERSION', meson.project_version())
  17
  18 version_xml = configure_file(input: 'version.xml.in',
  19   output: 'version.xml',
  20   configuration: docconf)
  21
  22 content_files = [
  23   'usermanual-what-is-harfbuzz.xml',
  24   'usermanual-install-harfbuzz.xml',
  25   'usermanual-getting-started.xml',
  26   'usermanual-glyph-information.xml',
  27   'usermanual-shaping-concepts.xml',
  28   'usermanual-object-model.xml',
  29   'usermanual-buffers-language-script-and-direction.xml',
  30   'usermanual-fonts-and-faces.xml',
  31   'usermanual-opentype-features.xml',
  32   'usermanual-clusters.xml',
  33   'usermanual-utilities.xml',
  34   'usermanual-integration.xml',
  35   version_xml,
  36 ]
  37
  38 html_images = [
  39   'HarfBuzz.png',
  40   'HarfBuzz.svg',
  41 ]
  42
  43 ignore_headers = []
  44 if have_gobject
  45   ignore_headers += [
  46     'hb-gobject.h',
  47     'hb-gobject-enums.h',
  48     'hb-gobject-enums-tmp.h',
  49     'hb-gobject-structs.h',
  50   ]
  51 endif
  52
  53 gnome.gtkdoc('harfbuzz',
  54   main_sgml: 'harfbuzz-docs.xml',
  55   src_dir: [meson.current_source_dir() / '..',
  56             meson.current_build_dir() / '..',
  57            ],
  58   scan_args: ['--deprecated-guards=HB_DISABLE_DEPRECATED',
  59               '--ignore-decorators=HB_EXTERN',
  60              ],
  61   mkdb_args: ['--source-suffixes=h,cc',
  62               '--xml-mode',
  63               '--output-format=xml',
  64              ],
  65   content_files: content_files,
  66   html_assets: html_images,
  67   ignore_headers: ignore_headers,
  68   dependencies: [libharfbuzz_dep, libharfbuzz_gobject_dep],
  69   install: true)