configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([HarfBuzz],
   3         [2.3.1],
   4         [https://github.com/harfbuzz/harfbuzz/issues/new],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_SRCDIR([src/harfbuzz.pc.in])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 AM_INIT_AUTOMAKE([1.13.0 gnits tar-ustar dist-bzip2 no-dist-gzip -Wall no-define color-tests -Wno-portability])
  13 AM_SILENT_RULES([yes])
  14 AX_CODE_COVERAGE
  15
  16 # Initialize libtool
  17 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  18 LT_PREREQ([2.2])
  19 LT_INIT([disable-static])
  20
  21 # Check for programs
  22 AC_PROG_CC
  23 AC_PROG_CC_C99
  24 AM_PROG_CC_C_O
  25 AC_PROG_CXX
  26 dnl AX_CXX_COMPILE_STDCXX(11, noext, optional)
  27 AC_SYS_LARGEFILE
  28 PKG_PROG_PKG_CONFIG([0.20])
  29 AM_MISSING_PROG([RAGEL], [ragel])
  30 AM_MISSING_PROG([GIT], [git])
  31
  32 # Version
  33 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  34 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  35 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  36 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  37 HB_VERSION_MAJOR=hb_version_major
  38 HB_VERSION_MINOR=hb_version_minor
  39 HB_VERSION_MICRO=hb_version_micro
  40 HB_VERSION=AC_PACKAGE_VERSION
  41 AC_SUBST(HB_VERSION_MAJOR)
  42 AC_SUBST(HB_VERSION_MINOR)
  43 AC_SUBST(HB_VERSION_MICRO)
  44 AC_SUBST(HB_VERSION)
  45
  46 # Libtool version
  47 m4_define([hb_version_int],
  48           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  49 m4_if(m4_eval(hb_version_minor % 2), [1],
  50       dnl for unstable releases
  51       [m4_define([hb_libtool_revision], 0)],
  52       dnl for stable releases
  53       [m4_define([hb_libtool_revision], hb_version_micro)])
  54 m4_define([hb_libtool_age],
  55           m4_eval(hb_version_int - hb_libtool_revision))
  56 m4_define([hb_libtool_current],
  57           m4_eval(hb_libtool_age))
  58 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  59 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  60
  61 AC_ARG_WITH([libstdc++],
  62         [AS_HELP_STRING([--with-libstdc++=@<:@yes/no@:>@],
  63                         [Allow linking with libstdc++ @<:@default=no@:>@])],
  64         [with_libstdcxx=$withval],
  65         [with_libstdcxx=no])
  66 AM_CONDITIONAL(WITH_LIBSTDCXX, [test "x$with_libstdcxx" = "xyes"])
  67
  68 # Documentation
  69 have_gtk_doc=false
  70 m4_ifdef([GTK_DOC_CHECK], [
  71 GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  72         if test "x$enable_gtk_doc" = xyes; then
  73                 have_gtk_doc=true
  74         fi
  75 ], [
  76         AM_CONDITIONAL([ENABLE_GTK_DOC], false)
  77 ])
  78
  79 # Functions and headers
  80 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l posix_memalign)
  81
  82 save_libs="$LIBS"
  83 LIBS="$LIBS -lm"
  84 AC_CHECK_FUNCS([round], ,[AC_CHECK_DECLS([round], , ,[#include <math.h>])])
  85 LIBS="$save_libs"
  86
  87 AC_CHECK_HEADERS(unistd.h sys/mman.h xlocale.h stdbool.h)
  88
  89 # Compiler flags
  90 AC_CANONICAL_HOST
  91 AC_CHECK_ALIGNOF([struct{char;}])
  92 if test "x$GCC" = "xyes"; then
  93
  94         # Make symbols link locally
  95         AX_CHECK_LINK_FLAG([[-Bsymbolic-functions]], [LDFLAGS="$LDFLAGS -Bsymbolic-functions"])
  96
  97         # Make it possible to not link to libstdc++
  98         # No threadsafe statics in C++ as we do it ourselves.
  99         # We don't use these features, so it's safe to disable them
 100         # even in the cases where we DO link to libstdc++.
 101         # Put -fno-rtti before $CXXFLAGS such that users can re-enable it
 102         # by overriding CXXFLAGS.
 103         CXXFLAGS="-fno-rtti $CXXFLAGS -fno-exceptions -fno-threadsafe-statics"
 104
 105         case "$host" in
 106                 *-*-mingw*)
 107                 ;;
 108                 *)
 109                         # Hide inline methods
 110                         CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
 111                 ;;
 112         esac
 113
 114         case "$host" in
 115                 arm-*-*)
 116                         if test "x$ac_cv_alignof_struct_char__" != x1; then
 117                                 # Request byte alignment
 118                                 CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
 119                         fi
 120                 ;;
 121         esac
 122 fi
 123
 124 AM_CONDITIONAL(HAVE_GCC, test "x$GCC" = "xyes")
 125
 126 hb_os_win32=no
 127 AC_MSG_CHECKING([for native Win32])
 128 case "$host" in
 129   *-*-mingw*)
 130     hb_os_win32=yes
 131     ;;
 132 esac
 133 AC_MSG_RESULT([$hb_os_win32])
 134 AM_CONDITIONAL(OS_WIN32, test "$hb_os_win32" = "yes")
 135
 136 have_pthread=false
 137 if test "$hb_os_win32" = no; then
 138         AX_PTHREAD([have_pthread=true])
 139 fi
 140 if $have_pthread; then
 141         AC_DEFINE(HAVE_PTHREAD, 1, [Have POSIX threads])
 142 fi
 143 AM_CONDITIONAL(HAVE_PTHREAD, $have_pthread)
 144
 145 dnl ==========================================================================
 146
 147 have_fallback=true
 148 if $have_fallback; then
 149         AC_DEFINE(HAVE_FALLBACK, 1, [Have simple TrueType Layout backend])
 150 fi
 151 AM_CONDITIONAL(HAVE_FALLBACK, $have_fallback)
 152
 153 dnl ===========================================================================
 154
 155 AC_ARG_WITH(glib,
 156         [AS_HELP_STRING([--with-glib=@<:@yes/no/auto@:>@],
 157                         [Use glib @<:@default=auto@:>@])],,
 158         [with_glib=auto])
 159 have_glib=false
 160 GLIB_DEPS="glib-2.0 >= 2.19.1"
 161 AC_SUBST(GLIB_DEPS)
 162 if test "x$with_glib" = "xyes" -o "x$with_glib" = "xauto"; then
 163         PKG_CHECK_MODULES(GLIB, $GLIB_DEPS, have_glib=true, :)
 164 fi
 165 if test "x$with_glib" = "xyes" -a "x$have_glib" != "xtrue"; then
 166         AC_MSG_ERROR([glib support requested but glib-2.0 not found])
 167 fi
 168 if $have_glib; then
 169         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
 170 fi
 171 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 172
 173 dnl ===========================================================================
 174
 175 AC_ARG_WITH(gobject,
 176         [AS_HELP_STRING([--with-gobject=@<:@yes/no/auto@:>@],
 177                         [Use gobject @<:@default=no@:>@])],,
 178         [with_gobject=no])
 179 have_gobject=false
 180 if test "x$with_gobject" = "xyes" -o "x$with_gobject" = "xauto"; then
 181         PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0, have_gobject=true, :)
 182 fi
 183 if test "x$with_gobject" = "xyes" -a "x$have_gobject" != "xtrue"; then
 184         AC_MSG_ERROR([gobject support requested but gobject-2.0 / glib-2.0 not found])
 185 fi
 186 if $have_gobject; then
 187         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 188         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 189         AC_SUBST(GLIB_MKENUMS)
 190 fi
 191 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 192 AC_SUBST(have_gobject)
 193
 194 dnl ===========================================================================
 195
 196
 197 dnl ===========================================================================
 198 # Gobject-Introspection
 199 have_introspection=false
 200 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
 201         if $have_gobject; then
 202                 GOBJECT_INTROSPECTION_CHECK([1.34.0])
 203                 if test "x$found_introspection" = xyes; then
 204                         have_introspection=true
 205                 fi
 206         else
 207                 AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 208         fi
 209 ], [
 210         AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 211 ])
 212
 213 dnl ==========================================================================
 214
 215 AC_ARG_WITH(cairo,
 216         [AS_HELP_STRING([--with-cairo=@<:@yes/no/auto@:>@],
 217                         [Use cairo @<:@default=auto@:>@])],,
 218         [with_cairo=auto])
 219 have_cairo=false
 220 if test "x$with_cairo" = "xyes" -o "x$with_cairo" = "xauto"; then
 221         PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, :)
 222 fi
 223 if test "x$with_cairo" = "xyes" -a "x$have_cairo" != "xtrue"; then
 224         AC_MSG_ERROR([cairo support requested but not found])
 225 fi
 226 if $have_cairo; then
 227         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 228 fi
 229 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 230
 231 have_cairo_ft=false
 232 if $have_cairo; then
 233         PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, :)
 234 fi
 235 if $have_cairo_ft; then
 236         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 237 fi
 238 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 239
 240 dnl ==========================================================================
 241
 242 AC_ARG_WITH(fontconfig,
 243         [AS_HELP_STRING([--with-fontconfig=@<:@yes/no/auto@:>@],
 244                         [Use fontconfig @<:@default=auto@:>@])],,
 245         [with_fontconfig=auto])
 246 have_fontconfig=false
 247 if test "x$with_fontconfig" = "xyes" -o "x$with_fontconfig" = "xauto"; then
 248         PKG_CHECK_MODULES(FONTCONFIG, fontconfig, have_fontconfig=true, :)
 249 fi
 250 if test "x$with_fontconfig" = "xyes" -a "x$have_fontconfig" != "xtrue"; then
 251         AC_MSG_ERROR([fontconfig support requested but not found])
 252 fi
 253 if $have_fontconfig; then
 254         AC_DEFINE(HAVE_FONTCONFIG, 1, [Have fontconfig library])
 255 fi
 256 AM_CONDITIONAL(HAVE_FONTCONFIG, $have_fontconfig)
 257
 258 dnl ==========================================================================
 259
 260 AC_ARG_WITH(icu,
 261         [AS_HELP_STRING([--with-icu=@<:@yes/no/builtin/auto@:>@],
 262                         [Use ICU @<:@default=auto@:>@])],,
 263         [with_icu=auto])
 264 have_icu=false
 265 if test "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" -o "x$with_icu" = "xauto"; then
 266         PKG_CHECK_MODULES(ICU, icu-uc, have_icu=true, :)
 267
 268         dnl Fallback to icu-config if ICU pkg-config files could not be found
 269         if test "$have_icu" != "true"; then
 270                 AC_CHECK_TOOL(ICU_CONFIG, icu-config, no)
 271                 AC_MSG_CHECKING([for ICU by using icu-config fallback])
 272                 if test "$ICU_CONFIG" != "no" && "$ICU_CONFIG" --version >/dev/null; then
 273                         have_icu=true
 274                         # We don't use --cflags as this gives us a lot of things that we don't
 275                         # necessarily want, like debugging and optimization flags
 276                         # See man (1) icu-config for more info.
 277                         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 278                         ICU_LIBS=`$ICU_CONFIG --ldflags-searchpath --ldflags-libsonly`
 279                         AC_SUBST(ICU_CFLAGS)
 280                         AC_SUBST(ICU_LIBS)
 281                         AC_MSG_RESULT([yes])
 282                 else
 283                         AC_MSG_RESULT([no])
 284                 fi
 285         fi
 286 fi
 287 if test \( "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" \) -a "x$have_icu" != "xtrue"; then
 288         AC_MSG_ERROR([icu support requested but icu-uc not found])
 289 fi
 290
 291 if $have_icu; then
 292         CXXFLAGS="$CXXFLAGS `$PKG_CONFIG --variable=CXXFLAGS icu-uc`"
 293         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 294         if test "x$with_icu" = "xbuiltin"; then
 295                 AC_DEFINE(HAVE_ICU_BUILTIN, 1, [Use hb-icu Unicode callbacks])
 296         fi
 297 fi
 298 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 299 AM_CONDITIONAL(HAVE_ICU_BUILTIN, $have_icu && test "x$with_icu" = "xbuiltin")
 300
 301 dnl ===========================================================================
 302
 303 AC_ARG_WITH(ucdn,
 304         [AS_HELP_STRING([--with-ucdn=@<:@yes/no@:>@],
 305                         [Use builtin UCDN library @<:@default=yes@:>@])],,
 306         [with_ucdn=yes])
 307 have_ucdn=false
 308 if test "x$with_ucdn" = "xyes"; then
 309         have_ucdn=true
 310 fi
 311 if $have_ucdn; then
 312         AC_DEFINE(HAVE_UCDN, 1, [Have UCDN Unicode functions])
 313 fi
 314 AM_CONDITIONAL(HAVE_UCDN, $have_ucdn)
 315
 316 dnl ==========================================================================
 317
 318 AC_ARG_WITH(graphite2,
 319         [AS_HELP_STRING([--with-graphite2=@<:@yes/no/auto@:>@],
 320                         [Use the graphite2 library @<:@default=no@:>@])],,
 321         [with_graphite2=no])
 322 have_graphite2=false
 323 GRAPHITE2_DEPS="graphite2 >= 1.2.0"
 324 AC_SUBST(GRAPHITE2_DEPS)
 325 if test "x$with_graphite2" = "xyes" -o "x$with_graphite2" = "xauto"; then
 326         PKG_CHECK_MODULES(GRAPHITE2, $GRAPHITE2_DEPS, have_graphite2=true, :)
 327         if test "x$have_graphite2" != "xtrue"; then
 328                 # If pkg-config is not available, graphite2 can still be there
 329                 ac_save_CFLAGS="$CFLAGS"
 330                 ac_save_CPPFLAGS="$CPPFLAGS"
 331                 CFLAGS="$CFLAGS $GRAPHITE2_CFLAGS"
 332                 CPPFLAGS="$CPPFLAGS $GRAPHITE2_CFLAGS"
 333                 AC_CHECK_HEADER(graphite2/Segment.h, have_graphite2=true, :)
 334                 CPPFLAGS="$ac_save_CPPFLAGS"
 335                 CFLAGS="$ac_save_CFLAGS"
 336         fi
 337 fi
 338 if test "x$with_graphite2" = "xyes" -a "x$have_graphite2" != "xtrue"; then
 339         AC_MSG_ERROR([graphite2 support requested but libgraphite2 not found])
 340 fi
 341 if $have_graphite2; then
 342         AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite2 library])
 343 fi
 344 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite2)
 345
 346 dnl ==========================================================================
 347
 348 AC_ARG_WITH(freetype,
 349         [AS_HELP_STRING([--with-freetype=@<:@yes/no/auto@:>@],
 350                         [Use the FreeType library @<:@default=auto@:>@])],,
 351         [with_freetype=auto])
 352 have_freetype=false
 353 FREETYPE_DEPS="freetype2 >= 12.0.6"
 354 AC_SUBST(FREETYPE_DEPS)
 355 if test "x$with_freetype" = "xyes" -o "x$with_freetype" = "xauto"; then
 356         # See freetype/docs/VERSION.DLL; 12.0.6 means freetype-2.4.2
 357         PKG_CHECK_MODULES(FREETYPE, $FREETYPE_DEPS, have_freetype=true, :)
 358 fi
 359 if test "x$with_freetype" = "xyes" -a "x$have_freetype" != "xtrue"; then
 360         AC_MSG_ERROR([FreeType support requested but libfreetype2 not found])
 361 fi
 362 if $have_freetype; then
 363         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 364         save_libs=$LIBS
 365         LIBS="$LIBS $FREETYPE_LIBS"
 366         AC_CHECK_FUNCS(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 367         LIBS=$save_libs
 368 fi
 369 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 370
 371 dnl ===========================================================================
 372
 373 AC_ARG_WITH(uniscribe,
 374         [AS_HELP_STRING([--with-uniscribe=@<:@yes/no/auto@:>@],
 375                         [Use the Uniscribe library @<:@default=no@:>@])],,
 376         [with_uniscribe=no])
 377 have_uniscribe=false
 378 if test "x$with_uniscribe" = "xyes" -o "x$with_uniscribe" = "xauto"; then
 379         AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true)
 380 fi
 381 if test "x$with_uniscribe" = "xyes" -a "x$have_uniscribe" != "xtrue"; then
 382         AC_MSG_ERROR([uniscribe support requested but not found])
 383 fi
 384 if $have_uniscribe; then
 385         UNISCRIBE_CFLAGS=
 386         UNISCRIBE_LIBS="-lusp10 -lgdi32 -lrpcrt4"
 387         AC_SUBST(UNISCRIBE_CFLAGS)
 388         AC_SUBST(UNISCRIBE_LIBS)
 389         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe library])
 390 fi
 391 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 392
 393 dnl ===========================================================================
 394
 395 AC_ARG_WITH(directwrite,
 396         [AS_HELP_STRING([--with-directwrite=@<:@yes/no/auto@:>@],
 397                         [Use the DirectWrite library (experimental) @<:@default=no@:>@])],,
 398         [with_directwrite=no])
 399 have_directwrite=false
 400 AC_LANG_PUSH([C++])
 401 if test "x$with_directwrite" = "xyes" -o "x$with_directwrite" = "xauto"; then
 402         AC_CHECK_HEADERS(dwrite.h, have_directwrite=true)
 403 fi
 404 AC_LANG_POP([C++])
 405 if test "x$with_directwrite" = "xyes" -a "x$have_directwrite" != "xtrue"; then
 406         AC_MSG_ERROR([directwrite support requested but not found])
 407 fi
 408 if $have_directwrite; then
 409         DIRECTWRITE_CXXFLAGS=
 410         DIRECTWRITE_LIBS="-ldwrite"
 411         AC_SUBST(DIRECTWRITE_CXXFLAGS)
 412         AC_SUBST(DIRECTWRITE_LIBS)
 413         AC_DEFINE(HAVE_DIRECTWRITE, 1, [Have DirectWrite library])
 414 fi
 415 AM_CONDITIONAL(HAVE_DIRECTWRITE, $have_directwrite)
 416
 417 dnl ===========================================================================
 418
 419 AC_ARG_WITH(coretext,
 420         [AS_HELP_STRING([--with-coretext=@<:@yes/no/auto@:>@],
 421                         [Use CoreText @<:@default=no@:>@])],,
 422         [with_coretext=no])
 423 have_coretext=false
 424 if test "x$with_coretext" = "xyes" -o "x$with_coretext" = "xauto"; then
 425         AC_CHECK_TYPE(CTFontRef, have_coretext=true,, [#include <ApplicationServices/ApplicationServices.h>])
 426
 427         if $have_coretext; then
 428                 CORETEXT_CFLAGS=
 429                 CORETEXT_LIBS="-framework ApplicationServices"
 430                 AC_SUBST(CORETEXT_CFLAGS)
 431                 AC_SUBST(CORETEXT_LIBS)
 432         else
 433                 # On iOS CoreText and CoreGraphics are stand-alone frameworks
 434                 if test "x$have_coretext" != "xtrue"; then
 435                         # Check for a different symbol to avoid getting cached result.
 436                         AC_CHECK_TYPE(CTRunRef, have_coretext=true,, [#include <CoreText/CoreText.h>])
 437                 fi
 438
 439                 if $have_coretext; then
 440                         CORETEXT_CFLAGS=
 441                         CORETEXT_LIBS="-framework CoreText -framework CoreGraphics -framework CoreFoundation"
 442                         AC_SUBST(CORETEXT_CFLAGS)
 443                         AC_SUBST(CORETEXT_LIBS)
 444                 fi
 445         fi
 446 fi
 447 if test "x$with_coretext" = "xyes" -a "x$have_coretext" != "xtrue"; then
 448         AC_MSG_ERROR([CoreText support requested but libcoretext not found])
 449 fi
 450 if $have_coretext; then
 451         AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
 452 fi
 453 AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
 454
 455 dnl ===========================================================================
 456
 457 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 458         hb_cv_have_intel_atomic_primitives=false
 459         AC_TRY_LINK([
 460                 void memory_barrier (void) { __sync_synchronize (); }
 461                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 462                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 463                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 464                 ], [], hb_cv_have_intel_atomic_primitives=true
 465         )
 466 ])
 467 if $hb_cv_have_intel_atomic_primitives; then
 468         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 469 fi
 470
 471 dnl ===========================================================================
 472
 473 AC_CACHE_CHECK([for Solaris atomic operations], hb_cv_have_solaris_atomic_ops, [
 474         hb_cv_have_solaris_atomic_ops=false
 475         AC_TRY_LINK([
 476                 #include <atomic.h>
 477                 /* This requires Solaris Studio 12.2 or newer: */
 478                 #include <mbarrier.h>
 479                 void memory_barrier (void) { __machine_rw_barrier (); }
 480                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 481                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 482                 ], [], hb_cv_have_solaris_atomic_ops=true
 483         )
 484 ])
 485 if $hb_cv_have_solaris_atomic_ops; then
 486         AC_DEFINE(HAVE_SOLARIS_ATOMIC_OPS, 1, [Have Solaris __machine_*_barrier and atomic_* operations])
 487 fi
 488
 489 if test "$os_win32" = no && ! $have_pthread; then
 490         AC_CHECK_HEADERS(sched.h)
 491         AC_SEARCH_LIBS(sched_yield,rt,AC_DEFINE(HAVE_SCHED_YIELD, 1, [Have sched_yield]))
 492 fi
 493
 494 dnl ===========================================================================
 495
 496 AC_CONFIG_FILES([
 497 Makefile
 498 src/Makefile
 499 src/harfbuzz-config.cmake
 500 src/hb-ucdn/Makefile
 501 util/Makefile
 502 test/Makefile
 503 test/api/Makefile
 504 test/fuzzing/Makefile
 505 test/shaping/Makefile
 506 test/shaping/data/Makefile
 507 test/shaping/data/aots/Makefile
 508 test/shaping/data/in-house/Makefile
 509 test/shaping/data/text-rendering-tests/Makefile
 510 test/subset/Makefile
 511 test/subset/data/Makefile
 512 docs/Makefile
 513 docs/version.xml
 514 ])
 515
 516 AC_OUTPUT
 517
 518 AC_MSG_NOTICE([
 519
 520 Build configuration:
 521
 522 Unicode callbacks (you want at least one):
 523         Builtin (UCDN):         ${have_ucdn}
 524         Glib:                   ${have_glib}
 525         ICU:                    ${have_icu}
 526
 527 Font callbacks (the more the merrier):
 528         FreeType:               ${have_freetype}
 529
 530 Tools used for command-line utilities:
 531         Cairo:                  ${have_cairo}
 532         Fontconfig:             ${have_fontconfig}
 533
 534 Additional shapers (the more the merrier):
 535         Graphite2:              ${have_graphite2}
 536
 537 Platform shapers (not normally needed):
 538         CoreText:               ${have_coretext}
 539         DirectWrite:            ${have_directwrite}
 540         Uniscribe:              ${have_uniscribe}
 541
 542 Other features:
 543         Documentation:          ${enable_gtk_doc}
 544         GObject bindings:       ${have_gobject}
 545         Introspection:          ${have_introspection}
 546 ])