configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([HarfBuzz],
   3         [0.9.3],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([1.11.1 gnits dist-bzip2 no-dist-gzip -Wall no-define])
  12 AM_SILENT_RULES([yes])
  13
  14 # Initialize libtool
  15 LT_PREREQ([2.2])
  16 LT_INIT([disable-static])
  17
  18 # Check for programs
  19 AC_PROG_CC
  20 AM_PROG_CC_C_O
  21 AC_PROG_CXX
  22
  23 # Version
  24 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  25 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  26 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  27 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  28 HB_VERSION_MAJOR=hb_version_major
  29 HB_VERSION_MINOR=hb_version_minor
  30 HB_VERSION_MICRO=hb_version_micro
  31 HB_VERSION=AC_PACKAGE_VERSION
  32 AC_SUBST(HB_VERSION_MAJOR)
  33 AC_SUBST(HB_VERSION_MINOR)
  34 AC_SUBST(HB_VERSION_MICRO)
  35 AC_SUBST(HB_VERSION)
  36
  37 # Libtool version
  38 m4_define([hb_version_int],
  39           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  40 m4_if(m4_eval(hb_version_minor % 2), [1],
  41       dnl for unstable releases
  42       [m4_define([hb_libtool_revision], 0)],
  43       dnl for stable releases
  44       [m4_define([hb_libtool_revision], hb_version_micro)])
  45 m4_define([hb_libtool_age],
  46           m4_eval(hb_version_int - hb_libtool_revision))
  47 m4_define([hb_libtool_current],
  48           m4_eval(hb_version_major + hb_libtool_age))
  49 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  50 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  51
  52 dnl GOBJECT_INTROSPECTION_CHECK([0.9.0])
  53 dnl GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  54
  55 # Functions and headers
  56 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize sched_yield mmap _setmode isatty)
  57 AC_CHECK_HEADERS(unistd.h sys/mman.h sched.h io.h)
  58
  59 # Compiler flags
  60 AC_CANONICAL_HOST
  61 if test "x$GCC" = "xyes"; then
  62
  63         # Make symbols link locally
  64         LDFLAGS="$LDFLAGS -Bsymbolic-functions"
  65
  66         # Make sure we don't link to libstdc++
  67         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  68
  69         # Assorted warnings
  70         CXXFLAGS="$CXXFLAGS -Wcast-align"
  71
  72         case "$host" in
  73                 *-*-mingw*)
  74                 ;;
  75                 *)
  76                         # Hide inline methods
  77                         CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
  78                 ;;
  79         esac
  80
  81         case "$host" in
  82                 arm-*-*)
  83                         # Request byte alignment on arm
  84                         CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
  85                 ;;
  86         esac
  87 fi
  88
  89 AC_MSG_CHECKING([for native Win32])
  90 case "$host" in
  91   *-*-mingw*)
  92     hb_os_win32=yes
  93     ;;
  94   *)
  95     hb_os_win32=no
  96     ;;
  97 esac
  98 AC_MSG_RESULT([$hb_os_win32])
  99 AM_CONDITIONAL(OS_WIN32, test "$hb_os_win32" = "yes")
 100
 101 dnl ==========================================================================
 102
 103 have_ot=true
 104 if $have_ot; then
 105         AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
 106 fi
 107 AM_CONDITIONAL(HAVE_OT, $have_ot)
 108
 109 dnl ===========================================================================
 110
 111 have_hb_old=true
 112 if $have_hb_old; then
 113         AC_DEFINE(HAVE_HB_OLD, 1, [Have Old HarfBuzz backend])
 114 fi
 115 AM_CONDITIONAL(HAVE_HB_OLD, $have_hb_old)
 116
 117 dnl ===========================================================================
 118
 119 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
 120 if $have_glib; then
 121         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
 122 fi
 123 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 124
 125 PKG_CHECK_MODULES(GTHREAD, gthread-2.0, have_gthread=true, have_gthread=false)
 126 if $have_gthread; then
 127         AC_DEFINE(HAVE_GTHREAD, 1, [Have gthread2 library])
 128 fi
 129 AM_CONDITIONAL(HAVE_GTHREAD, $have_gthread)
 130
 131 PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0 >= 2.16, have_gobject=true, have_gobject=false)
 132 if $have_gobject; then
 133         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 134         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 135         AC_SUBST(GLIB_MKENUMS)
 136 fi
 137 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 138
 139 dnl ==========================================================================
 140
 141 PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
 142 if $have_cairo; then
 143         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 144 fi
 145 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 146
 147 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
 148 if $have_cairo_ft; then
 149         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 150 fi
 151 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 152
 153 dnl ==========================================================================
 154
 155 PKG_CHECK_MODULES(ICU, icu-uc, have_icu=true, have_icu=false)
 156 if $have_icu; then
 157         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 158 fi
 159 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 160
 161 dnl ==========================================================================
 162
 163 PKG_CHECK_MODULES(GRAPHITE2, graphite2, have_graphite=true, have_graphite=false)
 164 if $have_graphite; then
 165     AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite library])
 166 fi
 167 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite)
 168
 169 dnl ==========================================================================
 170
 171 PKG_CHECK_MODULES(FREETYPE, freetype2 >= 2.3.8, have_freetype=true, have_freetype=false)
 172 if $have_freetype; then
 173         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 174         _save_libs="$LIBS"
 175         _save_cflags="$CFLAGS"
 176         LIBS="$LIBS $FREETYPE_LIBS"
 177         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 178         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
 179         LIBS="$_save_libs"
 180         CFLAGS="$_save_cflags"
 181 fi
 182 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 183
 184 dnl ===========================================================================
 185
 186 AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
 187 if $have_uniscribe; then
 188         UNISCRIBE_CFLAGS=
 189         UNISCRIBE_LIBS="-lusp10 -lgdi32"
 190         AC_SUBST(UNISCRIBE_CFLAGS)
 191         AC_SUBST(UNISCRIBE_LIBS)
 192         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe backend])
 193 fi
 194 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 195
 196 dnl ===========================================================================
 197
 198 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, have_coretext=true, have_coretext=false)
 199 if $have_coretext; then
 200         CORETEXT_CFLAGS=
 201         CORETEXT_LIBS=
 202         AC_SUBST(CORETEXT_CFLAGS)
 203         AC_SUBST(CORETEXT_LIBS)
 204         AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
 205 fi
 206 AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
 207
 208 dnl ===========================================================================
 209
 210 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 211         hb_cv_have_intel_atomic_primitives=false
 212         AC_TRY_LINK([
 213                 void memory_barrier (void) { __sync_synchronize (); }
 214                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 215                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 216                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 217                 ], [], hb_cv_have_intel_atomic_primitives=true
 218         )
 219 ])
 220 if $hb_cv_have_intel_atomic_primitives; then
 221         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 222 fi
 223
 224 dnl ===========================================================================
 225
 226 AC_CONFIG_FILES([
 227 Makefile
 228 harfbuzz.pc
 229 src/Makefile
 230 src/hb-version.h
 231 src/hb-old/Makefile
 232 util/Makefile
 233 test/Makefile
 234 test/api/Makefile
 235 test/shaping/Makefile
 236 ])
 237
 238 AC_OUTPUT