configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([HarfBuzz],
   3         [2.6.7],
   4         [https://github.com/harfbuzz/harfbuzz/issues/new],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_SRCDIR([src/harfbuzz.pc.in])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 AM_INIT_AUTOMAKE([1.13.0 gnits tar-ustar dist-xz no-dist-gzip -Wall no-define color-tests -Wno-portability])
  13 AM_SILENT_RULES([yes])
  14 AX_CODE_COVERAGE
  15
  16 # Initialize libtool
  17 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  18 LT_PREREQ([2.2])
  19 LT_INIT([disable-static])
  20
  21 # Check for programs
  22 AC_PROG_CC
  23 AC_PROG_CC_C99
  24 AM_PROG_CC_C_O
  25 AC_PROG_CXX
  26 AX_CXX_COMPILE_STDCXX(11)
  27 AC_SYS_LARGEFILE
  28 PKG_PROG_PKG_CONFIG([0.20])
  29 AM_MISSING_PROG([RAGEL], [ragel])
  30 AM_MISSING_PROG([GIT], [git])
  31
  32 # Version
  33 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  34 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  35 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  36 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  37 HB_VERSION_MAJOR=hb_version_major
  38 HB_VERSION_MINOR=hb_version_minor
  39 HB_VERSION_MICRO=hb_version_micro
  40 HB_VERSION=AC_PACKAGE_VERSION
  41 AC_SUBST(HB_VERSION_MAJOR)
  42 AC_SUBST(HB_VERSION_MINOR)
  43 AC_SUBST(HB_VERSION_MICRO)
  44 AC_SUBST(HB_VERSION)
  45
  46 # Libtool version
  47 m4_define([hb_version_int],
  48           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  49 m4_if(m4_eval(hb_version_minor % 2), [1],
  50       dnl for unstable releases
  51       [m4_define([hb_libtool_revision], 0)],
  52       dnl for stable releases
  53       [m4_define([hb_libtool_revision], hb_version_micro)])
  54 m4_define([hb_libtool_age],
  55           m4_eval(hb_version_int - hb_libtool_revision))
  56 m4_define([hb_libtool_current],
  57           m4_eval(hb_libtool_age))
  58 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  59 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  60
  61 AC_ARG_WITH([libstdc++],
  62         [AS_HELP_STRING([--with-libstdc++=@<:@yes/no@:>@],
  63                         [Allow linking with libstdc++ @<:@default=no@:>@])],
  64         [with_libstdcxx=$withval],
  65         [with_libstdcxx=no])
  66 AM_CONDITIONAL(WITH_LIBSTDCXX, [test "x$with_libstdcxx" = "xyes"])
  67
  68 # Documentation
  69 have_gtk_doc=false
  70 m4_ifdef([GTK_DOC_CHECK], [
  71 GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  72         if test "x$enable_gtk_doc" = xyes; then
  73                 have_gtk_doc=true
  74         fi
  75 ], [
  76         AM_CONDITIONAL([ENABLE_GTK_DOC], false)
  77 ])
  78
  79 # Functions and headers
  80 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize mmap isatty roundf)
  81 AC_CHECK_HEADERS(unistd.h sys/mman.h stdbool.h)
  82
  83 # Compiler flags
  84 AC_CANONICAL_HOST
  85 AC_CHECK_ALIGNOF([struct{char;}])
  86 if test "x$GCC" = "xyes"; then
  87
  88         # Make symbols link locally
  89         AX_CHECK_LINK_FLAG([[-Bsymbolic-functions]], [LDFLAGS="$LDFLAGS -Bsymbolic-functions"])
  90
  91         # Make it possible to not link to libstdc++
  92         # No threadsafe statics in C++ as we do it ourselves.
  93         # We don't use these features, so it's safe to disable them
  94         # even in the cases where we DO link to libstdc++.
  95         # Put -fno-rtti before $CXXFLAGS such that users can re-enable it
  96         # by overriding CXXFLAGS.
  97         CXXFLAGS="-fno-rtti $CXXFLAGS -fno-exceptions -fno-threadsafe-statics"
  98
  99         case "$host" in
 100                 *-*-mingw*)
 101                 ;;
 102                 *)
 103                         # Hide inline methods
 104                         CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
 105                 ;;
 106         esac
 107
 108         case "$host" in
 109                 arm-*-*)
 110                         if test "x$ac_cv_alignof_struct_char__" != x1; then
 111                                 # Request byte alignment
 112                                 CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
 113                         fi
 114                 ;;
 115         esac
 116 fi
 117
 118 AM_CONDITIONAL(HAVE_GCC, test "x$GCC" = "xyes")
 119
 120 hb_os_win32=no
 121 AC_MSG_CHECKING([for native Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     hb_os_win32=yes
 125     ;;
 126 esac
 127 AC_MSG_RESULT([$hb_os_win32])
 128 AM_CONDITIONAL(OS_WIN32, test "$hb_os_win32" = "yes")
 129
 130 have_pthread=false
 131 AX_PTHREAD([have_pthread=true])
 132 if $have_pthread; then
 133         AC_DEFINE(HAVE_PTHREAD, 1, [Have POSIX threads])
 134 fi
 135 AM_CONDITIONAL(HAVE_PTHREAD, $have_pthread)
 136
 137 dnl ==========================================================================
 138
 139 AC_ARG_WITH(glib,
 140         [AS_HELP_STRING([--with-glib=@<:@yes/no/auto@:>@],
 141                         [Use glib @<:@default=auto@:>@])],,
 142         [with_glib=auto])
 143 have_glib=false
 144 GLIB_DEPS="glib-2.0 >= 2.19.1"
 145 AC_SUBST(GLIB_DEPS)
 146 if test "x$with_glib" = "xyes" -o "x$with_glib" = "xauto"; then
 147         PKG_CHECK_MODULES(GLIB, $GLIB_DEPS, have_glib=true, :)
 148 fi
 149 if test "x$with_glib" = "xyes" -a "x$have_glib" != "xtrue"; then
 150         AC_MSG_ERROR([glib support requested but glib-2.0 not found])
 151 fi
 152 if $have_glib; then
 153         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
 154 fi
 155 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 156
 157 dnl ===========================================================================
 158
 159 AC_ARG_WITH(gobject,
 160         [AS_HELP_STRING([--with-gobject=@<:@yes/no/auto@:>@],
 161                         [Use gobject @<:@default=no@:>@])],,
 162         [with_gobject=no])
 163 have_gobject=false
 164 if test "x$with_gobject" = "xyes" -o "x$with_gobject" = "xauto"; then
 165         PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0, have_gobject=true, :)
 166 fi
 167 if test "x$with_gobject" = "xyes" -a "x$have_gobject" != "xtrue"; then
 168         AC_MSG_ERROR([gobject support requested but gobject-2.0 / glib-2.0 not found])
 169 fi
 170 if $have_gobject; then
 171         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 172         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 173         AC_SUBST(GLIB_MKENUMS)
 174 fi
 175 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 176 AC_SUBST(have_gobject)
 177
 178 dnl ===========================================================================
 179
 180
 181 dnl ===========================================================================
 182 # Gobject-Introspection
 183 have_introspection=false
 184 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
 185         if $have_gobject; then
 186                 GOBJECT_INTROSPECTION_CHECK([1.34.0])
 187                 if test "x$found_introspection" = xyes; then
 188                         have_introspection=true
 189                 fi
 190         else
 191                 AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 192         fi
 193 ], [
 194         AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 195 ])
 196
 197 dnl ==========================================================================
 198
 199 AC_ARG_WITH(cairo,
 200         [AS_HELP_STRING([--with-cairo=@<:@yes/no/auto@:>@],
 201                         [Use cairo @<:@default=auto@:>@])],,
 202         [with_cairo=auto])
 203 have_cairo=false
 204 if test "x$with_cairo" = "xyes" -o "x$with_cairo" = "xauto"; then
 205         PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, :)
 206 fi
 207 if test "x$with_cairo" = "xyes" -a "x$have_cairo" != "xtrue"; then
 208         AC_MSG_ERROR([cairo support requested but not found])
 209 fi
 210 if $have_cairo; then
 211         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 212 fi
 213 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 214
 215 have_cairo_ft=false
 216 if $have_cairo; then
 217         PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, :)
 218 fi
 219 if $have_cairo_ft; then
 220         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 221 fi
 222 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 223
 224 dnl ==========================================================================
 225
 226 AC_ARG_WITH(fontconfig,
 227         [AS_HELP_STRING([--with-fontconfig=@<:@yes/no/auto@:>@],
 228                         [Use fontconfig @<:@default=auto@:>@])],,
 229         [with_fontconfig=auto])
 230 have_fontconfig=false
 231 if test "x$with_fontconfig" = "xyes" -o "x$with_fontconfig" = "xauto"; then
 232         PKG_CHECK_MODULES(FONTCONFIG, fontconfig, have_fontconfig=true, :)
 233 fi
 234 if test "x$with_fontconfig" = "xyes" -a "x$have_fontconfig" != "xtrue"; then
 235         AC_MSG_ERROR([fontconfig support requested but not found])
 236 fi
 237 if $have_fontconfig; then
 238         AC_DEFINE(HAVE_FONTCONFIG, 1, [Have fontconfig library])
 239 fi
 240 AM_CONDITIONAL(HAVE_FONTCONFIG, $have_fontconfig)
 241
 242 dnl ==========================================================================
 243
 244 AC_ARG_WITH(icu,
 245         [AS_HELP_STRING([--with-icu=@<:@yes/no/builtin/auto@:>@],
 246                         [Use ICU @<:@default=auto@:>@])],,
 247         [with_icu=auto])
 248 have_icu=false
 249 if test "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" -o "x$with_icu" = "xauto"; then
 250         PKG_CHECK_MODULES(ICU, icu-uc, have_icu=true, :)
 251
 252         dnl Fallback to icu-config if ICU pkg-config files could not be found
 253         if test "$have_icu" != "true"; then
 254                 AC_CHECK_TOOL(ICU_CONFIG, icu-config, no)
 255                 AC_MSG_CHECKING([for ICU by using icu-config fallback])
 256                 if test "$ICU_CONFIG" != "no" && "$ICU_CONFIG" --version >/dev/null; then
 257                         have_icu=true
 258                         # We don't use --cflags as this gives us a lot of things that we don't
 259                         # necessarily want, like debugging and optimization flags
 260                         # See man (1) icu-config for more info.
 261                         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 262                         ICU_LIBS=`$ICU_CONFIG --ldflags-searchpath --ldflags-libsonly`
 263                         AC_SUBST(ICU_CFLAGS)
 264                         AC_SUBST(ICU_LIBS)
 265                         AC_MSG_RESULT([yes])
 266                 else
 267                         AC_MSG_RESULT([no])
 268                 fi
 269         fi
 270 fi
 271 if test \( "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" \) -a "x$have_icu" != "xtrue"; then
 272         AC_MSG_ERROR([icu support requested but icu-uc not found])
 273 fi
 274
 275 if $have_icu; then
 276         CXXFLAGS="$CXXFLAGS `$PKG_CONFIG --variable=CXXFLAGS icu-uc`"
 277         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 278         if test "x$with_icu" = "xbuiltin"; then
 279                 AC_DEFINE(HAVE_ICU_BUILTIN, 1, [Use hb-icu Unicode callbacks])
 280         fi
 281 fi
 282 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 283 AM_CONDITIONAL(HAVE_ICU_BUILTIN, $have_icu && test "x$with_icu" = "xbuiltin")
 284
 285 dnl ===========================================================================
 286
 287 AC_ARG_WITH(graphite2,
 288         [AS_HELP_STRING([--with-graphite2=@<:@yes/no/auto@:>@],
 289                         [Use the graphite2 library @<:@default=no@:>@])],,
 290         [with_graphite2=no])
 291 have_graphite2=false
 292 GRAPHITE2_DEPS="graphite2 >= 1.2.0"
 293 AC_SUBST(GRAPHITE2_DEPS)
 294 if test "x$with_graphite2" = "xyes" -o "x$with_graphite2" = "xauto"; then
 295         PKG_CHECK_MODULES(GRAPHITE2, $GRAPHITE2_DEPS, have_graphite2=true, :)
 296         if test "x$have_graphite2" != "xtrue"; then
 297                 # If pkg-config is not available, graphite2 can still be there
 298                 ac_save_CFLAGS="$CFLAGS"
 299                 ac_save_CPPFLAGS="$CPPFLAGS"
 300                 CFLAGS="$CFLAGS $GRAPHITE2_CFLAGS"
 301                 CPPFLAGS="$CPPFLAGS $GRAPHITE2_CFLAGS"
 302                 AC_CHECK_HEADER(graphite2/Segment.h, have_graphite2=true, :)
 303                 CPPFLAGS="$ac_save_CPPFLAGS"
 304                 CFLAGS="$ac_save_CFLAGS"
 305         fi
 306 fi
 307 if test "x$with_graphite2" = "xyes" -a "x$have_graphite2" != "xtrue"; then
 308         AC_MSG_ERROR([graphite2 support requested but libgraphite2 not found])
 309 fi
 310 if $have_graphite2; then
 311         AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite2 library])
 312 fi
 313 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite2)
 314
 315 dnl ==========================================================================
 316
 317 AC_ARG_WITH(freetype,
 318         [AS_HELP_STRING([--with-freetype=@<:@yes/no/auto@:>@],
 319                         [Use the FreeType library @<:@default=auto@:>@])],,
 320         [with_freetype=auto])
 321 have_freetype=false
 322 FREETYPE_DEPS="freetype2 >= 12.0.6"
 323 AC_SUBST(FREETYPE_DEPS)
 324 if test "x$with_freetype" = "xyes" -o "x$with_freetype" = "xauto"; then
 325         # See freetype/docs/VERSION.DLL; 12.0.6 means freetype-2.4.2
 326         PKG_CHECK_MODULES(FREETYPE, $FREETYPE_DEPS, have_freetype=true, :)
 327 fi
 328 if test "x$with_freetype" = "xyes" -a "x$have_freetype" != "xtrue"; then
 329         AC_MSG_ERROR([FreeType support requested but libfreetype2 not found])
 330 fi
 331 if $have_freetype; then
 332         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 333         save_libs=$LIBS
 334         LIBS="$LIBS $FREETYPE_LIBS"
 335         AC_CHECK_FUNCS(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 336         LIBS=$save_libs
 337 fi
 338 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 339
 340 dnl ===========================================================================
 341
 342 AC_ARG_WITH(uniscribe,
 343         [AS_HELP_STRING([--with-uniscribe=@<:@yes/no/auto@:>@],
 344                         [Use the Uniscribe library @<:@default=no@:>@])],,
 345         [with_uniscribe=no])
 346 have_uniscribe=false
 347 if test "x$with_uniscribe" = "xyes" -o "x$with_uniscribe" = "xauto"; then
 348         AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true)
 349 fi
 350 if test "x$with_uniscribe" = "xyes" -a "x$have_uniscribe" != "xtrue"; then
 351         AC_MSG_ERROR([uniscribe support requested but not found])
 352 fi
 353 if $have_uniscribe; then
 354         UNISCRIBE_CFLAGS=
 355         UNISCRIBE_LIBS="-lusp10 -lgdi32 -lrpcrt4"
 356         AC_SUBST(UNISCRIBE_CFLAGS)
 357         AC_SUBST(UNISCRIBE_LIBS)
 358         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe library])
 359 fi
 360 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 361
 362 dnl ===========================================================================
 363
 364 AC_ARG_WITH(gdi,
 365         [AS_HELP_STRING([--with-gdi=@<:@yes/no/auto@:>@],
 366                         [Provide GDI integration helpers @<:@default=no@:>@])],,
 367         [with_gdi=no])
 368 have_gdi=false
 369 if test "x$with_gdi" = "xyes" -o "x$with_gdi" = "xauto"; then
 370         AC_CHECK_HEADERS(windows.h, have_gdi=true)
 371 fi
 372 if test "x$with_gdi" = "xyes" -a "x$have_gdi" != "xtrue"; then
 373         AC_MSG_ERROR([gdi support requested but not found])
 374 fi
 375 if $have_gdi; then
 376         GDI_CFLAGS=
 377         GDI_LIBS="-lgdi32"
 378         AC_SUBST(GDI_CFLAGS)
 379         AC_SUBST(GDI_LIBS)
 380         AC_DEFINE(HAVE_GDI, 1, [Have GDI library])
 381 fi
 382 AM_CONDITIONAL(HAVE_GDI, $have_gdi)
 383
 384 dnl ===========================================================================
 385
 386 AC_ARG_WITH(directwrite,
 387         [AS_HELP_STRING([--with-directwrite=@<:@yes/no/auto@:>@],
 388                         [Use the DirectWrite library (experimental) @<:@default=no@:>@])],,
 389         [with_directwrite=no])
 390 have_directwrite=false
 391 AC_LANG_PUSH([C++])
 392 if test "x$with_directwrite" = "xyes" -o "x$with_directwrite" = "xauto"; then
 393         AC_CHECK_HEADERS(dwrite.h, have_directwrite=true)
 394 fi
 395 AC_LANG_POP([C++])
 396 if test "x$with_directwrite" = "xyes" -a "x$have_directwrite" != "xtrue"; then
 397         AC_MSG_ERROR([directwrite support requested but not found])
 398 fi
 399 if $have_directwrite; then
 400         DIRECTWRITE_CXXFLAGS=
 401         DIRECTWRITE_LIBS=
 402         AC_SUBST(DIRECTWRITE_CXXFLAGS)
 403         AC_SUBST(DIRECTWRITE_LIBS)
 404         AC_DEFINE(HAVE_DIRECTWRITE, 1, [Have DirectWrite library])
 405 fi
 406 AM_CONDITIONAL(HAVE_DIRECTWRITE, $have_directwrite)
 407
 408 dnl ===========================================================================
 409
 410 AC_ARG_WITH(coretext,
 411         [AS_HELP_STRING([--with-coretext=@<:@yes/no/auto@:>@],
 412                         [Use CoreText @<:@default=no@:>@])],,
 413         [with_coretext=no])
 414 have_coretext=false
 415 if test "x$with_coretext" = "xyes" -o "x$with_coretext" = "xauto"; then
 416         AC_CHECK_TYPE(CTFontRef, have_coretext=true,, [#include <ApplicationServices/ApplicationServices.h>])
 417
 418         if $have_coretext; then
 419                 CORETEXT_CFLAGS=
 420                 CORETEXT_LIBS="-framework ApplicationServices"
 421                 AC_SUBST(CORETEXT_CFLAGS)
 422                 AC_SUBST(CORETEXT_LIBS)
 423         else
 424                 # On iOS CoreText and CoreGraphics are stand-alone frameworks
 425                 if test "x$have_coretext" != "xtrue"; then
 426                         # Check for a different symbol to avoid getting cached result.
 427                         AC_CHECK_TYPE(CTRunRef, have_coretext=true,, [#include <CoreText/CoreText.h>])
 428                 fi
 429
 430                 if $have_coretext; then
 431                         CORETEXT_CFLAGS=
 432                         CORETEXT_LIBS="-framework CoreText -framework CoreGraphics -framework CoreFoundation"
 433                         AC_SUBST(CORETEXT_CFLAGS)
 434                         AC_SUBST(CORETEXT_LIBS)
 435                 fi
 436         fi
 437 fi
 438 if test "x$with_coretext" = "xyes" -a "x$have_coretext" != "xtrue"; then
 439         AC_MSG_ERROR([CoreText support requested but libcoretext not found])
 440 fi
 441 if $have_coretext; then
 442         AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
 443 fi
 444 AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
 445
 446 dnl ===========================================================================
 447
 448 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 449         hb_cv_have_intel_atomic_primitives=false
 450         AC_TRY_LINK([
 451                 void memory_barrier (void) { __sync_synchronize (); }
 452                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 453                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 454                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 455                 ], [], hb_cv_have_intel_atomic_primitives=true
 456         )
 457 ])
 458 if $hb_cv_have_intel_atomic_primitives; then
 459         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 460 fi
 461
 462 dnl ===========================================================================
 463
 464 AC_CACHE_CHECK([for Solaris atomic operations], hb_cv_have_solaris_atomic_ops, [
 465         hb_cv_have_solaris_atomic_ops=false
 466         AC_TRY_LINK([
 467                 #include <atomic.h>
 468                 /* This requires Solaris Studio 12.2 or newer: */
 469                 #include <mbarrier.h>
 470                 void memory_barrier (void) { __machine_rw_barrier (); }
 471                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 472                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 473                 ], [], hb_cv_have_solaris_atomic_ops=true
 474         )
 475 ])
 476 if $hb_cv_have_solaris_atomic_ops; then
 477         AC_DEFINE(HAVE_SOLARIS_ATOMIC_OPS, 1, [Have Solaris __machine_*_barrier and atomic_* operations])
 478 fi
 479
 480 if test "$os_win32" = no && ! $have_pthread; then
 481         AC_CHECK_HEADERS(sched.h)
 482         AC_SEARCH_LIBS(sched_yield,rt,AC_DEFINE(HAVE_SCHED_YIELD, 1, [Have sched_yield]))
 483 fi
 484
 485 dnl ===========================================================================
 486
 487 AC_CONFIG_FILES([
 488 Makefile
 489 src/Makefile
 490 src/harfbuzz-config.cmake
 491 util/Makefile
 492 test/Makefile
 493 test/api/Makefile
 494 test/fuzzing/Makefile
 495 test/shaping/Makefile
 496 test/shaping/data/Makefile
 497 test/shaping/data/aots/Makefile
 498 test/shaping/data/in-house/Makefile
 499 test/shaping/data/text-rendering-tests/Makefile
 500 test/subset/Makefile
 501 test/subset/data/Makefile
 502 docs/Makefile
 503 docs/version.xml
 504 ])
 505
 506 AC_OUTPUT
 507
 508 echo
 509 echo "C++ compiler version:"
 510 $CXX --version
 511 echo
 512
 513 AC_MSG_NOTICE([
 514
 515 Build configuration:
 516
 517 Unicode callbacks (you want at least one):
 518         Builtin                 true
 519         Glib:                   ${have_glib}
 520         ICU:                    ${have_icu}
 521
 522 Font callbacks (the more the merrier):
 523         FreeType:               ${have_freetype}
 524
 525 Tools used for command-line utilities:
 526         Cairo:                  ${have_cairo}
 527         Fontconfig:             ${have_fontconfig}
 528
 529 Additional shapers (the more the merrier):
 530         Graphite2:              ${have_graphite2}
 531
 532 Platform shapers (not normally needed):
 533         CoreText:               ${have_coretext}
 534         DirectWrite:            ${have_directwrite}
 535         GDI:                    ${have_gdi}
 536         Uniscribe:              ${have_uniscribe}
 537
 538 Other features:
 539         Documentation:          ${enable_gtk_doc}
 540         GObject bindings:       ${have_gobject}
 541         Introspection:          ${have_introspection}
 542 ])