configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([HarfBuzz],
   3         [1.7.6],
   4         [https://github.com/harfbuzz/harfbuzz/issues/new],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_SRCDIR([src/harfbuzz.pc.in])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 AM_INIT_AUTOMAKE([1.13.0 gnits tar-ustar dist-bzip2 no-dist-gzip -Wall no-define color-tests -Wno-portability])
  13 AM_SILENT_RULES([yes])
  14 AX_CODE_COVERAGE
  15
  16 # Initialize libtool
  17 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  18 LT_PREREQ([2.2])
  19 LT_INIT([disable-static])
  20
  21 # Check for programs
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_PROG_CC
  24 AC_PROG_CC_C99
  25 AM_PROG_CC_C_O
  26 AC_PROG_CXX
  27 dnl AX_CXX_COMPILE_STDCXX(11, noext, optional)
  28 AC_SYS_LARGEFILE
  29 PKG_PROG_PKG_CONFIG([0.20])
  30 AM_MISSING_PROG([RAGEL], [ragel])
  31 AM_MISSING_PROG([GIT], [git])
  32
  33 # Version
  34 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  35 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  36 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  37 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  38 HB_VERSION_MAJOR=hb_version_major
  39 HB_VERSION_MINOR=hb_version_minor
  40 HB_VERSION_MICRO=hb_version_micro
  41 HB_VERSION=AC_PACKAGE_VERSION
  42 AC_SUBST(HB_VERSION_MAJOR)
  43 AC_SUBST(HB_VERSION_MINOR)
  44 AC_SUBST(HB_VERSION_MICRO)
  45 AC_SUBST(HB_VERSION)
  46
  47 # Libtool version
  48 m4_define([hb_version_int],
  49           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  50 m4_if(m4_eval(hb_version_minor % 2), [1],
  51       dnl for unstable releases
  52       [m4_define([hb_libtool_revision], 0)],
  53       dnl for stable releases
  54       [m4_define([hb_libtool_revision], hb_version_micro)])
  55 m4_define([hb_libtool_age],
  56           m4_eval(hb_version_int - hb_libtool_revision))
  57 m4_define([hb_libtool_current],
  58           m4_eval(hb_libtool_age))
  59 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  60 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  61
  62 AC_ARG_WITH([libstdc++],
  63         [AS_HELP_STRING([--with-libstdc++=@<:@yes/no@:>@],
  64                         [Allow linking with libstdc++ @<:@default=no@:>@])],
  65         [with_libstdcxx=$withval],
  66         [with_libstdcxx=no])
  67 AM_CONDITIONAL(WITH_LIBSTDCXX, [test "x$with_libstdcxx" = "xyes"])
  68
  69 # Documentation
  70 have_gtk_doc=false
  71 m4_ifdef([GTK_DOC_CHECK], [
  72 GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  73         if test "x$enable_gtk_doc" = xyes; then
  74                 have_gtk_doc=true
  75         fi
  76 ], [
  77         AM_CONDITIONAL([ENABLE_GTK_DOC], false)
  78 ])
  79
  80 # Functions, and headers
  81 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l setlinebuf)
  82 AC_CHECK_HEADERS(unistd.h sys/mman.h xlocale.h)
  83
  84 # Compiler flags
  85 AC_CANONICAL_HOST
  86 AC_CHECK_ALIGNOF([struct{char;}])
  87 if test "x$GCC" = "xyes"; then
  88
  89         # Make symbols link locally
  90         LDFLAGS="$LDFLAGS -Bsymbolic-functions"
  91
  92         # Assorted warnings
  93         CXXFLAGS="$CXXFLAGS -Wcast-align"
  94
  95         case "$host" in
  96                 *-*-mingw*)
  97                 ;;
  98                 *)
  99                         # Hide inline methods
 100                         CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
 101                 ;;
 102         esac
 103
 104         case "$host" in
 105                 arm-*-*)
 106                         if test "x$ac_cv_alignof_struct_char__" != x1; then
 107                                 # Request byte alignment
 108                                 CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
 109                         fi
 110                 ;;
 111         esac
 112 fi
 113
 114 AM_CONDITIONAL(HAVE_GCC, test "x$GCC" = "xyes")
 115
 116 hb_os_win32=no
 117 AC_MSG_CHECKING([for native Win32])
 118 case "$host" in
 119   *-*-mingw*)
 120     hb_os_win32=yes
 121     ;;
 122 esac
 123 AC_MSG_RESULT([$hb_os_win32])
 124 AM_CONDITIONAL(OS_WIN32, test "$hb_os_win32" = "yes")
 125
 126 have_pthread=false
 127 if test "$hb_os_win32" = no; then
 128         AX_PTHREAD([have_pthread=true])
 129 fi
 130 if $have_pthread; then
 131         AC_DEFINE(HAVE_PTHREAD, 1, [Have POSIX threads])
 132 fi
 133 AM_CONDITIONAL(HAVE_PTHREAD, $have_pthread)
 134
 135 dnl ==========================================================================
 136
 137 have_ot=true
 138 if $have_ot; then
 139         AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
 140 fi
 141 AM_CONDITIONAL(HAVE_OT, $have_ot)
 142
 143 have_fallback=true
 144 if $have_fallback; then
 145         AC_DEFINE(HAVE_FALLBACK, 1, [Have simple TrueType Layout backend])
 146 fi
 147 AM_CONDITIONAL(HAVE_FALLBACK, $have_fallback)
 148
 149 dnl ===========================================================================
 150
 151 AC_ARG_WITH(glib,
 152         [AS_HELP_STRING([--with-glib=@<:@yes/no/auto@:>@],
 153                         [Use glib @<:@default=auto@:>@])],,
 154         [with_glib=auto])
 155 have_glib=false
 156 GLIB_DEPS="glib-2.0 >= 2.19.1"
 157 AC_SUBST(GLIB_DEPS)
 158 if test "x$with_glib" = "xyes" -o "x$with_glib" = "xauto"; then
 159         PKG_CHECK_MODULES(GLIB, $GLIB_DEPS, have_glib=true, :)
 160 fi
 161 if test "x$with_glib" = "xyes" -a "x$have_glib" != "xtrue"; then
 162         AC_MSG_ERROR([glib support requested but glib-2.0 not found])
 163 fi
 164 if $have_glib; then
 165         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
 166 fi
 167 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 168
 169 dnl ===========================================================================
 170
 171 AC_ARG_WITH(gobject,
 172         [AS_HELP_STRING([--with-gobject=@<:@yes/no/auto@:>@],
 173                         [Use gobject @<:@default=no@:>@])],,
 174         [with_gobject=no])
 175 have_gobject=false
 176 if test "x$with_gobject" = "xyes" -o "x$with_gobject" = "xauto"; then
 177         PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0, have_gobject=true, :)
 178 fi
 179 if test "x$with_gobject" = "xyes" -a "x$have_gobject" != "xtrue"; then
 180         AC_MSG_ERROR([gobject support requested but gobject-2.0 / glib-2.0 not found])
 181 fi
 182 if $have_gobject; then
 183         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 184         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 185         AC_SUBST(GLIB_MKENUMS)
 186 fi
 187 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 188 AC_SUBST(have_gobject)
 189
 190 dnl ===========================================================================
 191
 192
 193 dnl ===========================================================================
 194 # Gobject-Introspection
 195 have_introspection=false
 196 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
 197         if $have_gobject; then
 198                 GOBJECT_INTROSPECTION_CHECK([1.34.0])
 199                 if test "x$found_introspection" = xyes; then
 200                         have_introspection=true
 201                 fi
 202         else
 203                 AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 204         fi
 205 ], [
 206         AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 207 ])
 208
 209 dnl ==========================================================================
 210
 211 AC_ARG_WITH(cairo,
 212         [AS_HELP_STRING([--with-cairo=@<:@yes/no/auto@:>@],
 213                         [Use cairo @<:@default=auto@:>@])],,
 214         [with_cairo=auto])
 215 have_cairo=false
 216 if test "x$with_cairo" = "xyes" -o "x$with_cairo" = "xauto"; then
 217         PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, :)
 218 fi
 219 if test "x$with_cairo" = "xyes" -a "x$have_cairo" != "xtrue"; then
 220         AC_MSG_ERROR([cairo support requested but not found])
 221 fi
 222 if $have_cairo; then
 223         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 224 fi
 225 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 226
 227 have_cairo_ft=false
 228 if $have_cairo; then
 229         PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, :)
 230 fi
 231 if $have_cairo_ft; then
 232         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 233 fi
 234 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 235
 236 dnl ==========================================================================
 237
 238 AC_ARG_WITH(fontconfig,
 239         [AS_HELP_STRING([--with-fontconfig=@<:@yes/no/auto@:>@],
 240                         [Use fontconfig @<:@default=auto@:>@])],,
 241         [with_fontconfig=auto])
 242 have_fontconfig=false
 243 if test "x$with_fontconfig" = "xyes" -o "x$with_fontconfig" = "xauto"; then
 244         PKG_CHECK_MODULES(FONTCONFIG, fontconfig, have_fontconfig=true, :)
 245 fi
 246 if test "x$with_fontconfig" = "xyes" -a "x$have_fontconfig" != "xtrue"; then
 247         AC_MSG_ERROR([fontconfig support requested but not found])
 248 fi
 249 if $have_fontconfig; then
 250         AC_DEFINE(HAVE_FONTCONFIG, 1, [Have fontconfig library])
 251 fi
 252 AM_CONDITIONAL(HAVE_FONTCONFIG, $have_fontconfig)
 253
 254 dnl ==========================================================================
 255
 256 AC_ARG_WITH(icu,
 257         [AS_HELP_STRING([--with-icu=@<:@yes/no/builtin/auto@:>@],
 258                         [Use ICU @<:@default=auto@:>@])],,
 259         [with_icu=auto])
 260 have_icu=false
 261 if test "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" -o "x$with_icu" = "xauto"; then
 262         PKG_CHECK_MODULES(ICU, icu-uc, have_icu=true, :)
 263
 264         dnl Fallback to icu-config if ICU pkg-config files could not be found
 265         if test "$have_icu" != "true"; then
 266                 AC_CHECK_TOOL(ICU_CONFIG, icu-config, no)
 267                 AC_MSG_CHECKING([for ICU by using icu-config fallback])
 268                 if test "$ICU_CONFIG" != "no" && "$ICU_CONFIG" --version >/dev/null; then
 269                         have_icu=true
 270                         # We don't use --cflags as this gives us a lot of things that we don't
 271                         # necessarily want, like debugging and optimization flags
 272                         # See man (1) icu-config for more info.
 273                         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 274                         ICU_LIBS=`$ICU_CONFIG --ldflags-searchpath --ldflags-libsonly`
 275                         AC_SUBST(ICU_CFLAGS)
 276                         AC_SUBST(ICU_LIBS)
 277                         AC_MSG_RESULT([yes])
 278                 else
 279                         AC_MSG_RESULT([no])
 280                 fi
 281         fi
 282 fi
 283 if test \( "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" \) -a "x$have_icu" != "xtrue"; then
 284         AC_MSG_ERROR([icu support requested but icu-uc not found])
 285 fi
 286
 287 if $have_icu; then
 288         CXXFLAGS="$CXXFLAGS `$PKG_CONFIG --variable=CXXFLAGS icu-uc`"
 289         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 290         if test "x$with_icu" = "xbuiltin"; then
 291                 AC_DEFINE(HAVE_ICU_BUILTIN, 1, [Use hb-icu Unicode callbacks])
 292         fi
 293 fi
 294 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 295 AM_CONDITIONAL(HAVE_ICU_BUILTIN, $have_icu && test "x$with_icu" = "xbuiltin")
 296
 297 dnl ===========================================================================
 298
 299 AC_ARG_WITH(ucdn,
 300         [AS_HELP_STRING([--with-ucdn=@<:@yes/no@:>@],
 301                         [Use builtin UCDN library @<:@default=yes@:>@])],,
 302         [with_ucdn=yes])
 303 have_ucdn=false
 304 if test "x$with_ucdn" = "xyes"; then
 305         have_ucdn=true
 306 fi
 307 if $have_ucdn; then
 308         AC_DEFINE(HAVE_UCDN, 1, [Have UCDN Unicode functions])
 309 fi
 310 AM_CONDITIONAL(HAVE_UCDN, $have_ucdn)
 311
 312 dnl ==========================================================================
 313
 314 AC_ARG_WITH(graphite2,
 315         [AS_HELP_STRING([--with-graphite2=@<:@yes/no/auto@:>@],
 316                         [Use the graphite2 library @<:@default=no@:>@])],,
 317         [with_graphite2=no])
 318 have_graphite2=false
 319 GRAPHITE2_DEPS="graphite2"
 320 AC_SUBST(GRAPHITE2_DEPS)
 321 if test "x$with_graphite2" = "xyes" -o "x$with_graphite2" = "xauto"; then
 322         PKG_CHECK_MODULES(GRAPHITE2, $GRAPHITE2_DEPS, have_graphite2=true, :)
 323         if test "x$have_graphite2" != "xtrue"; then
 324                 # If pkg-config is not available, graphite2 can still be there
 325                 ac_save_CFLAGS="$CFLAGS"
 326                 ac_save_CPPFLAGS="$CPPFLAGS"
 327                 CFLAGS="$CFLAGS $GRAPHITE2_CFLAGS"
 328                 CPPFLAGS="$CPPFLAGS $GRAPHITE2_CFLAGS"
 329                 AC_CHECK_HEADER(graphite2/Segment.h, have_graphite2=true, :)
 330                 CPPFLAGS="$ac_save_CPPFLAGS"
 331                 CFLAGS="$ac_save_CFLAGS"
 332         fi
 333 fi
 334 if test "x$with_graphite2" = "xyes" -a "x$have_graphite2" != "xtrue"; then
 335         AC_MSG_ERROR([graphite2 support requested but libgraphite2 not found])
 336 fi
 337 if $have_graphite2; then
 338         AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite2 library])
 339 fi
 340 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite2)
 341
 342 dnl ==========================================================================
 343
 344 AC_ARG_WITH(freetype,
 345         [AS_HELP_STRING([--with-freetype=@<:@yes/no/auto@:>@],
 346                         [Use the FreeType library @<:@default=auto@:>@])],,
 347         [with_freetype=auto])
 348 have_freetype=false
 349 FREETYPE_DEPS="freetype2 >= 12.0.6"
 350 AC_SUBST(FREETYPE_DEPS)
 351 if test "x$with_freetype" = "xyes" -o "x$with_freetype" = "xauto"; then
 352         # See freetype/docs/VERSION.DLL; 12.0.6 means freetype-2.4.2
 353         PKG_CHECK_MODULES(FREETYPE, $FREETYPE_DEPS, have_freetype=true, :)
 354 fi
 355 if test "x$with_freetype" = "xyes" -a "x$have_freetype" != "xtrue"; then
 356         AC_MSG_ERROR([FreeType support requested but libfreetype2 not found])
 357 fi
 358 if $have_freetype; then
 359         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 360         save_libs=$LIBS
 361         LIBS="$LIBS $FREETYPE_LIBS"
 362         AC_CHECK_FUNCS(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 363         LIBS=$save_libs
 364 fi
 365 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 366
 367 dnl ===========================================================================
 368
 369 AC_ARG_WITH(uniscribe,
 370         [AS_HELP_STRING([--with-uniscribe=@<:@yes/no/auto@:>@],
 371                         [Use the Uniscribe library @<:@default=no@:>@])],,
 372         [with_uniscribe=no])
 373 have_uniscribe=false
 374 if test "x$with_uniscribe" = "xyes" -o "x$with_uniscribe" = "xauto"; then
 375         AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true)
 376 fi
 377 if test "x$with_uniscribe" = "xyes" -a "x$have_uniscribe" != "xtrue"; then
 378         AC_MSG_ERROR([uniscribe support requested but not found])
 379 fi
 380 if $have_uniscribe; then
 381         UNISCRIBE_CFLAGS=
 382         UNISCRIBE_LIBS="-lusp10 -lgdi32 -lrpcrt4"
 383         AC_SUBST(UNISCRIBE_CFLAGS)
 384         AC_SUBST(UNISCRIBE_LIBS)
 385         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe library])
 386 fi
 387 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 388
 389 dnl ===========================================================================
 390
 391 AC_ARG_WITH(directwrite,
 392         [AS_HELP_STRING([--with-directwrite=@<:@yes/no/auto@:>@],
 393                         [Use the DirectWrite library (experimental) @<:@default=no@:>@])],,
 394         [with_directwrite=no])
 395 have_directwrite=false
 396 AC_LANG_PUSH([C++])
 397 if test "x$with_directwrite" = "xyes" -o "x$with_directwrite" = "xauto"; then
 398         AC_CHECK_HEADERS(dwrite.h, have_directwrite=true)
 399 fi
 400 AC_LANG_POP([C++])
 401 if test "x$with_directwrite" = "xyes" -a "x$have_directwrite" != "xtrue"; then
 402         AC_MSG_ERROR([directwrite support requested but not found])
 403 fi
 404 if $have_directwrite; then
 405         DIRECTWRITE_CXXFLAGS=
 406         DIRECTWRITE_LIBS="-ldwrite"
 407         AC_SUBST(DIRECTWRITE_CXXFLAGS)
 408         AC_SUBST(DIRECTWRITE_LIBS)
 409         AC_DEFINE(HAVE_DIRECTWRITE, 1, [Have DirectWrite library])
 410 fi
 411 AM_CONDITIONAL(HAVE_DIRECTWRITE, $have_directwrite)
 412
 413 dnl ===========================================================================
 414
 415 AC_ARG_WITH(coretext,
 416         [AS_HELP_STRING([--with-coretext=@<:@yes/no/auto@:>@],
 417                         [Use CoreText @<:@default=no@:>@])],,
 418         [with_coretext=no])
 419 have_coretext=false
 420 if test "x$with_coretext" = "xyes" -o "x$with_coretext" = "xauto"; then
 421         AC_CHECK_TYPE(CTFontRef, have_coretext=true,, [#include <ApplicationServices/ApplicationServices.h>])
 422
 423         if $have_coretext; then
 424                 CORETEXT_CFLAGS=
 425                 CORETEXT_LIBS="-framework ApplicationServices"
 426                 AC_SUBST(CORETEXT_CFLAGS)
 427                 AC_SUBST(CORETEXT_LIBS)
 428         else
 429                 # On iOS CoreText and CoreGraphics are stand-alone frameworks
 430                 if test "x$have_coretext" != "xtrue"; then
 431                         # Check for a different symbol to avoid getting cached result.
 432                         AC_CHECK_TYPE(CTRunRef, have_coretext=true,, [#include <CoreText/CoreText.h>])
 433                 fi
 434
 435                 if $have_coretext; then
 436                         CORETEXT_CFLAGS=
 437                         CORETEXT_LIBS="-framework CoreText -framework CoreGraphics -framework CoreFoundation"
 438                         AC_SUBST(CORETEXT_CFLAGS)
 439                         AC_SUBST(CORETEXT_LIBS)
 440                 fi
 441         fi
 442 fi
 443 if test "x$with_coretext" = "xyes" -a "x$have_coretext" != "xtrue"; then
 444         AC_MSG_ERROR([CoreText support requested but libcoretext not found])
 445 fi
 446 if $have_coretext; then
 447         AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
 448 fi
 449 AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
 450
 451 dnl ===========================================================================
 452
 453 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 454         hb_cv_have_intel_atomic_primitives=false
 455         AC_TRY_LINK([
 456                 void memory_barrier (void) { __sync_synchronize (); }
 457                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 458                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 459                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 460                 ], [], hb_cv_have_intel_atomic_primitives=true
 461         )
 462 ])
 463 if $hb_cv_have_intel_atomic_primitives; then
 464         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 465 fi
 466
 467 dnl ===========================================================================
 468
 469 AC_CACHE_CHECK([for Solaris atomic operations], hb_cv_have_solaris_atomic_ops, [
 470         hb_cv_have_solaris_atomic_ops=false
 471         AC_TRY_LINK([
 472                 #include <atomic.h>
 473                 /* This requires Solaris Studio 12.2 or newer: */
 474                 #include <mbarrier.h>
 475                 void memory_barrier (void) { __machine_rw_barrier (); }
 476                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 477                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 478                 ], [], hb_cv_have_solaris_atomic_ops=true
 479         )
 480 ])
 481 if $hb_cv_have_solaris_atomic_ops; then
 482         AC_DEFINE(HAVE_SOLARIS_ATOMIC_OPS, 1, [Have Solaris __machine_*_barrier and atomic_* operations])
 483 fi
 484
 485 if test "$os_win32" = no && ! $have_pthread; then
 486         AC_CHECK_HEADERS(sched.h)
 487         AC_SEARCH_LIBS(sched_yield,rt,AC_DEFINE(HAVE_SCHED_YIELD, 1, [Have sched_yield]))
 488 fi
 489
 490 dnl ===========================================================================
 491
 492 AC_CONFIG_FILES([
 493 Makefile
 494 src/Makefile
 495 src/hb-version.h
 496 src/harfbuzz-config.cmake
 497 src/hb-ucdn/Makefile
 498 util/Makefile
 499 test/Makefile
 500 test/api/Makefile
 501 test/fuzzing/Makefile
 502 test/shaping/Makefile
 503 test/shaping/data/Makefile
 504 test/shaping/data/in-house/Makefile
 505 test/shaping/data/text-rendering-tests/Makefile
 506 test/subset/Makefile
 507 test/subset/data/Makefile
 508 docs/Makefile
 509 docs/version.xml
 510 ])
 511
 512 AC_OUTPUT
 513
 514 AC_MSG_NOTICE([
 515
 516 Build configuration:
 517
 518 Unicode callbacks (you want at least one):
 519         Builtin (UCDN):         ${have_ucdn}
 520         Glib:                   ${have_glib}
 521         ICU:                    ${have_icu}
 522
 523 Font callbacks (the more the merrier):
 524         FreeType:               ${have_freetype}
 525
 526 Tools used for command-line utilities:
 527         Cairo:                  ${have_cairo}
 528         Fontconfig:             ${have_fontconfig}
 529
 530 Additional shapers (the more the merrier):
 531         Graphite2:              ${have_graphite2}
 532
 533 Platform shapers (not normally needed):
 534         CoreText:               ${have_coretext}
 535         Uniscribe:              ${have_uniscribe}
 536         DirectWrite:            ${have_directwrite}
 537
 538 Other features:
 539         Documentation:          ${enable_gtk_doc}
 540         GObject bindings:       ${have_gobject}
 541         Introspection:          ${have_introspection}
 542 ])