configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([HarfBuzz],
   3         [1.8.1],
   4         [https://github.com/harfbuzz/harfbuzz/issues/new],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_SRCDIR([src/harfbuzz.pc.in])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 AM_INIT_AUTOMAKE([1.13.0 gnits tar-ustar dist-bzip2 no-dist-gzip -Wall no-define color-tests -Wno-portability])
  13 AM_SILENT_RULES([yes])
  14 AX_CODE_COVERAGE
  15
  16 # Initialize libtool
  17 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  18 LT_PREREQ([2.2])
  19 LT_INIT([disable-static])
  20
  21 # Check for programs
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_PROG_CC
  24 AC_PROG_CC_C99
  25 AM_PROG_CC_C_O
  26 AC_PROG_CXX
  27 dnl AX_CXX_COMPILE_STDCXX(11, noext, optional)
  28 AC_SYS_LARGEFILE
  29 PKG_PROG_PKG_CONFIG([0.20])
  30 AM_MISSING_PROG([RAGEL], [ragel])
  31 AM_MISSING_PROG([GIT], [git])
  32
  33 # Version
  34 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  35 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  36 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  37 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  38 HB_VERSION_MAJOR=hb_version_major
  39 HB_VERSION_MINOR=hb_version_minor
  40 HB_VERSION_MICRO=hb_version_micro
  41 HB_VERSION=AC_PACKAGE_VERSION
  42 AC_SUBST(HB_VERSION_MAJOR)
  43 AC_SUBST(HB_VERSION_MINOR)
  44 AC_SUBST(HB_VERSION_MICRO)
  45 AC_SUBST(HB_VERSION)
  46
  47 # Libtool version
  48 m4_define([hb_version_int],
  49           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  50 m4_if(m4_eval(hb_version_minor % 2), [1],
  51       dnl for unstable releases
  52       [m4_define([hb_libtool_revision], 0)],
  53       dnl for stable releases
  54       [m4_define([hb_libtool_revision], hb_version_micro)])
  55 m4_define([hb_libtool_age],
  56           m4_eval(hb_version_int - hb_libtool_revision))
  57 m4_define([hb_libtool_current],
  58           m4_eval(hb_libtool_age))
  59 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  60 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  61
  62 AC_ARG_WITH([libstdc++],
  63         [AS_HELP_STRING([--with-libstdc++=@<:@yes/no@:>@],
  64                         [Allow linking with libstdc++ @<:@default=no@:>@])],
  65         [with_libstdcxx=$withval],
  66         [with_libstdcxx=no])
  67 AM_CONDITIONAL(WITH_LIBSTDCXX, [test "x$with_libstdcxx" = "xyes"])
  68
  69 # Documentation
  70 have_gtk_doc=false
  71 m4_ifdef([GTK_DOC_CHECK], [
  72 GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  73         if test "x$enable_gtk_doc" = xyes; then
  74                 have_gtk_doc=true
  75         fi
  76 ], [
  77         AM_CONDITIONAL([ENABLE_GTK_DOC], false)
  78 ])
  79
  80 # Functions and headers
  81 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l)
  82
  83 save_libs="$LIBS"
  84 LIBS="$LIBS -lm"
  85 AC_CHECK_FUNCS([round], ,[AC_CHECK_DECLS([round], , ,[#include <math.h>])])
  86 LIBS="$save_libs"
  87
  88 AC_CHECK_HEADERS(unistd.h sys/mman.h xlocale.h stdbool.h)
  89
  90 # Compiler flags
  91 AC_CANONICAL_HOST
  92 AC_CHECK_ALIGNOF([struct{char;}])
  93 if test "x$GCC" = "xyes"; then
  94
  95         # Make symbols link locally
  96         AX_CHECK_LINK_FLAG([[-Bsymbolic-functions]], [LDFLAGS="$LDFLAGS -Bsymbolic-functions"])
  97
  98         # Make it possible to not link to libstdc++
  99         # No threadsafe statics in C++ as we do it ourselves.
 100         # We don't use these features, so it's safe to disable them
 101         # even in the cases where we DO link to libstdc++.
 102         # Put -fno-rtti before $CXXFLAGS such that users can re-enable it
 103         # by overriding CXXFLAGS.
 104         CXXFLAGS="-fno-rtti $CXXFLAGS -fno-exceptions -fno-threadsafe-statics"
 105
 106         # Assorted warnings
 107         CXXFLAGS="$CXXFLAGS -Wcast-align"
 108
 109         case "$host" in
 110                 *-*-mingw*)
 111                 ;;
 112                 *)
 113                         # Hide inline methods
 114                         CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
 115                 ;;
 116         esac
 117
 118         case "$host" in
 119                 arm-*-*)
 120                         if test "x$ac_cv_alignof_struct_char__" != x1; then
 121                                 # Request byte alignment
 122                                 CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
 123                         fi
 124                 ;;
 125         esac
 126 fi
 127
 128 AM_CONDITIONAL(HAVE_GCC, test "x$GCC" = "xyes")
 129
 130 hb_os_win32=no
 131 AC_MSG_CHECKING([for native Win32])
 132 case "$host" in
 133   *-*-mingw*)
 134     hb_os_win32=yes
 135     ;;
 136 esac
 137 AC_MSG_RESULT([$hb_os_win32])
 138 AM_CONDITIONAL(OS_WIN32, test "$hb_os_win32" = "yes")
 139
 140 have_pthread=false
 141 if test "$hb_os_win32" = no; then
 142         AX_PTHREAD([have_pthread=true])
 143 fi
 144 if $have_pthread; then
 145         AC_DEFINE(HAVE_PTHREAD, 1, [Have POSIX threads])
 146 fi
 147 AM_CONDITIONAL(HAVE_PTHREAD, $have_pthread)
 148
 149 dnl ==========================================================================
 150
 151 have_ot=true
 152 if $have_ot; then
 153         AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
 154 fi
 155 AM_CONDITIONAL(HAVE_OT, $have_ot)
 156
 157 have_fallback=true
 158 if $have_fallback; then
 159         AC_DEFINE(HAVE_FALLBACK, 1, [Have simple TrueType Layout backend])
 160 fi
 161 AM_CONDITIONAL(HAVE_FALLBACK, $have_fallback)
 162
 163 dnl ===========================================================================
 164
 165 AC_ARG_WITH(glib,
 166         [AS_HELP_STRING([--with-glib=@<:@yes/no/auto@:>@],
 167                         [Use glib @<:@default=auto@:>@])],,
 168         [with_glib=auto])
 169 have_glib=false
 170 GLIB_DEPS="glib-2.0 >= 2.19.1"
 171 AC_SUBST(GLIB_DEPS)
 172 if test "x$with_glib" = "xyes" -o "x$with_glib" = "xauto"; then
 173         PKG_CHECK_MODULES(GLIB, $GLIB_DEPS, have_glib=true, :)
 174 fi
 175 if test "x$with_glib" = "xyes" -a "x$have_glib" != "xtrue"; then
 176         AC_MSG_ERROR([glib support requested but glib-2.0 not found])
 177 fi
 178 if $have_glib; then
 179         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
 180 fi
 181 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 182
 183 dnl ===========================================================================
 184
 185 AC_ARG_WITH(gobject,
 186         [AS_HELP_STRING([--with-gobject=@<:@yes/no/auto@:>@],
 187                         [Use gobject @<:@default=no@:>@])],,
 188         [with_gobject=no])
 189 have_gobject=false
 190 if test "x$with_gobject" = "xyes" -o "x$with_gobject" = "xauto"; then
 191         PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0, have_gobject=true, :)
 192 fi
 193 if test "x$with_gobject" = "xyes" -a "x$have_gobject" != "xtrue"; then
 194         AC_MSG_ERROR([gobject support requested but gobject-2.0 / glib-2.0 not found])
 195 fi
 196 if $have_gobject; then
 197         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 198         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 199         AC_SUBST(GLIB_MKENUMS)
 200 fi
 201 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 202 AC_SUBST(have_gobject)
 203
 204 dnl ===========================================================================
 205
 206
 207 dnl ===========================================================================
 208 # Gobject-Introspection
 209 have_introspection=false
 210 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
 211         if $have_gobject; then
 212                 GOBJECT_INTROSPECTION_CHECK([1.34.0])
 213                 if test "x$found_introspection" = xyes; then
 214                         have_introspection=true
 215                 fi
 216         else
 217                 AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 218         fi
 219 ], [
 220         AM_CONDITIONAL([HAVE_INTROSPECTION], false)
 221 ])
 222
 223 dnl ==========================================================================
 224
 225 AC_ARG_WITH(cairo,
 226         [AS_HELP_STRING([--with-cairo=@<:@yes/no/auto@:>@],
 227                         [Use cairo @<:@default=auto@:>@])],,
 228         [with_cairo=auto])
 229 have_cairo=false
 230 if test "x$with_cairo" = "xyes" -o "x$with_cairo" = "xauto"; then
 231         PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, :)
 232 fi
 233 if test "x$with_cairo" = "xyes" -a "x$have_cairo" != "xtrue"; then
 234         AC_MSG_ERROR([cairo support requested but not found])
 235 fi
 236 if $have_cairo; then
 237         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 238 fi
 239 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 240
 241 have_cairo_ft=false
 242 if $have_cairo; then
 243         PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, :)
 244 fi
 245 if $have_cairo_ft; then
 246         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 247 fi
 248 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 249
 250 dnl ==========================================================================
 251
 252 AC_ARG_WITH(fontconfig,
 253         [AS_HELP_STRING([--with-fontconfig=@<:@yes/no/auto@:>@],
 254                         [Use fontconfig @<:@default=auto@:>@])],,
 255         [with_fontconfig=auto])
 256 have_fontconfig=false
 257 if test "x$with_fontconfig" = "xyes" -o "x$with_fontconfig" = "xauto"; then
 258         PKG_CHECK_MODULES(FONTCONFIG, fontconfig, have_fontconfig=true, :)
 259 fi
 260 if test "x$with_fontconfig" = "xyes" -a "x$have_fontconfig" != "xtrue"; then
 261         AC_MSG_ERROR([fontconfig support requested but not found])
 262 fi
 263 if $have_fontconfig; then
 264         AC_DEFINE(HAVE_FONTCONFIG, 1, [Have fontconfig library])
 265 fi
 266 AM_CONDITIONAL(HAVE_FONTCONFIG, $have_fontconfig)
 267
 268 dnl ==========================================================================
 269
 270 AC_ARG_WITH(icu,
 271         [AS_HELP_STRING([--with-icu=@<:@yes/no/builtin/auto@:>@],
 272                         [Use ICU @<:@default=auto@:>@])],,
 273         [with_icu=auto])
 274 have_icu=false
 275 if test "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" -o "x$with_icu" = "xauto"; then
 276         PKG_CHECK_MODULES(ICU, icu-uc, have_icu=true, :)
 277
 278         dnl Fallback to icu-config if ICU pkg-config files could not be found
 279         if test "$have_icu" != "true"; then
 280                 AC_CHECK_TOOL(ICU_CONFIG, icu-config, no)
 281                 AC_MSG_CHECKING([for ICU by using icu-config fallback])
 282                 if test "$ICU_CONFIG" != "no" && "$ICU_CONFIG" --version >/dev/null; then
 283                         have_icu=true
 284                         # We don't use --cflags as this gives us a lot of things that we don't
 285                         # necessarily want, like debugging and optimization flags
 286                         # See man (1) icu-config for more info.
 287                         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 288                         ICU_LIBS=`$ICU_CONFIG --ldflags-searchpath --ldflags-libsonly`
 289                         AC_SUBST(ICU_CFLAGS)
 290                         AC_SUBST(ICU_LIBS)
 291                         AC_MSG_RESULT([yes])
 292                 else
 293                         AC_MSG_RESULT([no])
 294                 fi
 295         fi
 296 fi
 297 if test \( "x$with_icu" = "xyes" -o "x$with_icu" = "xbuiltin" \) -a "x$have_icu" != "xtrue"; then
 298         AC_MSG_ERROR([icu support requested but icu-uc not found])
 299 fi
 300
 301 if $have_icu; then
 302         CXXFLAGS="$CXXFLAGS `$PKG_CONFIG --variable=CXXFLAGS icu-uc`"
 303         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 304         if test "x$with_icu" = "xbuiltin"; then
 305                 AC_DEFINE(HAVE_ICU_BUILTIN, 1, [Use hb-icu Unicode callbacks])
 306         fi
 307 fi
 308 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 309 AM_CONDITIONAL(HAVE_ICU_BUILTIN, $have_icu && test "x$with_icu" = "xbuiltin")
 310
 311 dnl ===========================================================================
 312
 313 AC_ARG_WITH(ucdn,
 314         [AS_HELP_STRING([--with-ucdn=@<:@yes/no@:>@],
 315                         [Use builtin UCDN library @<:@default=yes@:>@])],,
 316         [with_ucdn=yes])
 317 have_ucdn=false
 318 if test "x$with_ucdn" = "xyes"; then
 319         have_ucdn=true
 320 fi
 321 if $have_ucdn; then
 322         AC_DEFINE(HAVE_UCDN, 1, [Have UCDN Unicode functions])
 323 fi
 324 AM_CONDITIONAL(HAVE_UCDN, $have_ucdn)
 325
 326 dnl ==========================================================================
 327
 328 AC_ARG_WITH(graphite2,
 329         [AS_HELP_STRING([--with-graphite2=@<:@yes/no/auto@:>@],
 330                         [Use the graphite2 library @<:@default=no@:>@])],,
 331         [with_graphite2=no])
 332 have_graphite2=false
 333 GRAPHITE2_DEPS="graphite2"
 334 AC_SUBST(GRAPHITE2_DEPS)
 335 if test "x$with_graphite2" = "xyes" -o "x$with_graphite2" = "xauto"; then
 336         PKG_CHECK_MODULES(GRAPHITE2, $GRAPHITE2_DEPS, have_graphite2=true, :)
 337         if test "x$have_graphite2" != "xtrue"; then
 338                 # If pkg-config is not available, graphite2 can still be there
 339                 ac_save_CFLAGS="$CFLAGS"
 340                 ac_save_CPPFLAGS="$CPPFLAGS"
 341                 CFLAGS="$CFLAGS $GRAPHITE2_CFLAGS"
 342                 CPPFLAGS="$CPPFLAGS $GRAPHITE2_CFLAGS"
 343                 AC_CHECK_HEADER(graphite2/Segment.h, have_graphite2=true, :)
 344                 CPPFLAGS="$ac_save_CPPFLAGS"
 345                 CFLAGS="$ac_save_CFLAGS"
 346         fi
 347 fi
 348 if test "x$with_graphite2" = "xyes" -a "x$have_graphite2" != "xtrue"; then
 349         AC_MSG_ERROR([graphite2 support requested but libgraphite2 not found])
 350 fi
 351 if $have_graphite2; then
 352         AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite2 library])
 353 fi
 354 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite2)
 355
 356 dnl ==========================================================================
 357
 358 AC_ARG_WITH(freetype,
 359         [AS_HELP_STRING([--with-freetype=@<:@yes/no/auto@:>@],
 360                         [Use the FreeType library @<:@default=auto@:>@])],,
 361         [with_freetype=auto])
 362 have_freetype=false
 363 FREETYPE_DEPS="freetype2 >= 12.0.6"
 364 AC_SUBST(FREETYPE_DEPS)
 365 if test "x$with_freetype" = "xyes" -o "x$with_freetype" = "xauto"; then
 366         # See freetype/docs/VERSION.DLL; 12.0.6 means freetype-2.4.2
 367         PKG_CHECK_MODULES(FREETYPE, $FREETYPE_DEPS, have_freetype=true, :)
 368 fi
 369 if test "x$with_freetype" = "xyes" -a "x$have_freetype" != "xtrue"; then
 370         AC_MSG_ERROR([FreeType support requested but libfreetype2 not found])
 371 fi
 372 if $have_freetype; then
 373         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 374         save_libs=$LIBS
 375         LIBS="$LIBS $FREETYPE_LIBS"
 376         AC_CHECK_FUNCS(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 377         LIBS=$save_libs
 378 fi
 379 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 380
 381 dnl ===========================================================================
 382
 383 AC_ARG_WITH(uniscribe,
 384         [AS_HELP_STRING([--with-uniscribe=@<:@yes/no/auto@:>@],
 385                         [Use the Uniscribe library @<:@default=no@:>@])],,
 386         [with_uniscribe=no])
 387 have_uniscribe=false
 388 if test "x$with_uniscribe" = "xyes" -o "x$with_uniscribe" = "xauto"; then
 389         AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true)
 390 fi
 391 if test "x$with_uniscribe" = "xyes" -a "x$have_uniscribe" != "xtrue"; then
 392         AC_MSG_ERROR([uniscribe support requested but not found])
 393 fi
 394 if $have_uniscribe; then
 395         UNISCRIBE_CFLAGS=
 396         UNISCRIBE_LIBS="-lusp10 -lgdi32 -lrpcrt4"
 397         AC_SUBST(UNISCRIBE_CFLAGS)
 398         AC_SUBST(UNISCRIBE_LIBS)
 399         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe library])
 400 fi
 401 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 402
 403 dnl ===========================================================================
 404
 405 AC_ARG_WITH(directwrite,
 406         [AS_HELP_STRING([--with-directwrite=@<:@yes/no/auto@:>@],
 407                         [Use the DirectWrite library (experimental) @<:@default=no@:>@])],,
 408         [with_directwrite=no])
 409 have_directwrite=false
 410 AC_LANG_PUSH([C++])
 411 if test "x$with_directwrite" = "xyes" -o "x$with_directwrite" = "xauto"; then
 412         AC_CHECK_HEADERS(dwrite.h, have_directwrite=true)
 413 fi
 414 AC_LANG_POP([C++])
 415 if test "x$with_directwrite" = "xyes" -a "x$have_directwrite" != "xtrue"; then
 416         AC_MSG_ERROR([directwrite support requested but not found])
 417 fi
 418 if $have_directwrite; then
 419         DIRECTWRITE_CXXFLAGS=
 420         DIRECTWRITE_LIBS="-ldwrite"
 421         AC_SUBST(DIRECTWRITE_CXXFLAGS)
 422         AC_SUBST(DIRECTWRITE_LIBS)
 423         AC_DEFINE(HAVE_DIRECTWRITE, 1, [Have DirectWrite library])
 424 fi
 425 AM_CONDITIONAL(HAVE_DIRECTWRITE, $have_directwrite)
 426
 427 dnl ===========================================================================
 428
 429 AC_ARG_WITH(coretext,
 430         [AS_HELP_STRING([--with-coretext=@<:@yes/no/auto@:>@],
 431                         [Use CoreText @<:@default=no@:>@])],,
 432         [with_coretext=no])
 433 have_coretext=false
 434 if test "x$with_coretext" = "xyes" -o "x$with_coretext" = "xauto"; then
 435         AC_CHECK_TYPE(CTFontRef, have_coretext=true,, [#include <ApplicationServices/ApplicationServices.h>])
 436
 437         if $have_coretext; then
 438                 CORETEXT_CFLAGS=
 439                 CORETEXT_LIBS="-framework ApplicationServices"
 440                 AC_SUBST(CORETEXT_CFLAGS)
 441                 AC_SUBST(CORETEXT_LIBS)
 442         else
 443                 # On iOS CoreText and CoreGraphics are stand-alone frameworks
 444                 if test "x$have_coretext" != "xtrue"; then
 445                         # Check for a different symbol to avoid getting cached result.
 446                         AC_CHECK_TYPE(CTRunRef, have_coretext=true,, [#include <CoreText/CoreText.h>])
 447                 fi
 448
 449                 if $have_coretext; then
 450                         CORETEXT_CFLAGS=
 451                         CORETEXT_LIBS="-framework CoreText -framework CoreGraphics -framework CoreFoundation"
 452                         AC_SUBST(CORETEXT_CFLAGS)
 453                         AC_SUBST(CORETEXT_LIBS)
 454                 fi
 455         fi
 456 fi
 457 if test "x$with_coretext" = "xyes" -a "x$have_coretext" != "xtrue"; then
 458         AC_MSG_ERROR([CoreText support requested but libcoretext not found])
 459 fi
 460 if $have_coretext; then
 461         AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
 462 fi
 463 AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
 464
 465 dnl ===========================================================================
 466
 467 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 468         hb_cv_have_intel_atomic_primitives=false
 469         AC_TRY_LINK([
 470                 void memory_barrier (void) { __sync_synchronize (); }
 471                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 472                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 473                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 474                 ], [], hb_cv_have_intel_atomic_primitives=true
 475         )
 476 ])
 477 if $hb_cv_have_intel_atomic_primitives; then
 478         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 479 fi
 480
 481 dnl ===========================================================================
 482
 483 AC_CACHE_CHECK([for Solaris atomic operations], hb_cv_have_solaris_atomic_ops, [
 484         hb_cv_have_solaris_atomic_ops=false
 485         AC_TRY_LINK([
 486                 #include <atomic.h>
 487                 /* This requires Solaris Studio 12.2 or newer: */
 488                 #include <mbarrier.h>
 489                 void memory_barrier (void) { __machine_rw_barrier (); }
 490                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 491                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 492                 ], [], hb_cv_have_solaris_atomic_ops=true
 493         )
 494 ])
 495 if $hb_cv_have_solaris_atomic_ops; then
 496         AC_DEFINE(HAVE_SOLARIS_ATOMIC_OPS, 1, [Have Solaris __machine_*_barrier and atomic_* operations])
 497 fi
 498
 499 if test "$os_win32" = no && ! $have_pthread; then
 500         AC_CHECK_HEADERS(sched.h)
 501         AC_SEARCH_LIBS(sched_yield,rt,AC_DEFINE(HAVE_SCHED_YIELD, 1, [Have sched_yield]))
 502 fi
 503
 504 dnl ===========================================================================
 505
 506 AC_CONFIG_FILES([
 507 Makefile
 508 src/Makefile
 509 src/harfbuzz-config.cmake
 510 src/hb-ucdn/Makefile
 511 util/Makefile
 512 test/Makefile
 513 test/api/Makefile
 514 test/fuzzing/Makefile
 515 test/shaping/Makefile
 516 test/shaping/data/Makefile
 517 test/shaping/data/in-house/Makefile
 518 test/shaping/data/text-rendering-tests/Makefile
 519 test/subset/Makefile
 520 test/subset/data/Makefile
 521 docs/Makefile
 522 docs/version.xml
 523 ])
 524
 525 AC_OUTPUT
 526
 527 AC_MSG_NOTICE([
 528
 529 Build configuration:
 530
 531 Unicode callbacks (you want at least one):
 532         Builtin (UCDN):         ${have_ucdn}
 533         Glib:                   ${have_glib}
 534         ICU:                    ${have_icu}
 535
 536 Font callbacks (the more the merrier):
 537         FreeType:               ${have_freetype}
 538
 539 Tools used for command-line utilities:
 540         Cairo:                  ${have_cairo}
 541         Fontconfig:             ${have_fontconfig}
 542
 543 Additional shapers (the more the merrier):
 544         Graphite2:              ${have_graphite2}
 545
 546 Platform shapers (not normally needed):
 547         CoreText:               ${have_coretext}
 548         DirectWrite:            ${have_directwrite}
 549         Uniscribe:              ${have_uniscribe}
 550
 551 Other features:
 552         Documentation:          ${enable_gtk_doc}
 553         GObject bindings:       ${have_gobject}
 554         Introspection:          ${have_introspection}
 555 ])