CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 project(harfbuzz)
   3
   4 enable_testing()
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_BUILTIN_UCDN "Use HarfBuzz provided UCDN" ON)
  39 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  40 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  41 if (APPLE)
  42   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  43   set (CMAKE_MACOSX_RPATH ON)
  44 endif ()
  45 if (WIN32)
  46   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  47   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  48 endif ()
  49 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  50 if (HB_BUILD_UTILS)
  51   set (HB_HAVE_GLIB ON)
  52   set (HB_HAVE_FREETYPE ON)
  53 endif ()
  54
  55 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  56 if (HB_HAVE_GOBJECT)
  57   set (HB_HAVE_GLIB ON)
  58 endif ()
  59
  60 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  61 if (HB_HAVE_INTROSPECTION)
  62   set (HB_HAVE_GOBJECT ON)
  63   set (HB_HAVE_GLIB ON)
  64 endif ()
  65
  66 option(HB_CHECK OFF "Do a configuration suitable for testing (shared library and enable all options)")
  67 if (HB_CHECK)
  68   set (BUILD_SHARED_LIBS ON)
  69   set (HB_BUILD_UTILS ON)
  70   set (HB_BUILTIN_UCDN ON)
  71   set (HB_HAVE_ICU)
  72   set (HB_HAVE_GLIB ON)
  73   #set (HB_HAVE_GOBJECT ON)
  74   #set (HB_HAVE_INTROSPECTION ON)
  75   set (HB_HAVE_FREETYPE ON)
  76   set (HB_HAVE_GRAPHITE2 ON)
  77   if (WIN32)
  78     set (HB_HAVE_UNISCRIBE ON)
  79     set (HB_HAVE_DIRECTWRITE ON)
  80   elseif (APPLE)
  81     set (HB_HAVE_CORETEXT ON)
  82   endif ()
  83 endif ()
  84
  85 include_directories(AFTER
  86   ${PROJECT_SOURCE_DIR}/src
  87   ${PROJECT_BINARY_DIR}/src
  88 )
  89
  90 add_definitions(-DHAVE_OT)
  91 add_definitions(-DHAVE_FALLBACK)
  92
  93
  94 ## Functions and headers
  95 include (CheckFunctionExists)
  96 include (CheckIncludeFile)
  97 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
  98   foreach (func_name ${ARGN})
  99     string(TOUPPER ${func_name} definiton_to_add)
 100     check_function_exists(${func_name} HAVE_${definiton_to_add})
 101     if (${HAVE_${definiton_to_add}})
 102       add_definitions(-DHAVE_${definiton_to_add})
 103     endif ()
 104   endforeach ()
 105 endmacro ()
 106 check_funcs(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l)
 107 check_include_file(unistd.h HAVE_UNISTD_H)
 108 if (${HAVE_UNISTD_H})
 109   add_definitions(-DHAVE_UNISTD_H)
 110 endif ()
 111 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
 112 if (${HAVE_SYS_MMAN_H})
 113   add_definitions(-DHAVE_SYS_MMAN_H)
 114 endif ()
 115 check_include_file(xlocale.h HAVE_XLOCALE_H)
 116 if (${HAVE_XLOCALE_H})
 117   add_definitions(-DHAVE_XLOCALE_H)
 118 endif ()
 119
 120
 121 if (MSVC)
 122   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 123 endif ()
 124
 125 if (BUILD_SHARED_LIBS)
 126   if (WIN32 AND NOT MINGW)
 127     add_definitions("-DHB_EXTERN=__declspec(dllexport) extern")
 128   else ()
 129     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 130   endif ()
 131 endif ()
 132
 133
 134 ## Detect if we are running inside a distribution or regular repository folder
 135 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 136 #   # perhaps we are on dist directory
 137 #   set (IN_HB_DIST TRUE)
 138 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 139 # endif ()
 140
 141
 142 ## Extract variables from Makefile files
 143 function (extract_make_variable variable makefile_source)
 144   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp ${makefile_source})
 145   string(REGEX MATCHALL "[^ \n\t\\]+" listVar ${CMAKE_MATCH_1})
 146   set (${variable} ${listVar} PARENT_SCOPE)
 147 endfunction ()
 148
 149 # http://stackoverflow.com/a/27630120
 150 function (add_prefix_to_list var prefix)
 151   set (listVar "")
 152   foreach (f ${${var}})
 153     list(APPEND listVar "${prefix}${f}")
 154   endforeach ()
 155   set (${var} "${listVar}" PARENT_SCOPE)
 156 endfunction ()
 157
 158 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 159 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 160 file(READ ${PROJECT_SOURCE_DIR}/src/hb-ucdn/Makefile.sources UCDNSOURCES)
 161
 162 extract_make_variable(HB_BASE_sources ${SRCSOURCES})
 163 add_prefix_to_list(HB_BASE_sources "${PROJECT_SOURCE_DIR}/src/")
 164 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 165 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 166 extract_make_variable(HB_FALLBACK_sources ${SRCSOURCES})
 167 add_prefix_to_list(HB_FALLBACK_sources "${PROJECT_SOURCE_DIR}/src/")
 168 extract_make_variable(HB_OT_sources ${SRCSOURCES})
 169 add_prefix_to_list(HB_OT_sources "${PROJECT_SOURCE_DIR}/src/")
 170 extract_make_variable(HB_OT_headers ${SRCSOURCES})
 171 add_prefix_to_list(HB_OT_headers "${PROJECT_SOURCE_DIR}/src/")
 172
 173 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 174 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 175
 176 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 177 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 178
 179 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 180 extract_make_variable(HB_OT_RAGEL_GENERATED_sources ${SRCSOURCES})
 181 #if (IN_HB_DIST)
 182   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 183   add_prefix_to_list(HB_OT_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 184 #else ()
 185 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 186 #  add_prefix_to_list(HB_OT_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 187 #endif ()
 188
 189 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 190 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 191 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 192 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 193 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 194 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 195 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 196 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 197
 198 extract_make_variable(LIBHB_UCDN_sources ${UCDNSOURCES})
 199 add_prefix_to_list(LIBHB_UCDN_sources "${PROJECT_SOURCE_DIR}/src/hb-ucdn/")
 200
 201
 202 file(READ configure.ac CONFIGUREAC)
 203 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 204 set (HB_VERSION ${CMAKE_MATCH_1})
 205 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 206 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 207 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 208
 209
 210 ## Define ragel tasks
 211 # if (NOT IN_HB_DIST)
 212 #  foreach (ragel_output IN ITEMS ${HB_BASE_RAGEL_GENERATED_sources} ${HB_OT_RAGEL_GENERATED_sources})
 213 #    string(REGEX MATCH "([^/]+)\\.hh" temp ${ragel_output})
 214 #    set (target_name ${CMAKE_MATCH_1})
 215 #    add_custom_command(OUTPUT ${ragel_output}
 216 #      COMMAND ${RAGEL} -G2 -o ${ragel_output} ${PROJECT_SOURCE_DIR}/src/${target_name}.rl -I ${PROJECT_SOURCE_DIR} ${ARGN}
 217 #      DEPENDS ${PROJECT_SOURCE_DIR}/src/${target_name}.rl
 218 #    )
 219 #    add_custom_target(harfbuzz_${target_name} DEPENDS ${PROJECT_BINARY_DIR}/src/${target_name})
 220 #  endforeach ()
 221
 222 #  mark_as_advanced(RAGEL)
 223 # endif ()
 224
 225
 226 ## Generate hb-version.h
 227 # if (NOT IN_HB_DIST)
 228 #  set (HB_VERSION_H_IN "${PROJECT_SOURCE_DIR}/src/hb-version.h.in")
 229 #  set (HB_VERSION_H "${PROJECT_BINARY_DIR}/src/hb-version.h")
 230 #  set_source_files_properties("${HB_VERSION_H}" PROPERTIES GENERATED true)
 231 #  configure_file("${HB_VERSION_H_IN}" "${HB_VERSION_H}.tmp" @ONLY)
 232 #  execute_process(COMMAND "${CMAKE_COMMAND}" -E copy_if_different
 233 #    "${HB_VERSION_H}.tmp"
 234 #    "${HB_VERSION_H}"
 235 #  )
 236 #  file(REMOVE "${HB_VERSION_H}.tmp")
 237 # endif ()
 238
 239
 240 ## Define sources and headers of the project
 241 set (project_sources
 242   ${HB_BASE_sources}
 243   ${HB_BASE_RAGEL_GENERATED_sources}
 244
 245   ${HB_FALLBACK_sources}
 246   ${HB_OT_sources}
 247   ${HB_OT_RAGEL_GENERATED_sources}
 248 )
 249
 250 set (subset_project_sources
 251   ${HB_SUBSET_sources}
 252 )
 253
 254 set (project_extra_sources)
 255
 256 set (project_headers
 257   #${HB_VERSION_H}
 258
 259   ${HB_BASE_headers}
 260   ${HB_OT_headers}
 261 )
 262
 263 set (subset_project_headers
 264   ${HB_SUBSET_headers}
 265 )
 266
 267
 268 ## Find and include needed header folders and libraries
 269 if (HB_HAVE_FREETYPE)
 270   include (FindFreetype)
 271   if (NOT FREETYPE_FOUND)
 272     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 273   endif ()
 274
 275   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 276   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 277   add_definitions(-DHAVE_FREETYPE=1)
 278
 279   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-ft.cc)
 280   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 281
 282   # So check_funcs can find its headers
 283   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 284   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 285
 286   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 287 endif ()
 288
 289 if (HB_HAVE_GRAPHITE2)
 290   add_definitions(-DHAVE_GRAPHITE2)
 291
 292   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 293   find_library(GRAPHITE2_LIBRARY graphite2)
 294
 295   include_directories(${GRAPHITE2_INCLUDE_DIR})
 296
 297   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-graphite2.cc)
 298   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 299
 300   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 301
 302   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 303 endif ()
 304
 305 if (HB_BUILTIN_UCDN)
 306   include_directories(src/hb-ucdn)
 307   add_definitions(-DHAVE_UCDN)
 308
 309   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-ucdn.cc)
 310   list(APPEND project_extra_sources ${LIBHB_UCDN_sources})
 311 endif ()
 312
 313 if (HB_HAVE_GLIB)
 314   add_definitions(-DHAVE_GLIB)
 315
 316   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 317   find_package(PkgConfig)
 318   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 319
 320   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 321   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 322   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 323
 324   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 325
 326   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-glib.cc)
 327   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 328
 329   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 330
 331   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 332 endif ()
 333
 334 if (HB_HAVE_ICU)
 335   add_definitions(-DHAVE_ICU)
 336
 337   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
 338   find_package(PkgConfig)
 339   pkg_check_modules(PC_ICU QUIET icu-uc)
 340
 341   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 342   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 343
 344   include_directories(${ICU_INCLUDE_DIR})
 345
 346   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-icu.cc)
 347   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 348
 349   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 350
 351   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 352 endif ()
 353
 354 if (APPLE AND HB_HAVE_CORETEXT)
 355   # Apple Advanced Typography
 356   add_definitions(-DHAVE_CORETEXT)
 357
 358   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-coretext.cc)
 359   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 360
 361   find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 362   if (APPLICATION_SERVICES_FRAMEWORK)
 363     list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 364   endif (APPLICATION_SERVICES_FRAMEWORK)
 365
 366   mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 367 endif ()
 368
 369 if (WIN32 AND HB_HAVE_UNISCRIBE)
 370   add_definitions(-DHAVE_UNISCRIBE)
 371
 372   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.cc)
 373   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 374
 375   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 376 endif ()
 377
 378 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 379   add_definitions(-DHAVE_DIRECTWRITE)
 380
 381   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-directwrite.cc)
 382   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 383
 384   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 385 endif ()
 386
 387 if (HB_HAVE_GOBJECT)
 388   include (FindPythonInterp)
 389   include (FindPerl)
 390
 391   # Use the hints from glib-2.0.pc to find glib-mkenums
 392   find_package(PkgConfig)
 393   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 394   find_program(GLIB_MKENUMS glib-mkenums
 395     HINTS ${PC_glib_mkenums}
 396   )
 397   set (GLIB_MKENUMS_CMD)
 398
 399   if (WIN32 AND NOT MINGW)
 400     # In Visual Studio builds, shebang lines are not supported
 401     # in the standard cmd.exe shell that we use, so we need to
 402     # first determine whether glib-mkenums is a Python or PERL
 403     # script
 404     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 405       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 406       OUTPUT_QUIET ERROR_QUIET
 407     )
 408     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 409       message("${GLIB_MKENUMS} is a Python script.")
 410       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 411     else ()
 412       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 413         RESULT_VARIABLE GLIB_MKENUMS_PERL
 414         OUTPUT_QUIET ERROR_QUIET
 415       )
 416       if (GLIB_MKENUMS_PERL EQUAL 0)
 417         message("${GLIB_MKENUMS} is a PERL script.")
 418         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 419       endif ()
 420       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 421         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 422       endif ()
 423     endif ()
 424   else ()
 425     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 426   endif ()
 427   if (NOT GLIB_MKENUMS_CMD)
 428     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 429   endif ()
 430
 431   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 432
 433   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 434   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 435
 436   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 437   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 438
 439   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 440   list(APPEND hb_gobject_gen_sources
 441     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 442   )
 443   list(APPEND hb_gobject_structs_headers
 444     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 445   )
 446   list(APPEND hb_gobject_headers
 447     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 448     ${hb_gobject_structs_headers}
 449   )
 450   list(APPEND hb_gobject_gen_headers
 451     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 452   )
 453
 454   add_custom_command(
 455     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 456     COMMAND ${GLIB_MKENUMS_CMD}
 457       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 458       --identifier-prefix hb_
 459       --symbol-prefix hb_gobject
 460       ${hb_gobject_structs_headers}
 461       ${project_headers}
 462       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 463     COMMAND "${CMAKE_COMMAND}"
 464       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 465       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 466       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 467     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 468       ${hb_gobject_header}
 469       ${project_headers}
 470   )
 471
 472   add_custom_command(
 473     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 474     COMMAND ${GLIB_MKENUMS_CMD}
 475       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 476       --identifier-prefix hb_
 477       --symbol-prefix hb_gobject
 478       ${hb_gobject_header}
 479       ${project_headers}
 480       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 481     COMMAND "${CMAKE_COMMAND}"
 482       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 483       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 484       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 485     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 486       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 487       ${hb_gobject_header}
 488       ${project_headers}
 489   )
 490 endif ()
 491
 492
 493 ## Atomic ops availability detection
 494 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
 495 "               void memory_barrier (void) { __sync_synchronize (); }
 496                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 497                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 498                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 499                 int main () { return 0; }
 500 ")
 501 try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
 502   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
 503   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
 504 if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
 505   add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
 506 endif ()
 507
 508 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
 509 "               #include <atomic.h>
 510                 /* This requires Solaris Studio 12.2 or newer: */
 511                 #include <mbarrier.h>
 512                 void memory_barrier (void) { __machine_rw_barrier (); }
 513                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 514                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 515                 int main () { return 0; }
 516 ")
 517 try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
 518   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
 519   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
 520 if (HB_HAVE_SOLARIS_ATOMIC_OPS)
 521   add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
 522 endif ()
 523
 524
 525 ## Define harfbuzz library
 526 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 527 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 528
 529 ## Define harfbuzz-subset library
 530 add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 531 add_dependencies(harfbuzz-subset harfbuzz)
 532 target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 533
 534 if (UNIX OR MINGW)
 535   # Make symbols link locally
 536   link_libraries(-Bsymbolic-functions)
 537
 538   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 539     # Make sure we don't link to libstdc++
 540     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 541     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 542     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 543     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 544     set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 545
 546     # No threadsafe statics as we do it ourselves
 547     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 548   endif ()
 549 endif ()
 550
 551 ## Define harfbuzz-gobject library
 552 if (HB_HAVE_GOBJECT)
 553   add_library(harfbuzz-gobject
 554     ${hb_gobject_sources}
 555     ${hb_gobject_gen_sources}
 556     ${hb_gobject_headers}
 557     ${hb_gobject_gen_headers}
 558   )
 559   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 560   add_dependencies(harfbuzz-gobject harfbuzz)
 561   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 562 endif ()
 563
 564 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 565 if (WIN32)
 566   if (NOT BUILD_SHARED_LIBS)
 567     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 568     set (HB_HAVE_INTROSPECTION OFF)
 569   endif ()
 570 endif ()
 571
 572 if (HB_HAVE_INTROSPECTION)
 573
 574   find_package(PkgConfig)
 575   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 576
 577   find_program(G_IR_SCANNER g-ir-scanner
 578     HINTS ${PC_g_ir_scanner}
 579   )
 580
 581   find_program(G_IR_COMPILER g-ir-compiler
 582     HINTS ${PC_g_ir_compiler}
 583   )
 584
 585   if (WIN32 AND NOT MINGW)
 586     # Note that since we already enable HB_HAVE_GOBJECT
 587     # we would already have PYTHON_EXECUTABLE handy
 588     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 589   else ()
 590     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 591   endif ()
 592
 593   # We need to account for the varying output directories
 594   # when we build using Visual Studio projects
 595   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 596     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 597   else ()
 598     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 599   endif ()
 600
 601   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 602   set (hb_defines_cflags "")
 603   foreach (hb_cflag ${hb_cflags})
 604     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 605   endforeach (hb_cflag)
 606
 607   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 608   set (extra_libs "")
 609   foreach (extra_lib ${THIRD_PARTY_LIBS})
 610     # We don't want the .lib extension here...
 611     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 612     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 613   endforeach ()
 614
 615   set (introspected_sources)
 616   foreach (f
 617     ${project_headers}
 618     ${project_sources}
 619     ${hb_gobject_gen_sources}
 620     ${hb_gobject_gen_headers}
 621     ${hb_gobject_sources}
 622     ${hb_gobject_headers}
 623   )
 624     if (WIN32)
 625       # Nasty issue: We need to make drive letters lower case,
 626       # otherwise g-ir-scanner won't like it and give us a bunch
 627       # of invalid items and unresolved types...
 628       STRING(SUBSTRING "${f}" 0 1 drive)
 629       STRING(SUBSTRING "${f}" 1 -1 path)
 630       if (drive MATCHES "[A-Z]")
 631         STRING(TOLOWER ${drive} drive_lower)
 632         list(APPEND introspected_sources "${drive_lower}${path}")
 633       else ()
 634         list(APPEND introspected_sources "${f}")
 635       endif ()
 636     else ()
 637       list(APPEND introspected_sources "${f}")
 638     endif ()
 639   endforeach ()
 640
 641   # Finally, build the introspection files...
 642   add_custom_command(
 643     TARGET harfbuzz-gobject
 644     POST_BUILD
 645     COMMAND ${G_IR_SCANNER_CMD}
 646       --warn-all --no-libtool --verbose
 647       -n hb
 648       --namespace=HarfBuzz
 649       --nsversion=0.0
 650       --identifier-prefix=hb_
 651       --include GObject-2.0
 652       --pkg-export=harfbuzz
 653       --cflags-begin
 654       -I${PROJECT_SOURCE_DIR}/src
 655       -I${PROJECT_BINARY_DIR}/src
 656       ${hb_includedir_cflags}
 657       ${hb_defines_cflags}
 658       -DHB_H
 659       -DHB_H_IN
 660       -DHB_OT_H
 661       -DHB_OT_H_IN
 662       -DHB_GOBJECT_H
 663       -DHB_GOBJECT_H_IN
 664       -DHB_EXTERN=
 665       --cflags-end
 666       --library=harfbuzz-gobject
 667       --library=harfbuzz
 668       -L${hb_libpath}
 669       ${extra_libs}
 670       ${introspected_sources}
 671       -o ${hb_libpath}/HarfBuzz-0.0.gir
 672     DEPENDS harfbuzz-gobject harfbuzz
 673   )
 674
 675   add_custom_command(
 676     TARGET harfbuzz-gobject
 677     POST_BUILD
 678     COMMAND "${G_IR_COMPILER}"
 679       --verbose --debug
 680       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 681       ${hb_libpath}/HarfBuzz-0.0.gir
 682       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 683     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 684   )
 685 endif ()
 686
 687
 688 ## Additional framework build configs
 689 if (BUILD_FRAMEWORK)
 690   set (CMAKE_MACOSX_RPATH ON)
 691   set_target_properties(harfbuzz PROPERTIES
 692     FRAMEWORK TRUE
 693     PUBLIC_HEADER "${project_headers}"
 694     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 695   )
 696   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 697   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 698   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 699 endif ()
 700
 701
 702 ## Additional harfbuzz build artifacts
 703 if (HB_BUILD_UTILS)
 704   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 705   find_package(PkgConfig)
 706   pkg_check_modules(PC_CAIRO QUIET cairo)
 707
 708   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 709   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 710
 711   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 712   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 713   include_directories(${CAIRO_INCLUDE_DIRS})
 714
 715   add_executable(hb-view ${HB_VIEW_sources})
 716   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 717
 718   add_executable(hb-shape ${HB_SHAPE_sources})
 719   target_link_libraries(hb-shape harfbuzz)
 720
 721   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 722   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 723
 724   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 725   target_link_libraries(hb-ot-shape-closure harfbuzz)
 726
 727   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 728 endif ()
 729
 730
 731 ## Install
 732 include (GNUInstallDirs)
 733
 734 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 735   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 736   if (HB_HAVE_GOBJECT)
 737     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 738   endif ()
 739 endif ()
 740
 741 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 742   install(TARGETS harfbuzz
 743     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 744     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 745     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 746     FRAMEWORK DESTINATION Library/Frameworks
 747   )
 748   if (HB_BUILD_UTILS)
 749     install(TARGETS hb-view
 750       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 751     )
 752     install(TARGETS hb-view
 753       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 754     )
 755
 756     install(TARGETS hb-shape
 757       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 758     )
 759
 760     install(TARGETS hb-ot-shape-closure
 761       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 762     )
 763   endif ()
 764   if (HB_HAVE_GOBJECT)
 765     install(TARGETS harfbuzz-gobject
 766       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 767       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 768       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 769     )
 770     if (HB_HAVE_INTROSPECTION)
 771       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 772         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 773       else ()
 774         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 775       endif ()
 776
 777       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 778         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 779       )
 780
 781       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 782         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 783       )
 784     endif ()
 785   endif ()
 786 endif ()
 787
 788 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 789   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 790     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fcolor-diagnostics")
 791     set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fcolor-diagnostics")
 792   endif ()
 793   if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 794     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fdiagnostics-color")
 795     set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fdiagnostics-color")
 796   endif ()
 797 endif ()
 798
 799
 800 ## src/ executables
 801 foreach (prog main test test-would-substitute test-size-params test-buffer-serialize hb-ot-tag test-unicode-ranges)
 802   set (prog_name ${prog})
 803   if (${prog_name} STREQUAL "test")
 804     # test can not be used as a valid executable name on cmake, lets special case it
 805     set (prog_name test-test)
 806   endif ()
 807   add_executable(${prog_name} ${PROJECT_SOURCE_DIR}/src/${prog}.cc)
 808   target_link_libraries(${prog_name} harfbuzz ${THIRD_PARTY_LIBS})
 809 endforeach ()
 810 set_target_properties(hb-ot-tag PROPERTIES COMPILE_FLAGS "-DMAIN")
 811
 812 ## Tests
 813 if (UNIX OR MINGW)
 814   if (BUILD_SHARED_LIBS)
 815     # generate harfbuzz.def after build completion
 816     string(REPLACE ";" " " space_separated_headers "${project_headers}")
 817     add_custom_command(TARGET harfbuzz POST_BUILD
 818       COMMAND ${CMAKE_COMMAND} -E env "headers=${space_separated_headers}" python ${PROJECT_SOURCE_DIR}/src/gen-def.py ${PROJECT_BINARY_DIR}/harfbuzz.def
 819       WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src)
 820
 821     add_test(NAME check-static-inits.sh
 822       COMMAND ${PROJECT_SOURCE_DIR}/src/check-static-inits.sh
 823       WORKING_DIRECTORY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/harfbuzz.dir/src # ugly hack
 824     )
 825     add_test(NAME check-libstdc++.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-libstdc++.sh)
 826     add_test(NAME check-symbols.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-symbols.sh)
 827
 828     set_tests_properties(
 829       check-static-inits.sh check-libstdc++.sh check-symbols.sh
 830       PROPERTIES
 831         ENVIRONMENT "libs=.;srcdir=${PROJECT_SOURCE_DIR}/src"
 832         SKIP_RETURN_CODE 77)
 833   endif ()
 834
 835   add_test(NAME check-c-linkage-decls.sh COMMAND ./check-c-linkage-decls.sh)
 836   add_test(NAME check-header-guards.sh COMMAND ./check-header-guards.sh)
 837   add_test(NAME check-externs.sh COMMAND ./check-externs.sh)
 838   add_test(NAME check-includes.sh COMMAND ./check-includes.sh)
 839   set_tests_properties(
 840     check-c-linkage-decls.sh check-header-guards.sh check-externs.sh check-includes.sh
 841     PROPERTIES
 842       WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src
 843       SKIP_RETURN_CODE 77)
 844 endif ()
 845
 846 # Needs to come last so that variables defined above are passed to
 847 # subdirectories.
 848 add_subdirectory(test)