CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 project(harfbuzz)
   3
   4 enable_testing()
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_BUILTIN_UCDN "Use HarfBuzz provided UCDN" ON)
  39 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  40 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  41 if (APPLE)
  42   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  43   set (CMAKE_MACOSX_RPATH ON)
  44 endif ()
  45 if (WIN32)
  46   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  47   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  48 endif ()
  49 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  50 if (HB_BUILD_UTILS)
  51   set (HB_HAVE_GLIB ON)
  52   set (HB_HAVE_FREETYPE ON)
  53 endif ()
  54
  55 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  56 if (HB_HAVE_GOBJECT)
  57   set (HB_HAVE_GLIB ON)
  58 endif ()
  59
  60 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  61 if (HB_HAVE_INTROSPECTION)
  62   set (HB_HAVE_GOBJECT ON)
  63   set (HB_HAVE_GLIB ON)
  64 endif ()
  65
  66 option(HB_CHECK OFF "Do a configuration suitable for testing (shared library and enable all options)")
  67 if (HB_CHECK)
  68   set (BUILD_SHARED_LIBS ON)
  69   set (HB_BUILD_UTILS ON)
  70   set (HB_BUILTIN_UCDN ON)
  71   set (HB_HAVE_ICU)
  72   set (HB_HAVE_GLIB ON)
  73   #set (HB_HAVE_GOBJECT ON)
  74   #set (HB_HAVE_INTROSPECTION ON)
  75   set (HB_HAVE_FREETYPE ON)
  76   set (HB_HAVE_GRAPHITE2 ON)
  77   if (WIN32)
  78     set (HB_HAVE_UNISCRIBE ON)
  79     set (HB_HAVE_DIRECTWRITE ON)
  80   elseif (APPLE)
  81     set (HB_HAVE_CORETEXT ON)
  82   endif ()
  83 endif ()
  84
  85 include_directories(AFTER
  86   ${PROJECT_SOURCE_DIR}/src
  87   ${PROJECT_BINARY_DIR}/src
  88 )
  89
  90 add_definitions(-DHAVE_OT)
  91 add_definitions(-DHAVE_FALLBACK)
  92
  93 # We need PYTHON_EXECUTABLE to be set for running the tests...
  94 include (FindPythonInterp)
  95
  96 ## Functions and headers
  97 include (CheckFunctionExists)
  98 include (CheckIncludeFile)
  99 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
 100   foreach (func_name ${ARGN})
 101     string(TOUPPER ${func_name} definiton_to_add)
 102     check_function_exists(${func_name} HAVE_${definiton_to_add})
 103     if (${HAVE_${definiton_to_add}})
 104       add_definitions(-DHAVE_${definiton_to_add})
 105     endif ()
 106   endforeach ()
 107 endmacro ()
 108 if (UNIX)
 109   list(APPEND CMAKE_REQUIRED_LIBRARIES m)
 110 endif ()
 111 check_funcs(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l round)
 112 check_include_file(unistd.h HAVE_UNISTD_H)
 113 if (${HAVE_UNISTD_H})
 114   add_definitions(-DHAVE_UNISTD_H)
 115 endif ()
 116 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
 117 if (${HAVE_SYS_MMAN_H})
 118   add_definitions(-DHAVE_SYS_MMAN_H)
 119 endif ()
 120 check_include_file(xlocale.h HAVE_XLOCALE_H)
 121 if (${HAVE_XLOCALE_H})
 122   add_definitions(-DHAVE_XLOCALE_H)
 123 endif ()
 124 check_include_file(stdbool.h HAVE_STDBOOL_H)
 125 if (${HAVE_STDBOOL_H})
 126   add_definitions(-DHAVE_STDBOOL_H)
 127 endif ()
 128
 129
 130 if (MSVC)
 131   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 132 endif ()
 133
 134
 135 ## Detect if we are running inside a distribution or regular repository folder
 136 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 137 #   # perhaps we are on dist directory
 138 #   set (IN_HB_DIST TRUE)
 139 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 140 # endif ()
 141
 142
 143 ## Extract variables from Makefile files
 144 function (extract_make_variable variable makefile_source)
 145   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp ${makefile_source})
 146   string(REGEX MATCHALL "[^ \n\t\\]+" listVar ${CMAKE_MATCH_1})
 147   set (${variable} ${listVar} PARENT_SCOPE)
 148 endfunction ()
 149
 150 # http://stackoverflow.com/a/27630120
 151 function (add_prefix_to_list var prefix)
 152   set (listVar "")
 153   foreach (f ${${var}})
 154     list(APPEND listVar "${prefix}${f}")
 155   endforeach ()
 156   set (${var} "${listVar}" PARENT_SCOPE)
 157 endfunction ()
 158
 159 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 160 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 161 file(READ ${PROJECT_SOURCE_DIR}/src/hb-ucdn/Makefile.sources UCDNSOURCES)
 162
 163 extract_make_variable(HB_BASE_sources ${SRCSOURCES})
 164 add_prefix_to_list(HB_BASE_sources "${PROJECT_SOURCE_DIR}/src/")
 165 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 166 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 167 extract_make_variable(HB_FALLBACK_sources ${SRCSOURCES})
 168 add_prefix_to_list(HB_FALLBACK_sources "${PROJECT_SOURCE_DIR}/src/")
 169 extract_make_variable(HB_OT_sources ${SRCSOURCES})
 170 add_prefix_to_list(HB_OT_sources "${PROJECT_SOURCE_DIR}/src/")
 171 extract_make_variable(HB_OT_headers ${SRCSOURCES})
 172 add_prefix_to_list(HB_OT_headers "${PROJECT_SOURCE_DIR}/src/")
 173
 174 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 175 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 176
 177 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 178 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 179
 180 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 181 extract_make_variable(HB_OT_RAGEL_GENERATED_sources ${SRCSOURCES})
 182 #if (IN_HB_DIST)
 183   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 184   add_prefix_to_list(HB_OT_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 185 #else ()
 186 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 187 #  add_prefix_to_list(HB_OT_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 188 #endif ()
 189
 190 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 191 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 192 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 193 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 194 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 195 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 196 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 197 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 198
 199 extract_make_variable(LIBHB_UCDN_sources ${UCDNSOURCES})
 200 add_prefix_to_list(LIBHB_UCDN_sources "${PROJECT_SOURCE_DIR}/src/hb-ucdn/")
 201
 202
 203 file(READ configure.ac CONFIGUREAC)
 204 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 205 set (HB_VERSION ${CMAKE_MATCH_1})
 206 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 207 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 208 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 209
 210
 211 ## Define ragel tasks
 212 # if (NOT IN_HB_DIST)
 213 #  foreach (ragel_output IN ITEMS ${HB_BASE_RAGEL_GENERATED_sources} ${HB_OT_RAGEL_GENERATED_sources})
 214 #    string(REGEX MATCH "([^/]+)\\.hh" temp ${ragel_output})
 215 #    set (target_name ${CMAKE_MATCH_1})
 216 #    add_custom_command(OUTPUT ${ragel_output}
 217 #      COMMAND ${RAGEL} -G2 -o ${ragel_output} ${PROJECT_SOURCE_DIR}/src/${target_name}.rl -I ${PROJECT_SOURCE_DIR} ${ARGN}
 218 #      DEPENDS ${PROJECT_SOURCE_DIR}/src/${target_name}.rl
 219 #    )
 220 #    add_custom_target(harfbuzz_${target_name} DEPENDS ${PROJECT_BINARY_DIR}/src/${target_name})
 221 #  endforeach ()
 222
 223 #  mark_as_advanced(RAGEL)
 224 # endif ()
 225
 226
 227 ## Generate hb-version.h
 228 # if (NOT IN_HB_DIST)
 229 #  set (HB_VERSION_H_IN "${PROJECT_SOURCE_DIR}/src/hb-version.h.in")
 230 #  set (HB_VERSION_H "${PROJECT_BINARY_DIR}/src/hb-version.h")
 231 #  set_source_files_properties("${HB_VERSION_H}" PROPERTIES GENERATED true)
 232 #  configure_file("${HB_VERSION_H_IN}" "${HB_VERSION_H}.tmp" @ONLY)
 233 #  execute_process(COMMAND "${CMAKE_COMMAND}" -E copy_if_different
 234 #    "${HB_VERSION_H}.tmp"
 235 #    "${HB_VERSION_H}"
 236 #  )
 237 #  file(REMOVE "${HB_VERSION_H}.tmp")
 238 # endif ()
 239
 240
 241 ## Define sources and headers of the project
 242 set (project_sources
 243   ${HB_BASE_sources}
 244   ${HB_BASE_RAGEL_GENERATED_sources}
 245
 246   ${HB_FALLBACK_sources}
 247   ${HB_OT_sources}
 248   ${HB_OT_RAGEL_GENERATED_sources}
 249 )
 250
 251 set (subset_project_sources
 252   ${HB_SUBSET_sources}
 253 )
 254
 255 set (project_extra_sources)
 256
 257 set (project_headers
 258   #${HB_VERSION_H}
 259
 260   ${HB_BASE_headers}
 261   ${HB_OT_headers}
 262 )
 263
 264 set (subset_project_headers
 265   ${HB_SUBSET_headers}
 266 )
 267
 268
 269 ## Find and include needed header folders and libraries
 270 if (HB_HAVE_FREETYPE)
 271   include (FindFreetype)
 272   if (NOT FREETYPE_FOUND)
 273     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 274   endif ()
 275
 276   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 277   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 278   add_definitions(-DHAVE_FREETYPE=1)
 279
 280   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-ft.cc)
 281   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 282
 283   # So check_funcs can find its headers
 284   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 285   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 286
 287   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 288 endif ()
 289
 290 if (HB_HAVE_GRAPHITE2)
 291   add_definitions(-DHAVE_GRAPHITE2)
 292
 293   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 294   find_library(GRAPHITE2_LIBRARY graphite2)
 295
 296   include_directories(${GRAPHITE2_INCLUDE_DIR})
 297
 298   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-graphite2.cc)
 299   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 300
 301   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 302
 303   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 304 endif ()
 305
 306 if (HB_BUILTIN_UCDN)
 307   include_directories(src/hb-ucdn)
 308   add_definitions(-DHAVE_UCDN)
 309
 310   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-ucdn.cc)
 311   list(APPEND project_extra_sources ${LIBHB_UCDN_sources})
 312 endif ()
 313
 314 if (HB_HAVE_GLIB)
 315   add_definitions(-DHAVE_GLIB)
 316
 317   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 318   find_package(PkgConfig)
 319   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 320
 321   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 322   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 323   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 324
 325   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 326
 327   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-glib.cc)
 328   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 329
 330   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 331
 332   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 333 endif ()
 334
 335 if (HB_HAVE_ICU)
 336   add_definitions(-DHAVE_ICU)
 337
 338   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
 339   find_package(PkgConfig)
 340   pkg_check_modules(PC_ICU QUIET icu-uc)
 341
 342   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 343   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 344
 345   include_directories(${ICU_INCLUDE_DIR})
 346
 347   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-icu.cc)
 348   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 349
 350   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 351
 352   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 353 endif ()
 354
 355 if (APPLE AND HB_HAVE_CORETEXT)
 356   # Apple Advanced Typography
 357   add_definitions(-DHAVE_CORETEXT)
 358
 359   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-coretext.cc)
 360   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 361
 362   find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 363   if (APPLICATION_SERVICES_FRAMEWORK)
 364     list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 365   endif (APPLICATION_SERVICES_FRAMEWORK)
 366
 367   mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 368 endif ()
 369
 370 if (WIN32 AND HB_HAVE_UNISCRIBE)
 371   add_definitions(-DHAVE_UNISCRIBE)
 372
 373   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.cc)
 374   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 375
 376   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 377 endif ()
 378
 379 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 380   add_definitions(-DHAVE_DIRECTWRITE)
 381
 382   list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-directwrite.cc)
 383   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 384
 385   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 386 endif ()
 387
 388 if (HB_HAVE_GOBJECT)
 389   include (FindPerl)
 390
 391   # Use the hints from glib-2.0.pc to find glib-mkenums
 392   find_package(PkgConfig)
 393   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 394   find_program(GLIB_MKENUMS glib-mkenums
 395     HINTS ${PC_glib_mkenums}
 396   )
 397   set (GLIB_MKENUMS_CMD)
 398
 399   if (WIN32 AND NOT MINGW)
 400     # In Visual Studio builds, shebang lines are not supported
 401     # in the standard cmd.exe shell that we use, so we need to
 402     # first determine whether glib-mkenums is a Python or PERL
 403     # script
 404     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 405       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 406       OUTPUT_QUIET ERROR_QUIET
 407     )
 408     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 409       message("${GLIB_MKENUMS} is a Python script.")
 410       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 411     else ()
 412       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 413         RESULT_VARIABLE GLIB_MKENUMS_PERL
 414         OUTPUT_QUIET ERROR_QUIET
 415       )
 416       if (GLIB_MKENUMS_PERL EQUAL 0)
 417         message("${GLIB_MKENUMS} is a PERL script.")
 418         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 419       endif ()
 420       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 421         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 422       endif ()
 423     endif ()
 424   else ()
 425     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 426   endif ()
 427   if (NOT GLIB_MKENUMS_CMD)
 428     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 429   endif ()
 430
 431   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 432
 433   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 434   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 435
 436   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 437   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 438
 439   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 440   list(APPEND hb_gobject_gen_sources
 441     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 442   )
 443   list(APPEND hb_gobject_structs_headers
 444     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 445   )
 446   list(APPEND hb_gobject_headers
 447     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 448     ${hb_gobject_structs_headers}
 449   )
 450   list(APPEND hb_gobject_gen_headers
 451     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 452   )
 453
 454   add_custom_command(
 455     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 456     COMMAND ${GLIB_MKENUMS_CMD}
 457       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 458       --identifier-prefix hb_
 459       --symbol-prefix hb_gobject
 460       ${hb_gobject_structs_headers}
 461       ${project_headers}
 462       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 463     COMMAND "${CMAKE_COMMAND}"
 464       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 465       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 466       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 467     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 468       ${hb_gobject_header}
 469       ${project_headers}
 470   )
 471
 472   add_custom_command(
 473     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 474     COMMAND ${GLIB_MKENUMS_CMD}
 475       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 476       --identifier-prefix hb_
 477       --symbol-prefix hb_gobject
 478       ${hb_gobject_header}
 479       ${project_headers}
 480       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 481     COMMAND "${CMAKE_COMMAND}"
 482       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 483       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 484       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 485     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 486       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 487       ${hb_gobject_header}
 488       ${project_headers}
 489   )
 490 endif ()
 491
 492
 493 ## Atomic ops availability detection
 494 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
 495 "               void memory_barrier (void) { __sync_synchronize (); }
 496                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 497                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 498                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 499                 int main () { return 0; }
 500 ")
 501 try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
 502   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
 503   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
 504 if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
 505   add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
 506 endif ()
 507
 508 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
 509 "               #include <atomic.h>
 510                 /* This requires Solaris Studio 12.2 or newer: */
 511                 #include <mbarrier.h>
 512                 void memory_barrier (void) { __machine_rw_barrier (); }
 513                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 514                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 515                 int main () { return 0; }
 516 ")
 517 try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
 518   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
 519   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
 520 if (HB_HAVE_SOLARIS_ATOMIC_OPS)
 521   add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
 522 endif ()
 523
 524
 525 ## Define harfbuzz library
 526 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 527 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 528
 529 ## Define harfbuzz-subset library
 530 add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 531 add_dependencies(harfbuzz-subset harfbuzz)
 532 target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 533
 534 if (BUILD_SHARED_LIBS)
 535   set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 536 endif ()
 537
 538 if (UNIX OR MINGW)
 539   # Make symbols link locally
 540   include (CheckCXXCompilerFlag)
 541   check_cxx_compiler_flag(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 542   if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 543     link_libraries(-Bsymbolic-functions)
 544   endif ()
 545
 546   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 547     # Make sure we don't link to libstdc++
 548     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 549     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 550     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 551     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 552     set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 553
 554     # No threadsafe statics as we do it ourselves
 555     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 556   endif ()
 557 endif ()
 558
 559 ## Define harfbuzz-gobject library
 560 if (HB_HAVE_GOBJECT)
 561   add_library(harfbuzz-gobject
 562     ${hb_gobject_sources}
 563     ${hb_gobject_gen_sources}
 564     ${hb_gobject_headers}
 565     ${hb_gobject_gen_headers}
 566   )
 567   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 568   add_dependencies(harfbuzz-gobject harfbuzz)
 569   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 570
 571   if (BUILD_SHARED_LIBS)
 572     set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 573   endif ()
 574 endif ()
 575
 576 if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
 577   add_definitions("-DHB_EXTERN=__declspec(dllexport) extern")
 578 endif ()
 579
 580 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 581 if (WIN32)
 582   if (NOT BUILD_SHARED_LIBS)
 583     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 584     set (HB_HAVE_INTROSPECTION OFF)
 585   endif ()
 586 endif ()
 587
 588 if (HB_HAVE_INTROSPECTION)
 589
 590   find_package(PkgConfig)
 591   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 592
 593   find_program(G_IR_SCANNER g-ir-scanner
 594     HINTS ${PC_g_ir_scanner}
 595   )
 596
 597   find_program(G_IR_COMPILER g-ir-compiler
 598     HINTS ${PC_g_ir_compiler}
 599   )
 600
 601   if (WIN32 AND NOT MINGW)
 602     # Note that since we already enable HB_HAVE_GOBJECT
 603     # we would already have PYTHON_EXECUTABLE handy
 604     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 605   else ()
 606     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 607   endif ()
 608
 609   # We need to account for the varying output directories
 610   # when we build using Visual Studio projects
 611   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 612     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 613   else ()
 614     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 615   endif ()
 616
 617   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 618   set (hb_defines_cflags "")
 619   foreach (hb_cflag ${hb_cflags})
 620     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 621   endforeach (hb_cflag)
 622
 623   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 624   set (extra_libs "")
 625   foreach (extra_lib ${THIRD_PARTY_LIBS})
 626     # We don't want the .lib extension here...
 627     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 628     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 629   endforeach ()
 630
 631   set (introspected_sources)
 632   foreach (f
 633     ${project_headers}
 634     ${project_sources}
 635     ${hb_gobject_gen_sources}
 636     ${hb_gobject_gen_headers}
 637     ${hb_gobject_sources}
 638     ${hb_gobject_headers}
 639   )
 640     if (WIN32)
 641       # Nasty issue: We need to make drive letters lower case,
 642       # otherwise g-ir-scanner won't like it and give us a bunch
 643       # of invalid items and unresolved types...
 644       STRING(SUBSTRING "${f}" 0 1 drive)
 645       STRING(SUBSTRING "${f}" 1 -1 path)
 646       if (drive MATCHES "[A-Z]")
 647         STRING(TOLOWER ${drive} drive_lower)
 648         list(APPEND introspected_sources "${drive_lower}${path}")
 649       else ()
 650         list(APPEND introspected_sources "${f}")
 651       endif ()
 652     else ()
 653       list(APPEND introspected_sources "${f}")
 654     endif ()
 655   endforeach ()
 656
 657   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
 658   foreach (s ${introspected_sources})
 659     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
 660   endforeach ()
 661
 662   # Finally, build the introspection files...
 663   add_custom_command(
 664     TARGET harfbuzz-gobject
 665     POST_BUILD
 666     COMMAND ${G_IR_SCANNER_CMD}
 667       --warn-all --no-libtool --verbose
 668       -n hb
 669       --namespace=HarfBuzz
 670       --nsversion=0.0
 671       --identifier-prefix=hb_
 672       --include GObject-2.0
 673       --pkg-export=harfbuzz
 674       --cflags-begin
 675       -I${PROJECT_SOURCE_DIR}/src
 676       -I${PROJECT_BINARY_DIR}/src
 677       ${hb_includedir_cflags}
 678       ${hb_defines_cflags}
 679       -DHB_H
 680       -DHB_H_IN
 681       -DHB_OT_H
 682       -DHB_OT_H_IN
 683       -DHB_GOBJECT_H
 684       -DHB_GOBJECT_H_IN
 685       -DHB_EXTERN=
 686       --cflags-end
 687       --library=harfbuzz-gobject
 688       --library=harfbuzz
 689       -L${hb_libpath}
 690       ${extra_libs}
 691       --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 692       -o ${hb_libpath}/HarfBuzz-0.0.gir
 693     DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 694   )
 695
 696   add_custom_command(
 697     TARGET harfbuzz-gobject
 698     POST_BUILD
 699     COMMAND "${G_IR_COMPILER}"
 700       --verbose --debug
 701       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 702       ${hb_libpath}/HarfBuzz-0.0.gir
 703       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 704     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 705   )
 706 endif ()
 707
 708
 709 ## Additional framework build configs
 710 if (BUILD_FRAMEWORK)
 711   set (CMAKE_MACOSX_RPATH ON)
 712   set_target_properties(harfbuzz PROPERTIES
 713     FRAMEWORK TRUE
 714     PUBLIC_HEADER "${project_headers}"
 715     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 716   )
 717   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 718   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 719   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 720 endif ()
 721
 722
 723 ## Additional harfbuzz build artifacts
 724 if (HB_BUILD_UTILS)
 725   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 726   find_package(PkgConfig)
 727   pkg_check_modules(PC_CAIRO QUIET cairo)
 728
 729   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 730   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 731
 732   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 733   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 734   include_directories(${CAIRO_INCLUDE_DIRS})
 735
 736   add_executable(hb-view ${HB_VIEW_sources})
 737   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 738
 739   add_executable(hb-shape ${HB_SHAPE_sources})
 740   target_link_libraries(hb-shape harfbuzz)
 741
 742   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 743   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 744
 745   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 746   target_link_libraries(hb-ot-shape-closure harfbuzz)
 747
 748   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 749 endif ()
 750
 751
 752 ## Install
 753 include (GNUInstallDirs)
 754
 755 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 756   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 757   if (HB_HAVE_GOBJECT)
 758     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 759   endif ()
 760 endif ()
 761
 762 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 763   install(TARGETS harfbuzz
 764     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 765     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 766     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 767     FRAMEWORK DESTINATION Library/Frameworks
 768   )
 769   if (HB_BUILD_UTILS)
 770     install(TARGETS hb-view
 771       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 772     )
 773     install(TARGETS hb-subset
 774       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 775     )
 776
 777     install(TARGETS hb-shape
 778       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 779     )
 780
 781     install(TARGETS hb-ot-shape-closure
 782       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 783     )
 784   endif ()
 785   if (HB_HAVE_GOBJECT)
 786     install(TARGETS harfbuzz-gobject
 787       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 788       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 789       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 790     )
 791     if (HB_HAVE_INTROSPECTION)
 792       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 793         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 794       else ()
 795         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 796       endif ()
 797
 798       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 799         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 800       )
 801
 802       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 803         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 804       )
 805     endif ()
 806   endif ()
 807 endif ()
 808
 809 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 810   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 811     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fcolor-diagnostics")
 812     set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fcolor-diagnostics")
 813   endif ()
 814   if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 815     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fdiagnostics-color")
 816     set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fdiagnostics-color")
 817   endif ()
 818 endif ()
 819
 820
 821 ## src/ executables
 822 foreach (prog main test test-would-substitute test-size-params test-buffer-serialize hb-ot-tag test-unicode-ranges)
 823   set (prog_name ${prog})
 824   if (${prog_name} STREQUAL "test")
 825     # test can not be used as a valid executable name on cmake, lets special case it
 826     set (prog_name test-test)
 827   endif ()
 828   add_executable(${prog_name} ${PROJECT_SOURCE_DIR}/src/${prog}.cc)
 829   target_link_libraries(${prog_name} harfbuzz ${THIRD_PARTY_LIBS})
 830 endforeach ()
 831 set_target_properties(hb-ot-tag PROPERTIES COMPILE_FLAGS "-DMAIN")
 832
 833 ## Tests
 834 if (UNIX OR MINGW)
 835   if (BUILD_SHARED_LIBS)
 836     # generate harfbuzz.def after build completion
 837     string(REPLACE ";" " " space_separated_headers "${project_headers}")
 838     add_custom_command(TARGET harfbuzz POST_BUILD
 839       COMMAND ${CMAKE_COMMAND} -E env "headers=${space_separated_headers}" python ${PROJECT_SOURCE_DIR}/src/gen-def.py ${PROJECT_BINARY_DIR}/harfbuzz.def
 840       WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src)
 841
 842     add_test(NAME check-static-inits.sh
 843       COMMAND ${PROJECT_SOURCE_DIR}/src/check-static-inits.sh
 844       WORKING_DIRECTORY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/harfbuzz.dir/src # ugly hack
 845     )
 846     add_test(NAME check-libstdc++.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-libstdc++.sh)
 847     add_test(NAME check-symbols.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-symbols.sh)
 848
 849     set_tests_properties(
 850       check-static-inits.sh check-libstdc++.sh check-symbols.sh
 851       PROPERTIES
 852         ENVIRONMENT "libs=.;srcdir=${PROJECT_SOURCE_DIR}/src"
 853         SKIP_RETURN_CODE 77)
 854   endif ()
 855
 856   add_test(NAME check-c-linkage-decls.sh COMMAND ./check-c-linkage-decls.sh)
 857   add_test(NAME check-header-guards.sh COMMAND ./check-header-guards.sh)
 858   add_test(NAME check-externs.sh COMMAND ./check-externs.sh)
 859   add_test(NAME check-includes.sh COMMAND ./check-includes.sh)
 860   set_tests_properties(
 861     check-c-linkage-decls.sh check-header-guards.sh check-externs.sh check-includes.sh
 862     PROPERTIES
 863       WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src
 864       SKIP_RETURN_CODE 77)
 865 endif ()
 866
 867 # Needs to come last so that variables defined above are passed to
 868 # subdirectories.
 869 add_subdirectory(test)