CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 project(harfbuzz)
   3
   4 message("HarfBuzz has a Meson port also and tries to migrate all the other build systems to it, please consider using it.")
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  39 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  40 if (APPLE)
  41   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  42   set (CMAKE_MACOSX_RPATH ON)
  43 endif ()
  44 if (WIN32)
  45   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  46   option(HB_HAVE_GDI "Enable GDI integration helpers on Windows" OFF)
  47   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  48 endif ()
  49 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  50 if (HB_BUILD_UTILS)
  51   set (HB_HAVE_GLIB ON)
  52   set (HB_HAVE_FREETYPE ON)
  53 endif ()
  54
  55 option(HB_BUILD_SUBSET "Build harfbuzz-subset" ON)
  56
  57 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  58 if (HB_HAVE_GOBJECT)
  59   set (HB_HAVE_GLIB ON)
  60 endif ()
  61
  62 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  63 if (HB_HAVE_INTROSPECTION)
  64   set (HB_HAVE_GOBJECT ON)
  65   set (HB_HAVE_GLIB ON)
  66 endif ()
  67
  68 include_directories(AFTER
  69   ${PROJECT_SOURCE_DIR}/src
  70   ${PROJECT_BINARY_DIR}/src
  71 )
  72
  73 # We need PYTHON_EXECUTABLE to be set for running the tests...
  74 include (FindPythonInterp)
  75
  76 ## Functions and headers
  77 include (CheckFunctionExists)
  78 include (CheckIncludeFile)
  79 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
  80   foreach (func_name ${ARGN})
  81     string(TOUPPER ${func_name} definition_to_add)
  82     check_function_exists(${func_name} HAVE_${definition_to_add})
  83     if (${HAVE_${definition_to_add}})
  84       add_definitions(-DHAVE_${definition_to_add})
  85     endif ()
  86   endforeach ()
  87 endmacro ()
  88 if (UNIX)
  89   list(APPEND CMAKE_REQUIRED_LIBRARIES m)
  90 endif ()
  91 check_funcs(atexit mprotect sysconf getpagesize mmap isatty roundf)
  92 check_include_file(unistd.h HAVE_UNISTD_H)
  93 if (${HAVE_UNISTD_H})
  94   add_definitions(-DHAVE_UNISTD_H)
  95 endif ()
  96 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  97 if (${HAVE_SYS_MMAN_H})
  98   add_definitions(-DHAVE_SYS_MMAN_H)
  99 endif ()
 100 check_include_file(stdbool.h HAVE_STDBOOL_H)
 101 if (${HAVE_STDBOOL_H})
 102   add_definitions(-DHAVE_STDBOOL_H)
 103 endif ()
 104
 105
 106 if (MSVC)
 107   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 108 endif ()
 109
 110
 111 ## Detect if we are running inside a distribution or regular repository folder
 112 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 113 #   # perhaps we are on dist directory
 114 #   set (IN_HB_DIST TRUE)
 115 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 116 # endif ()
 117
 118
 119 ## Extract variables from Makefile files
 120 function (extract_make_variable variable makefile_source)
 121   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp "${makefile_source}")
 122   string(REGEX MATCHALL "[^ \n\t\\]+" listVar "${CMAKE_MATCH_1}")
 123   set (${variable} ${listVar} PARENT_SCOPE)
 124 endfunction ()
 125
 126 # https://stackoverflow.com/a/27630120
 127 function (add_prefix_to_list var prefix)
 128   set (listVar "")
 129   foreach (f ${${var}})
 130     list(APPEND listVar "${prefix}${f}")
 131   endforeach ()
 132   set (${var} "${listVar}" PARENT_SCOPE)
 133 endfunction ()
 134
 135 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 136 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 137
 138 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 139 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 140
 141 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 142 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 143
 144 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 145 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 146
 147 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 148 #if (IN_HB_DIST)
 149   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 150 #else ()
 151 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 152 #endif ()
 153
 154 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 155 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 156 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 157 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 158 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 159 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 160 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 161 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 162
 163
 164 file(READ configure.ac CONFIGUREAC)
 165 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 166 set (HB_VERSION ${CMAKE_MATCH_1})
 167 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 168 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 169 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 170
 171 ## Define sources and headers of the project
 172 set (project_sources ${PROJECT_SOURCE_DIR}/src/harfbuzz.cc) # use amalgam source
 173 set (subset_project_sources ${HB_SUBSET_sources})
 174 set (project_extra_sources)
 175 set (project_headers ${HB_BASE_headers})
 176 set (subset_project_headers ${HB_SUBSET_headers})
 177
 178 ## Find and include needed header folders and libraries
 179 if (HB_HAVE_FREETYPE)
 180   include (FindFreetype)
 181   if (NOT FREETYPE_FOUND)
 182     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 183   endif ()
 184
 185   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 186   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 187   add_definitions(-DHAVE_FREETYPE=1)
 188
 189   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 190
 191   # So check_funcs can find its headers
 192   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 193   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 194
 195   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 196 endif ()
 197
 198 if (HB_HAVE_GRAPHITE2)
 199   add_definitions(-DHAVE_GRAPHITE2)
 200
 201   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 202   find_library(GRAPHITE2_LIBRARY graphite2)
 203
 204   include_directories(${GRAPHITE2_INCLUDE_DIR})
 205
 206   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 207
 208   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 209
 210   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 211 endif ()
 212
 213 if (HB_HAVE_GLIB)
 214   add_definitions(-DHAVE_GLIB)
 215
 216   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 217   find_package(PkgConfig)
 218   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 219
 220   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 221   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 222   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 223
 224   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 225
 226   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 227
 228   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 229
 230   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 231 endif ()
 232
 233 if (HB_HAVE_ICU)
 234   add_definitions(-DHAVE_ICU)
 235
 236   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
 237   find_package(PkgConfig)
 238   pkg_check_modules(PC_ICU QUIET icu-uc)
 239
 240   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 241   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 242
 243   include_directories(${ICU_INCLUDE_DIR})
 244
 245   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 246
 247   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 248
 249   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 250 endif ()
 251
 252 if (APPLE AND HB_HAVE_CORETEXT)
 253   # Apple Advanced Typography
 254   add_definitions(-DHAVE_CORETEXT)
 255
 256   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 257
 258   if (HB_IOS)
 259     find_library(COREFOUNDATION CoreFoundation)
 260     if (COREFOUNDATION)
 261       list(APPEND THIRD_PARTY_LIBS ${COREFOUNDATION})
 262     endif ()
 263     mark_as_advanced(COREFOUNDATION)
 264
 265     find_library(CORETEXT CoreText)
 266     if (CORETEXT)
 267       list(APPEND THIRD_PARTY_LIBS ${CORETEXT})
 268     endif ()
 269     mark_as_advanced(CORETEXT)
 270
 271     find_library(COREGRAPHICS CoreGraphics)
 272     if (COREGRAPHICS)
 273       list(APPEND THIRD_PARTY_LIBS ${COREGRAPHICS})
 274     endif ()
 275     mark_as_advanced(COREGRAPHICS)
 276   else ()
 277     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 278     if (APPLICATION_SERVICES_FRAMEWORK)
 279       list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 280     endif ()
 281
 282     mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 283   endif ()
 284 endif ()
 285
 286 if (WIN32 AND HB_HAVE_GDI)
 287   add_definitions(-DHAVE_GDI)
 288   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-gdi.h)
 289   list(APPEND THIRD_PARTY_LIBS gdi32)
 290 endif ()
 291
 292 if (WIN32 AND HB_HAVE_UNISCRIBE)
 293   add_definitions(-DHAVE_UNISCRIBE)
 294   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 295   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 296 endif ()
 297
 298 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 299   add_definitions(-DHAVE_DIRECTWRITE)
 300   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 301   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 302 endif ()
 303
 304 if (HB_HAVE_GOBJECT)
 305   include (FindPerl)
 306
 307   # Use the hints from glib-2.0.pc to find glib-mkenums
 308   find_package(PkgConfig)
 309   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 310   find_program(GLIB_MKENUMS glib-mkenums
 311     HINTS ${PC_glib_mkenums}
 312   )
 313   set (GLIB_MKENUMS_CMD)
 314
 315   if (WIN32 AND NOT MINGW)
 316     # In Visual Studio builds, shebang lines are not supported
 317     # in the standard cmd.exe shell that we use, so we need to
 318     # first determine whether glib-mkenums is a Python or PERL
 319     # script
 320     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 321       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 322       OUTPUT_QUIET ERROR_QUIET
 323     )
 324     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 325       message("${GLIB_MKENUMS} is a Python script.")
 326       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 327     else ()
 328       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 329         RESULT_VARIABLE GLIB_MKENUMS_PERL
 330         OUTPUT_QUIET ERROR_QUIET
 331       )
 332       if (GLIB_MKENUMS_PERL EQUAL 0)
 333         message("${GLIB_MKENUMS} is a PERL script.")
 334         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 335       endif ()
 336       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 337         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 338       endif ()
 339     endif ()
 340   else ()
 341     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 342   endif ()
 343   if (NOT GLIB_MKENUMS_CMD)
 344     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 345   endif ()
 346
 347   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 348
 349   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 350   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 351
 352   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 353   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 354
 355   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 356   list(APPEND hb_gobject_gen_sources
 357     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 358   )
 359   list(APPEND hb_gobject_structs_headers
 360     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 361   )
 362   list(APPEND hb_gobject_headers
 363     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 364     ${hb_gobject_structs_headers}
 365   )
 366   list(APPEND hb_gobject_gen_headers
 367     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 368   )
 369
 370   add_custom_command(
 371     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 372     COMMAND ${GLIB_MKENUMS_CMD}
 373       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 374       --identifier-prefix hb_
 375       --symbol-prefix hb_gobject
 376       ${hb_gobject_structs_headers}
 377       ${project_headers}
 378       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 379     COMMAND "${CMAKE_COMMAND}"
 380       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 381       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 382       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 383     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 384       ${hb_gobject_header}
 385       ${project_headers}
 386   )
 387
 388   add_custom_command(
 389     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 390     COMMAND ${GLIB_MKENUMS_CMD}
 391       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 392       --identifier-prefix hb_
 393       --symbol-prefix hb_gobject
 394       ${hb_gobject_header}
 395       ${project_headers}
 396       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 397     COMMAND "${CMAKE_COMMAND}"
 398       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 399       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 400       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 401     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 402       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 403       ${hb_gobject_header}
 404       ${project_headers}
 405   )
 406 endif ()
 407
 408 ## Atomic ops availability detection
 409 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
 410 "               void memory_barrier (void) { __sync_synchronize (); }
 411                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 412                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 413                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 414                 int main () { return 0; }
 415 ")
 416 try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
 417   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
 418   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
 419 if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
 420   add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
 421 endif ()
 422
 423 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
 424 "               #include <atomic.h>
 425                 /* This requires Solaris Studio 12.2 or newer: */
 426                 #include <mbarrier.h>
 427                 void memory_barrier (void) { __machine_rw_barrier (); }
 428                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 429                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 430                 int main () { return 0; }
 431 ")
 432 try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
 433   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
 434   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
 435 if (HB_HAVE_SOLARIS_ATOMIC_OPS)
 436   add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
 437 endif ()
 438
 439
 440 ## Define harfbuzz library
 441 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 442 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 443
 444
 445 ## Define harfbuzz-icu library
 446 if (HB_HAVE_ICU)
 447   add_library(harfbuzz-icu ${PROJECT_SOURCE_DIR}/src/hb-icu.cc ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 448   add_dependencies(harfbuzz-icu harfbuzz)
 449   target_link_libraries(harfbuzz-icu harfbuzz ${THIRD_PARTY_LIBS})
 450
 451   if (BUILD_SHARED_LIBS)
 452     set_target_properties(harfbuzz harfbuzz-icu PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 453   endif ()
 454 endif ()
 455
 456
 457 ## Define harfbuzz-subset library
 458 if (HB_BUILD_SUBSET)
 459   add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 460   add_dependencies(harfbuzz-subset harfbuzz)
 461   target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 462
 463   if (BUILD_SHARED_LIBS)
 464     set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 465   endif ()
 466 endif ()
 467
 468 if (UNIX OR MINGW)
 469   # Make symbols link locally
 470   include (CheckCXXCompilerFlag)
 471   CHECK_CXX_COMPILER_FLAG(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 472   if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 473     link_libraries(-Bsymbolic-functions)
 474   endif ()
 475
 476   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 477     # Make sure we don't link to libstdc++
 478     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 479     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 480     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 481     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 482     if (HB_BUILD_SUBSET)
 483       set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 484     endif ()
 485
 486     # No threadsafe statics as we do it ourselves
 487     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 488   endif ()
 489
 490   CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 491   if (COMPILER_SUPPORTS_CXX11)
 492     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 493   else()
 494     message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 495   endif()
 496 endif ()
 497
 498
 499 ## Define harfbuzz-gobject library
 500 if (HB_HAVE_GOBJECT)
 501   add_library(harfbuzz-gobject
 502     ${hb_gobject_sources}
 503     ${hb_gobject_gen_sources}
 504     ${hb_gobject_headers}
 505     ${hb_gobject_gen_headers}
 506   )
 507   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 508   add_dependencies(harfbuzz-gobject harfbuzz)
 509   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 510
 511   if (BUILD_SHARED_LIBS)
 512     set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 513   endif ()
 514 endif ()
 515
 516 if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
 517   add_definitions("-DHB_DLL_EXPORT")
 518 endif ()
 519
 520 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 521 if (WIN32)
 522   if (NOT BUILD_SHARED_LIBS)
 523     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 524     set (HB_HAVE_INTROSPECTION OFF)
 525   endif ()
 526 endif ()
 527
 528 if (HB_HAVE_INTROSPECTION)
 529   find_package(PkgConfig)
 530   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 531
 532   find_program(G_IR_SCANNER g-ir-scanner
 533     HINTS ${PC_g_ir_scanner}
 534   )
 535
 536   find_program(G_IR_COMPILER g-ir-compiler
 537     HINTS ${PC_g_ir_compiler}
 538   )
 539
 540   if (WIN32 AND NOT MINGW)
 541     # Note that since we already enable HB_HAVE_GOBJECT
 542     # we would already have PYTHON_EXECUTABLE handy
 543     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 544   else ()
 545     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 546   endif ()
 547
 548   # We need to account for the varying output directories
 549   # when we build using Visual Studio projects
 550   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 551     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 552   else ()
 553     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 554   endif ()
 555
 556   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 557   set (hb_defines_cflags "")
 558   foreach (hb_cflag ${hb_cflags})
 559     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 560   endforeach (hb_cflag)
 561
 562   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 563   set (extra_libs "")
 564   foreach (extra_lib ${THIRD_PARTY_LIBS})
 565     # We don't want the .lib extension here...
 566     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 567     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 568   endforeach ()
 569
 570   set (introspected_sources)
 571   foreach (f
 572     ${project_headers}
 573     ${project_sources}
 574     ${hb_gobject_gen_sources}
 575     ${hb_gobject_gen_headers}
 576     ${hb_gobject_sources}
 577     ${hb_gobject_headers}
 578   )
 579     if (WIN32)
 580       # Nasty issue: We need to make drive letters lower case,
 581       # otherwise g-ir-scanner won't like it and give us a bunch
 582       # of invalid items and unresolved types...
 583       STRING(SUBSTRING "${f}" 0 1 drive)
 584       STRING(SUBSTRING "${f}" 1 -1 path)
 585       if (drive MATCHES "[A-Z]")
 586         STRING(TOLOWER ${drive} drive_lower)
 587         list(APPEND introspected_sources "${drive_lower}${path}")
 588       else ()
 589         list(APPEND introspected_sources "${f}")
 590       endif ()
 591     else ()
 592       list(APPEND introspected_sources "${f}")
 593     endif ()
 594   endforeach ()
 595
 596   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
 597   foreach (s ${introspected_sources})
 598     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
 599   endforeach ()
 600
 601   # Finally, build the introspection files...
 602   add_custom_command(
 603     TARGET harfbuzz-gobject
 604     POST_BUILD
 605     COMMAND ${G_IR_SCANNER_CMD}
 606       --warn-all --no-libtool --verbose
 607       --namespace=HarfBuzz
 608       --nsversion=0.0
 609       --symbol-prefix=hb
 610       --symbol-prefix=hb_gobject
 611       --identifier-prefix=hb_
 612       --include GObject-2.0
 613       --pkg-export=harfbuzz-gobject
 614       --c-include=hb-gobject.h
 615       --cflags-begin
 616       -I${PROJECT_SOURCE_DIR}/src
 617       -I${PROJECT_BINARY_DIR}/src
 618       ${hb_includedir_cflags}
 619       ${hb_defines_cflags}
 620       -DHB_H
 621       -DHB_H_IN
 622       -DHB_OT_H
 623       -DHB_OT_H_IN
 624       -DHB_AAT_H
 625       -DHB_AAT_H_IN
 626       -DHB_GOBJECT_H
 627       -DHB_GOBJECT_H_IN
 628       -DHB_EXTERN=
 629       --cflags-end
 630       --library=harfbuzz-gobject
 631       --library=harfbuzz
 632       -L${hb_libpath}
 633       ${extra_libs}
 634       --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 635       -o ${hb_libpath}/HarfBuzz-0.0.gir
 636     DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 637   )
 638
 639   add_custom_command(
 640     TARGET harfbuzz-gobject
 641     POST_BUILD
 642     COMMAND "${G_IR_COMPILER}"
 643       --verbose --debug
 644       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 645       ${hb_libpath}/HarfBuzz-0.0.gir
 646       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 647     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 648   )
 649 endif ()
 650
 651
 652 ## Additional framework build configs
 653 if (BUILD_FRAMEWORK)
 654   set (CMAKE_MACOSX_RPATH ON)
 655   set_target_properties(harfbuzz PROPERTIES
 656     FRAMEWORK TRUE
 657     PUBLIC_HEADER "${project_headers}"
 658     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 659   )
 660   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 661   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 662   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 663 endif ()
 664
 665
 666 ## Additional harfbuzz build artifacts
 667 if (HB_BUILD_UTILS)
 668   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 669   find_package(PkgConfig)
 670   pkg_check_modules(PC_CAIRO QUIET cairo)
 671
 672   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 673   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 674
 675   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 676   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 677   include_directories(${CAIRO_INCLUDE_DIRS})
 678
 679   add_executable(hb-view ${HB_VIEW_sources})
 680   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 681
 682   add_executable(hb-shape ${HB_SHAPE_sources})
 683   target_link_libraries(hb-shape harfbuzz)
 684
 685   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 686   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 687
 688   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 689   target_link_libraries(hb-ot-shape-closure harfbuzz)
 690
 691   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 692 endif ()
 693
 694
 695 ## Install
 696 include (GNUInstallDirs)
 697
 698 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 699   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 700   if (HB_HAVE_GOBJECT)
 701     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 702   endif ()
 703 endif ()
 704
 705 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 706   install(TARGETS harfbuzz
 707     EXPORT harfbuzzConfig
 708     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 709     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 710     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 711     FRAMEWORK DESTINATION Library/Frameworks
 712   )
 713   install(EXPORT harfbuzzConfig
 714       NAMESPACE harfbuzz::
 715       DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/harfbuzz
 716   )
 717   if (HB_HAVE_ICU)
 718     install(TARGETS harfbuzz-icu
 719       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 720       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 721       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 722       FRAMEWORK DESTINATION Library/Frameworks
 723     )
 724   endif ()
 725   if (HB_BUILD_UTILS)
 726     if (WIN32 AND BUILD_SHARED_LIBS)
 727       install(TARGETS harfbuzz-subset
 728         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 729       )
 730     endif ()
 731     install(TARGETS hb-view
 732       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 733     )
 734     install(TARGETS hb-subset
 735       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 736     )
 737
 738     install(TARGETS hb-shape
 739       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 740     )
 741
 742     install(TARGETS hb-ot-shape-closure
 743       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 744     )
 745   endif ()
 746   if (HB_HAVE_GOBJECT)
 747     install(TARGETS harfbuzz-gobject
 748       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 749       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 750       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 751     )
 752     if (HB_HAVE_INTROSPECTION)
 753       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 754         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 755       else ()
 756         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 757       endif ()
 758
 759       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 760         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 761       )
 762
 763       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 764         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 765       )
 766     endif ()
 767   endif ()
 768 endif ()