CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1)
   2 project(harfbuzz)
   3
   4 message(WARN "HarfBuzz has a Meson port and tries to migrate all the other build systems to it, please consider using it as we might remove our cmake port soon.")
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  39 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  40 if (TARGET freetype)
  41   set (HB_HAVE_FREETYPE ON)
  42   add_definitions(-DHAVE_FREETYPE=1)
  43 endif ()
  44 if (APPLE)
  45   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  46   set (CMAKE_MACOSX_RPATH ON)
  47 endif ()
  48 if (WIN32)
  49   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  50   option(HB_HAVE_GDI "Enable GDI integration helpers on Windows" OFF)
  51   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  52 endif ()
  53 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  54 if (HB_BUILD_UTILS)
  55   set (HB_HAVE_GLIB ON)
  56   set (HB_HAVE_FREETYPE ON)
  57 endif ()
  58
  59 option(HB_BUILD_SUBSET "Build harfbuzz-subset" ON)
  60
  61 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  62 if (HB_HAVE_GOBJECT)
  63   set (HB_HAVE_GLIB ON)
  64 endif ()
  65
  66 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  67 if (HB_HAVE_INTROSPECTION)
  68   set (HB_HAVE_GOBJECT ON)
  69   set (HB_HAVE_GLIB ON)
  70 endif ()
  71
  72 include_directories(AFTER
  73   ${PROJECT_SOURCE_DIR}/src
  74   ${PROJECT_BINARY_DIR}/src
  75 )
  76
  77 # We need PYTHON_EXECUTABLE to be set for running the tests...
  78 include (FindPythonInterp)
  79
  80 ## Functions and headers
  81 include (CheckFunctionExists)
  82 include (CheckIncludeFile)
  83 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
  84   foreach (func_name ${ARGN})
  85     string(TOUPPER ${func_name} definition_to_add)
  86     check_function_exists(${func_name} HAVE_${definition_to_add})
  87     if (${HAVE_${definition_to_add}})
  88       add_definitions(-DHAVE_${definition_to_add})
  89     endif ()
  90   endforeach ()
  91 endmacro ()
  92 if (UNIX)
  93   list(APPEND CMAKE_REQUIRED_LIBRARIES m)
  94 endif ()
  95 check_funcs(atexit mprotect sysconf getpagesize mmap isatty)
  96 check_include_file(unistd.h HAVE_UNISTD_H)
  97 if (${HAVE_UNISTD_H})
  98   add_definitions(-DHAVE_UNISTD_H)
  99 endif ()
 100 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
 101 if (${HAVE_SYS_MMAN_H})
 102   add_definitions(-DHAVE_SYS_MMAN_H)
 103 endif ()
 104 check_include_file(stdbool.h HAVE_STDBOOL_H)
 105 if (${HAVE_STDBOOL_H})
 106   add_definitions(-DHAVE_STDBOOL_H)
 107 endif ()
 108
 109 if (NOT MSVC)
 110   set(THREADS_PREFER_PTHREAD_FLAG ON)
 111   find_package(Threads)
 112   if (CMAKE_USE_PTHREADS_INIT)
 113     add_definitions("-DHAVE_PTHREAD")
 114     list(APPEND THIRD_PARTY_LIBS Threads::Threads)
 115   endif ()
 116 endif ()
 117
 118 if (MSVC)
 119   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 120 endif ()
 121
 122
 123 ## Detect if we are running inside a distribution or regular repository folder
 124 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 125 #   # perhaps we are on dist directory
 126 #   set (IN_HB_DIST TRUE)
 127 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 128 # endif ()
 129
 130
 131 ## Extract variables from Makefile files
 132 function (extract_make_variable variable makefile_source)
 133   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp "${makefile_source}")
 134   string(REGEX MATCHALL "[^ \n\t\\]+" listVar "${CMAKE_MATCH_1}")
 135   set (${variable} ${listVar} PARENT_SCOPE)
 136 endfunction ()
 137
 138 # https://stackoverflow.com/a/27630120
 139 function (add_prefix_to_list var prefix)
 140   set (listVar "")
 141   foreach (f ${${var}})
 142     list(APPEND listVar "${prefix}${f}")
 143   endforeach ()
 144   set (${var} "${listVar}" PARENT_SCOPE)
 145 endfunction ()
 146
 147 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 148 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 149
 150 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 151 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 152
 153 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 154 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 155
 156 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 157 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 158
 159 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 160 #if (IN_HB_DIST)
 161   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 162 #else ()
 163 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 164 #endif ()
 165
 166 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 167 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 168 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 169 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 170 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 171 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 172 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 173 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 174
 175
 176 file(READ configure.ac CONFIGUREAC)
 177 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 178 set (HB_VERSION ${CMAKE_MATCH_1})
 179 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 180 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 181 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 182
 183 ## Define sources and headers of the project
 184 set (project_sources ${PROJECT_SOURCE_DIR}/src/harfbuzz.cc) # use amalgam source
 185 set (subset_project_sources ${HB_SUBSET_sources})
 186 set (project_extra_sources)
 187 set (project_headers ${HB_BASE_headers})
 188 set (subset_project_headers ${HB_SUBSET_headers})
 189
 190 ## Find and include needed header folders and libraries
 191 if (HB_HAVE_FREETYPE AND NOT TARGET freetype)
 192   include (FindFreetype)
 193   if (NOT FREETYPE_FOUND)
 194     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 195   endif ()
 196
 197   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 198   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 199   add_definitions(-DHAVE_FREETYPE=1)
 200
 201   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 202
 203   # So check_funcs can find its headers
 204   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 205   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 206
 207   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 208 endif ()
 209
 210 if (HB_HAVE_GRAPHITE2)
 211   add_definitions(-DHAVE_GRAPHITE2)
 212
 213   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 214   find_library(GRAPHITE2_LIBRARY graphite2)
 215
 216   include_directories(${GRAPHITE2_INCLUDE_DIR})
 217
 218   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 219
 220   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 221
 222   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 223 endif ()
 224
 225 if (HB_HAVE_GLIB)
 226   add_definitions(-DHAVE_GLIB)
 227
 228   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 229   find_package(PkgConfig)
 230   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 231
 232   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 233   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 234   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 235
 236   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 237
 238   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 239
 240   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 241
 242   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 243 endif ()
 244
 245 if (HB_HAVE_ICU)
 246   add_definitions(-DHAVE_ICU)
 247
 248   # https://github.com/WebKit/webkit/blob/fdd7733f2f30eab7fe096a9791f98c60f62f49c0/Source/cmake/FindICU.cmake
 249   find_package(PkgConfig)
 250   pkg_check_modules(PC_ICU QUIET icu-uc)
 251
 252   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 253   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 254
 255   include_directories(${ICU_INCLUDE_DIR})
 256
 257   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 258
 259   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 260
 261   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 262 endif ()
 263
 264 if (APPLE AND HB_HAVE_CORETEXT)
 265   # Apple Advanced Typography
 266   add_definitions(-DHAVE_CORETEXT)
 267
 268   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 269
 270   if (HB_IOS)
 271     find_library(COREFOUNDATION CoreFoundation)
 272     if (COREFOUNDATION)
 273       list(APPEND THIRD_PARTY_LIBS ${COREFOUNDATION})
 274     endif ()
 275     mark_as_advanced(COREFOUNDATION)
 276
 277     find_library(CORETEXT CoreText)
 278     if (CORETEXT)
 279       list(APPEND THIRD_PARTY_LIBS ${CORETEXT})
 280     endif ()
 281     mark_as_advanced(CORETEXT)
 282
 283     find_library(COREGRAPHICS CoreGraphics)
 284     if (COREGRAPHICS)
 285       list(APPEND THIRD_PARTY_LIBS ${COREGRAPHICS})
 286     endif ()
 287     mark_as_advanced(COREGRAPHICS)
 288   else ()
 289     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 290     if (APPLICATION_SERVICES_FRAMEWORK)
 291       list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 292     endif ()
 293
 294     mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 295   endif ()
 296 endif ()
 297
 298 if (WIN32 AND HB_HAVE_GDI)
 299   add_definitions(-DHAVE_GDI)
 300   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-gdi.h)
 301   list(APPEND THIRD_PARTY_LIBS gdi32)
 302 endif ()
 303
 304 if (WIN32 AND HB_HAVE_UNISCRIBE)
 305   add_definitions(-DHAVE_UNISCRIBE)
 306   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 307   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 308 endif ()
 309
 310 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 311   add_definitions(-DHAVE_DIRECTWRITE)
 312   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 313   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 314 endif ()
 315
 316 if (HB_HAVE_GOBJECT)
 317   add_definitions(-DHAVE_GOBJECT)
 318   include (FindPerl)
 319
 320   # Use the hints from glib-2.0.pc to find glib-mkenums
 321   find_package(PkgConfig)
 322   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 323   find_program(GLIB_MKENUMS glib-mkenums
 324     HINTS ${PC_glib_mkenums}
 325   )
 326   set (GLIB_MKENUMS_CMD)
 327
 328   if (WIN32 AND NOT MINGW)
 329     # In Visual Studio builds, shebang lines are not supported
 330     # in the standard cmd.exe shell that we use, so we need to
 331     # first determine whether glib-mkenums is a Python or PERL
 332     # script
 333     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 334       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 335       OUTPUT_QUIET ERROR_QUIET
 336     )
 337     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 338       message("${GLIB_MKENUMS} is a Python script.")
 339       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 340     else ()
 341       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 342         RESULT_VARIABLE GLIB_MKENUMS_PERL
 343         OUTPUT_QUIET ERROR_QUIET
 344       )
 345       if (GLIB_MKENUMS_PERL EQUAL 0)
 346         message("${GLIB_MKENUMS} is a PERL script.")
 347         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 348       endif ()
 349       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 350         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 351       endif ()
 352     endif ()
 353   else ()
 354     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 355   endif ()
 356   if (NOT GLIB_MKENUMS_CMD)
 357     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 358   endif ()
 359
 360   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 361
 362   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 363   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 364
 365   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 366   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 367
 368   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 369   list(APPEND hb_gobject_gen_sources
 370     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 371   )
 372   list(APPEND hb_gobject_structs_headers
 373     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 374   )
 375   list(APPEND hb_gobject_headers
 376     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 377     ${hb_gobject_structs_headers}
 378   )
 379   list(APPEND hb_gobject_gen_headers
 380     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 381   )
 382
 383   add_custom_command(
 384     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 385     COMMAND ${GLIB_MKENUMS_CMD}
 386       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 387       --identifier-prefix hb_
 388       --symbol-prefix hb_gobject
 389       ${hb_gobject_structs_headers}
 390       ${project_headers}
 391       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 392     COMMAND "${CMAKE_COMMAND}"
 393       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 394       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 395       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 396     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 397       ${hb_gobject_header}
 398       ${project_headers}
 399   )
 400
 401   add_custom_command(
 402     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 403     COMMAND ${GLIB_MKENUMS_CMD}
 404       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 405       --identifier-prefix hb_
 406       --symbol-prefix hb_gobject
 407       ${hb_gobject_header}
 408       ${project_headers}
 409       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 410     COMMAND "${CMAKE_COMMAND}"
 411       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 412       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 413       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 414     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 415       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 416       ${hb_gobject_header}
 417       ${project_headers}
 418   )
 419 endif ()
 420
 421
 422 ## Define harfbuzz library
 423 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 424 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 425 target_include_directories(harfbuzz PUBLIC
 426                            "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>"
 427                            "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz>")
 428 if (HB_HAVE_FREETYPE AND TARGET freetype)
 429   target_link_libraries(harfbuzz PUBLIC freetype)
 430 endif ()
 431
 432
 433 ## Define harfbuzz-icu library
 434 if (HB_HAVE_ICU)
 435   add_library(harfbuzz-icu ${PROJECT_SOURCE_DIR}/src/hb-icu.cc ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 436   add_dependencies(harfbuzz-icu harfbuzz)
 437   target_link_libraries(harfbuzz-icu harfbuzz ${THIRD_PARTY_LIBS})
 438
 439   if (BUILD_SHARED_LIBS)
 440     set_target_properties(harfbuzz harfbuzz-icu PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 441   endif ()
 442 endif ()
 443
 444
 445 ## Define harfbuzz-subset library
 446 if (HB_BUILD_SUBSET)
 447   add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 448   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-subset.h)
 449   add_dependencies(harfbuzz-subset harfbuzz)
 450   target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 451
 452   if (BUILD_SHARED_LIBS)
 453     set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 454   endif ()
 455 endif ()
 456
 457 if (UNIX OR MINGW)
 458   # Make symbols link locally
 459   include (CheckCXXCompilerFlag)
 460   CHECK_CXX_COMPILER_FLAG(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 461   if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 462     link_libraries(-Bsymbolic-functions)
 463   endif ()
 464
 465   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 466     # Make sure we don't link to libstdc++
 467     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 468     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 469     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 470     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 471     if (HB_BUILD_SUBSET)
 472       set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 473     endif ()
 474
 475     # No threadsafe statics as we do it ourselves
 476     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 477   endif ()
 478
 479   CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 480   if (COMPILER_SUPPORTS_CXX11)
 481     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 482   else()
 483     message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 484   endif()
 485 endif ()
 486
 487
 488 ## Define harfbuzz-gobject library
 489 if (HB_HAVE_GOBJECT)
 490   add_library(harfbuzz-gobject
 491     ${hb_gobject_sources}
 492     ${hb_gobject_gen_sources}
 493     ${hb_gobject_headers}
 494     ${hb_gobject_gen_headers}
 495   )
 496   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 497   add_dependencies(harfbuzz-gobject harfbuzz)
 498   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 499
 500   if (BUILD_SHARED_LIBS)
 501     set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 502   endif ()
 503 endif ()
 504
 505 if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
 506   add_definitions("-DHB_DLL_EXPORT")
 507 endif ()
 508
 509 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 510 if (WIN32)
 511   if (NOT BUILD_SHARED_LIBS)
 512     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 513     set (HB_HAVE_INTROSPECTION OFF)
 514   endif ()
 515 endif ()
 516
 517 if (HB_HAVE_INTROSPECTION)
 518   find_package(PkgConfig)
 519   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 520
 521   find_program(G_IR_SCANNER g-ir-scanner
 522     HINTS ${PC_g_ir_scanner}
 523   )
 524
 525   find_program(G_IR_COMPILER g-ir-compiler
 526     HINTS ${PC_g_ir_compiler}
 527   )
 528
 529   if (WIN32 AND NOT MINGW)
 530     # Note that since we already enable HB_HAVE_GOBJECT
 531     # we would already have PYTHON_EXECUTABLE handy
 532     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 533   else ()
 534     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 535   endif ()
 536
 537   # We need to account for the varying output directories
 538   # when we build using Visual Studio projects
 539   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 540     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 541   else ()
 542     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 543   endif ()
 544
 545   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 546   set (hb_defines_cflags "")
 547   foreach (hb_cflag ${hb_cflags})
 548     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 549   endforeach (hb_cflag)
 550
 551   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 552   set (extra_libs "")
 553   foreach (extra_lib ${THIRD_PARTY_LIBS})
 554     # We don't want the .lib extension here...
 555     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 556     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 557   endforeach ()
 558
 559   set (introspected_sources)
 560   foreach (f
 561     ${project_headers}
 562     ${project_sources}
 563     ${hb_gobject_gen_sources}
 564     ${hb_gobject_gen_headers}
 565     ${hb_gobject_sources}
 566     ${hb_gobject_headers}
 567   )
 568     if (WIN32)
 569       # Nasty issue: We need to make drive letters lower case,
 570       # otherwise g-ir-scanner won't like it and give us a bunch
 571       # of invalid items and unresolved types...
 572       STRING(SUBSTRING "${f}" 0 1 drive)
 573       STRING(SUBSTRING "${f}" 1 -1 path)
 574       if (drive MATCHES "[A-Z]")
 575         STRING(TOLOWER ${drive} drive_lower)
 576         list(APPEND introspected_sources "${drive_lower}${path}")
 577       else ()
 578         list(APPEND introspected_sources "${f}")
 579       endif ()
 580     else ()
 581       list(APPEND introspected_sources "${f}")
 582     endif ()
 583   endforeach ()
 584
 585   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
 586   foreach (s ${introspected_sources})
 587     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
 588   endforeach ()
 589
 590   # Finally, build the introspection files...
 591   add_custom_command(
 592     TARGET harfbuzz-gobject
 593     POST_BUILD
 594     COMMAND ${G_IR_SCANNER_CMD}
 595       --warn-all --no-libtool --verbose
 596       --namespace=HarfBuzz
 597       --nsversion=0.0
 598       --symbol-prefix=hb
 599       --symbol-prefix=hb_gobject
 600       --identifier-prefix=hb_
 601       --include GObject-2.0
 602       --pkg-export=harfbuzz-gobject
 603       --c-include=hb-gobject.h
 604       --cflags-begin
 605       -I${PROJECT_SOURCE_DIR}/src
 606       -I${PROJECT_BINARY_DIR}/src
 607       ${hb_includedir_cflags}
 608       ${hb_defines_cflags}
 609       -DHB_H
 610       -DHB_H_IN
 611       -DHB_OT_H
 612       -DHB_OT_H_IN
 613       -DHB_AAT_H
 614       -DHB_AAT_H_IN
 615       -DHB_GOBJECT_H
 616       -DHB_GOBJECT_H_IN
 617       -DHB_EXTERN=
 618       --cflags-end
 619       --library=harfbuzz-gobject
 620       --library=harfbuzz
 621       -L${hb_libpath}
 622       ${extra_libs}
 623       --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 624       -o ${hb_libpath}/HarfBuzz-0.0.gir
 625     DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 626   )
 627
 628   add_custom_command(
 629     TARGET harfbuzz-gobject
 630     POST_BUILD
 631     COMMAND "${G_IR_COMPILER}"
 632       --verbose --debug
 633       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 634       ${hb_libpath}/HarfBuzz-0.0.gir
 635       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 636     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 637   )
 638 endif ()
 639
 640
 641 ## Additional framework build configs
 642 if (BUILD_FRAMEWORK)
 643   set (CMAKE_MACOSX_RPATH ON)
 644   set_target_properties(harfbuzz PROPERTIES
 645     FRAMEWORK TRUE
 646     PUBLIC_HEADER "${project_headers}"
 647     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 648   )
 649   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 650   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 651   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 652 endif ()
 653
 654
 655 ## Additional harfbuzz build artifacts
 656 if (HB_BUILD_UTILS)
 657   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 658   find_package(PkgConfig)
 659   pkg_check_modules(PC_CAIRO QUIET cairo)
 660
 661   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 662   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 663
 664   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 665   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 666   include_directories(${CAIRO_INCLUDE_DIRS})
 667
 668   add_executable(hb-view ${HB_VIEW_sources})
 669   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 670
 671   add_executable(hb-shape ${HB_SHAPE_sources})
 672   target_link_libraries(hb-shape harfbuzz)
 673
 674   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 675   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 676
 677   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 678   target_link_libraries(hb-ot-shape-closure harfbuzz)
 679
 680   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 681 endif ()
 682
 683
 684 ## Install
 685 include (GNUInstallDirs)
 686
 687 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 688   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 689   if (HB_HAVE_GOBJECT)
 690     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 691   endif ()
 692 endif ()
 693
 694 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 695   install(TARGETS harfbuzz
 696     EXPORT harfbuzzConfig
 697     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 698     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 699     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 700     FRAMEWORK DESTINATION Library/Frameworks
 701   )
 702   install(EXPORT harfbuzzConfig
 703       NAMESPACE harfbuzz::
 704       DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/harfbuzz
 705   )
 706   if (HB_HAVE_ICU)
 707     install(TARGETS harfbuzz-icu
 708       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 709       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 710       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 711       FRAMEWORK DESTINATION Library/Frameworks
 712     )
 713   endif ()
 714   if (HB_BUILD_SUBSET)
 715     install(TARGETS harfbuzz-subset
 716       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 717   )
 718   endif ()
 719   if (HB_BUILD_UTILS)
 720     if (WIN32 AND BUILD_SHARED_LIBS)
 721       install(TARGETS harfbuzz-subset
 722         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 723       )
 724     endif ()
 725     install(TARGETS hb-view
 726       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 727     )
 728     install(TARGETS hb-subset
 729       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 730     )
 731
 732     install(TARGETS hb-shape
 733       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 734     )
 735
 736     install(TARGETS hb-ot-shape-closure
 737       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 738     )
 739   endif ()
 740   if (HB_HAVE_GOBJECT)
 741     install(TARGETS harfbuzz-gobject
 742       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 743       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 744       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 745     )
 746     if (HB_HAVE_INTROSPECTION)
 747       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 748         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 749       else ()
 750         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 751       endif ()
 752
 753       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 754         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 755       )
 756
 757       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 758         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 759       )
 760     endif ()
 761   endif ()
 762 endif ()