CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 project(harfbuzz)
   3
   4 enable_testing()
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  39 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  40 if (APPLE)
  41   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  42   set (CMAKE_MACOSX_RPATH ON)
  43 endif ()
  44 if (WIN32)
  45   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  46   option(HB_HAVE_GDI "Enable GDI integration helpers on Windows" OFF)
  47   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  48 endif ()
  49 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  50 if (HB_BUILD_UTILS)
  51   set (HB_HAVE_GLIB ON)
  52   set (HB_HAVE_FREETYPE ON)
  53 endif ()
  54
  55 option(HB_BUILD_SUBSET "Build harfbuzz-subset" ON)
  56 option(HB_BUILD_TESTS "Build harfbuzz tests" ON)
  57
  58 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  59 if (HB_HAVE_GOBJECT)
  60   set (HB_HAVE_GLIB ON)
  61 endif ()
  62
  63 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  64 if (HB_HAVE_INTROSPECTION)
  65   set (HB_HAVE_GOBJECT ON)
  66   set (HB_HAVE_GLIB ON)
  67 endif ()
  68
  69 option(HB_CHECK OFF "Do a configuration suitable for testing (shared library and enable all options)")
  70 if (HB_CHECK)
  71   set (BUILD_SHARED_LIBS ON)
  72   set (HB_BUILD_UTILS ON)
  73   set (HB_HAVE_ICU)
  74   set (HB_HAVE_GLIB ON)
  75   #set (HB_HAVE_GOBJECT ON)
  76   #set (HB_HAVE_INTROSPECTION ON)
  77   set (HB_HAVE_FREETYPE ON)
  78   set (HB_HAVE_GRAPHITE2 ON)
  79   if (WIN32)
  80     set (HB_HAVE_UNISCRIBE ON)
  81     set (HB_HAVE_GDI ON)
  82     set (HB_HAVE_DIRECTWRITE ON)
  83   elseif (APPLE)
  84     set (HB_HAVE_CORETEXT ON)
  85   endif ()
  86 endif ()
  87
  88 include_directories(AFTER
  89   ${PROJECT_SOURCE_DIR}/src
  90   ${PROJECT_BINARY_DIR}/src
  91 )
  92
  93 # We need PYTHON_EXECUTABLE to be set for running the tests...
  94 include (FindPythonInterp)
  95
  96 ## Functions and headers
  97 include (CheckFunctionExists)
  98 include (CheckIncludeFile)
  99 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
 100   foreach (func_name ${ARGN})
 101     string(TOUPPER ${func_name} definition_to_add)
 102     check_function_exists(${func_name} HAVE_${definition_to_add})
 103     if (${HAVE_${definition_to_add}})
 104       add_definitions(-DHAVE_${definition_to_add})
 105     endif ()
 106   endforeach ()
 107 endmacro ()
 108 if (UNIX)
 109   list(APPEND CMAKE_REQUIRED_LIBRARIES m)
 110 endif ()
 111 check_funcs(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l roundf)
 112 check_include_file(unistd.h HAVE_UNISTD_H)
 113 if (${HAVE_UNISTD_H})
 114   add_definitions(-DHAVE_UNISTD_H)
 115 endif ()
 116 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
 117 if (${HAVE_SYS_MMAN_H})
 118   add_definitions(-DHAVE_SYS_MMAN_H)
 119 endif ()
 120 check_include_file(xlocale.h HAVE_XLOCALE_H)
 121 if (${HAVE_XLOCALE_H})
 122   add_definitions(-DHAVE_XLOCALE_H)
 123 endif ()
 124 check_include_file(stdbool.h HAVE_STDBOOL_H)
 125 if (${HAVE_STDBOOL_H})
 126   add_definitions(-DHAVE_STDBOOL_H)
 127 endif ()
 128
 129
 130 if (MSVC)
 131   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 132 endif ()
 133
 134
 135 ## Detect if we are running inside a distribution or regular repository folder
 136 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 137 #   # perhaps we are on dist directory
 138 #   set (IN_HB_DIST TRUE)
 139 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 140 # endif ()
 141
 142
 143 ## Extract variables from Makefile files
 144 function (extract_make_variable variable makefile_source)
 145   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp "${makefile_source}")
 146   string(REGEX MATCHALL "[^ \n\t\\]+" listVar "${CMAKE_MATCH_1}")
 147   set (${variable} ${listVar} PARENT_SCOPE)
 148 endfunction ()
 149
 150 # http://stackoverflow.com/a/27630120
 151 function (add_prefix_to_list var prefix)
 152   set (listVar "")
 153   foreach (f ${${var}})
 154     list(APPEND listVar "${prefix}${f}")
 155   endforeach ()
 156   set (${var} "${listVar}" PARENT_SCOPE)
 157 endfunction ()
 158
 159 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 160 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 161
 162 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 163 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 164
 165 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 166 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 167
 168 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 169 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 170
 171 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 172 #if (IN_HB_DIST)
 173   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 174 #else ()
 175 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 176 #endif ()
 177
 178 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 179 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 180 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 181 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 182 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 183 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 184 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 185 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 186
 187
 188 file(READ configure.ac CONFIGUREAC)
 189 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 190 set (HB_VERSION ${CMAKE_MATCH_1})
 191 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 192 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 193 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 194
 195 ## Define sources and headers of the project
 196 set (project_sources ${PROJECT_SOURCE_DIR}/src/harfbuzz.cc) # use amalgam source
 197 set (subset_project_sources ${HB_SUBSET_sources})
 198 set (project_extra_sources)
 199 set (project_headers ${HB_BASE_headers})
 200 set (subset_project_headers ${HB_SUBSET_headers})
 201
 202 ## Find and include needed header folders and libraries
 203 if (HB_HAVE_FREETYPE)
 204   include (FindFreetype)
 205   if (NOT FREETYPE_FOUND)
 206     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 207   endif ()
 208
 209   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 210   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 211   add_definitions(-DHAVE_FREETYPE=1)
 212
 213   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 214
 215   # So check_funcs can find its headers
 216   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 217   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 218
 219   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 220 endif ()
 221
 222 if (HB_HAVE_GRAPHITE2)
 223   add_definitions(-DHAVE_GRAPHITE2)
 224
 225   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 226   find_library(GRAPHITE2_LIBRARY graphite2)
 227
 228   include_directories(${GRAPHITE2_INCLUDE_DIR})
 229
 230   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 231
 232   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 233
 234   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 235 endif ()
 236
 237 if (HB_HAVE_GLIB)
 238   add_definitions(-DHAVE_GLIB)
 239
 240   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 241   find_package(PkgConfig)
 242   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 243
 244   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 245   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 246   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 247
 248   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 249
 250   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 251
 252   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 253
 254   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 255 endif ()
 256
 257 if (HB_HAVE_ICU)
 258   add_definitions(-DHAVE_ICU)
 259
 260   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
 261   find_package(PkgConfig)
 262   pkg_check_modules(PC_ICU QUIET icu-uc)
 263
 264   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 265   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 266
 267   include_directories(${ICU_INCLUDE_DIR})
 268
 269   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 270
 271   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 272
 273   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 274 endif ()
 275
 276 if (APPLE AND HB_HAVE_CORETEXT)
 277   # Apple Advanced Typography
 278   add_definitions(-DHAVE_CORETEXT)
 279
 280   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 281
 282   if (HB_IOS)
 283     find_library(COREFOUNDATION CoreFoundation)
 284     if (COREFOUNDATION)
 285       list(APPEND THIRD_PARTY_LIBS ${COREFOUNDATION})
 286     endif ()
 287     mark_as_advanced(COREFOUNDATION)
 288
 289     find_library(CORETEXT CoreText)
 290     if (CORETEXT)
 291       list(APPEND THIRD_PARTY_LIBS ${CORETEXT})
 292     endif ()
 293     mark_as_advanced(CORETEXT)
 294
 295     find_library(COREGRAPHICS CoreGraphics)
 296     if (COREGRAPHICS)
 297       list(APPEND THIRD_PARTY_LIBS ${COREGRAPHICS})
 298     endif ()
 299     mark_as_advanced(COREGRAPHICS)
 300   else ()
 301     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 302     if (APPLICATION_SERVICES_FRAMEWORK)
 303       list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 304     endif ()
 305
 306     mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 307   endif ()
 308 endif ()
 309
 310 if (WIN32 AND HB_HAVE_GDI)
 311   add_definitions(-DHAVE_GDI)
 312   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-gdi.h)
 313   list(APPEND THIRD_PARTY_LIBS gdi32)
 314 endif ()
 315
 316 if (WIN32 AND HB_HAVE_UNISCRIBE)
 317   add_definitions(-DHAVE_UNISCRIBE)
 318   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 319   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 320 endif ()
 321
 322 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 323   add_definitions(-DHAVE_DIRECTWRITE)
 324   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 325   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 326 endif ()
 327
 328 if (HB_HAVE_GOBJECT)
 329   include (FindPerl)
 330
 331   # Use the hints from glib-2.0.pc to find glib-mkenums
 332   find_package(PkgConfig)
 333   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 334   find_program(GLIB_MKENUMS glib-mkenums
 335     HINTS ${PC_glib_mkenums}
 336   )
 337   set (GLIB_MKENUMS_CMD)
 338
 339   if (WIN32 AND NOT MINGW)
 340     # In Visual Studio builds, shebang lines are not supported
 341     # in the standard cmd.exe shell that we use, so we need to
 342     # first determine whether glib-mkenums is a Python or PERL
 343     # script
 344     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 345       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 346       OUTPUT_QUIET ERROR_QUIET
 347     )
 348     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 349       message("${GLIB_MKENUMS} is a Python script.")
 350       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 351     else ()
 352       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 353         RESULT_VARIABLE GLIB_MKENUMS_PERL
 354         OUTPUT_QUIET ERROR_QUIET
 355       )
 356       if (GLIB_MKENUMS_PERL EQUAL 0)
 357         message("${GLIB_MKENUMS} is a PERL script.")
 358         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 359       endif ()
 360       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 361         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 362       endif ()
 363     endif ()
 364   else ()
 365     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 366   endif ()
 367   if (NOT GLIB_MKENUMS_CMD)
 368     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 369   endif ()
 370
 371   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 372
 373   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 374   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 375
 376   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 377   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 378
 379   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 380   list(APPEND hb_gobject_gen_sources
 381     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 382   )
 383   list(APPEND hb_gobject_structs_headers
 384     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 385   )
 386   list(APPEND hb_gobject_headers
 387     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 388     ${hb_gobject_structs_headers}
 389   )
 390   list(APPEND hb_gobject_gen_headers
 391     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 392   )
 393
 394   add_custom_command(
 395     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 396     COMMAND ${GLIB_MKENUMS_CMD}
 397       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 398       --identifier-prefix hb_
 399       --symbol-prefix hb_gobject
 400       ${hb_gobject_structs_headers}
 401       ${project_headers}
 402       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 403     COMMAND "${CMAKE_COMMAND}"
 404       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 405       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 406       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 407     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 408       ${hb_gobject_header}
 409       ${project_headers}
 410   )
 411
 412   add_custom_command(
 413     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 414     COMMAND ${GLIB_MKENUMS_CMD}
 415       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 416       --identifier-prefix hb_
 417       --symbol-prefix hb_gobject
 418       ${hb_gobject_header}
 419       ${project_headers}
 420       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 421     COMMAND "${CMAKE_COMMAND}"
 422       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 423       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 424       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 425     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 426       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 427       ${hb_gobject_header}
 428       ${project_headers}
 429   )
 430 endif ()
 431
 432 ## Atomic ops availability detection
 433 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
 434 "               void memory_barrier (void) { __sync_synchronize (); }
 435                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 436                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 437                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 438                 int main () { return 0; }
 439 ")
 440 try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
 441   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
 442   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
 443 if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
 444   add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
 445 endif ()
 446
 447 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
 448 "               #include <atomic.h>
 449                 /* This requires Solaris Studio 12.2 or newer: */
 450                 #include <mbarrier.h>
 451                 void memory_barrier (void) { __machine_rw_barrier (); }
 452                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 453                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 454                 int main () { return 0; }
 455 ")
 456 try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
 457   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
 458   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
 459 if (HB_HAVE_SOLARIS_ATOMIC_OPS)
 460   add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
 461 endif ()
 462
 463
 464 ## Define harfbuzz library
 465 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 466 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 467
 468 ## Define harfbuzz-subset library
 469 if (HB_BUILD_SUBSET)
 470   add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 471   add_dependencies(harfbuzz-subset harfbuzz)
 472   target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 473
 474   if (BUILD_SHARED_LIBS)
 475     set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 476   endif ()
 477 endif ()
 478
 479 if (UNIX OR MINGW)
 480   # Make symbols link locally
 481   include (CheckCXXCompilerFlag)
 482   CHECK_CXX_COMPILER_FLAG(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 483   if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 484     link_libraries(-Bsymbolic-functions)
 485   endif ()
 486
 487   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 488     # Make sure we don't link to libstdc++
 489     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 490     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 491     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 492     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 493     if (HB_BUILD_SUBSET)
 494       set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 495     endif ()
 496
 497     # No threadsafe statics as we do it ourselves
 498     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 499   endif ()
 500
 501   CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 502   if (COMPILER_SUPPORTS_CXX11)
 503     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 504   else()
 505     message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 506   endif()
 507 endif ()
 508
 509
 510 ## Define harfbuzz-gobject library
 511 if (HB_HAVE_GOBJECT)
 512   add_library(harfbuzz-gobject
 513     ${hb_gobject_sources}
 514     ${hb_gobject_gen_sources}
 515     ${hb_gobject_headers}
 516     ${hb_gobject_gen_headers}
 517   )
 518   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 519   add_dependencies(harfbuzz-gobject harfbuzz)
 520   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 521
 522   if (BUILD_SHARED_LIBS)
 523     set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 524   endif ()
 525 endif ()
 526
 527 if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
 528   add_definitions("-DHB_DLL_EXPORT")
 529 endif ()
 530
 531 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 532 if (WIN32)
 533   if (NOT BUILD_SHARED_LIBS)
 534     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 535     set (HB_HAVE_INTROSPECTION OFF)
 536   endif ()
 537 endif ()
 538
 539 if (HB_HAVE_INTROSPECTION)
 540   find_package(PkgConfig)
 541   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 542
 543   find_program(G_IR_SCANNER g-ir-scanner
 544     HINTS ${PC_g_ir_scanner}
 545   )
 546
 547   find_program(G_IR_COMPILER g-ir-compiler
 548     HINTS ${PC_g_ir_compiler}
 549   )
 550
 551   if (WIN32 AND NOT MINGW)
 552     # Note that since we already enable HB_HAVE_GOBJECT
 553     # we would already have PYTHON_EXECUTABLE handy
 554     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 555   else ()
 556     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 557   endif ()
 558
 559   # We need to account for the varying output directories
 560   # when we build using Visual Studio projects
 561   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 562     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 563   else ()
 564     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 565   endif ()
 566
 567   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 568   set (hb_defines_cflags "")
 569   foreach (hb_cflag ${hb_cflags})
 570     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 571   endforeach (hb_cflag)
 572
 573   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 574   set (extra_libs "")
 575   foreach (extra_lib ${THIRD_PARTY_LIBS})
 576     # We don't want the .lib extension here...
 577     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 578     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 579   endforeach ()
 580
 581   set (introspected_sources)
 582   foreach (f
 583     ${project_headers}
 584     ${project_sources}
 585     ${hb_gobject_gen_sources}
 586     ${hb_gobject_gen_headers}
 587     ${hb_gobject_sources}
 588     ${hb_gobject_headers}
 589   )
 590     if (WIN32)
 591       # Nasty issue: We need to make drive letters lower case,
 592       # otherwise g-ir-scanner won't like it and give us a bunch
 593       # of invalid items and unresolved types...
 594       STRING(SUBSTRING "${f}" 0 1 drive)
 595       STRING(SUBSTRING "${f}" 1 -1 path)
 596       if (drive MATCHES "[A-Z]")
 597         STRING(TOLOWER ${drive} drive_lower)
 598         list(APPEND introspected_sources "${drive_lower}${path}")
 599       else ()
 600         list(APPEND introspected_sources "${f}")
 601       endif ()
 602     else ()
 603       list(APPEND introspected_sources "${f}")
 604     endif ()
 605   endforeach ()
 606
 607   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
 608   foreach (s ${introspected_sources})
 609     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
 610   endforeach ()
 611
 612   # Finally, build the introspection files...
 613   add_custom_command(
 614     TARGET harfbuzz-gobject
 615     POST_BUILD
 616     COMMAND ${G_IR_SCANNER_CMD}
 617       --warn-all --no-libtool --verbose
 618       -n hb
 619       --namespace=HarfBuzz
 620       --nsversion=0.0
 621       --identifier-prefix=hb_
 622       --include GObject-2.0
 623       --pkg-export=harfbuzz
 624       --cflags-begin
 625       -I${PROJECT_SOURCE_DIR}/src
 626       -I${PROJECT_BINARY_DIR}/src
 627       ${hb_includedir_cflags}
 628       ${hb_defines_cflags}
 629       -DHB_H
 630       -DHB_H_IN
 631       -DHB_OT_H
 632       -DHB_OT_H_IN
 633       -DHB_AAT_H
 634       -DHB_AAT_H_IN
 635       -DHB_GOBJECT_H
 636       -DHB_GOBJECT_H_IN
 637       -DHB_EXTERN=
 638       --cflags-end
 639       --library=harfbuzz-gobject
 640       --library=harfbuzz
 641       -L${hb_libpath}
 642       ${extra_libs}
 643       --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 644       -o ${hb_libpath}/HarfBuzz-0.0.gir
 645     DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 646   )
 647
 648   add_custom_command(
 649     TARGET harfbuzz-gobject
 650     POST_BUILD
 651     COMMAND "${G_IR_COMPILER}"
 652       --verbose --debug
 653       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 654       ${hb_libpath}/HarfBuzz-0.0.gir
 655       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 656     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 657   )
 658 endif ()
 659
 660
 661 ## Additional framework build configs
 662 if (BUILD_FRAMEWORK)
 663   set (CMAKE_MACOSX_RPATH ON)
 664   set_target_properties(harfbuzz PROPERTIES
 665     FRAMEWORK TRUE
 666     PUBLIC_HEADER "${project_headers}"
 667     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 668   )
 669   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 670   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 671   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 672 endif ()
 673
 674
 675 ## Additional harfbuzz build artifacts
 676 if (HB_BUILD_UTILS)
 677   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 678   find_package(PkgConfig)
 679   pkg_check_modules(PC_CAIRO QUIET cairo)
 680
 681   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 682   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 683
 684   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 685   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 686   include_directories(${CAIRO_INCLUDE_DIRS})
 687
 688   add_executable(hb-view ${HB_VIEW_sources})
 689   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 690
 691   add_executable(hb-shape ${HB_SHAPE_sources})
 692   target_link_libraries(hb-shape harfbuzz)
 693
 694   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 695   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 696
 697   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 698   target_link_libraries(hb-ot-shape-closure harfbuzz)
 699
 700   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 701 endif ()
 702
 703
 704 ## Install
 705 include (GNUInstallDirs)
 706
 707 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 708   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 709   if (HB_HAVE_GOBJECT)
 710     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 711   endif ()
 712 endif ()
 713
 714 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 715   install(TARGETS harfbuzz
 716     EXPORT harfbuzzConfig
 717     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 718     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 719     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 720     FRAMEWORK DESTINATION Library/Frameworks
 721   )
 722   install(EXPORT harfbuzzConfig
 723       NAMESPACE harfbuzz::
 724       DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/harfbuzz
 725   )
 726   if (HB_BUILD_UTILS)
 727     if (WIN32 AND BUILD_SHARED_LIBS)
 728       install(TARGETS harfbuzz-subset
 729         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 730       )
 731     endif ()
 732     install(TARGETS hb-view
 733       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 734     )
 735     install(TARGETS hb-subset
 736       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 737     )
 738
 739     install(TARGETS hb-shape
 740       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 741     )
 742
 743     install(TARGETS hb-ot-shape-closure
 744       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 745     )
 746   endif ()
 747   if (HB_HAVE_GOBJECT)
 748     install(TARGETS harfbuzz-gobject
 749       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 750       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 751       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 752     )
 753     if (HB_HAVE_INTROSPECTION)
 754       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 755         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 756       else ()
 757         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 758       endif ()
 759
 760       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 761         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 762       )
 763
 764       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 765         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 766       )
 767     endif ()
 768   endif ()
 769 endif ()
 770
 771 if (HB_BUILD_TESTS)
 772   ## src/ executables
 773   foreach (prog main test test-gsub-would-substitute test-gpos-size-params test-buffer-serialize test-unicode-ranges) # hb-ot-tag
 774     set (prog_name ${prog})
 775     if (${prog_name} STREQUAL "test")
 776       # test can not be used as a valid executable name on cmake, lets special case it
 777       set (prog_name test-test)
 778     endif ()
 779     add_executable(${prog_name} ${PROJECT_SOURCE_DIR}/src/${prog}.cc)
 780     target_link_libraries(${prog_name} harfbuzz ${THIRD_PARTY_LIBS})
 781   endforeach ()
 782   # set_target_properties(hb-ot-tag PROPERTIES COMPILE_FLAGS "-DMAIN")
 783
 784   ## Tests
 785   if (UNIX OR MINGW)
 786     if (BUILD_SHARED_LIBS)
 787       # generate harfbuzz.def after build completion
 788       add_custom_command(TARGET harfbuzz POST_BUILD
 789         COMMAND "${PYTHON_EXECUTABLE}" ${PROJECT_SOURCE_DIR}/src/gen-def.py ${PROJECT_BINARY_DIR}/harfbuzz.def ${project_headers}
 790         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src)
 791
 792       add_test(NAME check-static-inits.sh
 793         COMMAND ${PROJECT_SOURCE_DIR}/src/check-static-inits.sh
 794         WORKING_DIRECTORY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/harfbuzz.dir/src # ugly hack
 795       )
 796       add_test(NAME check-libstdc++.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-libstdc++.sh)
 797       add_test(NAME check-symbols.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-symbols.sh)
 798
 799       set_tests_properties(
 800         check-static-inits.sh check-libstdc++.sh check-symbols.sh
 801         PROPERTIES
 802           ENVIRONMENT "libs=.;srcdir=${PROJECT_SOURCE_DIR}/src"
 803           SKIP_RETURN_CODE 77)
 804     endif ()
 805
 806     add_test(NAME check-c-linkage-decls.sh COMMAND ./check-c-linkage-decls.sh)
 807     add_test(NAME check-header-guards.sh COMMAND ./check-header-guards.sh)
 808     add_test(NAME check-externs.sh COMMAND ./check-externs.sh)
 809     add_test(NAME check-includes.sh COMMAND ./check-includes.sh)
 810     set_tests_properties(
 811       check-c-linkage-decls.sh check-header-guards.sh check-externs.sh check-includes.sh
 812       PROPERTIES
 813         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src
 814         SKIP_RETURN_CODE 77)
 815   endif ()
 816
 817   # Needs to come last so that variables defined above are passed to
 818   # subdirectories.
 819   add_subdirectory(test)
 820 endif ()