googletest/CMakeLists.txt

   1 ########################################################################
   2 # Note: CMake support is community-based. The maintainers do not use CMake
   3 # internally.
   4 #
   5 # CMake build script for Google Test.
   6 #
   7 # To run the tests for Google Test itself on Linux, use 'make test' or
   8 # ctest.  You can select which tests to run using 'ctest -R regex'.
   9 # For more options, run 'ctest --help'.
  10
  11 # When other libraries are using a shared version of runtime libraries,
  12 # Google Test also has to use one.
  13 option(
  14   gtest_force_shared_crt
  15   "Use shared (DLL) run-time lib even when Google Test is built as static lib."
  16   OFF)
  17
  18 option(gtest_build_tests "Build all of gtest's own tests." OFF)
  19
  20 option(gtest_build_samples "Build gtest's sample programs." OFF)
  21
  22 option(gtest_disable_pthreads "Disable uses of pthreads in gtest." OFF)
  23
  24 option(
  25   gtest_hide_internal_symbols
  26   "Build gtest with internal symbols hidden in shared libraries."
  27   OFF)
  28
  29 # Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build().
  30 include(cmake/hermetic_build.cmake OPTIONAL)
  31
  32 if (COMMAND pre_project_set_up_hermetic_build)
  33   pre_project_set_up_hermetic_build()
  34 endif()
  35
  36 ########################################################################
  37 #
  38 # Project-wide settings
  39
  40 # Name of the project.
  41 #
  42 # CMake files in this project can refer to the root source directory
  43 # as ${gtest_SOURCE_DIR} and to the root binary directory as
  44 # ${gtest_BINARY_DIR}.
  45 # Language "C" is required for find_package(Threads).
  46
  47 # Project version:
  48
  49 cmake_minimum_required(VERSION 3.5)
  50 cmake_policy(SET CMP0048 NEW)
  51 project(gtest VERSION ${GOOGLETEST_VERSION} LANGUAGES CXX C)
  52
  53 if (POLICY CMP0063) # Visibility
  54   cmake_policy(SET CMP0063 NEW)
  55 endif (POLICY CMP0063)
  56
  57 if (COMMAND set_up_hermetic_build)
  58   set_up_hermetic_build()
  59 endif()
  60
  61 # These commands only run if this is the main project
  62 if(CMAKE_PROJECT_NAME STREQUAL "gtest" OR CMAKE_PROJECT_NAME STREQUAL "googletest-distribution")
  63
  64   # BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to
  65   # make it prominent in the GUI.
  66   option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF)
  67
  68 else()
  69
  70   mark_as_advanced(
  71     gtest_force_shared_crt
  72     gtest_build_tests
  73     gtest_build_samples
  74     gtest_disable_pthreads
  75     gtest_hide_internal_symbols)
  76
  77 endif()
  78
  79
  80 if (gtest_hide_internal_symbols)
  81   set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  82   set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  83 endif()
  84
  85 # Define helper functions and macros used by Google Test.
  86 include(cmake/internal_utils.cmake)
  87
  88 config_compiler_and_linker()  # Defined in internal_utils.cmake.
  89
  90 # Needed to set the namespace for both the export targets and the
  91 # alias libraries
  92 set(cmake_package_name GTest CACHE INTERNAL "")
  93
  94 # Create the CMake package file descriptors.
  95 if (INSTALL_GTEST)
  96   include(CMakePackageConfigHelpers)
  97   set(targets_export_name ${cmake_package_name}Targets CACHE INTERNAL "")
  98   set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/generated" CACHE INTERNAL "")
  99   set(cmake_files_install_dir "${CMAKE_INSTALL_LIBDIR}/cmake/${cmake_package_name}")
 100   set(version_file "${generated_dir}/${cmake_package_name}ConfigVersion.cmake")
 101   write_basic_package_version_file(${version_file} VERSION ${GOOGLETEST_VERSION} COMPATIBILITY AnyNewerVersion)
 102   install(EXPORT ${targets_export_name}
 103     NAMESPACE ${cmake_package_name}::
 104     DESTINATION ${cmake_files_install_dir})
 105   set(config_file "${generated_dir}/${cmake_package_name}Config.cmake")
 106   configure_package_config_file("${gtest_SOURCE_DIR}/cmake/Config.cmake.in"
 107     "${config_file}" INSTALL_DESTINATION ${cmake_files_install_dir})
 108   install(FILES ${version_file} ${config_file}
 109     DESTINATION ${cmake_files_install_dir})
 110 endif()
 111
 112 # Where Google Test's .h files can be found.
 113 set(gtest_build_include_dirs
 114   "${gtest_SOURCE_DIR}/include"
 115   "${gtest_SOURCE_DIR}")
 116 include_directories(${gtest_build_include_dirs})
 117
 118 ########################################################################
 119 #
 120 # Defines the gtest & gtest_main libraries.  User tests should link
 121 # with one of them.
 122
 123 # Google Test libraries.  We build them using more strict warnings than what
 124 # are used for other targets, to ensure that gtest can be compiled by a user
 125 # aggressive about warnings.
 126 cxx_library(gtest "${cxx_strict}" src/gtest-all.cc)
 127 set_target_properties(gtest PROPERTIES VERSION ${GOOGLETEST_VERSION})
 128 cxx_library(gtest_main "${cxx_strict}" src/gtest_main.cc)
 129 set_target_properties(gtest_main PROPERTIES VERSION ${GOOGLETEST_VERSION})
 130 # If the CMake version supports it, attach header directory information
 131 # to the targets for when we are part of a parent build (ie being pulled
 132 # in via add_subdirectory() rather than being a standalone build).
 133 if (DEFINED CMAKE_VERSION AND NOT "${CMAKE_VERSION}" VERSION_LESS "2.8.11")
 134   string(REPLACE ";" "$<SEMICOLON>" dirs "${gtest_build_include_dirs}")
 135   target_include_directories(gtest SYSTEM INTERFACE
 136     "$<BUILD_INTERFACE:${dirs}>"
 137     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 138   target_include_directories(gtest_main SYSTEM INTERFACE
 139     "$<BUILD_INTERFACE:${dirs}>"
 140     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 141 endif()
 142 if(CMAKE_SYSTEM_NAME MATCHES "QNX")
 143   target_link_libraries(gtest PUBLIC regex)
 144 endif()
 145 target_link_libraries(gtest_main PUBLIC gtest)
 146
 147 ########################################################################
 148 #
 149 # Install rules
 150 install_project(gtest gtest_main)
 151
 152 ########################################################################
 153 #
 154 # Samples on how to link user tests with gtest or gtest_main.
 155 #
 156 # They are not built by default.  To build them, set the
 157 # gtest_build_samples option to ON.  You can do it by running ccmake
 158 # or specifying the -Dgtest_build_samples=ON flag when running cmake.
 159
 160 if (gtest_build_samples)
 161   cxx_executable(sample1_unittest samples gtest_main samples/sample1.cc)
 162   cxx_executable(sample2_unittest samples gtest_main samples/sample2.cc)
 163   cxx_executable(sample3_unittest samples gtest_main)
 164   cxx_executable(sample4_unittest samples gtest_main samples/sample4.cc)
 165   cxx_executable(sample5_unittest samples gtest_main samples/sample1.cc)
 166   cxx_executable(sample6_unittest samples gtest_main)
 167   cxx_executable(sample7_unittest samples gtest_main)
 168   cxx_executable(sample8_unittest samples gtest_main)
 169   cxx_executable(sample9_unittest samples gtest)
 170   cxx_executable(sample10_unittest samples gtest)
 171 endif()
 172
 173 ########################################################################
 174 #
 175 # Google Test's own tests.
 176 #
 177 # You can skip this section if you aren't interested in testing
 178 # Google Test itself.
 179 #
 180 # The tests are not built by default.  To build them, set the
 181 # gtest_build_tests option to ON.  You can do it by running ccmake
 182 # or specifying the -Dgtest_build_tests=ON flag when running cmake.
 183
 184 if (gtest_build_tests)
 185   # This must be set in the root directory for the tests to be run by
 186   # 'make test' or ctest.
 187   enable_testing()
 188
 189   ############################################################
 190   # C++ tests built with standard compiler flags.
 191
 192   cxx_test(googletest-death-test-test gtest_main)
 193   cxx_test(gtest_environment_test gtest)
 194   cxx_test(googletest-filepath-test gtest_main)
 195   cxx_test(googletest-listener-test gtest_main)
 196   cxx_test(gtest_main_unittest gtest_main)
 197   cxx_test(googletest-message-test gtest_main)
 198   cxx_test(gtest_no_test_unittest gtest)
 199   cxx_test(googletest-options-test gtest_main)
 200   cxx_test(googletest-param-test-test gtest
 201     test/googletest-param-test2-test.cc)
 202   cxx_test(googletest-port-test gtest_main)
 203   cxx_test(gtest_pred_impl_unittest gtest_main)
 204   cxx_test(gtest_premature_exit_test gtest
 205     test/gtest_premature_exit_test.cc)
 206   cxx_test(googletest-printers-test gtest_main)
 207   cxx_test(gtest_prod_test gtest_main
 208     test/production.cc)
 209   cxx_test(gtest_repeat_test gtest)
 210   cxx_test(gtest_sole_header_test gtest_main)
 211   cxx_test(gtest_stress_test gtest)
 212   cxx_test(googletest-test-part-test gtest_main)
 213   cxx_test(gtest_throw_on_failure_ex_test gtest)
 214   cxx_test(gtest-typed-test_test gtest_main
 215     test/gtest-typed-test2_test.cc)
 216   cxx_test(gtest_unittest gtest_main)
 217   cxx_test(gtest-unittest-api_test gtest)
 218   cxx_test(gtest_skip_in_environment_setup_test gtest_main)
 219   cxx_test(gtest_skip_test gtest_main)
 220
 221   ############################################################
 222   # C++ tests built with non-standard compiler flags.
 223
 224   # MSVC 7.1 does not support STL with exceptions disabled.
 225   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 226     cxx_library(gtest_no_exception "${cxx_no_exception}"
 227       src/gtest-all.cc)
 228     cxx_library(gtest_main_no_exception "${cxx_no_exception}"
 229       src/gtest-all.cc src/gtest_main.cc)
 230   endif()
 231   cxx_library(gtest_main_no_rtti "${cxx_no_rtti}"
 232     src/gtest-all.cc src/gtest_main.cc)
 233
 234   cxx_test_with_flags(gtest-death-test_ex_nocatch_test
 235     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=0"
 236     gtest test/googletest-death-test_ex_test.cc)
 237   cxx_test_with_flags(gtest-death-test_ex_catch_test
 238     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=1"
 239     gtest test/googletest-death-test_ex_test.cc)
 240
 241   cxx_test_with_flags(gtest_no_rtti_unittest "${cxx_no_rtti}"
 242     gtest_main_no_rtti test/gtest_unittest.cc)
 243
 244   cxx_shared_library(gtest_dll "${cxx_default}"
 245     src/gtest-all.cc src/gtest_main.cc)
 246
 247   cxx_executable_with_flags(gtest_dll_test_ "${cxx_default}"
 248     gtest_dll test/gtest_all_test.cc)
 249   set_target_properties(gtest_dll_test_
 250                         PROPERTIES
 251                         COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
 252
 253   ############################################################
 254   # Python tests.
 255
 256   cxx_executable(googletest-break-on-failure-unittest_ test gtest)
 257   py_test(googletest-break-on-failure-unittest)
 258
 259   py_test(gtest_skip_check_output_test)
 260   py_test(gtest_skip_environment_check_output_test)
 261
 262   # Visual Studio .NET 2003 does not support STL with exceptions disabled.
 263   if (NOT MSVC OR MSVC_VERSION GREATER 1310)  # 1310 is Visual Studio .NET 2003
 264     cxx_executable_with_flags(
 265       googletest-catch-exceptions-no-ex-test_
 266       "${cxx_no_exception}"
 267       gtest_main_no_exception
 268       test/googletest-catch-exceptions-test_.cc)
 269   endif()
 270
 271   cxx_executable_with_flags(
 272     googletest-catch-exceptions-ex-test_
 273     "${cxx_exception}"
 274     gtest_main
 275     test/googletest-catch-exceptions-test_.cc)
 276   py_test(googletest-catch-exceptions-test)
 277
 278   cxx_executable(googletest-color-test_ test gtest)
 279   py_test(googletest-color-test)
 280
 281   cxx_executable(googletest-env-var-test_ test gtest)
 282   py_test(googletest-env-var-test)
 283
 284   cxx_executable(googletest-filter-unittest_ test gtest)
 285   py_test(googletest-filter-unittest)
 286
 287   cxx_executable(gtest_help_test_ test gtest_main)
 288   py_test(gtest_help_test)
 289
 290   cxx_executable(googletest-list-tests-unittest_ test gtest)
 291   py_test(googletest-list-tests-unittest)
 292
 293   cxx_executable(googletest-output-test_ test gtest)
 294   py_test(googletest-output-test --no_stacktrace_support)
 295
 296   cxx_executable(googletest-shuffle-test_ test gtest)
 297   py_test(googletest-shuffle-test)
 298
 299   # MSVC 7.1 does not support STL with exceptions disabled.
 300   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 301     cxx_executable(googletest-throw-on-failure-test_ test gtest_no_exception)
 302     set_target_properties(googletest-throw-on-failure-test_
 303       PROPERTIES
 304       COMPILE_FLAGS "${cxx_no_exception}")
 305     py_test(googletest-throw-on-failure-test)
 306   endif()
 307
 308   cxx_executable(googletest-uninitialized-test_ test gtest)
 309   py_test(googletest-uninitialized-test)
 310
 311   cxx_executable(gtest_list_output_unittest_ test gtest)
 312   py_test(gtest_list_output_unittest)
 313
 314   cxx_executable(gtest_xml_outfile1_test_ test gtest_main)
 315   cxx_executable(gtest_xml_outfile2_test_ test gtest_main)
 316   py_test(gtest_xml_outfiles_test)
 317   py_test(googletest-json-outfiles-test)
 318
 319   cxx_executable(gtest_xml_output_unittest_ test gtest)
 320   py_test(gtest_xml_output_unittest --no_stacktrace_support)
 321   py_test(googletest-json-output-unittest --no_stacktrace_support)
 322 endif()