cmake/internal_utils.cmake

   1 # Defines functions and macros useful for building Google Test and
   2 # Google Mock.
   3 #
   4 # Note:
   5 #
   6 # - This file will be run twice when building Google Mock (once via
   7 #   Google Test's CMakeLists.txt, and once via Google Mock's).
   8 #   Therefore it shouldn't have any side effects other than defining
   9 #   the functions and macros.
  10 #
  11 # - The functions/macros defined in this file may depend on Google
  12 #   Test and Google Mock's option() definitions, and thus must be
  13 #   called *after* the options have been defined.
  14
  15 # Tweaks CMake's default compiler/linker settings to suit Google Test's needs.
  16 #
  17 # This must be a macro(), as inside a function string() can only
  18 # update variables in the function scope.
  19 macro(fix_default_compiler_settings_)
  20   if (MSVC)
  21     # For MSVC, CMake sets certain flags to defaults we want to override.
  22     # This replacement code is taken from sample in the CMake Wiki at
  23     # http://www.cmake.org/Wiki/CMake_FAQ#Dynamic_Replace.
  24     foreach (flag_var
  25              CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
  26              CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
  27       if (NOT BUILD_SHARED_LIBS AND NOT gtest_force_shared_crt)
  28         # When Google Test is built as a shared library, it should also use
  29         # shared runtime libraries.  Otherwise, it may end up with multiple
  30         # copies of runtime library data in different modules, resulting in
  31         # hard-to-find crashes. When it is built as a static library, it is
  32         # preferable to use CRT as static libraries, as we don't have to rely
  33         # on CRT DLLs being available. CMake always defaults to using shared
  34         # CRT libraries, so we override that default here.
  35         string(REPLACE "/MD" "-MT" ${flag_var} "${${flag_var}}")
  36       endif()
  37
  38       # We prefer more strict warning checking for building Google Test.
  39       # Replaces /W3 with /W4 in defaults.
  40       string(REPLACE "/W3" "/W4" ${flag_var} "${${flag_var}}")
  41     endforeach()
  42   endif()
  43 endmacro()
  44
  45 # Defines the compiler/linker flags used to build Google Test and
  46 # Google Mock.  You can tweak these definitions to suit your need.  A
  47 # variable's value is empty before it's explicitly assigned to.
  48 macro(config_compiler_and_linker)
  49   if (NOT gtest_disable_pthreads)
  50     # Defines CMAKE_USE_PTHREADS_INIT and CMAKE_THREAD_LIBS_INIT.
  51     find_package(Threads)
  52   endif()
  53
  54   fix_default_compiler_settings_()
  55   if (MSVC)
  56     # Newlines inside flags variables break CMake's NMake generator.
  57     # TODO(vladl@google.com): Add -RTCs and -RTCu to debug builds.
  58     set(cxx_base_flags "-GS -W4 -WX -wd4251 -wd4275 -nologo -J -Zi")
  59     if (MSVC_VERSION LESS 1400)  # 1400 is Visual Studio 2005
  60       # Suppress spurious warnings MSVC 7.1 sometimes issues.
  61       # Forcing value to bool.
  62       set(cxx_base_flags "${cxx_base_flags} -wd4800")
  63       # Copy constructor and assignment operator could not be generated.
  64       set(cxx_base_flags "${cxx_base_flags} -wd4511 -wd4512")
  65       # Compatibility warnings not applicable to Google Test.
  66       # Resolved overload was found by argument-dependent lookup.
  67       set(cxx_base_flags "${cxx_base_flags} -wd4675")
  68     endif()
  69     if (MSVC_VERSION LESS 1500)  # 1500 is Visual Studio 2008
  70       # Conditional expression is constant.
  71       # When compiling with /W4, we get several instances of C4127
  72       # (Conditional expression is constant). In our code, we disable that
  73       # warning on a case-by-case basis. However, on Visual Studio 2005,
  74       # the warning fires on std::list. Therefore on that compiler and earlier,
  75       # we disable the warning project-wide.
  76       set(cxx_base_flags "${cxx_base_flags} -wd4127")
  77     endif()
  78     if (NOT (MSVC_VERSION LESS 1700))  # 1700 is Visual Studio 2012.
  79       # Suppress "unreachable code" warning on VS 2012 and later.
  80       # http://stackoverflow.com/questions/3232669 explains the issue.
  81       set(cxx_base_flags "${cxx_base_flags} -wd4702")
  82     endif()
  83     if (NOT (MSVC_VERSION GREATER 1900))  # 1900 is Visual Studio 2015
  84       # BigObj required for tests.
  85       set(cxx_base_flags "${cxx_base_flags} -bigobj")
  86     endif()
  87
  88     set(cxx_base_flags "${cxx_base_flags} -D_UNICODE -DUNICODE -DWIN32 -D_WIN32")
  89     set(cxx_base_flags "${cxx_base_flags} -DSTRICT -DWIN32_LEAN_AND_MEAN")
  90     set(cxx_exception_flags "-EHsc -D_HAS_EXCEPTIONS=1")
  91     set(cxx_no_exception_flags "-D_HAS_EXCEPTIONS=0")
  92     set(cxx_no_rtti_flags "-GR-")
  93   elseif (CMAKE_COMPILER_IS_GNUCXX)
  94     set(cxx_base_flags "-Wall -Wshadow")
  95     set(cxx_exception_flags "-fexceptions")
  96     set(cxx_no_exception_flags "-fno-exceptions")
  97     # Until version 4.3.2, GCC doesn't define a macro to indicate
  98     # whether RTTI is enabled.  Therefore we define GTEST_HAS_RTTI
  99     # explicitly.
 100     set(cxx_no_rtti_flags "-fno-rtti -DGTEST_HAS_RTTI=0")
 101     set(cxx_strict_flags
 102       "-Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
 103   elseif (CMAKE_CXX_COMPILER_ID STREQUAL "SunPro")
 104     set(cxx_exception_flags "-features=except")
 105     # Sun Pro doesn't provide macros to indicate whether exceptions and
 106     # RTTI are enabled, so we define GTEST_HAS_* explicitly.
 107     set(cxx_no_exception_flags "-features=no%except -DGTEST_HAS_EXCEPTIONS=0")
 108     set(cxx_no_rtti_flags "-features=no%rtti -DGTEST_HAS_RTTI=0")
 109   elseif (CMAKE_CXX_COMPILER_ID STREQUAL "VisualAge" OR
 110       CMAKE_CXX_COMPILER_ID STREQUAL "XL")
 111     # CMake 2.8 changes Visual Age's compiler ID to "XL".
 112     set(cxx_exception_flags "-qeh")
 113     set(cxx_no_exception_flags "-qnoeh")
 114     # Until version 9.0, Visual Age doesn't define a macro to indicate
 115     # whether RTTI is enabled.  Therefore we define GTEST_HAS_RTTI
 116     # explicitly.
 117     set(cxx_no_rtti_flags "-qnortti -DGTEST_HAS_RTTI=0")
 118   elseif (CMAKE_CXX_COMPILER_ID STREQUAL "HP")
 119     set(cxx_base_flags "-AA -mt")
 120     set(cxx_exception_flags "-DGTEST_HAS_EXCEPTIONS=1")
 121     set(cxx_no_exception_flags "+noeh -DGTEST_HAS_EXCEPTIONS=0")
 122     # RTTI can not be disabled in HP aCC compiler.
 123     set(cxx_no_rtti_flags "")
 124   endif()
 125
 126   if (CMAKE_USE_PTHREADS_INIT)  # The pthreads library is available and allowed.
 127     set(cxx_base_flags "${cxx_base_flags} -DGTEST_HAS_PTHREAD=1")
 128   else()
 129     set(cxx_base_flags "${cxx_base_flags} -DGTEST_HAS_PTHREAD=0")
 130   endif()
 131
 132   # For building gtest's own tests and samples.
 133   set(cxx_exception "${CMAKE_CXX_FLAGS} ${cxx_base_flags} ${cxx_exception_flags}")
 134   set(cxx_no_exception
 135     "${CMAKE_CXX_FLAGS} ${cxx_base_flags} ${cxx_no_exception_flags}")
 136   set(cxx_default "${cxx_exception}")
 137   set(cxx_no_rtti "${cxx_default} ${cxx_no_rtti_flags}")
 138   set(cxx_use_own_tuple "${cxx_default} -DGTEST_USE_OWN_TR1_TUPLE=1")
 139
 140   # For building the gtest libraries.
 141   set(cxx_strict "${cxx_default} ${cxx_strict_flags}")
 142 endmacro()
 143
 144 # Defines the gtest & gtest_main libraries.  User tests should link
 145 # with one of them.
 146 function(cxx_library_with_type name type cxx_flags)
 147   # type can be either STATIC or SHARED to denote a static or shared library.
 148   # ARGN refers to additional arguments after 'cxx_flags'.
 149   add_library(${name} ${type} ${ARGN})
 150   set_target_properties(${name}
 151     PROPERTIES
 152     COMPILE_FLAGS "${cxx_flags}")
 153   if (BUILD_SHARED_LIBS OR type STREQUAL "SHARED")
 154     set_target_properties(${name}
 155       PROPERTIES
 156       COMPILE_DEFINITIONS "GTEST_CREATE_SHARED_LIBRARY=1")
 157   endif()
 158   if (CMAKE_USE_PTHREADS_INIT)
 159     target_link_libraries(${name} ${CMAKE_THREAD_LIBS_INIT})
 160   endif()
 161 endfunction()
 162
 163 ########################################################################
 164 #
 165 # Helper functions for creating build targets.
 166
 167 function(cxx_shared_library name cxx_flags)
 168   cxx_library_with_type(${name} SHARED "${cxx_flags}" ${ARGN})
 169 endfunction()
 170
 171 function(cxx_library name cxx_flags)
 172   cxx_library_with_type(${name} "" "${cxx_flags}" ${ARGN})
 173 endfunction()
 174
 175 # cxx_executable_with_flags(name cxx_flags libs srcs...)
 176 #
 177 # creates a named C++ executable that depends on the given libraries and
 178 # is built from the given source files with the given compiler flags.
 179 function(cxx_executable_with_flags name cxx_flags libs)
 180   add_executable(${name} ${ARGN})
 181   if (cxx_flags)
 182     set_target_properties(${name}
 183       PROPERTIES
 184       COMPILE_FLAGS "${cxx_flags}")
 185   endif()
 186   if (BUILD_SHARED_LIBS)
 187     set_target_properties(${name}
 188       PROPERTIES
 189       COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
 190   endif()
 191   # To support mixing linking in static and dynamic libraries, link each
 192   # library in with an extra call to target_link_libraries.
 193   foreach (lib "${libs}")
 194     target_link_libraries(${name} ${lib})
 195   endforeach()
 196 endfunction()
 197
 198 # cxx_executable(name dir lib srcs...)
 199 #
 200 # creates a named target that depends on the given libs and is built
 201 # from the given source files.  dir/name.cc is implicitly included in
 202 # the source file list.
 203 function(cxx_executable name dir libs)
 204   cxx_executable_with_flags(
 205     ${name} "${cxx_default}" "${libs}" "${dir}/${name}.cc" ${ARGN})
 206 endfunction()
 207
 208 # Sets PYTHONINTERP_FOUND and PYTHON_EXECUTABLE.
 209 find_package(PythonInterp)
 210
 211 # cxx_test_with_flags(name cxx_flags libs srcs...)
 212 #
 213 # creates a named C++ test that depends on the given libs and is built
 214 # from the given source files with the given compiler flags.
 215 function(cxx_test_with_flags name cxx_flags libs)
 216   cxx_executable_with_flags(${name} "${cxx_flags}" "${libs}" ${ARGN})
 217   add_test(${name} ${name})
 218 endfunction()
 219
 220 # cxx_test(name libs srcs...)
 221 #
 222 # creates a named test target that depends on the given libs and is
 223 # built from the given source files.  Unlike cxx_test_with_flags,
 224 # test/name.cc is already implicitly included in the source file list.
 225 function(cxx_test name libs)
 226   cxx_test_with_flags("${name}" "${cxx_default}" "${libs}"
 227     "test/${name}.cc" ${ARGN})
 228 endfunction()
 229
 230 # py_test(name)
 231 #
 232 # creates a Python test with the given name whose main module is in
 233 # test/name.py.  It does nothing if Python is not installed.
 234 function(py_test name)
 235   # We are not supporting Python tests on Linux yet as they consider
 236   # all Linux environments to be google3 and try to use google3 features.
 237   if (PYTHONINTERP_FOUND)
 238     # ${CMAKE_BINARY_DIR} is known at configuration time, so we can
 239     # directly bind it from cmake. ${CTEST_CONFIGURATION_TYPE} is known
 240     # only at ctest runtime (by calling ctest -c <Configuration>), so
 241     # we have to escape $ to delay variable substitution here.
 242     if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 3.1)
 243       add_test(
 244         NAME ${name}
 245         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test/${name}.py
 246             --build_dir=${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>)
 247     else (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 3.1)
 248       add_test(
 249         ${name}
 250         ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test/${name}.py
 251           --build_dir=${CMAKE_CURRENT_BINARY_DIR}/\${CTEST_CONFIGURATION_TYPE})
 252     endif (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 3.1)
 253   endif()
 254 endfunction()