subprojects/gst-plugins-good/meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.21.1',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21 if have_cxx
  22   cxx = meson.get_compiler('cpp')
  23 endif
  24
  25 glib_req = '>= 2.62.0'
  26 orc_req = '>= 0.4.17'
  27
  28 if gst_version_is_stable
  29   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30 else
  31   gst_req = '>= ' + gst_version
  32 endif
  33
  34 api_version = '1.0'
  35
  36 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  37 plugins = []
  38 static_build = get_option('default_library') == 'static'
  39
  40 cc = meson.get_compiler('c')
  41 host_system = host_machine.system()
  42
  43 if cc.get_id() == 'msvc'
  44   msvc_args = [
  45       # Ignore several spurious warnings for things gstreamer does very commonly
  46       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  47       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  48       # NOTE: Only add warnings here if you are sure they're spurious
  49       '/wd4018', # implicit signed/unsigned conversion
  50       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  51       '/wd4244', # lossy type conversion (e.g. double -> int)
  52       '/wd4305', # truncating type conversion (e.g. double -> float)
  53       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  54   ]
  55
  56   if gst_version_is_dev
  57     # Enable some warnings on MSVC to match GCC/Clang behaviour
  58     msvc_args += cc.get_supported_arguments([
  59       '/we4002', # too many actual parameters for macro 'identifier'
  60       '/we4003', # not enough actual parameters for macro 'identifier'
  61       '/we4013', # 'function' undefined; assuming extern returning int
  62       '/we4020', # 'function' : too many actual parameters
  63       '/we4027', # function declared without formal parameter list
  64       '/we4029', # declared formal parameter list different from definition
  65       '/we4033', # 'function' must return a value
  66       '/we4045', # 'array' : array bounds overflow
  67       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  68       '/we4053', # one void operand for '?:'
  69       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  70       '/we4098', # 'function' : void function returning a value
  71       '/we4101', # 'identifier' : unreferenced local variable
  72       '/we4189', # 'identifier' : local variable is initialized but not referenced
  73     ])
  74   endif
  75   if have_cxx
  76     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  77   else
  78     add_project_arguments(msvc_args, language: 'c')
  79   endif
  80   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  81   # are built with MinGW
  82   noseh_link_args = ['/SAFESEH:NO']
  83 else
  84   noseh_link_args = []
  85 endif
  86
  87 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  88   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  89 endif
  90 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  91   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  92 endif
  93
  94 # glib doesn't support unloading, which means that unloading and reloading
  95 # any library that registers static types will fail
  96 if cc.has_link_argument('-Wl,-z,nodelete')
  97   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  98 endif
  99 if have_cxx and cxx.has_link_argument('-Wl,-z,nodelete')
 100   add_project_link_arguments('-Wl,-z,nodelete', language: 'cpp')
 101 endif
 102
 103 # Symbol visibility
 104 if cc.has_argument('-fvisibility=hidden')
 105   add_project_arguments('-fvisibility=hidden', language: 'c')
 106 endif
 107
 108 # Disable strict aliasing
 109 if cc.has_argument('-fno-strict-aliasing')
 110   add_project_arguments('-fno-strict-aliasing', language: 'c')
 111 endif
 112
 113 # Define G_DISABLE_DEPRECATED for development versions
 114 if gst_version_is_dev
 115   message('Disabling deprecated GLib API')
 116   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 117 endif
 118
 119 cast_checks = get_option('gobject-cast-checks')
 120 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 121   message('Disabling GLib cast checks')
 122   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 123 endif
 124
 125 glib_asserts = get_option('glib-asserts')
 126 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 127   message('Disabling GLib asserts')
 128   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 129 endif
 130
 131 glib_checks = get_option('glib-checks')
 132 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 133   message('Disabling GLib checks')
 134   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 135 endif
 136
 137 cdata = configuration_data()
 138 cdata.set('ENABLE_NLS', 1)
 139
 140 check_headers = [
 141   ['HAVE_DLFCN_H', 'dlfcn.h'],
 142   ['HAVE_FCNTL_H', 'fcntl.h'],
 143   ['HAVE_INTTYPES_H', 'inttypes.h'],
 144   ['HAVE_MEMORY_H', 'memory.h'],
 145   ['HAVE_PROCESS_H', 'process.h'],
 146   ['HAVE_STDINT_H', 'stdint.h'],
 147   ['HAVE_STDLIB_H', 'stdlib.h'],
 148   ['HAVE_STRINGS_H', 'strings.h'],
 149   ['HAVE_STRING_H', 'string.h'],
 150   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
 151   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 152   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 153   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 154   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 155   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 156   ['HAVE_UNISTD_H', 'unistd.h'],
 157 ]
 158
 159 foreach h : check_headers
 160   if cc.has_header(h.get(1))
 161     cdata.set(h.get(0), 1)
 162   endif
 163 endforeach
 164
 165 check_functions = [
 166   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 167   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 168   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 169 # check token HAVE_CPU_ALPHA
 170 # check token HAVE_CPU_ARM
 171 # check token HAVE_CPU_CRIS
 172 # check token HAVE_CPU_CRISV32
 173 # check token HAVE_CPU_HPPA
 174 # check token HAVE_CPU_I386
 175 # check token HAVE_CPU_IA64
 176 # check token HAVE_CPU_M68K
 177 # check token HAVE_CPU_MIPS
 178 # check token HAVE_CPU_PPC
 179 # check token HAVE_CPU_PPC64
 180 # check token HAVE_CPU_S390
 181 # check token HAVE_CPU_SPARC
 182 # check token HAVE_CPU_X86_64
 183   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 184 # check token HAVE_DIRECTSOUND
 185 # check token HAVE_EXPERIMENTAL
 186 # check token HAVE_EXTERNAL
 187 # check token HAVE_FPCLASS
 188 # check token HAVE_GCC_ASM
 189   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 190 # check token HAVE_GETTEXT
 191 # check token HAVE_GST_V4L2
 192   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 193 # check token HAVE_LIBV4L2
 194   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 195   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 196 # check token HAVE_OSX_AUDIO
 197 # check token HAVE_OSX_VIDEO
 198 # check token HAVE_RDTSC
 199   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 200 # check token HAVE_WAVEFORM
 201   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 202 ]
 203
 204 libm = cc.find_library('m', required : false)
 205
 206 foreach f : check_functions
 207   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 208     cdata.set(f.get(0), 1)
 209   endif
 210 endforeach
 211
 212 cdata.set('HAVE_IOS', host_system == 'ios')
 213
 214 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 215 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 216 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 217 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 218 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 219 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 220
 221 have_rtld_noload = cc.has_header_symbol('dlfcn.h', 'RTLD_NOLOAD')
 222 cdata.set('HAVE_RTLD_NOLOAD', have_rtld_noload)
 223
 224 # Here be fixmes.
 225 # FIXME: check if this is correct
 226 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 227 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 228 cdata.set_quoted('VERSION', gst_version)
 229 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 230 cdata.set_quoted('GST_LICENSE', 'LGPL')
 231 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 232 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 233 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 234
 235 warning_flags = [
 236   '-Wmissing-declarations',
 237   '-Wredundant-decls',
 238   '-Wwrite-strings',
 239   '-Winit-self',
 240   '-Wmissing-include-dirs',
 241   '-Wno-multichar',
 242   '-Wvla',
 243   '-Wpointer-arith',
 244 ]
 245
 246 warning_c_flags = [
 247   '-Wmissing-prototypes',
 248   '-Wold-style-definition',
 249   '-Waggregate-return',
 250 ]
 251
 252 foreach extra_arg : warning_flags
 253   if cc.has_argument (extra_arg)
 254     add_project_arguments([extra_arg], language: 'c')
 255   endif
 256   if have_cxx and cxx.has_argument (extra_arg)
 257     add_project_arguments([extra_arg], language: 'cpp')
 258   endif
 259 endforeach
 260
 261 foreach extra_arg : warning_c_flags
 262   if cc.has_argument (extra_arg)
 263     add_project_arguments([extra_arg], language: 'c')
 264   endif
 265 endforeach
 266
 267 # GStreamer package name and origin url
 268 gst_package_name = get_option('package-name')
 269 if gst_package_name == ''
 270   if gst_version_nano == 0
 271     gst_package_name = 'GStreamer Good Plug-ins source release'
 272   elif gst_version_nano == 1
 273     gst_package_name = 'GStreamer Good Plug-ins git'
 274   else
 275     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 276   endif
 277 endif
 278 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 279 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 280
 281 # Mandatory GST deps
 282 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 283   fallback : ['gstreamer', 'gst_dep'])
 284 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 285   fallback : ['gstreamer', 'gst_base_dep'])
 286 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 287   fallback : ['gstreamer', 'gst_net_dep'])
 288 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 289   fallback : ['gstreamer', 'gst_controller_dep'])
 290 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 291   required : get_option('tests'),
 292   fallback : ['gstreamer', 'gst_check_dep'])
 293 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 294     fallback : ['gst-plugins-base', 'pbutils_dep'])
 295 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 296     fallback : ['gst-plugins-base', 'allocators_dep'])
 297 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 298     fallback : ['gst-plugins-base', 'app_dep'])
 299 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 300     fallback : ['gst-plugins-base', 'audio_dep'])
 301 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 302     fallback : ['gst-plugins-base', 'fft_dep'])
 303 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 304     fallback : ['gst-plugins-base', 'riff_dep'])
 305 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 306     fallback : ['gst-plugins-base', 'rtp_dep'])
 307 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 308     fallback : ['gst-plugins-base', 'rtsp_dep'])
 309 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 310     fallback : ['gst-plugins-base', 'sdp_dep'])
 311 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 312     fallback : ['gst-plugins-base', 'tag_dep'])
 313 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 314     fallback : ['gst-plugins-base', 'video_dep'])
 315
 316 # GStreamer OpenGL
 317 # FIXME: automagic
 318 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 319     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 320 gstglproto_dep = dependency('', required : false)
 321 gstglx11_dep = dependency('', required : false)
 322 gstglwayland_dep = dependency('', required : false)
 323 gstglegl_dep = dependency('', required : false)
 324
 325 have_gstgl = gstgl_dep.found()
 326
 327 if have_gstgl
 328   if gstgl_dep.type_name() == 'pkgconfig'
 329     gst_gl_apis = gstgl_dep.get_variable('gl_apis').split()
 330     gst_gl_winsys = gstgl_dep.get_variable('gl_winsys').split()
 331     gst_gl_platforms = gstgl_dep.get_variable('gl_platforms').split()
 332   else
 333     gstbase = subproject('gst-plugins-base')
 334     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 335     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 336     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 337   endif
 338
 339   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 340   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 341   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 342
 343   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 344     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 345   endforeach
 346
 347   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 348     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 349   endforeach
 350
 351   foreach api : ['gl', 'gles2']
 352     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 353   endforeach
 354
 355   gstglproto_dep = dependency('gstreamer-gl-prototypes-1.0', version : gst_req,
 356       fallback : ['gst-plugins-base', 'gstglproto_dep'], required: true)
 357   # Behind specific checks because meson fails at optional dependencies with a
 358   # fallback to the same subproject.  On the first failure, meson will never
 359   # check the system again even if the fallback never existed.
 360   # Last checked with meson 0.54.3
 361   if gst_gl_have_window_x11
 362     gstglx11_dep = dependency('gstreamer-gl-x11-1.0', version : gst_req,
 363        fallback : ['gst-plugins-base', 'gstglx11_dep'], required: true)
 364   endif
 365   if gst_gl_have_window_wayland
 366     gstglwayland_dep = dependency('gstreamer-gl-wayland-1.0', version : gst_req,
 367         fallback : ['gst-plugins-base', 'gstglwayland_dep'], required: true)
 368   endif
 369   if gst_gl_have_platform_egl
 370     gstglegl_dep = dependency('gstreamer-gl-egl-1.0', version : gst_req,
 371         fallback : ['gst-plugins-base', 'gstglegl_dep'], required: true)
 372   endif
 373 endif
 374
 375 zlib_dep = dependency('zlib')
 376 cdata.set('HAVE_ZLIB', true)
 377
 378 gio_dep = dependency('gio-2.0', version: glib_req)
 379 gmodule_dep = dependency('gmodule-no-export-2.0')
 380
 381 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 382 configinc = include_directories('.')
 383 libsinc = include_directories('gst-libs')
 384
 385 have_orcc = false
 386 orcc_args = []
 387 orc_targets = []
 388 # Used by various libraries/elements that use Orc code
 389 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 390     fallback : ['orc', 'orc_dep'])
 391 orcc = find_program('orcc', required : get_option('orc'))
 392 if orc_dep.found() and orcc.found()
 393   have_orcc = true
 394   orcc_args = [orcc, '--include', 'glib.h']
 395   cdata.set('HAVE_ORC', 1)
 396 else
 397   message('Orc Compiler not found, will use backup C code')
 398   cdata.set('DISABLE_ORC', 1)
 399 endif
 400
 401 have_nasm = false
 402 # FIXME: nasm path needs testing on non-Linux, esp. Windows
 403 host_cpu = host_machine.cpu_family()
 404 if host_cpu == 'x86_64'
 405   if cc.get_define('__ILP32__') == '1'
 406     message('Nasm disabled on x32')
 407   else
 408     asm_option = get_option('asm')
 409     nasm = find_program('nasm', native: true, required: asm_option)
 410     if nasm.found()
 411       # We can't use the version: kwarg for find_program because old versions
 412       # of nasm don't support --version
 413       ret = run_command(nasm, '-v', check: false)
 414       if ret.returncode() == 0
 415         nasm_version = ret.stdout().strip().split()[2]
 416         nasm_req = '>=2.13'
 417         if nasm_version.version_compare(nasm_req)
 418           message('nasm found on x86-64')
 419           cdata.set('HAVE_NASM', 1)
 420           have_nasm = true
 421         else
 422           if asm_option.enabled()
 423             error('asm option is enabled, and nasm @0@ was found, but @1@ is required'.format(nasm_version, nasm_req))
 424           endif
 425           message('nasm @0@ was found, but @1@ is required'.format(nasm_version, nasm_req))
 426         endif
 427       else
 428         if asm_option.enabled()
 429           error('asm option is enabled, but nasm is not usable: @0@\n@1@'.format(ret.stdout(), ret.stderr()))
 430         endif
 431         message('nasm was found, but it\'s not usable')
 432       endif
 433       # Unset nasm to not be 'found'
 434       if not have_nasm
 435         nasm = disabler()
 436       endif
 437     endif
 438   endif
 439 endif
 440
 441 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 442 if gst_dep.type_name() == 'internal'
 443   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 444 else
 445   # We can't check that in the case of subprojects as we won't
 446   # be able to build against an internal dependency (which is not built yet)
 447   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 448 endif
 449
 450 if gst_debug_disabled
 451   message('GStreamer debug system is disabled')
 452   if cc.has_argument('-Wno-unused')
 453     add_project_arguments('-Wno-unused', language: 'c')
 454   endif
 455   if have_cxx and cxx.has_argument ('-Wno-unused')
 456     add_project_arguments('-Wno-unused', language: 'cpp')
 457   endif
 458 else
 459   message('GStreamer debug system is enabled')
 460 endif
 461
 462 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 463
 464 python3 = import('python').find_installation()
 465 pkgconfig = import('pkgconfig')
 466 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 467 if get_option('default_library') == 'shared'
 468   # If we don't build static plugins there is no need to generate pc files
 469   plugins_pkgconfig_install_dir = disabler()
 470 endif
 471
 472 subdir('gst')
 473 subdir('sys')
 474 subdir('ext')
 475 subdir('tests')
 476 subdir('docs')
 477
 478 if have_orcc and orc_targets.length() > 0
 479   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 480
 481   orc_update_targets = []
 482   foreach t : orc_targets
 483     orc_name = t.get('name')
 484     orc_file = t.get('orc-source')
 485     header = t.get('header')
 486     source = t.get('source')
 487     # alias_target() only works with build targets, so can't use run_target() here
 488     orc_update_targets += [
 489       custom_target('update-orc-@0@'.format(orc_name),
 490         input: [header, source],
 491         command: [update_orc_dist_files, orc_file, header, source],
 492         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 493     ]
 494   endforeach
 495
 496   if orc_update_targets.length() > 0
 497     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 498   endif
 499 endif
 500
 501 # xgettext is optional (on Windows for instance)
 502 if find_program('xgettext', required : get_option('nls')).found()
 503   subdir('po')
 504 endif
 505
 506 subdir('scripts')
 507
 508 # Set release date
 509 if gst_version_nano == 0
 510   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 511   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-good.doap'), check: true)
 512   release_date = run_result.stdout().strip()
 513   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 514   message('Package release date: ' + release_date)
 515 endif
 516
 517 if gio_dep.version().version_compare('< 2.67.4')
 518   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 519 endif
 520
 521 configure_file(output : 'config.h', configuration : cdata)
 522
 523 plugin_names = []
 524 gst_plugins = []
 525 foreach plugin: plugins
 526   # gstsoup is a special case because of the way we build the static/dynamic libraries
 527   if plugin.name() not in ['gstsoup', 'gstadaptivedemux2']
 528     pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 529   endif
 530   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 531   meson.override_dependency(plugin.name(), dep)
 532   gst_plugins += [dep]
 533   if plugin.name().startswith('gst')
 534     plugin_names += [plugin.name().substring(3)]
 535   else
 536     plugin_names += [plugin.name()]
 537   endif
 538 endforeach
 539
 540 summary({
 541     'Plugins': plugin_names,
 542 }, list_sep: ', ')