configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [9])
   5 m4_define([gst_vaapi_pre_version],   [0])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # gstreamer-vaapi library (libtool) version number
  13 m4_define([gst_vaapi_lt_current],       [5])
  14 m4_define([gst0_vaapi_lt_current_bias], [0])
  15 m4_define([gst1_vaapi_lt_current_bias], [2])
  16 m4_define([gst2_vaapi_lt_current_bias], [4])
  17 m4_define([gst4_vaapi_lt_current_bias], [5])
  18 m4_define([gst6_vaapi_lt_current_bias], [5])
  19 m4_define([gst_vaapi_lt_revision],      [0])
  20 m4_define([gst_vaapi_lt_age],           [0])
  21
  22 # glib version number
  23 m4_define([glib_version], [2.28])
  24
  25 # gstreamer version number
  26 m4_define([gst_api_version],            [autodetect])
  27 m4_define([gst0_version],               [0.10.36])
  28 m4_define([gst0_plugins_base_version],  [0.10.31])
  29 m4_define([gst0_plugins_bad_version],   [0.10.22])
  30 m4_define([gst1_version],               [1.0.0])
  31 m4_define([gst1_plugins_base_version],  [1.0.0])
  32 m4_define([gst1_plugins_bad_version],   [1.0.0])
  33 m4_define([gst12_version],              [1.1.90])
  34 m4_define([gst12_plugins_base_version], [1.1.0])
  35 m4_define([gst12_plugins_bad_version],  [1.1.0])
  36 m4_define([gst14_version],              [1.2.90])
  37 m4_define([gst14_plugins_base_version], [1.3.0])
  38 m4_define([gst14_plugins_bad_version],  [1.3.0])
  39 m4_define([gst16_version],              [1.5.0])
  40 m4_define([gst16_plugins_base_version], [1.5.0])
  41 m4_define([gst16_plugins_bad_version],  [1.5.0])
  42
  43 # Wayland minimum version number
  44 m4_define([wayland_api_version], [1.0.0])
  45
  46 # VA-API minimum version number
  47 m4_define([va_api_version],     [0.30.4])
  48 m4_define([va_api_enc_version], [0.34.0])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_glx_version], [0.32.0])
  52 m4_define([va_api_wld_version], [0.33.0])
  53
  54 # libva package version number
  55 m4_define([libva_enc_package_version], [1.2.0])
  56 m4_define([libva_drm_package_version], [1.1.0])
  57 m4_define([libva_x11_package_version], [1.0.3])
  58 m4_define([libva_glx_package_version], [1.0.9])
  59 m4_define([libva_wld_package_version], [1.1.0])
  60
  61 # gtk-doc version number
  62 # XXX: introspection annotations require gtk-doc >= 1.12
  63 m4_define([gtkdoc_version], [1.9])
  64
  65 AC_PREREQ([2.66])
  66 AC_INIT([gst_vaapi], [gst_vaapi_version],
  67     [gwenole.beauchesne@intel.com],
  68     [gstreamer-vaapi])
  69
  70 AC_CONFIG_HEADERS([config.h])
  71 AC_CONFIG_SRCDIR([Makefile.am])
  72 AC_CONFIG_MACRO_DIR([m4])
  73 AC_CONFIG_AUX_DIR([build-aux])
  74
  75 AC_CANONICAL_TARGET
  76
  77 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  78
  79 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  80 AC_SUBST(TODAY)
  81
  82 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  83 AC_SUBST(LIBVA_PACKAGE_VERSION)
  84
  85 WAYLAND_API_VERSION=wayland_api_version
  86 AC_SUBST(WAYLAND_API_VERSION)
  87
  88 dnl Use pretty build output with automake >= 1.11
  89 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  90   AM_DEFAULT_VERBOSITY=1
  91   AC_SUBST(AM_DEFAULT_VERBOSITY)
  92 ])
  93
  94 dnl Check for tools
  95 AC_PROG_CC
  96 AM_PROG_CC_C_O
  97
  98 AC_ARG_VAR([GIT], [Path to git program, if any])
  99 AC_PATH_PROG([GIT], [git])
 100 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
 101
 102 AC_ARG_VAR([YASM], [Path to yasm program, if any])
 103 AC_PATH_PROG([YASM], [yasm])
 104 if test -z "$YASM" -a "$enable_builtin_libvpx" = "yes"; then
 105     AC_MSG_ERROR([yasm is needed to build libvpx sources])
 106 fi
 107
 108 dnl Initialize libtool
 109 LT_PREREQ([2.2])
 110 LT_INIT
 111
 112 AC_ARG_ENABLE(builtin_videoparsers,
 113     AS_HELP_STRING([--enable-builtin-videoparsers],
 114                    [enable built-in videoparsers @<:@default=yes@:>@]),
 115     [], [enable_builtin_videoparsers="yes"])
 116
 117 AC_ARG_ENABLE(builtin_codecparsers,
 118     AS_HELP_STRING([--enable-builtin-codecparsers],
 119                    [enable built-in codecparsers @<:@default=yes@:>@]),
 120     [], [enable_builtin_codecparsers="yes"])
 121
 122 AC_ARG_ENABLE(builtin_libvpx,
 123     AS_HELP_STRING([--enable-builtin-libvpx],
 124                    [enable built-in libvpx @<:@default=yes@:>@]),
 125     [], [enable_builtin_libvpx="yes"])
 126
 127 AC_ARG_ENABLE([encoders],
 128     AS_HELP_STRING([--enable-encoders],
 129                    [enable video encoders @<:@default=yes@:>@]),
 130     [], [enable_encoders="yes"])
 131
 132 AC_ARG_ENABLE(drm,
 133     AS_HELP_STRING([--enable-drm],
 134                    [enable DRM backend @<:@default=yes@:>@]),
 135     [], [enable_drm="yes"])
 136
 137 AC_ARG_ENABLE(x11,
 138     AS_HELP_STRING([--enable-x11],
 139                    [enable X11 output @<:@default=yes@:>@]),
 140     [], [enable_x11="yes"])
 141
 142 AC_ARG_ENABLE(glx,
 143     AS_HELP_STRING([--enable-glx],
 144                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 145     [], [enable_glx="yes"])
 146
 147 AC_ARG_ENABLE(wayland,
 148     AC_HELP_STRING([--enable-wayland],
 149                    [enable Wayland output @<:@default=yes@:>@]),
 150     [], [enable_wayland="yes"])
 151
 152 AC_ARG_WITH([gstreamer-api],
 153     AC_HELP_STRING([--with-gstreamer-api=VERSION],
 154                    [build against the specified GStreamer API version
 155                     @<:@default=gst_api_version@:>@]),
 156     [GST_API_VERSION="$with_gstreamer_api"], [GST_API_VERSION=gst_api_version])
 157
 158 dnl Check for basic libraries
 159 AC_CHECK_LIB(m, tan)
 160
 161 dnl Check for Gtk doc
 162 GTKDOC_VERSION=gtkdoc_version
 163 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 164 m4_ifdef([GTK_DOC_CHECK], [
 165 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 166 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 167 AC_SUBST(GTKDOC_VERSION)
 168
 169 dnl Check for GLib
 170 GLIB_VERSION_REQUIRED=glib_version
 171 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 172 AC_SUBST(GLIB_VERSION_REQUIRED)
 173
 174 dnl Check to see if dlopen is in default libraries (like Solaris, which
 175 dnl has it in libc), or if libdl is needed to get it.
 176 AC_CHECK_FUNC([dlopen], [], [
 177     AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 178 AC_SUBST([DLOPEN_LIBS])
 179
 180 dnl ---------------------------------------------------------------------------
 181 dnl -- GStreamer                                                             --
 182 dnl ---------------------------------------------------------------------------
 183
 184 dnl If GStreamer API version is to be autodetected, then always try
 185 dnl with the latest version first
 186 AC_MSG_CHECKING([for GStreamer API version])
 187 if test "$GST_API_VERSION" = "autodetect"; then
 188     gst_pkg_versions="1.0 0.10"
 189 else
 190     AS_VERSION_COMPARE([$GST_API_VERSION], [1.0],
 191         [gst_pkg_versions="0.10"], [gst_pkg_versions="1.0"],
 192         dnl GStreamer 1.2.x APIs don't have their own namespace
 193         [gst_pkg_versions="1.0"])
 194 fi
 195 for gst_pkg_version in ${gst_pkg_versions}; do
 196     if $PKG_CONFIG --exists "gstreamer-$gst_pkg_version"; then
 197         gst_version=`$PKG_CONFIG --modversion "gstreamer-$gst_pkg_version"`
 198         gst_major_version=`echo "$gst_version" | cut -d'.' -f1`
 199         gst_minor_version=`echo "$gst_version" | cut -d'.' -f2`
 200         GST_API_VERSION="${gst_major_version}.${gst_minor_version}"
 201         GST_PKG_VERSION="$gst_pkg_version"
 202         break
 203     fi
 204 done
 205 if test -z "$GST_PKG_VERSION"; then
 206     AC_MSG_ERROR([version $GST_API_VERSION not found])
 207 fi
 208 AC_MSG_RESULT([$GST_API_VERSION])
 209
 210 dnl Versions for GStreamer and plugins-base
 211 case $GST_API_VERSION in
 212 0.10)
 213     GST_VERSION_REQUIRED=gst0_version
 214     GST_PLUGINS_BASE_VERSION_REQUIRED=gst0_plugins_base_version
 215     GST_PLUGINS_BAD_VERSION_REQUIRED=gst0_plugins_bad_version
 216     ;;
 217 1.0)
 218     GST_VERSION_REQUIRED=gst1_version
 219     GST_PLUGINS_BASE_VERSION_REQUIRED=gst1_plugins_base_version
 220     GST_PLUGINS_BAD_VERSION_REQUIRED=gst1_plugins_bad_version
 221     ;;
 222 1.2)
 223     GST_VERSION_REQUIRED=gst12_version
 224     GST_PLUGINS_BASE_VERSION_REQUIRED=gst12_plugins_base_version
 225     GST_PLUGINS_BAD_VERSION_REQUIRED=gst12_plugins_bad_version
 226     ;;
 227 1.[[3-4]])
 228     GST_VERSION_REQUIRED=gst14_version
 229     GST_PLUGINS_BASE_VERSION_REQUIRED=gst14_plugins_base_version
 230     GST_PLUGINS_BAD_VERSION_REQUIRED=gst14_plugins_bad_version
 231     ;;
 232 1.5)
 233     GST_VERSION_REQUIRED=gst16_version
 234     GST_PLUGINS_BASE_VERSION_REQUIRED=gst16_plugins_base_version
 235     GST_PLUGINS_BAD_VERSION_REQUIRED=gst16_plugins_bad_version
 236     ;;
 237 *)
 238     AC_MSG_ERROR([unsupported GStreamer API version $GST_API_VERSION])
 239     ;;
 240 esac
 241 AC_SUBST(GST_API_VERSION)
 242 AC_SUBST(GST_VERSION_REQUIRED)
 243 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 244 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 245
 246 USE_GST_API_0_10="no"
 247 USE_GST_API_1_0p="no"
 248 USE_GST_API_1_2p="no"
 249 AS_VERSION_COMPARE([$GST_API_VERSION], [0.10],
 250     [], [USE_GST_API_0_10="yes"], [])
 251 AS_VERSION_COMPARE([$GST_API_VERSION], [1.0],
 252     [], [USE_GST_API_1_0p="yes"], [USE_GST_API_1_0p="yes"])
 253 AS_VERSION_COMPARE([$GST_API_VERSION], [1.2],
 254     [], [USE_GST_API_1_2p="yes"], [USE_GST_API_1_2p="yes"])
 255 AM_CONDITIONAL([USE_GST_API_0_10], [test "$USE_GST_API_0_10" = "yes"])
 256 AM_CONDITIONAL([USE_GST_API_1_0p], [test "$USE_GST_API_1_0p" = "yes"])
 257 AM_CONDITIONAL([USE_GST_API_1_2p], [test "$USE_GST_API_1_2p" = "yes"])
 258
 259 dnl GStreamer 1.2.x APIs don't have their own namespace
 260 GST_PKG_VERSION="$GST_API_VERSION"
 261 if test "$USE_GST_API_1_2p" = "yes"; then
 262     GST_PKG_VERSION="1.0"
 263 fi
 264 AC_SUBST([GST_PKG_VERSION])
 265
 266 dnl Validate certain features
 267 if test "$USE_GST_API_0_10" = "yes"; then
 268     AC_MSG_WARN([support for GStreamer 0.10 is obsolete, and will be removed])
 269     if test "$enable_builtin_videoparsers" = "yes"; then
 270         AC_MSG_WARN([disabled built-in videoparsers (unsupported)])
 271         enable_builtin_videoparsers="no"
 272     fi
 273 elif test "$USE_GST_API_1_2p" != "yes"; then
 274     AC_MSG_WARN([support for GStreamer < 1.2 is deprecated, please upgrade])
 275 fi
 276
 277 dnl GStreamer Core
 278 PKG_CHECK_MODULES([GST],
 279     [gstreamer-$GST_PKG_VERSION >= $GST_VERSION_REQUIRED])
 280 PKG_CHECK_MODULES([GST_BASE],
 281     [gstreamer-base-$GST_PKG_VERSION >= $GST_VERSION_REQUIRED])
 282
 283 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 284     saved_CPPFLAGS="$CPPFLAGS"
 285     CPPFLAGS="$CPPFLAGS $GST_BASE_CFLAGS"
 286     saved_LIBS="$LIBS"
 287     LIBS="$LIBS $GST_BASE_LIBS"
 288     AC_COMPILE_IFELSE(
 289         [AC_LANG_PROGRAM(
 290             [[#include <gst/base/gstbasesink.h>]],
 291             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 292         [ac_cv_have_gst_base_sink_query="yes"],
 293         [ac_cv_have_gst_base_sink_query="no"]
 294     )
 295     CPPFLAGS="$saved_CPPFLAGS"
 296     LIBS="$saved_LIBS"
 297 ])
 298 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 299     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 300 fi
 301
 302 dnl GStreamer -base plugins
 303 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 304     [gstreamer-plugins-base-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 305 if test "$GST_API_VERSION" = "0.10"; then
 306 PKG_CHECK_MODULES([GST_INTERFACES],
 307     [gstreamer-interfaces-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 308 fi
 309
 310 dnl ... GstVideoOverlayComposition (gstreamer-video)
 311 PKG_CHECK_MODULES([GST_VIDEO],
 312     [gstreamer-video-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 313
 314 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 315     ac_cv_have_gst_video_overlay_composition, [
 316     saved_CPPFLAGS="$CPPFLAGS"
 317     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 318     saved_LIBS="$LIBS"
 319     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 320     AC_COMPILE_IFELSE(
 321         [AC_LANG_PROGRAM(
 322             [[#include <gst/video/video-overlay-composition.h>]],
 323             [[GstVideoOverlayComposition *c;
 324               c = gst_video_overlay_composition_new(0);]])],
 325         [ac_cv_have_gst_video_overlay_composition="yes"],
 326         [ac_cv_have_gst_video_overlay_composition="no"]
 327     )
 328     CPPFLAGS="$saved_CPPFLAGS"
 329     LIBS="$saved_LIBS"
 330 ])
 331 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 332     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 333 fi
 334
 335 AC_CACHE_CHECK([... with advanced format flags],
 336     ac_cv_have_gst_video_overlay_hwcaps, [
 337     saved_CPPFLAGS="$CPPFLAGS"
 338     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 339     saved_LIBS="$LIBS"
 340     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 341     AC_COMPILE_IFELSE(
 342         [AC_LANG_PROGRAM(
 343             [[#include <gst/video/video-overlay-composition.h>]],
 344             [[GstVideoOverlayRectangle *rect;
 345               const guint w = 64, h = 64;
 346               guint flags = (
 347                   GST_VIDEO_OVERLAY_FORMAT_FLAG_PREMULTIPLIED_ALPHA|
 348                   GST_VIDEO_OVERLAY_FORMAT_FLAG_GLOBAL_ALPHA);
 349               rect = gst_video_overlay_rectangle_new_argb(NULL, w, h, w * 4,
 350                   0, 0, w, h, flags);
 351               gst_video_overlay_rectangle_set_global_alpha(rect, 0.5f);]])],
 352         [ac_cv_have_gst_video_overlay_hwcaps="yes"],
 353         [ac_cv_have_gst_video_overlay_hwcaps="no"]
 354     )
 355     CPPFLAGS="$saved_CPPFLAGS"
 356     LIBS="$saved_LIBS"
 357 ])
 358 if test "$ac_cv_have_gst_video_overlay_hwcaps" = "yes"; then
 359     AC_DEFINE_UNQUOTED([HAVE_GST_VIDEO_OVERLAY_HWCAPS], 1,
 360         [Defined to 1 if GstVideoOverlayComposition API supports HW hints.])
 361 fi
 362
 363 dnl GStreamer -bad plugins (deprecated in GStreamer v1.2)
 364 if test "$USE_GST_API_1_2p" != "yes"; then
 365 PKG_CHECK_MODULES([GST_BASEVIDEO],
 366     [gstreamer-basevideo-$GST_PKG_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 367 fi
 368
 369 dnl ... bitstream parsers
 370 if test "$enable_builtin_codecparsers" = "yes"; then
 371     ac_cv_have_gst_mpeg2_parser="no"
 372     ac_cv_have_gst_h264_parser="no"
 373     ac_cv_have_gst_jpeg_parser="no"
 374     ac_cv_have_gst_vp8_parser="no"
 375 else
 376 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 377     [gstreamer-codecparsers-$GST_PKG_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 378 fi
 379
 380 dnl ... MPEG-2 parser, with the required extensions
 381 AC_CACHE_CHECK([for MPEG-2 parser],
 382     ac_cv_have_gst_mpeg2_parser, [
 383     saved_CPPFLAGS="$CPPFLAGS"
 384     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 385     saved_LIBS="$LIBS"
 386     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 387     AC_COMPILE_IFELSE(
 388         [AC_LANG_PROGRAM(
 389             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 390             [[GstMpegVideoSequenceHdr seq_hdr;
 391               GstMpegVideoSequenceExt seq_ext;
 392               GstMpegVideoSequenceDisplayExt seq_dpy;
 393               GstMpegVideoSliceHdr slice_hdr;
 394               GstMpegVideoPacket packet;
 395               gst_mpeg_video_packet_parse_slice_header(&packet, &slice_hdr,
 396                   &seq_hdr, NULL);
 397               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 398                   &seq_ext, &seq_dpy);]])],
 399         [ac_cv_have_gst_mpeg2_parser="yes"],
 400         [ac_cv_have_gst_mpeg2_parser="no"]
 401     )
 402     CPPFLAGS="$saved_CPPFLAGS"
 403     LIBS="$saved_LIBS"
 404 ])
 405 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 406     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 407
 408 dnl ... H.264 parser, with the required extensions
 409 AC_CACHE_CHECK([for H.264 parser],
 410     ac_cv_have_gst_h264_parser, [
 411     saved_CPPFLAGS="$CPPFLAGS"
 412     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 413     saved_LIBS="$LIBS"
 414     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 415     AC_COMPILE_IFELSE(
 416         [AC_LANG_PROGRAM(
 417             [[#include <gst/codecparsers/gsth264parser.h>]],
 418             [[GstH264SliceHdr slice_hdr;
 419               GstH264VUIParams vui_params;
 420               GstH264Profile profile = GST_H264_PROFILE_HIGH;
 421               slice_hdr.n_emulation_prevention_bytes = 0;
 422               vui_params.par_n = 0;
 423               vui_params.par_d = 0;]])],
 424         [ac_cv_have_gst_h264_parser="yes"],
 425         [ac_cv_have_gst_h264_parser="no"]
 426     )
 427     CPPFLAGS="$saved_CPPFLAGS"
 428     LIBS="$saved_LIBS"
 429 ])
 430 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 431     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 432
 433 dnl ... JPEG parser, not upstream yet
 434 AC_CACHE_CHECK([for JPEG parser],
 435     ac_cv_have_gst_jpeg_parser, [
 436     saved_CPPFLAGS="$CPPFLAGS"
 437     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 438     saved_LIBS="$LIBS"
 439     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 440     AC_COMPILE_IFELSE(
 441         [AC_LANG_PROGRAM(
 442             [[#include <gst/codecparsers/gstjpegparser.h>]],
 443             [[GstJpegImage jpeg_image;]])],
 444         [ac_cv_have_gst_jpeg_parser="yes"],
 445         [ac_cv_have_gst_jpeg_parser="no"]
 446     )
 447     CPPFLAGS="$saved_CPPFLAGS"
 448     LIBS="$saved_LIBS"
 449 ])
 450 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 451     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 452
 453 dnl ... VP8 parser, not upstream yet
 454 if test "$enable_builtin_libvpx" = "yes"; then
 455     ac_cv_have_gst_vp8_parser="no"
 456 fi
 457 AC_CACHE_CHECK([for VP8 parser],
 458     ac_cv_have_gst_vp8_parser, [
 459     saved_CPPFLAGS="$CPPFLAGS"
 460     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 461     saved_LIBS="$LIBS"
 462     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 463     AC_COMPILE_IFELSE(
 464         [AC_LANG_PROGRAM(
 465             [[#include <gst/codecparsers/gstvp8parser.h>]],
 466             [[GstVp8FrameHdr frame_hdr;]])],
 467         [ac_cv_have_gst_vp8_parser="yes"],
 468         [ac_cv_have_gst_vp8_parser="no"]
 469     )
 470     CPPFLAGS="$saved_CPPFLAGS"
 471     LIBS="$saved_LIBS"
 472 ])
 473 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_VP8],
 474     [test "$ac_cv_have_gst_vp8_parser" != "yes"])
 475 AM_CONDITIONAL([USE_BUILTIN_LIBVPX], [test "$enable_builtin_libvpx" = "yes"])
 476
 477 dnl ... video parsers
 478 AM_CONDITIONAL([USE_LOCAL_VIDEO_PARSERS],
 479     [test "$enable_builtin_videoparsers" = "yes"])
 480
 481 case $GST_API_VERSION in
 482 0.10)   lt_bias=gst0_vaapi_lt_current_bias;;
 483 1.0)    lt_bias=gst1_vaapi_lt_current_bias;;
 484 1.2)    lt_bias=gst2_vaapi_lt_current_bias;;
 485 1.[[3-4]]) lt_bias=gst4_vaapi_lt_current_bias;;
 486 1.5)    lt_bias=gst6_vaapi_lt_current_bias;;
 487 esac
 488 GST_VAAPI_MAJOR_VERSION=`expr gst_vaapi_lt_current - "$lt_bias"`
 489 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
 490
 491 dnl GST_VAAPI_LT_LDFLAGS:
 492 GST_VAAPI_LT_CURRENT="$GST_VAAPI_MAJOR_VERSION"
 493 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 494 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 495 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 496 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 497 AC_SUBST(GST_VAAPI_LT_VERSION)
 498 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 499
 500 dnl GST_ALL_LDFLAGS:
 501 dnl LDFLAGS really should only contain flags, not libs - they get added before
 502 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 503 GST_ALL_LDFLAGS="-no-undefined"
 504 AC_SUBST(GST_ALL_LDFLAGS)
 505
 506 dnl GST_PLUGIN_LDFLAGS:
 507 dnl this really should only contain flags, not libs - they get added before
 508 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 509 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 510 AC_SUBST(GST_PLUGIN_LDFLAGS)
 511
 512 dnl Check for the GStreamer plugins directory
 513 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements for GStreamer 0.10])
 514 AC_ARG_VAR([GST_PLUGIN_PATH_1_0], [installation path for gstreamer-vaapi plugin elements for GStreamer 1.0])
 515 AC_MSG_CHECKING([for GStreamer plugins directory])
 516 case $GST_PKG_VERSION in
 517 0.10)   _gst_plugin_path="$GST_PLUGIN_PATH";;
 518 1.0)    _gst_plugin_path="$GST_PLUGIN_PATH_1_0";;
 519 esac
 520 if test -d "$_gst_plugin_path"; then
 521     GST_PLUGINS_DIR="$_gst_plugin_path"
 522 else
 523     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_PKG_VERSION --variable pluginsdir`
 524     if test -z "$GST_PLUGINS_DIR"; then
 525         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_PKG_VERSION"
 526     fi
 527 fi
 528 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 529 plugindir="$GST_PLUGINS_DIR"
 530 AC_SUBST(plugindir)
 531
 532 dnl ---------------------------------------------------------------------------
 533 dnl -- Renderers                                                             --
 534 dnl ---------------------------------------------------------------------------
 535
 536 dnl Check for DRM/libudev
 537 USE_DRM=0
 538 if test "$enable_drm" = "yes"; then
 539     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 540     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 541
 542     if test $USE_DRM -eq 1; then
 543         saved_CPPFLAGS="$CPPFLAGS"
 544         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 545         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 546         CPPFLAGS="$saved_CPPFLAGS"
 547     fi
 548 fi
 549
 550 dnl Check for X11
 551 USE_X11=0
 552 if test "$enable_x11" = "yes"; then
 553     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 554     if test $USE_X11 -eq 1; then
 555         saved_CPPFLAGS="$CPPFLAGS"
 556         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 557         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 558         CPPFLAGS="$saved_CPPFLAGS"
 559     fi
 560 fi
 561
 562 dnl Check for XRandR
 563 HAVE_XRANDR=0
 564 if test $USE_X11 -eq 1; then
 565     HAVE_XRANDR=1
 566     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 567     if test $HAVE_XRANDR -eq 1; then
 568         saved_CPPFLAGS="$CPPFLAGS"
 569         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 570         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 571         CPPFLAGS="$saved_CPPFLAGS"
 572     fi
 573 fi
 574 if test $HAVE_XRANDR -eq 1; then
 575     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 576         [Defined to 1 if the XRandR extension exists.])
 577 fi
 578
 579 dnl Check for XRender
 580 HAVE_XRENDER=0
 581 if test $USE_X11 -eq 1; then
 582     HAVE_XRENDER=1
 583     PKG_CHECK_MODULES([XRENDER], [xrender], [:], [HAVE_XRENDER=0])
 584     if test $HAVE_XRENDER -eq 1; then
 585         saved_CPPFLAGS="$CPPFLAGS"
 586         CPPFLAGS="$CPPFLAGS $XRENDER_CFLAGS"
 587         AC_CHECK_HEADERS([X11/extensions/Xrender.h], [:], [HAVE_XRENDER=0])
 588         CPPFLAGS="$saved_CPPFLAGS"
 589     fi
 590 fi
 591 if test $HAVE_XRENDER -eq 1; then
 592     AC_DEFINE_UNQUOTED([HAVE_XRENDER], [1],
 593         [Defined to 1 if the XRender extension exists.])
 594 fi
 595
 596 dnl OpenGL
 597 enable_opengl="no"
 598 if test "$enable_glx" = "yes"; then
 599     enable_opengl="yes"
 600 fi
 601
 602 HAVE_GL=0
 603 if test "$enable_opengl" = "yes"; then
 604     HAVE_GL=1
 605     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 606     saved_CPPFLAGS="$CPPFLAGS"
 607     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 608     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 609 #ifdef HAVE_GL_GL_H
 610 # include <GL/gl.h>
 611 #endif
 612     ])
 613     CPPFLAGS="$saved_CPPFLAGS"
 614 fi
 615
 616 dnl ... GLX
 617 USE_GLX=0
 618 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 619     USE_GLX=1
 620     saved_CPPFLAGS="$CPPFLAGS"
 621     saved_LIBS="$LIBS"
 622     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 623     LIBS="$LIBS $GL_LIBS"
 624     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 625 #ifdef HAVE_GL_GL_H
 626 # include <GL/gl.h>
 627 #endif
 628     ])
 629     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 630     CPPFLAGS="$saved_CPPFLAGS"
 631     LIBS="$saved_LIBS"
 632 fi
 633
 634 dnl Check for Wayland
 635 USE_WAYLAND=0
 636 if test "$enable_wayland" = "yes"; then
 637     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 638         [USE_WAYLAND=1], [USE_WAYLAND=0])
 639
 640     if test $USE_WAYLAND -eq 1; then
 641         saved_CPPFLAGS="$CPPFLAGS"
 642         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 643         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 644         CPPFLAGS="$saved_CPPFLAGS"
 645     fi
 646 fi
 647
 648 dnl ---------------------------------------------------------------------------
 649 dnl -- VA-API                                                                --
 650 dnl ---------------------------------------------------------------------------
 651
 652 dnl Core API
 653 LIBVA_PKGNAME="libva"
 654 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 655 AC_SUBST(LIBVA_PKGNAME)
 656
 657 VA_VERSION=`$PKG_CONFIG --modversion libva`
 658 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 659 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 660 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 661 VA_VERSION_STR="$VA_VERSION"
 662
 663 dnl VA/DRM API
 664 HAVE_VA_DRM=0
 665 if test $USE_DRM -eq 1; then
 666     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 667         [HAVE_VA_DRM=1], [USE_DRM=0])
 668
 669     if test $HAVE_VA_DRM -eq 1; then
 670         saved_CPPFLAGS="$CPPFLAGS"
 671         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 672         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 673         CPPFLAGS="$saved_CPPFLAGS"
 674     fi
 675 fi
 676
 677 dnl VA/X11 API
 678 HAVE_VA_X11=0
 679 LIBVA_X11_PKGNAME="libva-x11"
 680 if test $USE_X11 -eq 1; then
 681     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 682         [HAVE_VA_X11=1], [USE_X11=0])
 683 fi
 684 AC_SUBST(LIBVA_X11_PKGNAME)
 685
 686 dnl VA/GLX API
 687 HAVE_VA_GLX=0
 688 LIBVA_GLX_PKGNAME="libva-glx"
 689 if test $USE_GLX -eq 1; then
 690     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 691         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 692
 693     if test $HAVE_VA_GLX -eq 1; then
 694         saved_CPPFLAGS="$CPPFLAGS"
 695         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 696         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 697         CPPFLAGS="$saved_CPPFLAGS"
 698     fi
 699 fi
 700 AC_SUBST(LIBVA_GLX_PKGNAME)
 701
 702 dnl Check for va_dec_jpeg.h header
 703 saved_CPPFLAGS="$CPPFLAGS"
 704 CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 705 AC_CHECK_HEADERS([va/va_dec_jpeg.h], [], [], [#include <va/va.h>])
 706 CPPFLAGS="$saved_CPPFLAGS"
 707
 708 dnl Check for JPEG decoding API (0.32.1+)
 709 USE_JPEG_DECODER=0
 710 AC_CACHE_CHECK([for JPEG decoding API],
 711     ac_cv_have_jpeg_decoding_api, [
 712     saved_CPPFLAGS="$CPPFLAGS"
 713     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 714     saved_LIBS="$LIBS"
 715     LIBS="$LIBS $LIBVA_LIBS"
 716     AC_COMPILE_IFELSE(
 717         [AC_LANG_PROGRAM(
 718             [[#include <va/va.h>
 719               #ifdef HAVE_VA_VA_DEC_JPEG_H
 720               #include <va/va_dec_jpeg.h>
 721               #endif
 722             ]],
 723             [[VAPictureParameterBufferJPEGBaseline pic_param;
 724               VASliceParameterBufferJPEGBaseline slice_param;
 725               VAHuffmanTableBufferJPEGBaseline huffman_table;
 726               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 727         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 728         [ac_cv_have_jpeg_decoding_api="no"]
 729     )
 730     CPPFLAGS="$saved_CPPFLAGS"
 731     LIBS="$saved_LIBS"
 732 ])
 733
 734 dnl Check for va_dec_vp8.h header
 735 saved_CPPFLAGS="$CPPFLAGS"
 736 CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 737 AC_CHECK_HEADERS([va/va_dec_vp8.h], [], [], [#include <va/va.h>])
 738 CPPFLAGS="$saved_CPPFLAGS"
 739
 740 dnl Check for VP8 decoding API (0.34+)
 741 USE_VP8_DECODER=0
 742 AC_CACHE_CHECK([for VP8 decoding API],
 743     ac_cv_have_vp8_decoding_api, [
 744     saved_CPPFLAGS="$CPPFLAGS"
 745     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 746     saved_LIBS="$LIBS"
 747     LIBS="$LIBS $LIBVA_LIBS"
 748     AC_COMPILE_IFELSE(
 749         [AC_LANG_PROGRAM(
 750             [[#include <va/va.h>
 751               #ifdef HAVE_VA_VA_DEC_VP8_H
 752               #include <va/va_dec_vp8.h>
 753               #endif
 754             ]],
 755             [[VAPictureParameterBufferVP8 pic_param;
 756               VASliceParameterBufferVP8 slice_param;
 757               VAProbabilityDataBufferVP8 prob_data;
 758               VAIQMatrixBufferVP8 iq_matrix;
 759               slice_param.slice_data_offset = 0;
 760               slice_param.slice_data_flag = 0;]])],
 761         [ac_cv_have_vp8_decoding_api="yes" USE_VP8_DECODER=1],
 762         [ac_cv_have_vp8_decoding_api="no"]
 763     )
 764     CPPFLAGS="$saved_CPPFLAGS"
 765     LIBS="$saved_LIBS"
 766 ])
 767
 768
 769 dnl Check for vpp (video post-processing) support
 770 USE_VA_VPP=0
 771 AC_CACHE_CHECK([for video post-postprocessing API],
 772     ac_cv_have_va_vpp_api, [
 773     saved_CPPFLAGS="$CPPFLAGS"
 774     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 775     saved_LIBS="$LIBS"
 776     LIBS="$LIBS $LIBVA_LIBS"
 777     AC_COMPILE_IFELSE(
 778         [AC_LANG_PROGRAM(
 779             [[#include <va/va.h>
 780               #include <va/va_vpp.h>]],
 781             [[VADisplay va_dpy;
 782               VAContextID vpp_ctx;
 783               VAProcFilterType filters[VAProcFilterCount];
 784               unsigned int num_filters = VAProcFilterCount;
 785               vaQueryVideoProcFilters(va_dpy, vpp_ctx, filters, &num_filters);
 786               ]])],
 787         [ac_cv_have_va_vpp_api="yes" USE_VA_VPP=1],
 788         [ac_cv_have_va_vpp_api="no"]
 789     )
 790     CPPFLAGS="$saved_CPPFLAGS"
 791     LIBS="$saved_LIBS"
 792 ])
 793
 794 dnl Check for encoding support
 795 USE_ENCODERS=0
 796 if test "$enable_encoders" = "yes"; then
 797     PKG_CHECK_MODULES([LIBVA], [libva >= va_api_enc_version],
 798         [HAVE_VA_ENC=1], [HAVE_VA_ENC=0])
 799
 800     if test $HAVE_VA_ENC -eq 1; then
 801         saved_CPPFLAGS="$CPPFLAGS"
 802         CPPFLAGS="$LIBVA_CFLAGS"
 803         AC_CHECK_HEADERS([va/va_enc_mpeg2.h va/va_enc_h264.h],
 804             [USE_ENCODERS=1], [HAVE_VA_ENC=0 USE_ENCODERS=0],
 805             [#include <va/va.h>
 806             ])
 807         CPPFLAGS="$saved_CPPFLAGS"
 808     fi
 809 fi
 810
 811 dnl VA/Wayland API
 812 if test "$enable_wayland" = "yes"; then
 813     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 814         [:], [USE_WAYLAND=0])
 815 fi
 816
 817 dnl ---------------------------------------------------------------------------
 818 dnl -- Generate files and summary                                            --
 819 dnl ---------------------------------------------------------------------------
 820
 821 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 822 *:1:*)
 823     ;;
 824 *)
 825     AC_MSG_ERROR([No renderer is enabled])
 826     ;;
 827 esac
 828
 829 AC_DEFINE_UNQUOTED([USE_ENCODERS], $USE_ENCODERS,
 830     [Defined to 1 if video encoders are used])
 831 AM_CONDITIONAL([USE_ENCODERS], [test $USE_ENCODERS -eq 1])
 832
 833 AC_DEFINE_UNQUOTED(USE_VA_VPP, $USE_VA_VPP,
 834     [Defined to 1 if video post-processing is used])
 835 AM_CONDITIONAL(USE_VA_VPP, test $USE_VA_VPP -eq 1)
 836
 837 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 838     [Defined to 1 if JPEG decoder is used])
 839 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 840
 841 AC_DEFINE_UNQUOTED(USE_VP8_DECODER, $USE_VP8_DECODER,
 842     [Defined to 1 if VP8 decoder is used])
 843 AM_CONDITIONAL(USE_VP8_DECODER, test $USE_VP8_DECODER -eq 1)
 844
 845 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 846     [Defined to 1 if DRM is enabled])
 847 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 848
 849 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 850     [Defined to 1 if X11 is enabled])
 851 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 852
 853 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 854     [Defined to 1 if GLX is enabled])
 855 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 856
 857 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 858     [Defined to 1 if WAYLAND is enabled])
 859 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 860
 861 pkgconfigdir=${libdir}/pkgconfig
 862 AC_SUBST(pkgconfigdir)
 863
 864 AC_CONFIG_FILES([
 865     Makefile
 866     debian.upstream/Makefile
 867     debian.upstream/changelog
 868     debian.upstream/control
 869     debian.upstream/gstreamer$GST_API_VERSION-vaapi-doc.install:\
 870 debian.upstream/gstreamer-vaapi-doc.install.in
 871     debian.upstream/gstreamer$GST_API_VERSION-vaapi.install:\
 872 debian.upstream/gstreamer-vaapi.install.in
 873     debian.upstream/libgstvaapi$GST_PKG_VERSION-dev.install:\
 874 debian.upstream/libgstvaapi-dev.install.in
 875     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 876 debian.upstream/libgstvaapi.install.in
 877     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 878 debian.upstream/libgstvaapi-drm.install.in
 879     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 880 debian.upstream/libgstvaapi-glx.install.in
 881     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 882 debian.upstream/libgstvaapi-wayland.install.in
 883     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 884 debian.upstream/libgstvaapi-x11.install.in
 885     docs/Makefile
 886     docs/reference/Makefile
 887     docs/reference/libs/Makefile
 888     docs/reference/libs/libs-docs.xml
 889     docs/reference/plugins/Makefile
 890     docs/reference/plugins/plugins-docs.xml
 891     ext/Makefile
 892     ext/libvpx/Makefile
 893     gst-libs/Makefile
 894     gst-libs/gst/Makefile
 895     gst-libs/gst/base/Makefile
 896     gst-libs/gst/codecparsers/Makefile
 897     gst-libs/gst/vaapi/Makefile
 898     gst-libs/gst/video/Makefile
 899     gst/Makefile
 900     gst/vaapi/Makefile
 901     patches/Makefile
 902     patches/videoparsers/Makefile
 903     pkgconfig/Makefile
 904     pkgconfig/gstreamer-vaapi-$GST_PKG_VERSION.pc:\
 905 pkgconfig/gstreamer-vaapi.pc.in
 906     pkgconfig/gstreamer-vaapi-drm-$GST_PKG_VERSION.pc:\
 907 pkgconfig/gstreamer-vaapi-drm.pc.in
 908     pkgconfig/gstreamer-vaapi-glx-$GST_PKG_VERSION.pc:\
 909 pkgconfig/gstreamer-vaapi-glx.pc.in
 910     pkgconfig/gstreamer-vaapi-wayland-$GST_PKG_VERSION.pc:\
 911 pkgconfig/gstreamer-vaapi-wayland.pc.in
 912     pkgconfig/gstreamer-vaapi-x11-$GST_PKG_VERSION.pc:\
 913 pkgconfig/gstreamer-vaapi-x11.pc.in
 914     tests/Makefile
 915 ])
 916 AC_OUTPUT
 917
 918 dnl Print summary
 919 yesno() {
 920     test $1 -eq 1 && echo yes || echo no
 921 }
 922
 923 VIDEO_OUTPUTS=""
 924 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 925 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 926 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 927 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 928
 929 echo
 930 echo $PACKAGE configuration summary:
 931 echo
 932 echo GStreamer API version ............ : $GST_API_VERSION
 933 echo VA-API version ................... : $VA_VERSION_STR
 934 echo Video encoding ................... : $(yesno $USE_ENCODERS)
 935 echo Video outputs .................... : $VIDEO_OUTPUTS
 936 echo