configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.12.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1202, 0, 1202)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.12.0
  50 GSTPB_REQ=1.12.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 201
 202 dnl Check for mmap (needed by electricfence plugin)
 203
 204 AC_CHECK_TYPE([struct ip_mreqn], [
 205               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 206               [#include <netinet/in.h>])
 207
 208 dnl *** checks for dependency libraries ***
 209
 210
 211 dnl GLib
 212 GLIB_REQ=2.40.0
 213 AG_GST_GLIB_CHECK([$GLIB_REQ])
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.17])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK_REQ=3.0.0
 249 if test "x$BUILD_EXAMPLES" = "xyes"; then
 250   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 251   dnl some examples need gtk+-x11
 252   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 253   AC_SUBST(GTK_LIBS)
 254   AC_SUBST(GTK_CFLAGS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 258
 259 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 260   [
 261     case "${enableval}" in
 262       yes) PCM_DUMP_ENABLE=yes ;;
 263       no)  PCM_DUMP_ENABLE=no ;;
 264       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 265     esac
 266   ],
 267   [PCM_DUMP_ENABLE=no])
 268 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 269
 270 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 271 PKG_CHECK_MODULES(VCONF, vconf)
 272 AC_SUBST(VCONF_CFLAGS)
 273 AC_SUBST(VCONF_LIBS)
 274 fi
 275
 276 PKG_CHECK_MODULES(GIO, gio-2.0)
 277 AC_SUBST(GIO_CFLAGS)
 278 AC_SUBST(GIO_LIBS)
 279
 280 dnl Check for -Bsymbolic-functions linker flag used to avoid
 281 dnl intra-library PLT jumps, if available.
 282 AC_ARG_ENABLE(Bsymbolic,
 283               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 284               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 285                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 286                LDFLAGS=-Wl,-Bsymbolic-functions
 287                LIBS=
 288                AC_TRY_LINK([], [return 0],
 289                            AC_MSG_RESULT(yes)
 290                            enable_Bsymbolic=yes,
 291                            AC_MSG_RESULT(no)
 292                            enable_Bsymbolic=no)
 293                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 294
 295 dnl *** set variables based on configure arguments ***
 296
 297 dnl set license and copyright notice
 298 GST_LICENSE="LGPL"
 299 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 300 AC_SUBST(GST_LICENSE)
 301
 302 dnl set location of plugin directory
 303 AG_GST_SET_PLUGINDIR
 304
 305 dnl set release date/time
 306 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 307   ["${srcdir}/gst-plugins-good.doap"],
 308   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 309
 310 dnl build static plugins or not
 311 AC_MSG_CHECKING([whether to build static plugins or not])
 312 AC_ARG_ENABLE(
 313   static-plugins,
 314   AC_HELP_STRING(
 315     [--enable-static-plugins],
 316     [build static plugins @<:@default=no@:>@]),
 317   [AS_CASE(
 318     [$enableval], [no], [], [yes], [],
 319     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 320   [enable_static_plugins=no])
 321 AC_MSG_RESULT([$enable_static_plugins])
 322 if test "x$enable_static_plugins" = xyes; then
 323   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 324     [Define if static plugins should be built])
 325   GST_PLUGIN_LIBTOOLFLAGS=""
 326 else
 327   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 328 fi
 329 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 330 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 331
 332 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 333 dnl make sure it doesn't complain about unused variables if debugging is disabled
 334 NO_WARNINGS=""
 335 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 336
 337 dnl define an ERROR_CFLAGS Makefile variable
 338 dnl -Wundef: too many broken headers
 339 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 340       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 341       -Wwrite-strings -Wold-style-definition -Waggregate-return
 342       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 343       -Wnested-externs $NO_WARNINGS])
 344
 345 dnl define an ERROR_CXXFLAGS Makefile variable
 346 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 347         -Wmissing-declarations -Wredundant-decls
 348         -Wwrite-strings
 349         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 350         $NO_WARNINGS])
 351
 352 dnl define an ERROR_OBJCFLAGS Makefile variable
 353 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 354       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 355       -Wwrite-strings -Wold-style-definition
 356       -Winit-self -Wmissing-include-dirs -Wno-multichar
 357       -Wnested-externs $NO_WARNINGS])
 358
 359 dnl define correct level for debugging messages
 360 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 361
 362 dnl used in examples
 363 AG_GST_DEFAULT_ELEMENTS
 364
 365 dnl *** plug-ins to include ***
 366
 367 dnl these are all the gst plug-ins, compilable without additional libs
 368 dnl videofilter is at the top because others depend on it
 369 AG_GST_CHECK_PLUGIN(alpha)
 370 AG_GST_CHECK_PLUGIN(apetag)
 371 AG_GST_CHECK_PLUGIN(audiofx)
 372 AG_GST_CHECK_PLUGIN(audioparsers)
 373 AG_GST_CHECK_PLUGIN(auparse)
 374 AG_GST_CHECK_PLUGIN(autodetect)
 375 AG_GST_CHECK_PLUGIN(avi)
 376 AG_GST_CHECK_PLUGIN(cutter)
 377 AG_GST_CHECK_PLUGIN(debugutils)
 378 AG_GST_CHECK_PLUGIN(deinterlace)
 379 AG_GST_CHECK_PLUGIN(dtmf)
 380 AG_GST_CHECK_PLUGIN(effectv)
 381 AG_GST_CHECK_PLUGIN(equalizer)
 382 AG_GST_CHECK_PLUGIN(flv)
 383 AG_GST_CHECK_PLUGIN(flx)
 384 AG_GST_CHECK_PLUGIN(goom)
 385 AG_GST_CHECK_PLUGIN(goom2k1)
 386 AG_GST_CHECK_PLUGIN(icydemux)
 387 AG_GST_CHECK_PLUGIN(id3demux)
 388 AG_GST_CHECK_PLUGIN(imagefreeze)
 389 AG_GST_CHECK_PLUGIN(interleave)
 390 AG_GST_CHECK_PLUGIN(isomp4)
 391 AG_GST_CHECK_PLUGIN(law)
 392 AG_GST_CHECK_PLUGIN(level)
 393 AG_GST_CHECK_PLUGIN(matroska)
 394 AG_GST_CHECK_PLUGIN(monoscope)
 395 AG_GST_CHECK_PLUGIN(multifile)
 396 AG_GST_CHECK_PLUGIN(multipart)
 397 AG_GST_CHECK_PLUGIN(replaygain)
 398 AG_GST_CHECK_PLUGIN(rtp)
 399 AG_GST_CHECK_PLUGIN(rtpmanager)
 400 AG_GST_CHECK_PLUGIN(rtsp)
 401 AG_GST_CHECK_PLUGIN(shapewipe)
 402 AG_GST_CHECK_PLUGIN(smpte)
 403 AG_GST_CHECK_PLUGIN(spectrum)
 404 AG_GST_CHECK_PLUGIN(udp)
 405 AG_GST_CHECK_PLUGIN(videobox)
 406 AG_GST_CHECK_PLUGIN(videocrop)
 407 AG_GST_CHECK_PLUGIN(videofilter)
 408 AG_GST_CHECK_PLUGIN(videomixer)
 409 AG_GST_CHECK_PLUGIN(wavenc)
 410 AG_GST_CHECK_PLUGIN(wavparse)
 411 AG_GST_CHECK_PLUGIN(y4m)
 412
 413 dnl disable experimental plug-ins
 414 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 415   AG_GST_DISABLE_PLUGIN(monoscope)
 416 fi
 417
 418 dnl *** sys plug-ins ***
 419
 420 echo
 421 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 422 echo
 423
 424 dnl DirectSound
 425 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 426 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 427   HAVE_DIRECTSOUND="no"
 428   save_CFLAGS="$CFLAGS"
 429   save_LDFLAGS="$LDFLAGS"
 430   save_LIBS="$LIBS"
 431   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 432   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 433   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 434   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 435   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 436 #include <windows.h>
 437 #include <dxerr9.h>
 438 #include <dsound.h>
 439 ]], [[
 440   DXGetErrorString9 (0);
 441   DirectSoundCreate(NULL, NULL, NULL);
 442   CLSIDFromString(NULL, NULL);
 443 ]])
 444 ],
 445     [HAVE_DIRECTSOUND="yes"],
 446     [HAVE_DIRECTSOUND="no"])
 447   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 448   CFLAGS=$save_CFLAGS
 449   LDFLAGS=$save_LDFLAGS
 450   LIBS=$save_LIBS
 451
 452   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 453     dnl this is much more than we want
 454     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 455     AC_SUBST(DIRECTSOUND_CFLAGS)
 456     AC_SUBST(DIRECTSOUND_LDFLAGS)
 457     AC_SUBST(DIRECTSOUND_LIBS)
 458   fi
 459   AC_SUBST(HAVE_DIRECTSOUND)
 460 ])
 461
 462 dnl *** Win32 WaveOut ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 464 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 465   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 466 ])
 467
 468 dnl *** OSS audio *** (Linux, *BSD)
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 470 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 471  HAVE_OSS="yes"
 472 dnl Linux and newer BSD versions :
 473  AC_CHECK_HEADER(sys/soundcard.h, [
 474    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 475    ] , [
 476 dnl Some old BSD versions and also newer OpenBSD versions :
 477    AC_CHECK_HEADER(soundcard.h, [
 478      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 479      ], [
 480   dnl Some old BSD versions :
 481      AC_CHECK_HEADER(machine/soundcard.h, [
 482        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 483          [Define if OSS includes are in /machine/])
 484        ], [
 485        HAVE_OSS="no"
 486      ])
 487    ])
 488  ])
 489 ])
 490
 491 dnl *** oss4 ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 493 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 494   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 495   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 496       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 497       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 498 ])
 499
 500 dnl *** Sun Audio ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 502 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 503   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 504 ])
 505
 506 dnl *** OSX Audio ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 508 HAVE_IOS="no"
 509 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 510   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 511     [HAVE_OSX_AUDIO="yes"],
 512     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 513     [
 514       HAVE_OSX_AUDIO="yes"
 515       HAVE_IOS="yes"
 516     ], [
 517       HAVE_OSX_AUDIO="no"
 518       HAVE_IOS="no"
 519     ])]
 520   )
 521 ])
 522 if test "x$HAVE_IOS" = "xyes"; then
 523   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 524 fi
 525 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 526
 527 dnl *** OS X video ***
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 529 HAVE_OSX_VIDEO="no"
 530 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 531   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 532
 533   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 534   dnl also require Snow Leopard or newer
 535
 536   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 537         #include <AvailabilityMacros.h>
 538         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 539         #error Too old OSX version
 540         #endif
 541       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 542 ])
 543
 544 dnl *** Video 4 Linux 2 ***
 545 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 546 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 547 HAVE_GST_V4L2=no
 548 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 549   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 550   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 551   [
 552     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 553     [
 554       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 555     ])
 556   ])
 557   if test "x$HAVE_VIDEODEV" = "xno"; then
 558      AC_MSG_WARN([video4linux2 was not found])
 559   fi
 560 ])
 561
 562 # Optional gudev for device probing
 563 AC_ARG_WITH([gudev],
 564   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 565   [],
 566   [with_gudev=check])
 567 if test x$HAVE_GST_V4L2 = xyes; then
 568   if test x$with_gudev != xno; then
 569     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 570       [ AC_DEFINE(HAVE_GUDEV, 1,
 571           [Whether gudev is available for device detection])
 572       ],
 573       [true])
 574   fi
 575 fi
 576
 577 AC_SUBST(GUDEV_CFLAGS)
 578 AC_SUBST(GUDEV_LIBS)
 579
 580 # Make libv4l2 non-automagic
 581 AC_ARG_WITH([libv4l2],
 582   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 583   [],
 584   [with_libv4l2=check])
 585 if test x$HAVE_GST_V4L2 = xyes; then
 586   if test x$with_libv4l2 != xno; then
 587       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 588           [ have_libv4l2=yes
 589             AC_DEFINE(HAVE_LIBV4L2, 1,
 590                 [Whether libv4l2 is available for video buffer conversion])
 591           ], [
 592           have_libv4l2=no
 593           ])
 594   else
 595     have_libv4l2=no
 596   fi
 597 fi
 598
 599 dnl Allow enabling v4l2 device probing
 600 AS_CASE([$host],
 601     [*-*linux*],
 602       [AS_CASE([$host_cpu],
 603         [arm*], [
 604           enable_v4l2_probe="yes"],
 605         [aarch64*], [
 606           enable_v4l2_probe="yes"])])
 607 AC_ARG_ENABLE(
 608   v4l2-probe,
 609   AC_HELP_STRING(
 610     [--enable-v4l2-probe],
 611     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 612 if test "x$enable_v4l2_probe" = "xyes"; then
 613   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 614     [Define if Video4Linux probe shall be run at plugin load])
 615 fi
 616
 617 dnl Check for X11
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 619 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 620                   [ximagesrc], [
 621   AG_GST_CHECK_X
 622
 623   if test "x$HAVE_X" = "xyes"
 624   then
 625     dnl check for Xfixes
 626     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 627     if test "x$HAVE_XFIXES" = "xyes"
 628     then
 629         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 630     fi
 631     AC_SUBST(XFIXES_LIBS)
 632     AC_SUBST(XFIXES_CFLAGS)
 633
 634     dnl check for Xdamage
 635     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 636     if test "x$HAVE_XDAMAGE" = "xyes"
 637     then
 638         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 639     fi
 640     AC_SUBST(XDAMAGE_LIBS)
 641     AC_SUBST(XDAMAGE_CFLAGS)
 642   fi
 643 ])
 644
 645 dnl FIXME: this should be rolled into the test above, it's just an additional
 646 dnl feature of the ximagesrc plug-in
 647 dnl This is the same as in gst-plugins-base
 648 dnl check for X Shm
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 650 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 651   if test x$HAVE_X = xyes; then
 652     AC_CHECK_LIB(Xext, XShmAttach,
 653                  HAVE_XSHM="yes", HAVE_XSHM="no",
 654                  $X_LIBS)
 655     if test "x$HAVE_XSHM" = "xyes"; then
 656       XSHM_LIBS="-lXext"
 657     else
 658       dnl On AIX, it is in XextSam instead, but we still need -lXext
 659       AC_CHECK_LIB(XextSam, XShmAttach,
 660                    HAVE_XSHM="yes", HAVE_XSHM="no",
 661                    $X_LIBS)
 662       if test "x$HAVE_XSHM" = "xyes"; then
 663         XSHM_LIBS="-lXext -lXextSam"
 664       fi
 665     fi
 666   fi
 667 ], ,[
 668   AC_SUBST(HAVE_XSHM)
 669   AC_SUBST(XSHM_LIBS)
 670 ])
 671
 672 dnl *** ext plug-ins ***
 673 dnl keep this list sorted alphabetically !
 674
 675 if test "x$BUILD_EXTERNAL" = "xyes"; then
 676
 677 echo
 678 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 679 echo
 680
 681 dnl *** aalib ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 683 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 684   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 685 ])
 686
 687 dnl *** cairo ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 689 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 690   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 691 ])
 692
 693 dnl *** FLAC ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 695 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 696   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 697 ])
 698
 699 dnl *** GDK pixbuf ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 701 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 702   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 703 ])
 704
 705 dnl *** Jack ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 707 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 708   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 709   AC_SUBST(JACK_CFLAGS)
 710   AC_SUBST(JACK_LIBS)
 711
 712   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 713   if test x$HAVE_JACK_0_120_1 = xyes; then
 714     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 715   fi
 716   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 717   if test x$HAVE_JACK_1_9_7 = xyes; then
 718     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 719   fi
 720
 721 ])
 722
 723 dnl *** jpeg ***
 724 dnl FIXME: we could use header checks here as well IMO
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 726 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 727   AC_ARG_WITH(jpeg-mmx,
 728     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 729   OLD_LIBS="$LIBS"
 730   if test x$with_jpeg_mmx != x; then
 731     LIBS="$LIBS -L$with_jpeg_mmx"
 732   fi
 733   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734   JPEG_LIBS="$LIBS -ljpeg-mmx"
 735   LIBS="$OLD_LIBS"
 736   if test x$HAVE_JPEG != xyes; then
 737     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 738     JPEG_LIBS="-ljpeg"
 739   fi
 740   AC_SUBST(JPEG_LIBS)
 741 ])
 742
 743 dnl *** libcaca ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 745 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 746   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 747 ])
 748
 749 dnl *** libdv ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 751 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 752   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 753 ])
 754
 755 dnl *** libpng ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 757 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 758   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 759 ])
 760
 761 dnl *** pulseaudio ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 763 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 764
 765   dnl used in ext/pulse/pulseutil.c
 766   AC_CHECK_HEADERS([process.h])
 767
 768   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 769 ])
 770
 771 dnl *** dv1394 ***
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 773 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 774   dnl first test for libraw1394 >= 2.0.0
 775   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 776   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 777   dnl now see how far we got
 778   if test x$HAVE_RAW1394 = xyes && \
 779      test x$HAVE_LIBIEC61883 = xyes; then
 780        AG_GST_CHECK_LIBHEADER(AVC1394,
 781         avc1394, avc1394_send_command, $RAW1394_LIBS,
 782         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 783        AG_GST_CHECK_LIBHEADER(ROM1394,
 784         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 785         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 786        if test x$HAVE_AVC1394 = xyes && \
 787           test x$HAVE_AVC1394 = xyes && \
 788           test x$HAVE_ROM1394 = xyes; then
 789           HAVE_DV1394=yes
 790           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 791           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 792           AC_SUBST(DV1394_CFLAGS)
 793           AC_SUBST(DV1394_LIBS)
 794         fi
 795   else
 796        if test x$HAVE_RAW1394 = xno; then
 797           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 798           AG_GST_CHECK_LIBHEADER(AVC1394,
 799            avc1394, avc1394_send_command, $RAW1394_LIBS,
 800            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 801           AG_GST_CHECK_LIBHEADER(ROM1394,
 802            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 803            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 804           if test x$HAVE_RAW1394 = xyes && \
 805              test x$HAVE_AVC1394 = xyes && \
 806              test x$HAVE_ROM1394 = xyes; then
 807              HAVE_DV1394=yes
 808              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 809              DV1394_CFLAGS="$RAW1394_CFLAGS"
 810              if test x$HAVE_LIBIEC61883 = xyes; then
 811                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 812                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 813              fi
 814              AC_SUBST(DV1394_CFLAGS)
 815              AC_SUBST(DV1394_LIBS)
 816            fi
 817          fi
 818   fi
 819 ])
 820 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 821
 822 dnl *** shout2 ***
 823 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 824 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 825   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 826 ])
 827
 828 dnl *** soup ***
 829 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 830 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 831   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.46, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 832   AC_SUBST(SOUP_CFLAGS)
 833   AC_SUBST(SOUP_LIBS)
 834 ])
 835
 836 dnl *** speex ***
 837 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 838 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 839   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 840 ])
 841
 842 dnl *** taglib ***
 843 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 844 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 845   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 846   if test "x$HAVE_CXX" != "xyes"; then
 847     USE_TAGLIB=false
 848     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 849   else
 850     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 851     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 852         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 853       ], [
 854         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 855     ])
 856     AC_SUBST(TAGLIB_CXXFLAGS)
 857   fi
 858 ])
 859
 860 dnl *** vpx ***
 861 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 862 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 863   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 864   HAVE_VP8=no
 865   HAVE_VP9=no
 866
 867   if test $HAVE_VPX = "yes"; then
 868     OLD_LIBS="$LIBS"
 869     OLD_CFLAGS="$CFLAGS"
 870     CFLAGS="$CFLAGS $VPX_CFLAGS"
 871     LIBS="$LIBS $VPX_LIBS"
 872     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 873       HAVE_VP8=yes
 874       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 875     ])
 876     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 877       HAVE_VP8=yes
 878       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 879     ])
 880
 881     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 882       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 883         HAVE_VP9=yes
 884         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 885       ])
 886       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 887         HAVE_VP9=yes
 888         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 889       ])
 890     ], [true])
 891
 892     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 893       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 894     ], [true])
 895
 896     LIBS="$OLD_LIBS"
 897     CFLAGS="$OLD_CFLAGS"
 898   fi
 899   AC_SUBST(VPX_LIBS)
 900   AC_SUBST(VPX_CFLAGS)
 901 ])
 902
 903 dnl *** wavpack ***
 904 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 905 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 906   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 907 ])
 908
 909 dnl *** qtdemux & matroska prefer to have zlib ***
 910 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 911 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 912   AG_GST_CHECK_LIBHEADER(ZLIB,
 913     z, uncompress,, zlib.h, [
 914     HAVE_ZLIB="yes"
 915     ZLIB_LIBS="-lz"
 916     AC_SUBST(ZLIB_LIBS)
 917   ])
 918 ])
 919
 920 dnl *** matroska prefers to have bz2 ***
 921 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 922 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 923   save_LIBS=$LIBS
 924   LIBS="$LIBS -lbz2"
 925   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 926   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 927   AC_MSG_RESULT($HAVE_BZ2)
 928   LIBS=$save_LIBS
 929   if test "x$HAVE_BZ2" = "xyes"; then
 930     BZ2_LIBS="-lbz2"
 931   fi
 932   AC_SUBST(BZ2_LIBS)
 933 ])
 934
 935 else
 936
 937 dnl not building plugins with external dependencies,
 938 dnl but we still need to set the conditionals
 939 AM_CONDITIONAL(USE_AALIB, false)
 940 AM_CONDITIONAL(USE_BZ2, false)
 941 AM_CONDITIONAL(USE_CAIRO, false)
 942 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 943 AM_CONDITIONAL(USE_DV1394, false)
 944 AM_CONDITIONAL(USE_FLAC, false)
 945 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 946 AM_CONDITIONAL(USE_JACK, false)
 947 AM_CONDITIONAL(USE_JPEG, false)
 948 AM_CONDITIONAL(USE_LIBCACA, false)
 949 AM_CONDITIONAL(USE_LIBDV, false)
 950 AM_CONDITIONAL(USE_LIBIEC61883, false)
 951 AM_CONDITIONAL(USE_LIBPNG, false)
 952 AM_CONDITIONAL(USE_OSS, false)
 953 AM_CONDITIONAL(USE_OSS4, false)
 954 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 955 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 956 AM_CONDITIONAL(USE_PULSE, false)
 957 AM_CONDITIONAL(USE_SHOUT2, false)
 958 AM_CONDITIONAL(USE_SOUP, false)
 959 AM_CONDITIONAL(USE_SPEEX, false)
 960 AM_CONDITIONAL(USE_SUNAUDIO, false)
 961 AM_CONDITIONAL(USE_TAGLIB, false)
 962 AM_CONDITIONAL(USE_VPX, false)
 963 AM_CONDITIONAL(USE_WAVEFORM, false)
 964 AM_CONDITIONAL(USE_WAVPACK, false)
 965 AM_CONDITIONAL(USE_X, false)
 966 AM_CONDITIONAL(USE_XSHM, false)
 967 AM_CONDITIONAL(USE_ZLIB, false)
 968
 969 fi dnl of EXT plugins
 970
 971 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 972
 973 dnl Overview:
 974 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 975 dnl GST_*:              flags shared by all built objects
 976 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 977 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 978 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 979 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 980
 981 dnl GST_OPTION_CFLAGS
 982 if test "x$USE_DEBUG" = xyes; then
 983    PROFILE_CFLAGS="-g"
 984 fi
 985 AC_SUBST(PROFILE_CFLAGS)
 986
 987 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 988   dnl Define _only_ for git (not pre-releases or releases)
 989   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 990 else
 991   DEPRECATED_CFLAGS=""
 992 fi
 993 AC_SUBST(DEPRECATED_CFLAGS)
 994
 995 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 996 dnl at make time with e.g. make ERROR_CFLAGS=""
 997 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 998 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 999 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1000 AC_SUBST(GST_OPTION_CFLAGS)
1001 AC_SUBST(GST_OPTION_CXXFLAGS)
1002 AC_SUBST(GST_OPTION_OBJCFLAGS)
1003
1004 dnl our libraries need to be versioned correctly
1005 AC_SUBST(GST_LT_LDFLAGS)
1006
1007 dnl FIXME: do we want to rename to GST_ALL_* ?
1008 dnl prefer internal headers to already installed ones
1009 dnl also add builddir include for enumtypes and marshal
1010 dnl add ERROR_CFLAGS, but overridable
1011 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1012 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1013 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1014 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1015 AC_SUBST(GST_CFLAGS)
1016 AC_SUBST(GST_CXXFLAGS)
1017 AC_SUBST(GST_OBJCFLAGS)
1018 AC_SUBST(GST_LIBS)
1019
1020 dnl LDFLAGS really should only contain flags, not libs - they get added before
1021 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1022 GST_ALL_LDFLAGS="-no-undefined"
1023 if test "x${enable_Bsymbolic}" = "xyes"; then
1024   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1025 fi
1026 AC_SUBST(GST_ALL_LDFLAGS)
1027
1028 dnl this really should only contain flags, not libs - they get added before
1029 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1030 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1031 AC_SUBST(GST_PLUGIN_LDFLAGS)
1032
1033 dnl *** output files ***
1034
1035 $MKDIR_P tests/check/orc
1036
1037 dnl keep this alphabetic per directory, please
1038 AC_CONFIG_FILES(
1039 Makefile
1040 gst/Makefile
1041 gst/alpha/Makefile
1042 gst/apetag/Makefile
1043 gst/audiofx/Makefile
1044 gst/audioparsers/Makefile
1045 gst/auparse/Makefile
1046 gst/autodetect/Makefile
1047 gst/avi/Makefile
1048 gst/cutter/Makefile
1049 gst/deinterlace/Makefile
1050 gst/dtmf/Makefile
1051 gst/debugutils/Makefile
1052 gst/effectv/Makefile
1053 gst/equalizer/Makefile
1054 gst/flv/Makefile
1055 gst/goom/Makefile
1056 gst/goom2k1/Makefile
1057 gst/id3demux/Makefile
1058 gst/icydemux/Makefile
1059 gst/imagefreeze/Makefile
1060 gst/interleave/Makefile
1061 gst/isomp4/Makefile
1062 gst/law/Makefile
1063 gst/level/Makefile
1064 gst/matroska/Makefile
1065 gst/monoscope/Makefile
1066 gst/multifile/Makefile
1067 gst/multipart/Makefile
1068 gst/replaygain/Makefile
1069 gst/rtp/Makefile
1070 gst/rtpmanager/Makefile
1071 gst/rtsp/Makefile
1072 gst/shapewipe/Makefile
1073 gst/smpte/Makefile
1074 gst/spectrum/Makefile
1075 gst/udp/Makefile
1076 gst/videobox/Makefile
1077 gst/videocrop/Makefile
1078 gst/videofilter/Makefile
1079 gst/videomixer/Makefile
1080 gst/wavenc/Makefile
1081 gst/wavparse/Makefile
1082 gst/flx/Makefile
1083 gst/y4m/Makefile
1084 ext/Makefile
1085 ext/aalib/Makefile
1086 ext/cairo/Makefile
1087 ext/dv/Makefile
1088 ext/flac/Makefile
1089 ext/gdk_pixbuf/Makefile
1090 ext/jack/Makefile
1091 ext/jpeg/Makefile
1092 ext/libcaca/Makefile
1093 ext/libpng/Makefile
1094 ext/pulse/Makefile
1095 ext/raw1394/Makefile
1096 ext/shout2/Makefile
1097 ext/soup/Makefile
1098 ext/speex/Makefile
1099 ext/taglib/Makefile
1100 ext/vpx/Makefile
1101 ext/wavpack/Makefile
1102 sys/Makefile
1103 sys/directsound/Makefile
1104 sys/oss/Makefile
1105 sys/oss4/Makefile
1106 sys/osxaudio/Makefile
1107 sys/osxvideo/Makefile
1108 sys/sunaudio/Makefile
1109 sys/v4l2/Makefile
1110 sys/waveform/Makefile
1111 sys/ximage/Makefile
1112 po/Makefile.in
1113 tests/Makefile
1114 tests/check/Makefile
1115 tests/examples/Makefile
1116 tests/examples/audiofx/Makefile
1117 tests/examples/cairo/Makefile
1118 tests/examples/equalizer/Makefile
1119 tests/examples/jack/Makefile
1120 tests/examples/level/Makefile
1121 tests/examples/rtp/Makefile
1122 tests/examples/shapewipe/Makefile
1123 tests/examples/spectrum/Makefile
1124 tests/examples/v4l2/Makefile
1125 tests/files/Makefile
1126 tests/icles/Makefile
1127 common/Makefile
1128 common/m4/Makefile
1129 m4/Makefile
1130 docs/Makefile
1131 docs/plugins/Makefile
1132 docs/version.entities
1133 pkgconfig/Makefile
1134 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1135 )
1136 AC_OUTPUT
1137
1138 AG_GST_OUTPUT_PLUGINS
1139 ORC_OUTPUT
1140