meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.19.2',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.56.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32 mathlib = cc.find_library('m', required : false)
  33
  34 cdata = configuration_data()
  35
  36 prefix = get_option('prefix')
  37 datadir = prefix / get_option('datadir')
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50
  51       # Enable some warnings on MSVC to match GCC/Clang behaviour
  52       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  53       '/w14101', # 'identifier' : unreferenced local variable
  54       '/w14189', # 'identifier' : local variable is initialized but not referenced
  55   ]
  56   add_project_arguments(msvc_args, language: 'c')
  57 endif
  58
  59 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  60   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  61 endif
  62
  63 # Symbol visibility
  64 if cc.get_id() == 'msvc'
  65   export_define = '__declspec(dllexport) extern'
  66 elif cc.has_argument('-fvisibility=hidden')
  67   add_project_arguments('-fvisibility=hidden', language: 'c')
  68   export_define = 'extern __attribute__ ((visibility ("default")))'
  69 else
  70   export_define = 'extern'
  71 endif
  72
  73 # Passing this through the command line would be too messy
  74 cdata.set('GST_API_EXPORT', export_define)
  75
  76 # Disable strict aliasing
  77 if cc.has_argument('-fno-strict-aliasing')
  78   add_project_arguments('-fno-strict-aliasing', language: 'c')
  79 endif
  80
  81 cdata.set('VERSION', '"@0@"'.format(gst_version))
  82 cdata.set('PACKAGE', '"gst-editing-services"')
  83 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  84 cdata.set('PACKAGE_BUGREPORT', '"https://gitlab.freedesktop.org/gstreamer/gst-editing-services/issues/new"')
  85 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  86 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  87 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  88 cdata.set('GST_LICENSE', '"LGPL"')
  89
  90 # Mandatory GST deps
  91 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  92     fallback : ['gstreamer', 'gst_dep'])
  93 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  94     fallback : ['gst-plugins-base', 'pbutils_dep'])
  95 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  96     fallback : ['gst-plugins-base', 'video_dep'])
  97 gstaudio_dep = dependency('gstreamer-audio-' + apiversion, version : gst_req,
  98     fallback : ['gst-plugins-base', 'audio_dep'])
  99 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 100     fallback : ['gstreamer', 'gst_base_dep'])
 101 if host_machine.system() != 'windows'
 102   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 103     required : get_option('tests'),
 104     fallback : ['gstreamer', 'gst_check_dep'])
 105 endif
 106 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 107   fallback : ['gstreamer', 'gst_controller_dep'])
 108 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : get_option('validate'),
 109   fallback : ['gst-devtools', 'validate_dep'])
 110
 111 gio_dep = dependency('gio-2.0', version: glib_req, fallback: ['glib', 'libgio_dep'])
 112 libxml_dep = dependency('libxml-2.0', required: get_option('xptv'))
 113 cdata.set('DISABLE_XPTV', not libxml_dep.found())
 114
 115 # TODO Properly port to Gtk 3
 116 # gtk_dep = dependency('gtk+-3.0', required : false)
 117
 118 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
 119                gstcontroller_dep, gio_dep, libxml_dep, mathlib]
 120
 121 if gstvalidate_dep.found()
 122     libges_deps = libges_deps + [gstvalidate_dep]
 123     cdata.set('HAVE_GST_VALIDATE', 1)
 124 endif
 125
 126 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 127 gnome = import('gnome')
 128
 129 # Fixme, not very elegant.
 130 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 131 gir_init_section = [ '--add-init-section=' + \
 132     'extern void gst_init(gint*,gchar**);' + \
 133     'extern void ges_init(void);' + \
 134     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 135     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 136     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 137     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 138     'gst_init(NULL,NULL);' + \
 139     'ges_init();', '--quiet']
 140
 141 has_python = false
 142 if build_gir
 143   pymod = import('python')
 144   python = pymod.find_installation(required: get_option('python'))
 145   if python.found()
 146     # Workaround for https://github.com/mesonbuild/meson/issues/5629
 147     pythonver = python.language_version()
 148     python_dep = dependency('python-@0@-embed'.format(pythonver), version: '>=3', required: false)
 149     if not python_dep.found()
 150       python_dep = python.dependency(required : get_option('python'))
 151     endif
 152   else
 153     python_dep = dependency('', required: false)
 154   endif
 155   if python_dep.found()
 156     python_abi_flags = python.get_variable('ABIFLAGS', '')
 157     pylib_loc = get_option('libpython-dir')
 158
 159     error_msg = ''
 160     if not cc.compiles('#include <Python.h>', dependencies: [python_dep])
 161       error_msg = 'Could not compile a simple program against python'
 162     elif pylib_loc == ''
 163       check_path_exists = 'import os, sys; assert(os.path.exists(sys.argv[1]))'
 164       pylib_loc = python.get_variable('LIBPL', '')
 165       if host_machine.system() != 'windows' and host_machine.system() != 'darwin'
 166         pylib_ldlibrary = python.get_variable('LDLIBRARY', '')
 167         if run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary)).returncode() != 0
 168           # Workaround for Fedora
 169           pylib_loc = python.get_variable('LIBDIR', '')
 170           message('pylib_loc = @0@'.format(pylib_loc))
 171         endif
 172
 173         res = run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary))
 174         if res.returncode() != 0
 175           error_msg = '@0@ doesn\' exist, can\'t use python'.format(join_paths(pylib_loc, pylib_ldlibrary))
 176         endif
 177       endif
 178       if error_msg == ''
 179         pylib_suffix = 'so'
 180         if host_machine.system() == 'windows'
 181           pylib_suffix = 'dll'
 182         elif host_machine.system() == 'darwin'
 183           pylib_suffix = 'dylib'
 184         endif
 185
 186         gmodule_dep = dependency('gmodule-2.0')
 187         libges_deps = libges_deps + [python_dep, gmodule_dep]
 188         has_python = true
 189         message('python_abi_flags = @0@'.format(python_abi_flags))
 190         message('pylib_loc = @0@'.format(pylib_loc))
 191         cdata.set('HAS_PYTHON', true)
 192         cdata.set('PY_LIB_LOC', '"@0@"'.format(pylib_loc))
 193         cdata.set('PY_ABI_FLAGS', '"@0@"'.format(python_abi_flags))
 194         cdata.set('PY_LIB_SUFFIX', '"@0@"'.format(pylib_suffix))
 195         cdata.set('PYTHON_VERSION', '"@0@"'.format(python_dep.version()))
 196       else
 197           if get_option('python').enabled()
 198             error(error_msg)
 199           else
 200             message(error_msg)
 201           endif
 202       endif
 203     endif
 204   endif
 205 endif
 206
 207 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 208 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 209
 210 pkgconfig = import('pkgconfig')
 211 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 212 if get_option('default_library') == 'shared'
 213   # If we don't build static plugins there is no need to generate pc files
 214   plugins_pkgconfig_install_dir = disabler()
 215 endif
 216
 217 if gst_dep.type_name() == 'internal'
 218   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 219 else
 220   # We can't check that in the case of subprojects as we won't
 221   # be able to build against an internal dependency (which is not built yet)
 222   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 223 endif
 224
 225 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 226   add_project_arguments('-Wno-unused', language: 'c')
 227 endif
 228
 229 warning_flags = [
 230   '-Wmissing-declarations',
 231   '-Wmissing-prototypes',
 232   '-Wredundant-decls',
 233   '-Wundef',
 234   '-Wwrite-strings',
 235   '-Wformat',
 236   '-Wformat-security',
 237   '-Winit-self',
 238   '-Wmissing-include-dirs',
 239   '-Waddress',
 240   '-Wno-multichar',
 241   '-Wdeclaration-after-statement',
 242   '-Wvla',
 243   '-Wpointer-arith',
 244 ]
 245
 246 foreach extra_arg : warning_flags
 247   if cc.has_argument (extra_arg)
 248     add_project_arguments([extra_arg], language: 'c')
 249   endif
 250 endforeach
 251
 252 python3 = import('python').find_installation()
 253 pkgconfig = import('pkgconfig')
 254 pkgconfig_subdirs = ['gstreamer-1.0']
 255
 256 configinc = include_directories('.')
 257 subdir('ges')
 258 subdir('plugins')
 259 if not get_option('tools').disabled()
 260   subdir('tools')
 261 endif
 262 subdir('tests')
 263 if not get_option('examples').disabled()
 264   subdir('examples')
 265 endif
 266 subdir('docs')
 267
 268 override_detector = '''
 269 import sys
 270 import os
 271
 272 prefix = sys.argv[1]
 273 version = sys.version_info
 274
 275 # If we are installing in the same prefix as PyGobject
 276 # make sure to install in the right place.
 277 import gi.overrides
 278
 279 overrides_path = os.path.dirname(gi.overrides.__file__)
 280 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 281     print(overrides_path)
 282     exit(0)
 283
 284 # Otherwise follow python's way of install site packages inside
 285 # the provided prefix
 286 if os.name == 'posix':
 287     print(os.path.join(
 288         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 289         'site-packages', 'gi', 'overrides'))
 290 else:
 291     print(os.path.join(
 292         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 293         'site-packages', 'gi', 'overrides'))
 294 '''
 295 pygi_override_dir = get_option('pygi-overrides-dir')
 296 if pygi_override_dir == ''
 297     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 298     if cres.returncode() == 0
 299       pygi_override_dir = cres.stdout().strip()
 300     endif
 301     if cres.stderr() != ''
 302         message(cres.stderr())
 303     endif
 304 endif
 305
 306 if pygi_override_dir != ''
 307   message('pygobject overrides directory ' + pygi_override_dir)
 308   subdir('bindings/python')
 309 endif
 310
 311 # Set release date
 312 if gst_version_nano == 0
 313   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 314   run_result = run_command(extract_release_date, gst_version, files('gst-editing-services.doap'))
 315   if run_result.returncode() == 0
 316     release_date = run_result.stdout().strip()
 317     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 318     message('Package release date: ' + release_date)
 319   else
 320     # Error out if our release can't be found in the .doap file
 321     error(run_result.stderr())
 322   endif
 323 endif
 324
 325 if gio_dep.version().version_compare('< 2.67.4')
 326   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 327 endif
 328
 329 configure_file(output: 'config.h', configuration: cdata)
 330
 331 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')