configure.ac

   1 # configure.ac - for GnuPG 2.1
   2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
   3 # Copyright (C) 1998-2018 Werner Koch
   4 #
   5 # This file is part of GnuPG.
   6 #
   7 # GnuPG is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GnuPG is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
  19
  20 # Process this file with autoconf to produce a configure script.
  21 AC_PREREQ(2.61)
  22 min_automake_version="1.14"
  23
  24 # To build a release you need to create a tag with the version number
  25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
  26 # bump the version number immediately *after* the release and do
  27 # another commit and push so that the git magic is able to work.
  28 m4_define([mym4_package],[gnupg])
  29 m4_define([mym4_major], [2])
  30 m4_define([mym4_minor], [2])
  31 m4_define([mym4_micro], [6])
  32
  33 # To start a new development series, i.e a new major or minor number
  34 # you need to mark an arbitrary commit before the first beta release
  35 # with an annotated tag.  For example the 2.1 branch starts off with
  36 # the tag "gnupg-2.1-base".  This is used as the base for counting
  37 # beta numbers before the first release of a series.
  38
  39 # Below is m4 magic to extract and compute the git revision number,
  40 # the decimalized short revision number, a beta version string and a
  41 # flag indicating a development version (mym4_isbeta).  Note that the
  42 # m4 processing is done by autoconf and not during the configure run.
  43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
  44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
  45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
  46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
  47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
  48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
  49 m4_esyscmd([echo ]mym4_version[>VERSION])
  50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
  51
  52 # When changing the SWDB tag please also adjust the hard coded tags in
  53 # build-aux/speedo.mk and Makefile.am
  54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg22", [swdb tag for this branch])
  55
  56 NEED_GPG_ERROR_VERSION=1.24
  57
  58 NEED_LIBGCRYPT_API=1
  59 NEED_LIBGCRYPT_VERSION=1.7.0
  60
  61 NEED_LIBASSUAN_API=2
  62 NEED_LIBASSUAN_VERSION=2.5.0
  63
  64 NEED_KSBA_API=1
  65 NEED_KSBA_VERSION=1.3.4
  66
  67 NEED_NTBTLS_API=1
  68 NEED_NTBTLS_VERSION=0.1.0
  69
  70 NEED_NPTH_API=1
  71 NEED_NPTH_VERSION=1.2
  72
  73
  74 NEED_GNUTLS_VERSION=3.0
  75
  76 NEED_SQLITE_VERSION=3.7
  77
  78 development_version=mym4_isbeta
  79 PACKAGE=$PACKAGE_NAME
  80 PACKAGE_GT=${PACKAGE_NAME}2
  81 VERSION=$PACKAGE_VERSION
  82
  83 AC_CONFIG_AUX_DIR([build-aux])
  84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
  85 AC_CONFIG_HEADER([config.h])
  86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
  87 AC_CANONICAL_HOST
  88 AB_INIT
  89
  90 AC_GNU_SOURCE
  91
  92
  93 # Some status variables.
  94 have_gpg_error=no
  95 have_libgcrypt=no
  96 have_libassuan=no
  97 have_ksba=no
  98 have_ntbtls=no
  99 have_gnutls=no
 100 have_sqlite=no
 101 have_npth=no
 102 have_libusb=no
 103 have_system_resolver=no
 104 gnupg_have_ldap="n/a"
 105
 106 use_zip=yes
 107 use_bzip2=yes
 108 use_exec=yes
 109 use_trust_models=yes
 110 use_tofu=yes
 111 use_libdns=yes
 112 card_support=yes
 113 use_ccid_driver=auto
 114 dirmngr_auto_start=yes
 115 use_tls_library=no
 116 large_secmem=no
 117 show_tor_support=no
 118
 119
 120 GNUPG_BUILD_PROGRAM(gpg, yes)
 121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
 122 # The agent is a required part and can't be disabled anymore.
 123 build_agent=yes
 124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
 125 GNUPG_BUILD_PROGRAM(g13, no)
 126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
 127 GNUPG_BUILD_PROGRAM(doc, yes)
 128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
 129 # We use gpgtar to unpack test data, hence we always build it.  If the
 130 # user opts out, we simply don't install it.
 131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
 132 GNUPG_BUILD_PROGRAM(wks-tools, no)
 133
 134 AC_SUBST(PACKAGE)
 135 AC_SUBST(PACKAGE_GT)
 136 AC_SUBST(VERSION)
 137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
 138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
 139                                 [Name of this package for gettext])
 140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
 141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
 142                                         [Bug report address])
 143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
 144                                        [Required version of Libgcrypt])
 145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
 146                                        [Required version of Libksba])
 147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
 148                                        [Required version of NTBTLS])
 149
 150
 151
 152 # The default is to use the modules from this package and the few
 153 # other packages in a standard place; i.e where this package gets
 154 # installed.  With these options it is possible to override these
 155 # ${prefix} depended values with fixed paths, which can't be replaced
 156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
 157 AC_ARG_WITH(agent-pgm,
 158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
 159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
 160 AC_SUBST(GNUPG_AGENT_PGM)
 161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
 162 show_gnupg_agent_pgm="(default)"
 163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
 164
 165 AC_ARG_WITH(pinentry-pgm,
 166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
 167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
 168 AC_SUBST(GNUPG_PINENTRY_PGM)
 169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
 170 show_gnupg_pinentry_pgm="(default)"
 171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
 172
 173
 174 AC_ARG_WITH(scdaemon-pgm,
 175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
 176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
 177 AC_SUBST(GNUPG_SCDAEMON_PGM)
 178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
 179 show_gnupg_scdaemon_pgm="(default)"
 180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
 181
 182
 183 AC_ARG_WITH(dirmngr-pgm,
 184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
 185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
 186 AC_SUBST(GNUPG_DIRMNGR_PGM)
 187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
 188 show_gnupg_dirmngr_pgm="(default)"
 189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
 190
 191 AC_ARG_WITH(protect-tool-pgm,
 192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
 193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
 194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
 195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
 196 show_gnupg_protect_tool_pgm="(default)"
 197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
 198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
 199
 200 AC_ARG_WITH(dirmngr-ldap-pgm,
 201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
 202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
 203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
 204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
 205 show_gnupg_dirmngr_ldap_pgm="(default)"
 206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
 207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
 208
 209
 210 #
 211 # For a long time gpg 2.x was installed as gpg2.  This changed with
 212 # 2.2.  This option can be used to install gpg under the name gpg2.
 213 #
 214 AC_ARG_ENABLE(gpg-is-gpg2,
 215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
 216     gpg_is_gpg2=$enableval)
 217 if test "$gpg_is_gpg2" = "yes"; then
 218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
 219 fi
 220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
 221
 222
 223 # SELinux support includes tracking of sensitive files to avoid
 224 # leaking their contents through processing these files by gpg itself
 225 AC_MSG_CHECKING([whether SELinux support is requested])
 226 AC_ARG_ENABLE(selinux-support,
 227               AC_HELP_STRING([--enable-selinux-support],
 228                              [enable SELinux support]),
 229               selinux_support=$enableval, selinux_support=no)
 230 AC_MSG_RESULT($selinux_support)
 231
 232
 233 AC_MSG_CHECKING([whether to allocate extra secure memory])
 234 AC_ARG_ENABLE(large-secmem,
 235               AC_HELP_STRING([--enable-large-secmem],
 236                              [allocate extra secure memory]),
 237               large_secmem=$enableval, large_secmem=no)
 238 AC_MSG_RESULT($large_secmem)
 239 if test "$large_secmem" = yes ; then
 240    SECMEM_BUFFER_SIZE=65536
 241 else
 242    SECMEM_BUFFER_SIZE=32768
 243 fi
 244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
 245                    [Size of secure memory buffer])
 246
 247 AC_MSG_CHECKING([whether to enable trust models])
 248 AC_ARG_ENABLE(trust-models,
 249               AC_HELP_STRING([--disable-trust-models],
 250                              [disable all trust models except "always"]),
 251               use_trust_models=$enableval)
 252 AC_MSG_RESULT($use_trust_models)
 253 if test "$use_trust_models" = no ; then
 254     AC_DEFINE(NO_TRUST_MODELS, 1,
 255              [Define to include only trust-model always])
 256 fi
 257
 258 AC_MSG_CHECKING([whether to enable TOFU])
 259 AC_ARG_ENABLE(tofu,
 260                 AC_HELP_STRING([--disable-tofu],
 261                                [disable the TOFU trust model]),
 262               use_tofu=$enableval, use_tofu=$use_trust_models)
 263 AC_MSG_RESULT($use_tofu)
 264 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
 265     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
 266 fi
 267
 268 AC_MSG_CHECKING([whether to enable libdns])
 269 AC_ARG_ENABLE(libdns,
 270                 AC_HELP_STRING([--disable-libdns],
 271                                [do not build with libdns support]),
 272               use_libdns=$enableval, use_libdns=yes)
 273 AC_MSG_RESULT($use_libdns)
 274 if test x"$use_libdns" = xyes ; then
 275     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
 276 fi
 277 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
 278
 279
 280 #
 281 # Options to disable algorithm
 282 #
 283
 284 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
 285 # Elgamal is a MUST algorithm
 286 # DSA is a MUST algorithm
 287 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
 288 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
 289 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
 290
 291 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
 292 # 3DES is a MUST algorithm
 293 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
 294 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
 295 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
 296 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
 297 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
 298 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
 299 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
 300 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
 301 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
 302
 303 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
 304 # SHA1 is a MUST algorithm
 305 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
 306 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
 307 # SHA256 is a MUST algorithm for GnuPG.
 308 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
 309 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
 310
 311
 312 # Allow disabling of zip support.
 313 # This is in general not a good idea because according to rfc4880 OpenPGP
 314 # implementations SHOULD support ZLIB.
 315 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
 316 AC_ARG_ENABLE(zip,
 317    AC_HELP_STRING([--disable-zip],
 318                   [disable the ZIP and ZLIB compression algorithm]),
 319    use_zip=$enableval)
 320 AC_MSG_RESULT($use_zip)
 321
 322 # Allow disabling of bzib2 support.
 323 # It is defined only after we confirm the library is available later
 324 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
 325 AC_ARG_ENABLE(bzip2,
 326    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
 327    use_bzip2=$enableval)
 328 AC_MSG_RESULT($use_bzip2)
 329
 330 # Configure option to allow or disallow execution of external
 331 # programs, like a photo viewer.
 332 AC_MSG_CHECKING([whether to enable external program execution])
 333 AC_ARG_ENABLE(exec,
 334     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
 335     use_exec=$enableval)
 336 AC_MSG_RESULT($use_exec)
 337 if test "$use_exec" = no ; then
 338     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
 339 fi
 340
 341 if test "$use_exec" = yes ; then
 342   AC_MSG_CHECKING([whether to enable photo ID viewing])
 343   AC_ARG_ENABLE(photo-viewers,
 344       [  --disable-photo-viewers disable photo ID viewers],
 345       [if test "$enableval" = no ; then
 346          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
 347       fi],enableval=yes)
 348   gnupg_cv_enable_photo_viewers=$enableval
 349   AC_MSG_RESULT($enableval)
 350
 351   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
 352     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
 353     AC_ARG_WITH(photo-viewer,
 354         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
 355         [if test "$withval" = yes ; then
 356            withval=no
 357         elif test "$withval" != no ; then
 358            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
 359                             [if set, restrict photo-viewer to this])
 360         fi],withval=no)
 361     AC_MSG_RESULT($withval)
 362   fi
 363 fi
 364
 365
 366 #
 367 # Check for the key/uid cache size.  This can't be zero, but can be
 368 # pretty small on embedded systems.  This is used for the gpg part.
 369 #
 370 AC_MSG_CHECKING([for the size of the key and uid cache])
 371 AC_ARG_ENABLE(key-cache,
 372         AC_HELP_STRING([--enable-key-cache=SIZE],
 373                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
 374 if test "$enableval" = "no"; then
 375    enableval=5
 376 elif test "$enableval" = "yes" || test "$enableval" = ""; then
 377    enableval=4096
 378 fi
 379 changequote(,)dnl
 380 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
 381 changequote([,])dnl
 382 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
 383    AC_MSG_ERROR([invalid key-cache size])
 384 fi
 385 AC_MSG_RESULT($key_cache_size)
 386 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
 387                   [Size of the key and UID caches])
 388
 389
 390
 391 #
 392 # Check whether we want to use Linux capabilities
 393 #
 394 AC_MSG_CHECKING([whether use of capabilities is requested])
 395 AC_ARG_WITH(capabilities,
 396     [  --with-capabilities     use linux capabilities [default=no]],
 397 [use_capabilities="$withval"],[use_capabilities=no])
 398 AC_MSG_RESULT($use_capabilities)
 399
 400 #
 401 # Check whether to disable the card support
 402 AC_MSG_CHECKING([whether smartcard support is requested])
 403 AC_ARG_ENABLE(card-support,
 404               AC_HELP_STRING([--disable-card-support],
 405                              [disable smartcard support]),
 406               card_support=$enableval)
 407 AC_MSG_RESULT($card_support)
 408 if test "$card_support" = yes ; then
 409   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
 410 else
 411   build_scdaemon=no
 412 fi
 413
 414 #
 415 # Allow disabling of internal CCID support.
 416 # It is defined only after we confirm the library is available later
 417 #
 418 AC_MSG_CHECKING([whether to enable the internal CCID driver])
 419 AC_ARG_ENABLE(ccid-driver,
 420               AC_HELP_STRING([--disable-ccid-driver],
 421                              [disable the internal CCID driver]),
 422               use_ccid_driver=$enableval)
 423 AC_MSG_RESULT($use_ccid_driver)
 424
 425 AC_MSG_CHECKING([whether to auto start dirmngr])
 426 AC_ARG_ENABLE(dirmngr-auto-start,
 427               AC_HELP_STRING([--disable-dirmngr-auto-start],
 428                              [disable auto starting of the dirmngr]),
 429               dirmngr_auto_start=$enableval)
 430 AC_MSG_RESULT($dirmngr_auto_start)
 431 if test "$dirmngr_auto_start" = yes ; then
 432     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
 433               [Define to enable auto starting of the dirmngr])
 434 fi
 435
 436
 437 #
 438 # To avoid double inclusion of config.h which might happen at some
 439 # places, we add the usual double inclusion protection at the top of
 440 # config.h.
 441 #
 442 AH_TOP([
 443 #ifndef GNUPG_CONFIG_H_INCLUDED
 444 #define GNUPG_CONFIG_H_INCLUDED
 445 ])
 446
 447 #
 448 # Stuff which goes at the bottom of config.h.
 449 #
 450 AH_BOTTOM([
 451 /* This is the major version number of GnuPG so that
 452    source included files can test for this.  Note, that
 453    we use 2 here even for GnuPG 1.9.x. */
 454 #define GNUPG_MAJOR_VERSION 2
 455
 456 /* Now to separate file name parts.
 457    Please note that the string version must not contain more
 458    than one character because the code assumes strlen()==1 */
 459 #ifdef HAVE_DOSISH_SYSTEM
 460 #define DIRSEP_C '\\'
 461 #define DIRSEP_S "\\"
 462 #define EXTSEP_C '.'
 463 #define EXTSEP_S "."
 464 #define PATHSEP_C ';'
 465 #define PATHSEP_S ";"
 466 #define EXEEXT_S ".exe"
 467 #else
 468 #define DIRSEP_C '/'
 469 #define DIRSEP_S "/"
 470 #define EXTSEP_C '.'
 471 #define EXTSEP_S "."
 472 #define PATHSEP_C ':'
 473 #define PATHSEP_S ":"
 474 #define EXEEXT_S ""
 475 #endif
 476
 477 /* This is the same as VERSION, but should be overridden if the
 478    platform cannot handle things like dots '.' in filenames. Set
 479    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
 480    uses for dots and dashes. */
 481 #define SAFE_VERSION VERSION
 482 #define SAFE_VERSION_DOT  '.'
 483 #define SAFE_VERSION_DASH '-'
 484
 485 /* Some global constants.
 486  * Note that the homedir must not end in a slash.  */
 487 #ifdef HAVE_DOSISH_SYSTEM
 488 # ifdef HAVE_DRIVE_LETTERS
 489 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
 490 # else
 491 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
 492 # endif
 493 #elif defined(__VMS)
 494 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
 495 #else
 496 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
 497 #endif
 498 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
 499 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
 500
 501 /* For some systems (DOS currently), we hardcode the path here.  For
 502    POSIX systems the values are constructed by the Makefiles, so that
 503    the values may be overridden by the make invocations; this is to
 504    comply with the GNU coding standards.  Note that these values are
 505    only defaults.  */
 506 #ifdef HAVE_DOSISH_SYSTEM
 507 # ifdef HAVE_DRIVE_LETTERS
 508 #  define GNUPG_BINDIR      "c:\\gnupg"
 509 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
 510 #  define GNUPG_LIBDIR      "c:\\gnupg"
 511 #  define GNUPG_DATADIR     "c:\\gnupg"
 512 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
 513 # else
 514 #  define GNUPG_BINDIR      "\\gnupg"
 515 #  define GNUPG_LIBEXECDIR  "\\gnupg"
 516 #  define GNUPG_LIBDIR      "\\gnupg"
 517 #  define GNUPG_DATADIR     "\\gnupg"
 518 #  define GNUPG_SYSCONFDIR  "\\gnupg"
 519 # endif
 520 #endif
 521
 522 /* Derive some other constants. */
 523 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
 524 #define EXEC_TEMPFILE_ONLY
 525 #endif
 526
 527
 528 /* We didn't define endianness above, so get it from OS macros.  This
 529    is intended for making fat binary builds on OS X. */
 530 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
 531 #if defined(__BIG_ENDIAN__)
 532 #define BIG_ENDIAN_HOST 1
 533 #elif defined(__LITTLE_ENDIAN__)
 534 #define LITTLE_ENDIAN_HOST 1
 535 #else
 536 #error "No endianness found"
 537 #endif
 538 #endif
 539
 540
 541 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
 542    ldap_start_tls_s because that is the actual symbol used in the
 543    library.  winldap.h redefines it to our commonly used value,
 544    thus we define our usual macro here.  */
 545 #ifdef HAVE_LDAP_START_TLS_SA
 546 # ifndef HAVE_LDAP_START_TLS_S
 547 #  define HAVE_LDAP_START_TLS_S 1
 548 # endif
 549 #endif
 550
 551 /* Provide the es_ macro for estream.  */
 552 #define GPGRT_ENABLE_ES_MACROS 1
 553
 554 /* Tell libgcrypt not to use its own libgpg-error implementation. */
 555 #define USE_LIBGPG_ERROR 1
 556
 557 /* Tell Libgcrypt not to include deprecated definitions.  */
 558 #define GCRYPT_NO_DEPRECATED 1
 559
 560 /* Our HTTP code is used in estream mode.  */
 561 #define HTTP_USE_ESTREAM 1
 562
 563 /* Under W32 we do an explicit socket initialization, thus we need to
 564    avoid the on-demand initialization which would also install an atexit
 565    handler.  */
 566 #define HTTP_NO_WSASTARTUP
 567
 568 /* Under Windows we use the gettext code from libgpg-error.  */
 569 #define GPG_ERR_ENABLE_GETTEXT_MACROS
 570
 571 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
 572 #define GPG_ERR_ENABLE_ERRNO_MACROS
 573
 574 #endif /*GNUPG_CONFIG_H_INCLUDED*/
 575 ])
 576
 577
 578 AM_MAINTAINER_MODE
 579 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
 580
 581 # Checks for programs.
 582 AC_MSG_NOTICE([checking for programs])
 583 AC_PROG_MAKE_SET
 584 AM_SANITY_CHECK
 585 missing_dir=`cd $ac_aux_dir && pwd`
 586 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 587 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 588 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
 589 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 590 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
 591 AM_SILENT_RULES
 592 AC_PROG_AWK
 593 AC_PROG_CC
 594 AC_PROG_CPP
 595 AM_PROG_CC_C_O
 596 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
 597   AC_MSG_ERROR([[No C-89 compiler found]])
 598 fi
 599 AC_PROG_INSTALL
 600 AC_PROG_LN_S
 601 AC_PROG_RANLIB
 602 AC_CHECK_TOOL(AR, ar, :)
 603 AC_PATH_PROG(PERL,"perl")
 604 AC_CHECK_TOOL(WINDRES, windres, :)
 605 AC_PATH_PROG(YAT2M, "yat2m")
 606 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
 607 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
 608 AC_ISC_POSIX
 609 AC_SYS_LARGEFILE
 610 GNUPG_CHECK_USTAR
 611
 612
 613 # We need to compile and run a program on the build machine.  A
 614 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
 615 # the AC archive is broken for autoconf 2.57.  Given that there is no
 616 # newer version of that macro, we assume that it is also broken for
 617 # autoconf 2.61 and thus we use a simple but usually sufficient
 618 # approach.
 619 AC_MSG_CHECKING(for cc for build)
 620 if test "$cross_compiling" = "yes"; then
 621   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
 622 else
 623   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
 624 fi
 625 AC_MSG_RESULT($CC_FOR_BUILD)
 626 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
 627
 628 # We need to call this macro because other pkg-config macros are
 629 # not always used.
 630 PKG_PROG_PKG_CONFIG
 631
 632
 633 try_gettext=yes
 634 require_iconv=yes
 635 have_dosish_system=no
 636 have_w32_system=no
 637 have_w32ce_system=no
 638 have_android_system=no
 639 use_simple_gettext=no
 640 use_ldapwrapper=yes
 641 mmap_needed=yes
 642 require_pipe_to_unblock_pselect=yes
 643 case "${host}" in
 644     *-mingw32*)
 645         # special stuff for Windoze NT
 646         ac_cv_have_dev_random=no
 647         AC_DEFINE(USE_ONLY_8DOT3,1,
 648                   [Set this to limit filenames to the 8.3 format])
 649         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
 650                   [Because the Unix gettext has too much overhead on
 651                    MingW32 systems and these systems lack Posix functions,
 652                    we use a simplified version of gettext])
 653         have_dosish_system=yes
 654         have_w32_system=yes
 655         require_iconv=no
 656         use_ldapwrapper=no  # Fixme: Do this only for CE.
 657         require_pipe_to_unblock_pselect=no
 658         case "${host}" in
 659           *-mingw32ce*)
 660             have_w32ce_system=yes
 661             ;;
 662           *)
 663             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
 664                       [Defined if the OS supports drive letters.])
 665             ;;
 666         esac
 667         try_gettext="no"
 668         use_simple_gettext=yes
 669         mmap_needed=no
 670         ;;
 671     i?86-emx-os2 | i?86-*-os2*emx )
 672         # OS/2 with the EMX environment
 673         ac_cv_have_dev_random=no
 674         AC_DEFINE(HAVE_DRIVE_LETTERS)
 675         have_dosish_system=yes
 676         try_gettext="no"
 677         ;;
 678
 679     i?86-*-msdosdjgpp*)
 680         # DOS with the DJGPP environment
 681         ac_cv_have_dev_random=no
 682         AC_DEFINE(HAVE_DRIVE_LETTERS)
 683         have_dosish_system=yes
 684         try_gettext="no"
 685         ;;
 686
 687     *-*-hpux*)
 688         if test -z "$GCC" ; then
 689             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
 690         fi
 691         ;;
 692     *-dec-osf4*)
 693         if test -z "$GCC" ; then
 694             # Suppress all warnings
 695             # to get rid of the unsigned/signed char mismatch warnings.
 696             CFLAGS="-w $CFLAGS"
 697         fi
 698         ;;
 699     *-dec-osf5*)
 700         if test -z "$GCC" ; then
 701             # Use the newer compiler `-msg_disable ptrmismatch1' to
 702             # get rid of the unsigned/signed char mismatch warnings.
 703             # Using this may hide other pointer mismatch warnings, but
 704             # it at least lets other warning classes through
 705             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
 706         fi
 707         ;;
 708     m68k-atari-mint)
 709         ;;
 710     *-linux-android*)
 711         have_android_system=yes
 712         # Android is fully utf-8 and we do not want to use iconv to
 713         # keeps things simple
 714         require_iconv=no
 715         ;;
 716     *-apple-darwin*)
 717         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
 718                   Expose all libc features (__DARWIN_C_FULL).)
 719         ;;
 720     *-*-netbsd*)
 721         require_pipe_to_unblock_pselect=yes
 722         ;;
 723     *)
 724         ;;
 725 esac
 726
 727 if test "$require_pipe_to_unblock_pselect" = yes; then
 728    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
 729              [Defined if we run on systems like NetBSD, where
 730               pselect cannot be unblocked by signal from a thread
 731               within the same process.  We use pipe in this case, instead.])
 732 fi
 733
 734 if test "$have_dosish_system" = yes; then
 735    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
 736              [Defined if we run on some of the PCDOS like systems
 737               (DOS, Windoze. OS/2) with special properties like
 738               no file modes, case insensitive file names and preferred
 739               use of backslashes as directory name separators.])
 740 fi
 741 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
 742
 743 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
 744
 745 if test "$have_w32_system" = yes; then
 746    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 747    if test "$have_w32ce_system" = yes; then
 748       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
 749    fi
 750 fi
 751 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 752 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
 753
 754 if test "$have_android_system" = yes; then
 755    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
 756 fi
 757 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
 758
 759
 760 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
 761 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
 762
 763
 764 #
 765 # Checks for libraries.
 766 #
 767 AC_MSG_NOTICE([checking for libraries])
 768
 769
 770 #
 771 # libgpg-error is a library with error codes shared between GnuPG
 772 # related projects.
 773 #
 774 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
 775                   have_gpg_error=yes,have_gpg_error=no)
 776
 777
 778 #
 779 # Libgcrypt is our generic crypto library
 780 #
 781 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
 782         have_libgcrypt=yes,have_libgcrypt=no)
 783
 784
 785 #
 786 # libassuan is used for IPC
 787 #
 788 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
 789                   have_libassuan=yes,have_libassuan=no)
 790 if test "$have_libassuan" = "yes"; then
 791   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
 792                      [version of the libassuan library])
 793   show_tor_support="only .onion"
 794 fi
 795
 796
 797 #
 798 # libksba is our X.509 support library
 799 #
 800 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
 801
 802
 803 #
 804 # libusb allows us to use the integrated CCID smartcard reader driver.
 805 #
 806 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
 807 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
 808    case "${host}" in
 809      *-mingw32*)
 810        LIBUSB_NAME=
 811        LIBUSB_LIBS=
 812        LIBUSB_CPPFLAGS=
 813        ;;
 814      *-*-darwin*)
 815        LIBUSB_NAME=usb-1.0
 816        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
 817        ;;
 818      *-*-freebsd*)
 819        # FreeBSD has a native 1.0 compatible library by -lusb.
 820        LIBUSB_NAME=usb
 821        LIBUSB_LIBS=
 822        ;;
 823      *)
 824        LIBUSB_NAME=usb-1.0
 825        LIBUSB_LIBS=
 826        ;;
 827    esac
 828 fi
 829 if test x"$LIBUSB_NAME" != x ; then
 830    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
 831                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
 832                   have_libusb=yes ])
 833    AC_MSG_CHECKING([libusb include dir])
 834    usb_incdir_found="no"
 835    for _incdir in "" "/usr/include/libusb-1.0" \
 836        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
 837      _libusb_save_cppflags=$CPPFLAGS
 838      if test -n "${_incdir}"; then
 839        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
 840      fi
 841      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
 842      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
 843      CPPFLAGS=${_libusb_save_cppflags}
 844      if test "$usb_incdir_found" = "yes"; then
 845        break
 846      fi
 847    done
 848    if test "$usb_incdir_found" = "yes"; then
 849      AC_MSG_RESULT([${usb_incdir}])
 850    else
 851      AC_MSG_RESULT([not found])
 852      usb_incdir=""
 853      have_libusb=no
 854      if test "$use_ccid_driver" != yes; then
 855        use_ccid_driver=no
 856      fi
 857      LIBUSB_LIBS=""
 858    fi
 859
 860    if test "$have_libusb" = yes; then
 861      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
 862    fi
 863    if test x"$usb_incdir" = x; then
 864      LIBUSB_CPPFLAGS=""
 865    else
 866      LIBUSB_CPPFLAGS="-I${usb_incdir}"
 867    fi
 868 fi
 869 AC_SUBST(LIBUSB_LIBS)
 870 AC_SUBST(LIBUSB_CPPFLAGS)
 871
 872 #
 873 # Check whether it is necessary to link against libdl.
 874 # (For example to load libpcsclite)
 875 #
 876 gnupg_dlopen_save_libs="$LIBS"
 877 LIBS=""
 878 AC_SEARCH_LIBS(dlopen, c dl,,,)
 879 DL_LIBS=$LIBS
 880 AC_SUBST(DL_LIBS)
 881 LIBS="$gnupg_dlopen_save_libs"
 882
 883
 884 # Checks for g10
 885
 886 AC_ARG_ENABLE(sqlite,
 887                 AC_HELP_STRING([--disable-sqlite],
 888                                [disable the use of SQLITE]),
 889               try_sqlite=$enableval, try_sqlite=yes)
 890
 891 if test x"$use_tofu" = xyes ; then
 892   if test x"$try_sqlite" = xyes ; then
 893     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
 894                                  [have_sqlite=yes],
 895                                  [have_sqlite=no])
 896   fi
 897   if test "$have_sqlite" = "yes"; then
 898     :
 899     AC_SUBST([SQLITE3_CFLAGS])
 900     AC_SUBST([SQLITE3_LIBS])
 901   else
 902     use_tofu=no
 903     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
 904     AC_MSG_WARN([[
 905 ***
 906 *** Building without SQLite support - TOFU disabled
 907 ***
 908 *** $tmp]])
 909   fi
 910 fi
 911
 912 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
 913
 914 if test x"$use_tofu" = xyes ; then
 915     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
 916 fi
 917
 918
 919 # Checks for g13
 920
 921 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
 922 AC_DEFINE_UNQUOTED(ENCFS,
 923         "${ENCFS}", [defines the filename of the encfs program])
 924
 925 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
 926 AC_DEFINE_UNQUOTED(FUSERMOUNT,
 927         "${FUSERMOUNT}", [defines the filename of the fusermount program])
 928
 929
 930 # Checks for dirmngr
 931
 932
 933 #
 934 # Checks for symcryptrun:
 935 #
 936
 937 # libutil has openpty() and login_tty().
 938 AC_CHECK_LIB(util, openpty,
 939               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
 940                 AC_DEFINE(HAVE_LIBUTIL,1,
 941                          [defined if libutil is available])
 942              ])
 943 AC_SUBST(LIBUTIL_LIBS)
 944
 945 # shred is used to clean temporary plain text files.
 946 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
 947 AC_DEFINE_UNQUOTED(SHRED,
 948         "${SHRED}", [defines the filename of the shred program])
 949
 950
 951 #
 952 # Check whether the nPth library is available
 953 #
 954 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
 955 if test "$have_npth" = "yes"; then
 956   AC_DEFINE(HAVE_NPTH, 1,
 957               [Defined if the New Portable Thread Library is available])
 958   AC_DEFINE(USE_NPTH, 1,
 959               [Defined if support for nPth is requested and nPth is available])
 960 else
 961   AC_MSG_WARN([[
 962 ***
 963 *** To support concurrent access for example in gpg-agent and the SCdaemon
 964 *** we need the support of the New Portable Threads Library.
 965 ***]])
 966 fi
 967
 968
 969 #
 970 # NTBTLS is our TLS library.  If it is not available fallback to
 971 # GNUTLS.
 972 #
 973 AC_ARG_ENABLE(ntbtls,
 974               AC_HELP_STRING([--disable-ntbtls],
 975                              [disable the use of NTBTLS as TLS library]),
 976               try_ntbtls=$enableval, try_ntbtls=yes)
 977 if test x"$try_ntbtls" = xyes ; then
 978   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
 979                  [have_ntbtls=yes],[have_ntbtls=no])
 980 fi
 981 if test "$have_ntbtls" = yes ; then
 982    use_tls_library=ntbtls
 983    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
 984 else
 985   AC_ARG_ENABLE(gnutls,
 986                 AC_HELP_STRING([--disable-gnutls],
 987                                [disable GNUTLS as fallback TLS library]),
 988                 try_gnutls=$enableval, try_gnutls=yes)
 989   if test x"$try_gnutls" = xyes ; then
 990     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
 991                                    [have_gnutls=yes],
 992                                    [have_gnutls=no])
 993   fi
 994   if test "$have_gnutls" = "yes"; then
 995     AC_SUBST([LIBGNUTLS_CFLAGS])
 996     AC_SUBST([LIBGNUTLS_LIBS])
 997     use_tls_library=gnutls
 998     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
 999   else
1000     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1001     AC_MSG_WARN([[
1002 ***
1003 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1004 ***
1005 *** $tmp]])
1006   fi
1007 fi
1008
1009 #
1010 # Allow to set a fixed trust store file for system provided certificates.
1011 #
1012 AC_ARG_WITH([default-trust-store-file],
1013             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1014                             [Use FILE as system trust store])],
1015             default_trust_store_file="$withval",
1016             default_trust_store_file="")
1017 if test x"$default_trust_store_file" = xno;then
1018   default_trust_store_file=""
1019 fi
1020 if test x"$default_trust_store_file" != x ; then
1021   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1022     ["$default_trust_store_file"], [Use as default system trust store file])
1023 fi
1024
1025
1026 AC_MSG_NOTICE([checking for networking options])
1027
1028 #
1029 # Must check for network library requirements before doing link tests
1030 # for ldap, for example. If ldap libs are static (or dynamic and without
1031 # ELF runtime link paths), then link will fail and LDAP support won't
1032 # be detected.
1033 #
1034 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1035         [NETLIBS="-lnsl $NETLIBS"]))
1036 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1037         [NETLIBS="-lsocket $NETLIBS"]))
1038
1039
1040 #
1041 # Check standard resolver functions.
1042 #
1043 if test "$build_dirmngr" = "yes"; then
1044   _dns_save_libs=$LIBS
1045   LIBS=""
1046
1047   # Find the system resolver which can always be enabled with
1048   # the dirmngr option --standard-resolver.
1049
1050   # the double underscore thing is a glibc-ism?
1051   AC_SEARCH_LIBS(res_query,resolv bind,,
1052                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1053   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1054                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1055
1056   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1057   # and for some reason fools us into believing we don't need
1058   # -lresolv even if we do.  Since the test program checking for the
1059   # symbol does not include <resolv.h>, we need to check for the
1060   # renamed symbol explicitly.
1061   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1062       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1063           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1064
1065   if test x"$have_resolver" != xno ; then
1066
1067       # Make sure that the BIND 4 resolver interface is workable before
1068       # enabling any code that calls it.  At some point I'll rewrite the
1069       # code to use the BIND 8 resolver API.
1070       # We might also want to use libdns instead.
1071
1072     AC_MSG_CHECKING([whether the resolver is usable])
1073     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1074 #include <netinet/in.h>
1075 #include <arpa/nameser.h>
1076 #include <resolv.h>]],
1077 [[unsigned char answer[PACKETSZ];
1078   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1079   dn_skipname(0,0);
1080   dn_expand(0,0,0,0,0);
1081 ]])],have_resolver=yes,have_resolver=no)
1082     AC_MSG_RESULT($have_resolver)
1083
1084     # This is Apple-specific and somewhat bizarre as they changed the
1085     # define in bind 8 for some reason.
1086
1087     if test x"$have_resolver" != xyes ; then
1088       AC_MSG_CHECKING(
1089            [whether I can make the resolver usable with BIND_8_COMPAT])
1090       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1091 #include <sys/types.h>
1092 #include <netinet/in.h>
1093 #include <arpa/nameser.h>
1094 #include <resolv.h>]],
1095 [[unsigned char answer[PACKETSZ];
1096   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1097   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1098 ]])],[have_resolver=yes ; need_compat=yes])
1099       AC_MSG_RESULT($have_resolver)
1100     fi
1101   fi
1102
1103   if test x"$have_resolver" = xyes ; then
1104     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1105     DNSLIBS="$DNSLIBS $LIBS"
1106     if test x"$need_compat" = xyes ; then
1107       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1108     fi
1109     if test "$use_libdns" = yes; then
1110      show_tor_support=yes
1111     fi
1112   elif test "$use_libdns" = yes; then
1113     show_tor_support=yes
1114   else
1115     AC_MSG_WARN([[
1116 ***
1117 *** The system's DNS resolver is not usable.
1118 *** Dirmngr functionality is limited.
1119 ***]])
1120     show_tor_support="${show_tor_support} (no system resolver)"
1121   fi
1122
1123   if test "$have_w32_system" = yes; then
1124     if test "$use_libdns" = yes; then
1125       DNSLIBS="$DNSLIBS -liphlpapi"
1126     fi
1127   fi
1128
1129   LIBS=$_dns_save_libs
1130 fi
1131
1132 AC_SUBST(DNSLIBS)
1133
1134
1135 #
1136 # Check for LDAP
1137 #
1138 # Note that running the check changes the variable
1139 # gnupg_have_ldap from "n/a" to "no" or "yes".
1140
1141 AC_ARG_ENABLE(ldap,
1142     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1143     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1144
1145 if test "$gnupg_have_ldap" != "no" ; then
1146   if test "$build_dirmngr" = "yes" ; then
1147      GNUPG_CHECK_LDAP($NETLIBS)
1148      AC_CHECK_LIB(lber, ber_free,
1149                   [ LBER_LIBS="$LBER_LIBS -llber"
1150                     AC_DEFINE(HAVE_LBER,1,
1151                              [defined if liblber is available])
1152                     have_lber=yes
1153                  ])
1154   fi
1155 fi
1156 AC_SUBST(LBER_LIBS)
1157 if test "$gnupg_have_ldap" = "no"; then
1158     AC_MSG_WARN([[
1159 ***
1160 *** Building without LDAP support.
1161 *** No CRL access or X.509 certificate search available.
1162 ***]])
1163 fi
1164
1165 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1166 if test "$gnupg_have_ldap" = yes ; then
1167   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1168 else
1169  use_ldapwrapper=no
1170 fi
1171
1172 if test "$use_ldapwrapper" = yes; then
1173    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1174 fi
1175 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1176
1177
1178
1179
1180 #
1181 # Check for sendmail
1182 #
1183 # This isn't necessarily sendmail itself, but anything that gives a
1184 # sendmail-ish interface to the outside world.  That includes Exim,
1185 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1186 AC_ARG_WITH(mailprog,
1187       AC_HELP_STRING([--with-mailprog=NAME],
1188                      [use "NAME -t" for mail transport]),
1189              ,with_mailprog=yes)
1190 if test x"$with_mailprog" = xyes ; then
1191     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1192 elif test x"$with_mailprog" != xno ; then
1193     AC_MSG_CHECKING([for a mail transport program])
1194     AC_SUBST(SENDMAIL,$with_mailprog)
1195     AC_MSG_RESULT($with_mailprog)
1196 fi
1197
1198
1199 #
1200 # Construct a printable name of the OS
1201 #
1202 case "${host}" in
1203     *-mingw32ce*)
1204         PRINTABLE_OS_NAME="W32CE"
1205         ;;
1206     *-mingw32*)
1207         PRINTABLE_OS_NAME="MingW32"
1208         ;;
1209     *-*-cygwin*)
1210         PRINTABLE_OS_NAME="Cygwin"
1211         ;;
1212     i?86-emx-os2 | i?86-*-os2*emx )
1213         PRINTABLE_OS_NAME="OS/2"
1214         ;;
1215     i?86-*-msdosdjgpp*)
1216         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1217         try_dynload=no
1218         ;;
1219     *-linux*)
1220         PRINTABLE_OS_NAME="GNU/Linux"
1221         ;;
1222     *)
1223         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1224         ;;
1225 esac
1226 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1227                    [A human readable text with the name of the OS])
1228
1229
1230 #
1231 # Checking for iconv
1232 #
1233 if test "$require_iconv" = yes; then
1234   AM_ICONV
1235 else
1236   LIBICONV=
1237   LTLIBICONV=
1238   AC_SUBST(LIBICONV)
1239   AC_SUBST(LTLIBICONV)
1240 fi
1241
1242
1243 #
1244 # Check for gettext
1245 #
1246 # This is "GNU gnupg" - The project-id script from gettext
1247 #                       needs this string
1248 #
1249 AC_MSG_NOTICE([checking for gettext])
1250 AM_PO_SUBDIRS
1251 AM_GNU_GETTEXT_VERSION([0.17])
1252 if test "$try_gettext" = yes; then
1253   AM_GNU_GETTEXT([external],[need-ngettext])
1254
1255   # gettext requires some extra checks.  These really should be part of
1256   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1257   # function checks to here.
1258
1259   AC_CHECK_FUNCS(strchr)
1260 else
1261   USE_NLS=no
1262   USE_INCLUDED_LIBINTL=no
1263   BUILD_INCLUDED_LIBINTL=no
1264   POSUB=po
1265   AC_SUBST(USE_NLS)
1266   AC_SUBST(USE_INCLUDED_LIBINTL)
1267   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1268   AC_SUBST(POSUB)
1269 fi
1270
1271 # We use HAVE_LANGINFO_CODESET in a couple of places.
1272 AM_LANGINFO_CODESET
1273
1274 # Checks required for our use of locales
1275 gt_LC_MESSAGES
1276
1277
1278 #
1279 # SELinux support
1280 #
1281 if test "$selinux_support" = yes ; then
1282   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1283 fi
1284
1285
1286 #
1287 # Checks for header files.
1288 #
1289 AC_MSG_NOTICE([checking for header files])
1290 AC_HEADER_STDC
1291 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1292                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1293                   stdint.h signal.h util.h libutil.h termios.h \
1294                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1295
1296 AC_HEADER_TIME
1297
1298
1299 #
1300 # Checks for typedefs, structures, and compiler characteristics.
1301 #
1302 AC_MSG_NOTICE([checking for system characteristics])
1303 AC_C_CONST
1304 AC_C_INLINE
1305 AC_C_VOLATILE
1306 AC_TYPE_SIZE_T
1307 AC_TYPE_MODE_T
1308 AC_TYPE_SIGNAL
1309 AC_DECL_SYS_SIGLIST
1310
1311 gl_HEADER_SYS_SOCKET
1312 gl_TYPE_SOCKLEN_T
1313
1314 AC_SEARCH_LIBS([inet_addr], [nsl])
1315
1316 AC_ARG_ENABLE(endian-check,
1317               AC_HELP_STRING([--disable-endian-check],
1318               [disable the endian check and trust the OS provided macros]),
1319               endiancheck=$enableval,endiancheck=yes)
1320
1321 if test x"$endiancheck" = xyes ; then
1322   GNUPG_CHECK_ENDIAN
1323 fi
1324
1325 # fixme: we should get rid of the byte type
1326 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1327 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1328 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1329 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1330 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1331
1332 AC_CHECK_SIZEOF(unsigned short)
1333 AC_CHECK_SIZEOF(unsigned int)
1334 AC_CHECK_SIZEOF(unsigned long)
1335 AC_CHECK_SIZEOF(unsigned long long)
1336 AC_HEADER_TIME
1337 AC_CHECK_SIZEOF(time_t,,[[
1338 #include <stdio.h>
1339 #if TIME_WITH_SYS_TIME
1340 # include <sys/time.h>
1341 # include <time.h>
1342 #else
1343 # if HAVE_SYS_TIME_H
1344 #  include <sys/time.h>
1345 # else
1346 #  include <time.h>
1347 # endif
1348 #endif
1349 ]])
1350 GNUPG_TIME_T_UNSIGNED
1351
1352
1353 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1354    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1355    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1356     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1357 fi
1358
1359
1360 #
1361 # Checks for library functions.
1362 #
1363 AC_MSG_NOTICE([checking for library functions])
1364 AC_CHECK_DECLS(getpagesize)
1365 AC_FUNC_FSEEKO
1366 AC_FUNC_VPRINTF
1367 AC_FUNC_FORK
1368 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1369 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1370 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1371 AC_CHECK_FUNCS([canonicalize_file_name])
1372 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1373 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1374 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1375 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1376 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1377                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1378                 flockfile funlockfile getpwnam getpwuid \
1379                 getenv inet_pton strpbrk])
1380
1381 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1382 # Given that we use nanosleep only as an optimization over a select
1383 # based wait function we want it only if it is available in libc.
1384 _save_libs="$LIBS"
1385 AC_SEARCH_LIBS([nanosleep], [],
1386                [AC_DEFINE(HAVE_NANOSLEEP,1,
1387                 [Define to 1 if you have the `nanosleep' function in libc.])])
1388 LIBS="$_save_libs"
1389
1390
1391 # See whether libc supports the Linux inotify interface
1392 case "${host}" in
1393     *-*-linux*)
1394         AC_CHECK_FUNCS([inotify_init])
1395         ;;
1396 esac
1397
1398
1399 if test "$have_android_system" = yes; then
1400    # On Android ttyname is a stub but prints an error message.
1401    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1402              [Defined if ttyname does not work properly])
1403 fi
1404
1405 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1406
1407 # Dirmngr requires mmap on Unix systems.
1408 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1409   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1410 fi
1411
1412
1413 #
1414 # Check for the getsockopt SO_PEERCRED, etc.
1415 #
1416 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1417 #include <sys/socket.h> ])
1418
1419 # (Open)Solaris
1420 AC_CHECK_FUNCS([getpeerucred])
1421
1422
1423 #
1424 # W32 specific test
1425 #
1426 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1427
1428 #
1429 # Sanity check regex.  Tests adapted from mutt.
1430 #
1431 AC_MSG_CHECKING([whether regular expression support is requested])
1432 AC_ARG_ENABLE(regex,
1433   AC_HELP_STRING([--disable-regex],
1434     [do not handle regular expressions in trust signatures]),
1435   use_regex=$enableval, use_regex=yes)
1436 AC_MSG_RESULT($use_regex)
1437
1438 if test "$use_regex" = yes ; then
1439   _cppflags="${CPPFLAGS}"
1440   _ldflags="${LDFLAGS}"
1441   AC_ARG_WITH(regex,
1442      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1443       [
1444       if test -d "$withval" ; then
1445         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1446         LDFLAGS="${LDFLAGS} -L$withval/lib"
1447       fi
1448       ],withval="")
1449
1450   # Does the system have regex functions at all?
1451   AC_SEARCH_LIBS([regcomp], [regex])
1452   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1453
1454   if test $gnupg_cv_have_regex = no; then
1455     use_regex=no
1456   else
1457     if test x"$cross_compiling" = xyes; then
1458       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1459     else
1460       AC_CACHE_CHECK([whether your system's regexp library is broken],
1461        [gnupg_cv_regex_broken],
1462        AC_TRY_RUN([
1463 #include <unistd.h>
1464 #include <regex.h>
1465 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1466        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1467
1468       if test $gnupg_cv_regex_broken = yes; then
1469         AC_MSG_WARN([your regex is broken - disabling regex use])
1470         use_regex=no
1471       fi
1472     fi
1473   fi
1474   CPPFLAGS="${_cppflags}"
1475   LDFLAGS="${_ldflags}"
1476 fi
1477
1478 if test "$use_regex" != yes ; then
1479   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1480 fi
1481 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1482
1483
1484
1485 #
1486 # Do we have zlib? Must do it here because Solaris failed
1487 # when compiling a conftest (due to the "-lz" from LIBS).
1488 # Note that we combine zlib and bzlib2 in ZLIBS.
1489 #
1490 if test "$use_zip" = yes ; then
1491   _cppflags="${CPPFLAGS}"
1492   _ldflags="${LDFLAGS}"
1493   AC_ARG_WITH(zlib,
1494     [  --with-zlib=DIR         use libz in DIR],[
1495       if test -d "$withval"; then
1496         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1497         LDFLAGS="${LDFLAGS} -L$withval/lib"
1498       fi
1499     ])
1500
1501   AC_CHECK_HEADER(zlib.h,
1502      AC_CHECK_LIB(z, deflateInit2_,
1503        [
1504        ZLIBS="-lz"
1505        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1506        ],
1507        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1508        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1509 fi
1510
1511
1512 #
1513 # Check whether we can support bzip2
1514 #
1515 if test "$use_bzip2" = yes ; then
1516   _cppflags="${CPPFLAGS}"
1517   _ldflags="${LDFLAGS}"
1518   AC_ARG_WITH(bzip2,
1519      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1520       [
1521       if test -d "$withval" ; then
1522         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1523         LDFLAGS="${LDFLAGS} -L$withval/lib"
1524       fi
1525       ],withval="")
1526
1527   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1528   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1529   # woefully out of date.
1530   if test "$withval" != no ; then
1531      AC_CHECK_HEADER(bzlib.h,
1532         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1533           [
1534           have_bz2=yes
1535           ZLIBS="$ZLIBS -lbz2"
1536           AC_DEFINE(HAVE_BZIP2,1,
1537                   [Defined if the bz2 compression library is available])
1538           ],
1539           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1540           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1541   fi
1542 fi
1543 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1544 AC_SUBST(ZLIBS)
1545
1546
1547 # Check for readline support
1548 GNUPG_CHECK_READLINE
1549
1550
1551 if test "$development_version" = yes; then
1552     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1553             [Defined if this is not a regular release])
1554 fi
1555
1556 if test "$USE_MAINTAINER_MODE" = "yes"; then
1557     AC_DEFINE(MAINTAINER_MODE,1,
1558             [Defined if this build is in maintainer mode])
1559 fi
1560
1561 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1562
1563 GNUPG_CHECK_GNUMAKE
1564
1565 # Add some extra libs here so that previous tests don't fail for
1566 # mysterious reasons - the final link step should bail out.
1567 # W32SOCKLIBS is also defined so that if can be used for tools not
1568 # requiring any network stuff but linking to code in libcommon which
1569 # tracks in winsock stuff (e.g. init_common_subsystems).
1570 if test "$have_w32_system" = yes; then
1571    if test "$have_w32ce_system" = yes; then
1572      W32SOCKLIBS="-lws2"
1573    else
1574      W32SOCKLIBS="-lws2_32"
1575    fi
1576    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1577 fi
1578
1579 AC_SUBST(NETLIBS)
1580 AC_SUBST(W32SOCKLIBS)
1581
1582 #
1583 # Setup gcc specific options
1584 #
1585 USE_C99_CFLAGS=
1586 AC_MSG_NOTICE([checking for cc features])
1587 if test "$GCC" = yes; then
1588     mycflags=
1589     mycflags_save=$CFLAGS
1590
1591     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1592     # options.  This is the case for gcc >= 4.6
1593     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1594     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1595 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1596 #kickerror
1597 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1598     AC_MSG_RESULT($_gcc_silent_wno)
1599
1600     # Note that it is okay to use CFLAGS here because these are just
1601     # warning options and the user should have a chance of overriding
1602     # them.
1603     if test "$USE_MAINTAINER_MODE" = "yes"; then
1604         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1605         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1606         if test x"$_gcc_silent_wno" = xyes ; then
1607           _gcc_wopt=yes
1608         else
1609           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1610           CFLAGS="-Wno-missing-field-initializers"
1611           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1612                             [_gcc_wopt=yes],[_gcc_wopt=no])
1613           AC_MSG_RESULT($_gcc_wopt)
1614         fi
1615         if test x"$_gcc_wopt" = xyes ; then
1616           mycflags="$mycflags -W -Wno-sign-compare"
1617           mycflags="$mycflags -Wno-missing-field-initializers"
1618         fi
1619
1620         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1621         CFLAGS="-Wdeclaration-after-statement"
1622         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1623         AC_MSG_RESULT($_gcc_wopt)
1624         if test x"$_gcc_wopt" = xyes ; then
1625           mycflags="$mycflags -Wdeclaration-after-statement"
1626         fi
1627
1628         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1629         CFLAGS="-Wlogical-op -Werror"
1630         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1631         AC_MSG_RESULT($_gcc_wopt)
1632         if test x"$_gcc_wopt" = xyes ; then
1633           mycflags="$mycflags -Wlogical-op"
1634         fi
1635
1636         AC_MSG_CHECKING([if gcc supports -Wvla])
1637         CFLAGS="-Wvla"
1638         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1639         AC_MSG_RESULT($_gcc_wopt)
1640         if test x"$_gcc_wopt" = xyes ; then
1641           mycflags="$mycflags -Wvla"
1642         fi
1643
1644     else
1645         mycflags="$mycflags -Wall"
1646     fi
1647
1648     if test x"$_gcc_silent_wno" = xyes ; then
1649       _gcc_psign=yes
1650     else
1651       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1652       CFLAGS="-Wno-pointer-sign"
1653       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1654                         [_gcc_psign=yes],[_gcc_psign=no])
1655       AC_MSG_RESULT($_gcc_psign)
1656     fi
1657     if test x"$_gcc_psign" = xyes ; then
1658        mycflags="$mycflags -Wno-pointer-sign"
1659     fi
1660
1661     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1662     CFLAGS="-Wpointer-arith"
1663     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1664     AC_MSG_RESULT($_gcc_psign)
1665     if test x"$_gcc_psign" = xyes ; then
1666        mycflags="$mycflags -Wpointer-arith"
1667     fi
1668
1669     CFLAGS="$mycflags $mycflags_save"
1670     if test "$use_libdns" = yes; then
1671        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1672        USE_C99_CFLAGS="-std=gnu99"
1673     fi
1674 fi
1675
1676 AC_SUBST(USE_C99_CFLAGS)
1677
1678
1679 #
1680 # This is handy for debugging so the compiler doesn't rearrange
1681 # things and eliminate variables.
1682 #
1683 AC_ARG_ENABLE(optimization,
1684    AC_HELP_STRING([--disable-optimization],
1685                   [disable compiler optimization]),
1686                   [if test $enableval = no ; then
1687                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1688                    fi])
1689
1690 #
1691 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1692 # misbehaving autoconf tests in case the user supplied -Werror.
1693 #
1694 AC_ARG_ENABLE(werror,
1695    AC_HELP_STRING([--enable-werror],
1696                   [append -Werror to CFLAGS]),
1697                   [if test $enableval = yes ; then
1698                       CFLAGS="$CFLAGS -Werror"
1699                    fi])
1700
1701 #
1702 # Configure option --enable-all-tests
1703 #
1704 AC_MSG_CHECKING([whether "make check" shall run all tests])
1705 AC_ARG_ENABLE(all-tests,
1706               AC_HELP_STRING([--enable-all-tests],
1707                              [let "make check" run all tests]),
1708               run_all_tests=$enableval, run_all_tests=no)
1709 AC_MSG_RESULT($run_all_tests)
1710 if test "$run_all_tests" = "yes"; then
1711     AC_DEFINE(RUN_ALL_TESTS,1,
1712             [Defined if "make check" shall run all tests])
1713 fi
1714
1715 #
1716 # We do not want support for the GNUPG_BUILDDIR environment variable
1717 # in a released version.  However, our regression tests suite requires
1718 # this and thus we build with support for it during "make distcheck".
1719 # This configure option implements this along with the top Makefile's
1720 # AM_DISTCHECK_CONFIGURE_FLAGS.
1721 #
1722 gnupg_builddir_envvar=no
1723 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1724               gnupg_builddir_envvar=$enableval)
1725 if test x"$gnupg_builddir_envvar" = x"yes"; then
1726    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1727       [This is only used with "make distcheck"])
1728 fi
1729
1730
1731 #
1732 # To avoid problems with systemd cleaning up the /run/user directory,
1733 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1734 # before /run/user
1735 #
1736 AC_ARG_ENABLE(run-gnupg-user-socket,
1737     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1738                    [try /run/gnupg/user for sockets prior to /run/user]),
1739     use_run_gnupg_user_socket=$enableval)
1740 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1741    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1742             [If defined try /run/gnupg/user before /run/user])
1743 fi
1744
1745
1746 #
1747 # Decide what to build
1748 #
1749
1750 build_scdaemon_extra=""
1751 if test "$build_scdaemon" = "yes"; then
1752   if test $have_libusb = no; then
1753      build_scdaemon_extra="without internal CCID driver"
1754   fi
1755   if test -n "$build_scdaemon_extra"; then
1756      build_scdaemon_extra="(${build_scdaemon_extra})"
1757   fi
1758 fi
1759
1760
1761 #
1762 # Set variables for use by automake makefiles.
1763 #
1764 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1765 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1766 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1767 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1768 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1769 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1770 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1771 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1772 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1773 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1774
1775 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1776 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1777 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1778
1779 #
1780 # Set some defines for use gpgconf.
1781 #
1782 if test "$build_gpg" = yes ; then
1783     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1784 fi
1785 if test "$build_gpgsm" = yes ; then
1786     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1787 fi
1788 if test "$build_agent" = yes ; then
1789     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1790 fi
1791 if test "$build_scdaemon" = yes ; then
1792     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1793 fi
1794 if test "$build_dirmngr" = yes ; then
1795     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1796 fi
1797 if test "$build_g13" = yes ; then
1798     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1799 fi
1800
1801
1802 #
1803 # Define Name strings
1804 #
1805 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1806
1807 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1808 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1809
1810 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1811 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1812
1813 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1814 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1815                                         [The displayed name of gpg-agent])
1816
1817 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1818 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1819                                        [The displayed name of scdaemon])
1820
1821 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1822 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1823                                       [The displayed name of dirmngr])
1824
1825 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1826 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1827
1828 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1829 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1830                                       [The displayed name of gpgconf])
1831
1832 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1833
1834 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1835                    [The name of the agent socket])
1836 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1837                    [The name of the agent socket for remote access])
1838 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1839                    [The name of the agent socket for browsers])
1840 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1841                    [The name of the agent socket for ssh])
1842 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1843                    [The name of the dirmngr info envvar])
1844 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1845                    [The name of the SCdaemon socket])
1846 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1847                    [The name of the dirmngr socket])
1848 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1849                    "hkps://hkps.pool.sks-keyservers.net",
1850       [The default keyserver for dirmngr to use, if none is explicitly given])
1851
1852 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1853
1854 if test "$have_w32_system" = yes; then
1855   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1856                      [The directory part of the W32 registry keys])
1857 fi
1858
1859
1860 #
1861 # Provide information about the build.
1862 #
1863 BUILD_REVISION="mym4_revision"
1864 AC_SUBST(BUILD_REVISION)
1865 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1866                    [GIT commit id revision used to build this package])
1867
1868 changequote(,)dnl
1869 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1870 changequote([,])dnl
1871 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1872 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1873 AC_SUBST(BUILD_VERSION)
1874 AC_SUBST(BUILD_FILEVERSION)
1875
1876 AC_ARG_ENABLE([build-timestamp],
1877   AC_HELP_STRING([--enable-build-timestamp],
1878                  [set an explicit build timestamp for reproducibility.
1879                   (default is the current time in ISO-8601 format)]),
1880      [if test "$enableval" = "yes"; then
1881         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1882       else
1883         BUILD_TIMESTAMP="$enableval"
1884       fi
1885       BUILD_HOSTNAME="$ac_hostname"],
1886      [BUILD_TIMESTAMP="<none>"
1887       BUILD_HOSTNAME="<anon>"])
1888 AC_SUBST(BUILD_TIMESTAMP)
1889 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1890                    [The time this package was configured for a build])
1891 AC_SUBST(BUILD_HOSTNAME)
1892
1893
1894 #
1895 # Print errors here so that they are visible all
1896 # together and the user can acquire them all together.
1897 #
1898 die=no
1899 if test "$have_gpg_error" = "no"; then
1900    die=yes
1901    AC_MSG_NOTICE([[
1902 ***
1903 *** You need libgpg-error to build this program.
1904 **  This library is for example available at
1905 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1906 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1907 ***]])
1908 fi
1909 if test "$have_libgcrypt" = "no"; then
1910    die=yes
1911    AC_MSG_NOTICE([[
1912 ***
1913 *** You need libgcrypt to build this program.
1914 **  This library is for example available at
1915 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1916 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1917 ***]])
1918 fi
1919 if test "$have_libassuan" = "no"; then
1920    die=yes
1921    AC_MSG_NOTICE([[
1922 ***
1923 *** You need libassuan to build this program.
1924 *** This library is for example available at
1925 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1926 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1927 ***]])
1928 fi
1929 if test "$have_ksba" = "no"; then
1930     die=yes
1931     AC_MSG_NOTICE([[
1932 ***
1933 *** You need libksba to build this program.
1934 *** This library is for example available at
1935 ***   https://gnupg.org/ftp/gcrypt/libksba/
1936 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1937 ***]])
1938 fi
1939 if test "$gnupg_have_ldap" = yes; then
1940   if test "$have_w32ce_system" = yes; then
1941     AC_MSG_NOTICE([[
1942 *** Note that CeGCC might be broken, a package fixing this is:
1943 ***    http://files.kolab.org/local/windows-ce/
1944 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1945 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1946 ***]])
1947    fi
1948 fi
1949 if test "$have_npth" = "no"; then
1950     die=yes
1951     AC_MSG_NOTICE([[
1952 ***
1953 *** It is now required to build with support for the
1954 *** New Portable Threads Library (nPth). Please install this
1955 *** library first.  The library is for example available at
1956 ***   https://gnupg.org/ftp/gcrypt/npth/
1957 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1958 ***]])
1959 fi
1960
1961 if test "$require_iconv" = yes; then
1962   if test "$am_func_iconv" != yes; then
1963     die=yes
1964     AC_MSG_NOTICE([[
1965 ***
1966 *** The system does not provide a working iconv function.  Please
1967 *** install a suitable library; for example GNU Libiconv which is
1968 *** available at:
1969 ***   https://ftp.gnu.org/gnu/libiconv/
1970 ***]])
1971   fi
1972 fi
1973
1974 if test "$use_ccid_driver" = yes; then
1975   if test "$have_libusb" != yes; then
1976     die=yes
1977     AC_MSG_NOTICE([[
1978 ***
1979 *** You need libusb to build the internal ccid driver.  Please
1980 *** install a libusb suitable for your system.
1981 ***]])
1982   fi
1983 fi
1984
1985 if test "$die" = "yes"; then
1986     AC_MSG_ERROR([[
1987 ***
1988 *** Required libraries not found. Please consult the above messages
1989 *** and install them before running configure again.
1990 ***]])
1991 fi
1992
1993
1994
1995 AC_CONFIG_FILES([ m4/Makefile
1996 Makefile
1997 po/Makefile.in
1998 common/Makefile
1999 common/w32info-rc.h
2000 kbx/Makefile
2001 g10/Makefile
2002 sm/Makefile
2003 agent/Makefile
2004 scd/Makefile
2005 g13/Makefile
2006 dirmngr/Makefile
2007 tools/gpg-zip
2008 tools/Makefile
2009 doc/Makefile
2010 tests/Makefile
2011 tests/gpgscm/Makefile
2012 tests/openpgp/Makefile
2013 tests/migrations/Makefile
2014 tests/gpgsm/Makefile
2015 tests/gpgme/Makefile
2016 tests/pkits/Makefile
2017 g10/gpg.w32-manifest
2018 ])
2019
2020
2021 AC_OUTPUT
2022
2023
2024 echo "
2025         GnuPG v${VERSION} has been configured as follows:
2026
2027         Revision:  mym4_revision  (mym4_revision_dec)
2028         Platform:  $PRINTABLE_OS_NAME ($host)
2029
2030         OpenPGP:   $build_gpg
2031         S/MIME:    $build_gpgsm
2032         Agent:     $build_agent
2033         Smartcard: $build_scdaemon $build_scdaemon_extra
2034         G13:       $build_g13
2035         Dirmngr:   $build_dirmngr
2036         Gpgtar:    $build_gpgtar
2037         WKS tools: $build_wks_tools
2038
2039         Protect tool:      $show_gnupg_protect_tool_pgm
2040         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2041         Default agent:     $show_gnupg_agent_pgm
2042         Default pinentry:  $show_gnupg_pinentry_pgm
2043         Default scdaemon:  $show_gnupg_scdaemon_pgm
2044         Default dirmngr:   $show_gnupg_dirmngr_pgm
2045
2046         Dirmngr auto start:  $dirmngr_auto_start
2047         Readline support:    $gnupg_cv_have_readline
2048         LDAP support:        $gnupg_have_ldap
2049         TLS support:         $use_tls_library
2050         TOFU support:        $use_tofu
2051         Tor support:         $show_tor_support
2052 "
2053 if test x"$use_regex" != xyes ; then
2054 echo "
2055         Warning: No regular expression support available.
2056                  OpenPGP trust signatures won't work.
2057                  gpg-check-pattern will not be built.
2058 "
2059 fi
2060 if test "x${gpg_config_script_warn}" != x; then
2061 cat <<G10EOF
2062         Warning: Mismatches between the target platform and the
2063                  to be used libraries have been detected for:
2064                   ${gpg_config_script_warn}
2065                  Please check above for more warning messages.
2066
2067 G10EOF
2068 fi