configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.3.5], [bugs@gnutls.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CANONICAL_HOST
  28
  29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
  30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  31 AC_CONFIG_HEADERS([config.h])
  32
  33 AC_MSG_RESULT([***
  34 *** Checking for compilation programs...
  35 ])
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 gl_EARLY
  40 ggl_EARLY
  41 AM_PROG_AS
  42 AM_PROG_AR
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AC_PROG_YACC
  46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
  47
  48 if test x"$AUTOGEN" = "x/bin/true"; then
  49   AC_MSG_WARN([[
  50 ***
  51 *** autogen not found. Will not link against libopts.
  52 *** ]])
  53 enable_local_libopts=yes
  54 fi
  55
  56 # For includes/gnutls/gnutls.h.in.
  57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  59 AC_SUBST(PATCH_VERSION, [[`echo $PACKAGE_VERSION | sed 's/.*\..*\.\([0-9]*\).*/\1/g'`]])
  60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  61
  62 touch suppressions.valgrind
  63 dnl C and C++ capabilities
  64 AC_C_INLINE
  65 AC_HEADER_STDC
  66
  67 # For the C++ code
  68 AC_ARG_ENABLE(cxx,
  69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  70     use_cxx=$enableval, use_cxx=yes)
  71 if test "$use_cxx" != "no"; then
  72   AC_LANG_PUSH(C++)
  73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  74   AC_LANG_POP(C++)
  75 fi
  76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  78
  79 dnl Detect windows build
  80 case "$host" in
  81   *mingw32* | *mingw64*)
  82     have_win=yes
  83   ;;
  84   *darwin*)
  85     have_macosx=yes
  86   ;;
  87   *)
  88     have_elf=yes
  89   ;;
  90 esac
  91
  92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
  94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
  95
  96 dnl Hardware Acceleration
  97 AC_ARG_ENABLE(hardware-acceleration,
  98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  99     use_accel=$enableval, use_accel=yes)
 100 hw_accel=none
 101
 102
 103 if test "$use_accel" != "no"; then
 104 case $host_cpu in
 105   i?86 | x86_64 | amd64)
 106       AC_CHECK_HEADERS(cpuid.h)
 107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
 108         hw_accel="x86-64"
 109       else
 110         hw_accel="x86"
 111       fi
 112   ;;
 113   *)
 114   ;;
 115 esac
 116
 117 fi
 118
 119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 124
 125
 126 dnl Try the hooks.m4
 127 LIBGNUTLS_HOOKS
 128 LIBGNUTLS_EXTRA_HOOKS
 129
 130 AC_ARG_ENABLE(doc,
 131   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
 132     enable_doc=$enableval, enable_doc=yes)
 133 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
 134
 135 AC_ARG_ENABLE(tests,
 136   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
 137     enable_tests=$enableval, enable_tests=yes)
 138 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 139
 140 GTK_DOC_CHECK(1.1)
 141 AM_GNU_GETTEXT([external])
 142 AM_GNU_GETTEXT_VERSION([0.18])
 143
 144 AC_C_BIGENDIAN
 145
 146 dnl No fork on MinGW, disable some self-tests until we fix them.
 147 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
 148 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime iconv localtime vasprintf],,)
 149 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 150
 151 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
 152 #include <signal.h>
 153 ], [timer_create (0,0,0);])
 154
 155 if test "$have_win" != "yes";then
 156   AC_CHECK_FUNCS([pthread_mutex_lock],,)
 157   if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
 158     AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 159   fi
 160 fi
 161
 162 if test "$ac_cv_func_nanosleep" != "yes";then
 163   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
 164   gnutls_needs_librt=yes
 165 fi
 166
 167 if test "$ac_cv_func_clock_gettime" != "yes";then
 168   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
 169   gnutls_needs_librt=yes
 170 fi
 171
 172 ac_have_unicode=no
 173 if test "$ac_cv_func_iconv" != "yes";then
 174   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
 175   if test "$HAVE_LIBICONV" = "yes";then
 176     ac_have_unicode=yes
 177   fi
 178 else
 179   ac_have_unicode=yes
 180 fi
 181
 182 if test "$ac_have_unicode" != "yes";then
 183   if test "$have_win" = "yes";then
 184     ac_have_unicode=yes
 185   fi
 186 fi
 187
 188 dnl Note that g*l_INIT are run after we check for library capabilities,
 189 dnl to prevent issues from caching lib dependencies. See discussion
 190 dnl in https://bugs.gentoo.org/show_bug.cgi?id=494940 and
 191 dnl http://gnu-autoconf.7623.n7.nabble.com/Correct-way-to-check-for-clock-gettime-td12276.html
 192 gl_INIT
 193 ggl_INIT
 194
 195 dnl GCC warnings to enable
 196
 197 AC_ARG_ENABLE([gcc-warnings],
 198   [AS_HELP_STRING([--enable-gcc-warnings],
 199                   [turn on lots of GCC warnings (for developers)])],
 200   [case $enableval in
 201      yes|no) ;;
 202      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 203    esac
 204    gl_gcc_warnings=$enableval],
 205   [gl_gcc_warnings=no]
 206 )
 207
 208 if test "$gl_gcc_warnings" = yes; then
 209   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
 210
 211   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 212   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 213   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 214   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 215   nw="$nw -Wlogical-op"             # Too many false positives
 216   nw="$nw -Wold-style-definition"   #
 217   nw="$nw -Wpadded"                 # Our structs are not padded
 218   nw="$nw -Wunreachable-code"       # Too many false positives
 219   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 220   nw="$nw -Wcast-qual"              # Too many warnings for now
 221   nw="$nw -Waggregate-return"       # Too many warnings for now
 222   nw="$nw -Wshadow"                 # Too many warnings for now
 223   nw="$nw -Wswitch-default"         # Too many warnings for now
 224   nw="$nw -Wswitch-enum"            # Too many warnings for now
 225   nw="$nw -Wconversion"             # Too many warnings for now
 226   nw="$nw -Wsign-conversion"        # Too many warnings for now
 227   nw="$nw -Wformat-y2k"             # Too many warnings for now
 228   nw="$nw -Woverlength-strings"     # We use some in tests/
 229   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 230   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 231   nw="$nw -Wunsafe-loop-optimizations"
 232   nw="$nw -Wstrict-overflow"
 233   nw="$nw -Wmissing-noreturn"
 234   nw="$nw -Winline"                 # Too compiler dependent
 235   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
 236   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
 237   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
 238   nw="$nw -Wstack-protector"        # Some functions cannot be protected
 239   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
 240
 241   gl_MANYWARN_ALL_GCC([ws])
 242   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 243   for w in $ws; do
 244     gl_WARN_ADD([$w])
 245   done
 246
 247   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 248   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 249   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 250   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 251   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 252   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 253   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 254   gl_WARN_ADD([-fdiagnostics-show-option])
 255 fi
 256
 257 AC_SUBST([WERROR_CFLAGS])
 258 AC_SUBST([WSTACK_CFLAGS])
 259 AC_SUBST([WARN_CFLAGS])
 260
 261 dnl Programs for compilation or development
 262 AC_PROG_LN_S
 263 LT_INIT([disable-static,win32-dll,shared])
 264
 265
 266
 267 AC_ARG_ENABLE(self-checks,
 268   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
 269     enable_self_checks=$enableval, enable_self_checks=no)
 270
 271 AC_ARG_ENABLE(fips140-mode,
 272   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
 273     enable_fips=$enableval, enable_fips=no)
 274 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
 275 if [ test "$enable_fips" = "yes" ];then
 276   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
 277   if test "x$HAVE_LIBDL" = "xyes";then
 278     enable_self_checks=yes
 279
 280     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
 281
 282     AC_SUBST([FIPS140_LIBS], $LIBDL)
 283   else
 284     enable_fips=no
 285     AC_MSG_WARN([[
 286 ***
 287 *** This system is not supported in FIPS140 mode.
 288 *** libdl and dladdr() are required.
 289 *** ]])
 290   fi
 291 fi
 292
 293 AC_ARG_ENABLE(non-suiteb-curves,
 294   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
 295     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
 296 if [ test "$enable_non_suiteb" = "yes" ];then
 297   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
 298 fi
 299
 300 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
 301 if [ test "$enable_self_checks" = "yes" ];then
 302    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
 303 fi
 304
 305 AC_MSG_CHECKING([whether to build libdane])
 306 AC_ARG_ENABLE(libdane,
 307     AS_HELP_STRING([--disable-libdane],
 308                    [disable the built of libdane]),
 309     enable_dane=$enableval, enable_dane=yes)
 310 AC_MSG_RESULT($enable_dane)
 311
 312 if test "$enable_dane" != "no"; then
 313     LIBS="$oldlibs -lunbound"
 314     AC_MSG_CHECKING([for unbound library])
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM([
 316                    #include <unbound.h>],[
 317                    struct ub_ctx* ctx;
 318                    ctx = ub_ctx_create();])],
 319                   [AC_MSG_RESULT(yes)
 320                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
 321                    AC_SUBST([UNBOUND_CFLAGS], [])
 322                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
 323                    enable_dane=yes],
 324                   [AC_MSG_RESULT(no)
 325                    AC_MSG_WARN([[
 326 ***
 327 *** libunbound was not found. Libdane will not be built.
 328 *** ]])
 329                   enable_dane=no])
 330     LIBS="$oldlibs"
 331 fi
 332
 333 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
 334
 335 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
 336                                  [specify the unbound root key file]),
 337             unbound_root_key_file="$withval",
 338 if test "$have_win" = yes; then
 339     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
 340 else
 341     if test -f /var/lib/unbound/root.key;then
 342         unbound_root_key_file="/var/lib/unbound/root.key"
 343     else
 344         unbound_root_key_file="/etc/unbound/root.key"
 345     fi
 346 fi
 347 )
 348
 349 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
 350   ["$unbound_root_key_file"], [The DNSSEC root key file])
 351
 352 AC_ARG_WITH(system-priority-file, AS_HELP_STRING([--with-system-priority-file],
 353                                  [specify the system priority file]),
 354             system_priority_file="$withval",
 355 system_priority_file="/etc/gnutls/default-priorities"
 356 )
 357
 358 AC_DEFINE_UNQUOTED([SYSTEM_PRIORITY_FILE],
 359   ["$system_priority_file"], [The system priority file])
 360
 361 dnl Check for p11-kit
 362 P11_KIT_MINIMUM=0.20.0
 363 AC_ARG_WITH(p11-kit,
 364         AS_HELP_STRING([--without-p11-kit],
 365                 [Build without p11-kit and PKCS#11 support]))
 366 if test "$with_p11_kit" != "no"; then
 367         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
 368         if test "$with_p11_kit" != "no";then
 369                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 370                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 371                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 372                 else
 373                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 374                 fi
 375         else
 376                 with_p11_kit=no
 377                 AC_MSG_WARN([[
 378 ***
 379 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
 380 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 381 *** ]])
 382         fi
 383 fi
 384
 385 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 386
 387 AC_ARG_WITH(tpm,
 388         AS_HELP_STRING([--without-tpm],
 389                 [Disable TPM (trousers) support.]),
 390                 [with_tpm=$withval], [with_tpm=yes])
 391 if test "$with_tpm" != "no"; then
 392     LIBS="$oldlibs -ltspi"
 393     AC_MSG_CHECKING([for tss library])
 394     AC_LINK_IFELSE([AC_LANG_PROGRAM([
 395                    #include <trousers/tss.h>
 396                    #include <trousers/trousers.h>],[
 397                    int err = Tspi_Context_Create((void *)0);
 398                    Trspi_Error_String(err);])],
 399                   [AC_MSG_RESULT(yes)
 400                    AC_SUBST([TSS_LIBS], [-ltspi])
 401                    AC_SUBST([TSS_CFLAGS], [])
 402                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
 403                    with_tpm=yes],
 404                   [AC_MSG_RESULT(no)
 405                    AC_MSG_WARN([[
 406 ***
 407 *** trousers was not found. TPM support will be disabled.
 408 *** ]])
 409                   with_tpm=no])
 410     LIBS="$oldlibs"
 411 fi
 412
 413 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
 414
 415 LIBOPTS_CHECK([src/libopts])
 416 if test "$NEED_LIBOPTS_DIR" = "true";then
 417         dnl replace libopts-generated files with distributed backups, if present
 418         missing_baks=
 419         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
 420                 nam=`echo $i|sed 's/.bak//g'`
 421                 if test -f $i;then
 422                         cp -f $i $nam
 423                 else
 424                         missing_baks=true
 425                 fi
 426         done
 427         if test -z "$missing_baks"; then
 428                 AC_SUBST([AUTOGEN], [/bin/true])
 429         fi
 430         enable_local_libopts=yes
 431 else
 432         enable_local_libopts=no
 433 fi
 434 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
 435
 436 AC_CHECK_TYPE(ssize_t,
 437   [
 438     DEFINE_SSIZE_T="#include <sys/types.h>"
 439     AC_SUBST(DEFINE_SSIZE_T)
 440   ], [
 441     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 442     DEFINE_SSIZE_T="typedef int ssize_t;"
 443     AC_SUBST(DEFINE_SSIZE_T)
 444   ], [
 445     #include <sys/types.h>
 446   ])
 447
 448 # For minitasn1.
 449 AC_CHECK_SIZEOF(unsigned long int, 4)
 450 AC_CHECK_SIZEOF(unsigned int, 4)
 451
 452 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 453                                  [disable zlib compression support]),
 454             ac_zlib=$withval, ac_zlib=yes)
 455 AC_MSG_CHECKING([whether to include zlib compression support])
 456 if test x$ac_zlib != xno; then
 457  AC_MSG_RESULT(yes)
 458  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 459  if test x$ac_cv_libz != xyes; then
 460    AC_MSG_WARN(
 461 ***
 462 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 463  fi
 464 else
 465  AC_MSG_RESULT(no)
 466 fi
 467
 468 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 469
 470 if test x$ac_zlib != xno; then
 471   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 472     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 473       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 474     else
 475       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 476     fi
 477   fi
 478 fi
 479 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 480
 481
 482
 483 AC_ARG_WITH([default-trust-store-pkcs11],
 484   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
 485     [use the given pkcs11 uri as default trust store])])
 486
 487 if test "x$with_default_trust_store_pkcs11" != x; then
 488   if test "x$with_p11_kit" = xno; then
 489     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
 490   fi
 491   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
 492     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
 493 fi
 494
 495 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
 496 AC_ARG_WITH([default-trust-store-file],
 497   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
 498     [use the given file default trust store])], with_default_trust_store_file="$withval",
 499   [if test "$build" = "$host" && test x$with_default_trust_store_pkcs11 = x;then
 500   for i in \
 501     /etc/ssl/ca-bundle.pem \
 502     /etc/ssl/certs/ca-certificates.crt \
 503     /etc/pki/tls/cert.pem \
 504     /usr/local/share/certs/ca-root-nss.crt \
 505     /etc/ssl/cert.pem
 506     do
 507     if test -e "$i"; then
 508       with_default_trust_store_file="$i"
 509       break
 510     fi
 511   done
 512   fi]
 513 )
 514
 515 if test "$with_default_trust_store_file" = "no";then
 516   with_default_trust_store_file=""
 517 fi
 518
 519 AC_ARG_WITH([default-crl-file],
 520   [AS_HELP_STRING([--with-default-crl-file=FILE],
 521     [use the given CRL file as default])])
 522
 523 AC_ARG_WITH([default-blacklist-file],
 524   [AS_HELP_STRING([--with-default-blacklist-file=FILE],
 525     [use the given certificate blacklist file as default])])
 526
 527 if test "x$with_default_trust_store_file" != x; then
 528   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
 529     ["$with_default_trust_store_file"], [use the given file default trust store])
 530 fi
 531
 532 if test "x$with_default_crl_file" != x; then
 533   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
 534     ["$with_default_crl_file"], [use the given CRL file])
 535 fi
 536
 537 if test "x$with_default_blacklist_file" != x; then
 538   AC_DEFINE_UNQUOTED([DEFAULT_BLACKLIST_FILE],
 539     ["$with_default_blacklist_file"], [use the given certificate blacklist file])
 540 fi
 541
 542 dnl Guile bindings.
 543 opt_guile_bindings=yes
 544 AC_MSG_CHECKING([whether building Guile bindings])
 545 AC_ARG_ENABLE(guile,
 546         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 547 opt_guile_bindings=$enableval)
 548 AC_MSG_RESULT($opt_guile_bindings)
 549
 550 AC_ARG_WITH([guile-site-dir],
 551   [AS_HELP_STRING([--with-guile-site-dir],
 552      [use the given directory as the Guile site (use with care)])])
 553
 554 if test "$opt_guile_bindings" = "yes"; then
 555    AC_MSG_RESULT([***
 556 *** Detecting GNU Guile...
 557 ])
 558
 559    AC_PATH_PROG([guile_snarf], [guile-snarf])
 560    if test "x$guile_snarf" = "x"; then
 561       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 562       opt_guile_bindings=no
 563    else
 564       GUILE_PROGS
 565       GUILE_FLAGS
 566
 567       save_CFLAGS="$CFLAGS"
 568       save_LIBS="$LIBS"
 569       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 570       LIBS="$LIBS $GUILE_LDFLAGS"
 571       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 572       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
 573         [], [opt_guile_bindings=no])
 574       CFLAGS="$save_CFLAGS"
 575       LIBS="$save_LIBS"
 576
 577       if test "$opt_guile_bindings" = "yes"; then
 578         AC_MSG_RESULT([yes])
 579         case "x$with_guile_site_dir" in
 580              xno)
 581                 # Use the default $(GUILE_SITE).
 582                 GUILE_SITE_DIR
 583                 ;;
 584              x|xyes)
 585                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 586                 # hack is used to allow `distcheck' to work (see
 587                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 588                 GUILE_SITE="\$(datadir)/guile/site"
 589                 AC_SUBST(GUILE_SITE)
 590                 ;;
 591              *)
 592                 # Use the user-specified directory as $(GUILE_SITE).
 593                 GUILE_SITE="$with_guile_site_dir"
 594                 AC_SUBST(GUILE_SITE)
 595                 ;;
 596         esac
 597         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 598         _gcc_cflags_save="$CFLAGS"
 599         CFLAGS="${CFLAGS} -fgnu89-inline"
 600         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 601                           gnu89_inline=yes, gnu89_inline=no)
 602         AC_MSG_RESULT($gnu89_inline)
 603         CFLAGS="$_gcc_cflags_save"
 604
 605         # Optional Guile functions.
 606         save_CFLAGS="$CFLAGS"
 607         save_LIBS="$LIBS"
 608         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 609         LIBS="$LIBS $GUILE_LDFLAGS"
 610         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 611         CFLAGS="$save_CFLAGS"
 612         LIBS="$save_LIBS"
 613
 614         # The place where guile-gnutls.la will go.
 615         AC_MSG_CHECKING([the Guile effective version])
 616         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 617         AC_MSG_RESULT([$guile_effective_version])
 618         guileextensiondir="$libdir/guile/$guile_effective_version"
 619         AC_SUBST([guileextensiondir])
 620       else
 621         AC_MSG_RESULT([no])
 622         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 623         opt_guile_bindings=no
 624       fi
 625    fi
 626 fi
 627 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 628
 629 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 630 LIBGNUTLS_CFLAGS="-I${includedir}"
 631 AC_SUBST(LIBGNUTLS_LIBS)
 632 AC_SUBST(LIBGNUTLS_CFLAGS)
 633
 634 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
 635
 636 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 637 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 638
 639 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 640 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 641 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 642
 643 dnl Crywrap dependencies
 644    AC_MSG_RESULT([***
 645 *** Checking dependencies for crywrap...
 646 ])
 647
 648 crywrap=no
 649
 650 if test "$have_win" != "yes"; then
 651
 652 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 653
 654 dnl **********************
 655 dnl * Typedefs & co
 656 dnl **********************
 657 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 658 [AC_LANG_PROGRAM([#include <sys/types.h>
 659 #include <signal.h>
 660 ],
 661                  [return *(signal (0, 0)) (0) == 1;])],
 662                    [ac_cv_type_signal=int],
 663                    [ac_cv_type_signal=void])])
 664 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 665                     (`int' or `void').])
 666
 667 AC_FUNC_SELECT_ARGTYPES
 668 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 669                 putenv regcomp scandir select socket strcasecmp strchr \
 670                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 671
 672 AC_ARG_ENABLE(crywrap,
 673         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
 674
 675  libidn=no
 676
 677  if test "x$enable_crywrap" != "xno" ; then
 678         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 679         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
 680  fi
 681
 682  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
 683   crywrap=yes
 684  fi
 685
 686 fi
 687
 688 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 689
 690 dnl end of crywrap requirements
 691
 692 dnl Some variables needed in makefiles
 693 YEAR=`date +%Y`
 694 AC_SUBST([YEAR], $YEAR)
 695
 696 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 697 AC_CONFIG_FILES([
 698   Makefile
 699   doc/Makefile
 700   doc/credentials/Makefile
 701   doc/credentials/openpgp/Makefile
 702   doc/credentials/srp/Makefile
 703   doc/credentials/x509/Makefile
 704   doc/cyclo/Makefile
 705   doc/doxygen/Doxyfile
 706   doc/examples/Makefile
 707   doc/latex/Makefile
 708   doc/manpages/Makefile
 709   doc/reference/Makefile
 710   doc/reference/version.xml
 711   doc/scripts/Makefile
 712   extra/Makefile
 713   extra/includes/Makefile
 714   libdane/Makefile
 715   libdane/includes/Makefile
 716   libdane/gnutls-dane.pc
 717   gl/Makefile
 718   gl/tests/Makefile
 719   guile/Makefile
 720   guile/modules/Makefile
 721   guile/src/Makefile
 722   guile/tests/Makefile
 723   lib/Makefile
 724   lib/accelerated/Makefile
 725   lib/accelerated/x86/Makefile
 726   lib/algorithms/Makefile
 727   lib/auth/Makefile
 728   lib/ext/Makefile
 729   lib/extras/Makefile
 730   lib/gnutls.pc
 731   lib/includes/Makefile
 732   lib/includes/gnutls/gnutls.h
 733   lib/minitasn1/Makefile
 734   lib/nettle/Makefile
 735   lib/opencdk/Makefile
 736   lib/openpgp/Makefile
 737   lib/x509/Makefile
 738   po/Makefile.in
 739   src/Makefile
 740   src/crywrap/Makefile
 741   src/gl/Makefile
 742   tests/Makefile
 743   tests/cert-tests/Makefile
 744   tests/dsa/Makefile
 745   tests/dtls/Makefile
 746   tests/srp/Makefile
 747   tests/ecdsa/Makefile
 748   tests/key-tests/Makefile
 749   tests/openpgp-certs/Makefile
 750   tests/pkcs1-padding/Makefile
 751   tests/pkcs12-decode/Makefile
 752   tests/pkcs8-decode/Makefile
 753   tests/rsa-md5-collision/Makefile
 754   tests/safe-renegotiation/Makefile
 755   tests/scripts/Makefile
 756   tests/sha2/Makefile
 757   tests/slow/Makefile
 758   tests/suite/Makefile
 759   tests/userid/Makefile
 760 ])
 761
 762 AC_OUTPUT
 763
 764 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 765 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
 766 AC_MSG_NOTICE([summary of build options:
 767
 768   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 769   Host/Target system:   ${host}
 770   Build system:         ${build}
 771   Install prefix:       ${prefix}
 772   Compiler:             ${CC}
 773   CFlags:               ${CFLAGS}
 774   Library types:        Shared=${enable_shared}, Static=${enable_static}
 775   Local libopts:        ${enable_local_libopts}
 776   Local libtasn1:       ${included_libtasn1}
 777   Use nettle-mini:      ${mini_nettle}
 778 ])
 779
 780 AC_MSG_NOTICE([External hardware support:
 781
 782   /dev/crypto:          $enable_cryptodev
 783   Hardware accel:       $hw_accel
 784   PKCS#11 support:      $with_p11_kit
 785   TPM support:          $with_tpm
 786 ])
 787
 788 AC_MSG_NOTICE([Optional features:
 789 (note that included applications might not compile properly
 790 if features are disabled)
 791
 792   DTLS-SRTP support:    $ac_enable_srtp
 793   ALPN support:         $ac_enable_alpn
 794   OCSP support:         $ac_enable_ocsp
 795   Ses. ticket support:  $ac_enable_session_tickets
 796   OpenPGP support:      $ac_enable_openpgp
 797   SRP support:          $ac_enable_srp
 798   PSK support:          $ac_enable_psk
 799   DHE support:          $ac_enable_dhe
 800   ECDHE support:        $ac_enable_ecdhe
 801   RSA-EXPORT support:   $ac_enable_rsa_export
 802   Anon auth support:    $ac_enable_anon
 803   Heartbeat support:    $ac_enable_heartbeat
 804   Unicode support:      $ac_have_unicode
 805   Self checks:          $enable_self_checks
 806   Non-SuiteB curves:    $enable_non_suiteb
 807   FIPS140 mode:         $enable_fips
 808 ])
 809
 810 AC_MSG_NOTICE([Optional applications:
 811
 812   crywrap app:          $libidn
 813 ])
 814
 815 AC_MSG_NOTICE([Optional libraries:
 816
 817   Guile wrappers:       $opt_guile_bindings
 818   C++ library:          $use_cxx
 819   DANE library:         $enable_dane
 820   OpenSSL compat:       $enable_openssl
 821 ])
 822
 823 AC_MSG_NOTICE([System files:
 824
 825   Trust store pkcs11:   $with_default_trust_store_pkcs11
 826   Trust store file:     $with_default_trust_store_file
 827   Blacklist file:       $with_default_blacklist_file
 828   CRL file:             $with_default_crl_file
 829   Priority file:        $system_priority_file
 830   DNSSEC root key file: $unbound_root_key_file
 831 ])
 832
 833 if test ! -f "$unbound_root_key_file"; then
 834 AC_MSG_WARN([[
 835 ***
 836 *** The DNSSEC root key file in $unbound_root_key_file was not found.
 837 *** This file is needed for the verification of DNSSEC responses.
 838 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
 839 *** to generate or update it.
 840 *** ]])
 841 fi