m4macros/gsettings.m4

   1 dnl GLIB_GSETTINGS
   2 dnl Defines GSETTINGS_SCHEMAS_INSTALL which controls whether
   3 dnl the schema should be compiled
   4 dnl
   5
   6 AC_DEFUN([GLIB_GSETTINGS],
   7 [
   8   m4_pattern_allow([AM_V_GEN])
   9   AC_ARG_ENABLE(schemas-compile,
  10                 AC_HELP_STRING([--disable-schemas-compile],
  11                                [Disable regeneration of gschemas.compiled on install]),
  12                 [case ${enableval} in
  13                   yes) GSETTINGS_DISABLE_SCHEMAS_COMPILE=""  ;;
  14                   no)  GSETTINGS_DISABLE_SCHEMAS_COMPILE="1" ;;
  15                   *) AC_MSG_ERROR([bad value ${enableval} for --enable-schemas-compile]) ;;
  16                  esac])
  17   AC_SUBST([GSETTINGS_DISABLE_SCHEMAS_COMPILE])
  18   PKG_PROG_PKG_CONFIG([0.16])
  19   AC_SUBST(gsettingsschemadir, [${datadir}/glib-2.0/schemas])
  20   if test x$cross_compiling != xyes; then
  21     GLIB_COMPILE_SCHEMAS=`$PKG_CONFIG --variable glib_compile_schemas gio-2.0`
  22   else
  23     AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas)
  24   fi
  25   AC_SUBST(GLIB_COMPILE_SCHEMAS)
  26   if test "x$GLIB_COMPILE_SCHEMAS" = "x"; then
  27     ifelse([$2],,[AC_MSG_ERROR([glib-compile-schemas not found.])],[$2])
  28   else
  29     ifelse([$1],,[:],[$1])
  30   fi
  31
  32   GSETTINGS_RULES='
  33 .PHONY : uninstall-gsettings-schemas install-gsettings-schemas clean-gsettings-schemas
  34
  35 mostlyclean-am: clean-gsettings-schemas
  36
  37 %.gschema.valid: %.gschema.xml
  38         $(AM_V_GEN) if test -f "$^"; then d=; else d="$(srcdir)/"; fi; $(GLIB_COMPILE_SCHEMAS) --dry-run --schema-file=$${d}$^ && touch [$]@
  39
  40 all-am: $(gsettings_SCHEMAS:.xml=.valid)
  41 uninstall-am: uninstall-gsettings-schemas
  42 install-data-am: install-gsettings-schemas
  43
  44 .SECONDARY: $(gsettings_SCHEMAS)
  45
  46 gsettings__base_list = \
  47   sed "$$!N;$$!N;$$!N;$$!N;$$!N;$$!N;$$!N;s/\n/ /g" | \
  48   sed "$$!N;$$!N;$$!N;$$!N;s/\n/ /g"
  49
  50 install-gsettings-schemas: $(gsettings_SCHEMAS:.xml=.valid)
  51         @$(NORMAL_INSTALL)
  52         test -z "$(gsettingsschemadir)" || $(MKDIR_P) "$(DESTDIR)$(gsettingsschemadir)"
  53         @list='\''$(gsettings_SCHEMAS)'\''; test -n "$(gsettingsschemadir)" || list=; \
  54         for p in $$list; do \
  55           if test -f "$$p"; then d=; else d="$(srcdir)/"; fi; \
  56           echo "$$d$$p"; \
  57         done | $(gsettings__base_list) | \
  58         while read files; do \
  59           echo " $(INSTALL_DATA) $$files '\''$(DESTDIR)$(gsettingsschemadir)'\''"; \
  60           $(INSTALL_DATA) $$files "$(DESTDIR)$(gsettingsschemadir)" || exit $$?; \
  61         done
  62         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) $(gsettingsschemadir)
  63
  64 uninstall-gsettings-schemas:
  65         @$(NORMAL_UNINSTALL)
  66         @list='\''$(gsettings_SCHEMAS)'\''; test -n "$(gsettingsschemadir)" || list=; \
  67         files=`for p in $$list; do echo $$p; done | sed -e '\''s|^.*/||'\''`; \
  68         test -n "$$files" || exit 0; \
  69         echo " ( cd '\''$(DESTDIR)$(gsettingsschemadir)'\'' && rm -f" $$files ")"; \
  70         cd "$(DESTDIR)$(gsettingsschemadir)" && rm -f $$files
  71         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) --uninstall $(gsettingsschemadir)
  72
  73 clean-gsettings-schemas:
  74         rm -f $(gsettings_SCHEMAS:.xml=.valid)
  75
  76 '
  77   _GSETTINGS_SUBST(GSETTINGS_RULES)
  78 ])
  79
  80 dnl _GSETTINGS_SUBST(VARIABLE)
  81 dnl Abstract macro to do either _AM_SUBST_NOTMAKE or AC_SUBST
  82 AC_DEFUN([_GSETTINGS_SUBST],
  83 [
  84 AC_SUBST([$1])
  85 m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([$1])])
  86 ]
  87 )